arch/x86/kernel/entry_64.S

   1 /*
   2  *  linux/arch/x86_64/entry.S
   3  *
   4  *  Copyright (C) 1991, 1992  Linus Torvalds
   5  *  Copyright (C) 2000, 2001, 2002  Andi Kleen SuSE Labs
   6  *  Copyright (C) 2000  Pavel Machek <pavel@suse.cz>
   7  */
   8
   9 /*
  10  * entry.S contains the system-call and fault low-level handling routines.
  11  *
  12  * NOTE: This code handles signal-recognition, which happens every time
  13  * after an interrupt and after each system call.
  14  *
  15  * Normal syscalls and interrupts don't save a full stack frame, this is
  16  * only done for syscall tracing, signals or fork/exec et.al.
  17  *
  18  * A note on terminology:
  19  * - top of stack: Architecture defined interrupt frame from SS to RIP
  20  * at the top of the kernel process stack.
  21  * - partial stack frame: partially saved registers upto R11.
  22  * - full stack frame: Like partial stack frame, but all register saved.
  23  *
  24  * Some macro usage:
  25  * - CFI macros are used to generate dwarf2 unwind information for better
  26  * backtraces. They don't change any code.
  27  * - SAVE_ALL/RESTORE_ALL - Save/restore all registers
  28  * - SAVE_ARGS/RESTORE_ARGS - Save/restore registers that C functions modify.
  29  * There are unfortunately lots of special cases where some registers
  30  * not touched. The macro is a big mess that should be cleaned up.
  31  * - SAVE_REST/RESTORE_REST - Handle the registers not saved by SAVE_ARGS.
  32  * Gives a full stack frame.
  33  * - ENTRY/END Define functions in the symbol table.
  34  * - FIXUP_TOP_OF_STACK/RESTORE_TOP_OF_STACK - Fix up the hardware stack
  35  * frame that is otherwise undefined after a SYSCALL
  36  * - TRACE_IRQ_* - Trace hard interrupt state for lock debugging.
  37  * - errorentry/paranoidentry/zeroentry - Define exception entry points.
  38  */
  39
  40 #include <linux/linkage.h>
  41 #include <asm/segment.h>
  42 #include <asm/cache.h>
  43 #include <asm/errno.h>
  44 #include <asm/dwarf2.h>
  45 #include <asm/calling.h>
  46 #include <asm/asm-offsets.h>
  47 #include <asm/msr.h>
  48 #include <asm/unistd.h>
  49 #include <asm/thread_info.h>
  50 #include <asm/hw_irq.h>
  51 #include <asm/page_types.h>
  52 #include <asm/irqflags.h>
  53 #include <asm/paravirt.h>
  54 #include <asm/ftrace.h>
  55 #include <asm/percpu.h>
  56
  57 /* Avoid __ASSEMBLER__'ifying <linux/audit.h> just for this.  */
  58 #include <linux/elf-em.h>
  59 #define AUDIT_ARCH_X86_64       (EM_X86_64|__AUDIT_ARCH_64BIT|__AUDIT_ARCH_LE)
  60 #define __AUDIT_ARCH_64BIT 0x80000000
  61 #define __AUDIT_ARCH_LE    0x40000000
  62
  63         .code64
  64 #ifdef CONFIG_FUNCTION_TRACER
  65 #ifdef CONFIG_DYNAMIC_FTRACE
  66 ENTRY(mcount)
  67         retq
  68 END(mcount)
  69
  70 ENTRY(ftrace_caller)
  71         cmpl $0, function_trace_stop
  72         jne  ftrace_stub
  73
  74         MCOUNT_SAVE_FRAME
  75
  76         movq 0x38(%rsp), %rdi
  77         movq 8(%rbp), %rsi
  78         subq $MCOUNT_INSN_SIZE, %rdi
  79
  80 GLOBAL(ftrace_call)
  81         call ftrace_stub
  82
  83         MCOUNT_RESTORE_FRAME
  84
  85 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
  86 GLOBAL(ftrace_graph_call)
  87         jmp ftrace_stub
  88 #endif
  89
  90 GLOBAL(ftrace_stub)
  91         retq
  92 END(ftrace_caller)
  93
  94 #else /* ! CONFIG_DYNAMIC_FTRACE */
  95 ENTRY(mcount)
  96         cmpl $0, function_trace_stop
  97         jne  ftrace_stub
  98
  99         cmpq $ftrace_stub, ftrace_trace_function
 100         jnz trace
 101
 102 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 103         cmpq $ftrace_stub, ftrace_graph_return
 104         jnz ftrace_graph_caller
 105
 106         cmpq $ftrace_graph_entry_stub, ftrace_graph_entry
 107         jnz ftrace_graph_caller
 108 #endif
 109
 110 GLOBAL(ftrace_stub)
 111         retq
 112
 113 trace:
 114         MCOUNT_SAVE_FRAME
 115
 116         movq 0x38(%rsp), %rdi
 117         movq 8(%rbp), %rsi
 118         subq $MCOUNT_INSN_SIZE, %rdi
 119
 120         call   *ftrace_trace_function
 121
 122         MCOUNT_RESTORE_FRAME
 123
 124         jmp ftrace_stub
 125 END(mcount)
 126 #endif /* CONFIG_DYNAMIC_FTRACE */
 127 #endif /* CONFIG_FUNCTION_TRACER */
 128
 129 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 130 ENTRY(ftrace_graph_caller)
 131         cmpl $0, function_trace_stop
 132         jne ftrace_stub
 133
 134         MCOUNT_SAVE_FRAME
 135
 136         leaq 8(%rbp), %rdi
 137         movq 0x38(%rsp), %rsi
 138         movq (%rbp), %rdx
 139         subq $MCOUNT_INSN_SIZE, %rsi
 140
 141         call    prepare_ftrace_return
 142
 143         MCOUNT_RESTORE_FRAME
 144
 145         retq
 146 END(ftrace_graph_caller)
 147
 148 GLOBAL(return_to_handler)
 149         subq  $24, %rsp
 150
 151         /* Save the return values */
 152         movq %rax, (%rsp)
 153         movq %rdx, 8(%rsp)
 154         movq %rbp, %rdi
 155
 156         call ftrace_return_to_handler
 157
 158         movq %rax, 16(%rsp)
 159         movq 8(%rsp), %rdx
 160         movq (%rsp), %rax
 161         addq $16, %rsp
 162         retq
 163 #endif
 164
 165
 166 #ifndef CONFIG_PREEMPT
 167 #define retint_kernel retint_restore_args
 168 #endif
 169
 170 #ifdef CONFIG_PARAVIRT
 171 ENTRY(native_usergs_sysret64)
 172         swapgs
 173         sysretq
 174 ENDPROC(native_usergs_sysret64)
 175 #endif /* CONFIG_PARAVIRT */
 176
 177
 178 .macro TRACE_IRQS_IRETQ offset=ARGOFFSET
 179 #ifdef CONFIG_TRACE_IRQFLAGS
 180         bt   $9,EFLAGS-\offset(%rsp)    /* interrupts off? */
 181         jnc  1f
 182         TRACE_IRQS_ON
 183 1:
 184 #endif
 185 .endm
 186
 187 /*
 188  * C code is not supposed to know about undefined top of stack. Every time
 189  * a C function with an pt_regs argument is called from the SYSCALL based
 190  * fast path FIXUP_TOP_OF_STACK is needed.
 191  * RESTORE_TOP_OF_STACK syncs the syscall state after any possible ptregs
 192  * manipulation.
 193  */
 194
 195         /* %rsp:at FRAMEEND */
 196         .macro FIXUP_TOP_OF_STACK tmp offset=0
 197         movq PER_CPU_VAR(old_rsp),\tmp
 198         movq \tmp,RSP+\offset(%rsp)
 199         movq $__USER_DS,SS+\offset(%rsp)
 200         movq $__USER_CS,CS+\offset(%rsp)
 201         movq $-1,RCX+\offset(%rsp)
 202         movq R11+\offset(%rsp),\tmp  /* get eflags */
 203         movq \tmp,EFLAGS+\offset(%rsp)
 204         .endm
 205
 206         .macro RESTORE_TOP_OF_STACK tmp offset=0
 207         movq RSP+\offset(%rsp),\tmp
 208         movq \tmp,PER_CPU_VAR(old_rsp)
 209         movq EFLAGS+\offset(%rsp),\tmp
 210         movq \tmp,R11+\offset(%rsp)
 211         .endm
 212
 213         .macro FAKE_STACK_FRAME child_rip
 214         /* push in order ss, rsp, eflags, cs, rip */
 215         xorl %eax, %eax
 216         pushq $__KERNEL_DS /* ss */
 217         CFI_ADJUST_CFA_OFFSET   8
 218         /*CFI_REL_OFFSET        ss,0*/
 219         pushq %rax /* rsp */
 220         CFI_ADJUST_CFA_OFFSET   8
 221         CFI_REL_OFFSET  rsp,0
 222         pushq $X86_EFLAGS_IF /* eflags - interrupts on */
 223         CFI_ADJUST_CFA_OFFSET   8
 224         /*CFI_REL_OFFSET        rflags,0*/
 225         pushq $__KERNEL_CS /* cs */
 226         CFI_ADJUST_CFA_OFFSET   8
 227         /*CFI_REL_OFFSET        cs,0*/
 228         pushq \child_rip /* rip */
 229         CFI_ADJUST_CFA_OFFSET   8
 230         CFI_REL_OFFSET  rip,0
 231         pushq   %rax /* orig rax */
 232         CFI_ADJUST_CFA_OFFSET   8
 233         .endm
 234
 235         .macro UNFAKE_STACK_FRAME
 236         addq $8*6, %rsp
 237         CFI_ADJUST_CFA_OFFSET   -(6*8)
 238         .endm
 239
 240 /*
 241  * initial frame state for interrupts (and exceptions without error code)
 242  */
 243         .macro EMPTY_FRAME start=1 offset=0
 244         .if \start
 245         CFI_STARTPROC simple
 246         CFI_SIGNAL_FRAME
 247         CFI_DEF_CFA rsp,8+\offset
 248         .else
 249         CFI_DEF_CFA_OFFSET 8+\offset
 250         .endif
 251         .endm
 252
 253 /*
 254  * initial frame state for interrupts (and exceptions without error code)
 255  */
 256         .macro INTR_FRAME start=1 offset=0
 257         EMPTY_FRAME \start, SS+8+\offset-RIP
 258         /*CFI_REL_OFFSET ss, SS+\offset-RIP*/
 259         CFI_REL_OFFSET rsp, RSP+\offset-RIP
 260         /*CFI_REL_OFFSET rflags, EFLAGS+\offset-RIP*/
 261         /*CFI_REL_OFFSET cs, CS+\offset-RIP*/
 262         CFI_REL_OFFSET rip, RIP+\offset-RIP
 263         .endm
 264
 265 /*
 266  * initial frame state for exceptions with error code (and interrupts
 267  * with vector already pushed)
 268  */
 269         .macro XCPT_FRAME start=1 offset=0
 270         INTR_FRAME \start, RIP+\offset-ORIG_RAX
 271         /*CFI_REL_OFFSET orig_rax, ORIG_RAX-ORIG_RAX*/
 272         .endm
 273
 274 /*
 275  * frame that enables calling into C.
 276  */
 277         .macro PARTIAL_FRAME start=1 offset=0
 278         XCPT_FRAME \start, ORIG_RAX+\offset-ARGOFFSET
 279         CFI_REL_OFFSET rdi, RDI+\offset-ARGOFFSET
 280         CFI_REL_OFFSET rsi, RSI+\offset-ARGOFFSET
 281         CFI_REL_OFFSET rdx, RDX+\offset-ARGOFFSET
 282         CFI_REL_OFFSET rcx, RCX+\offset-ARGOFFSET
 283         CFI_REL_OFFSET rax, RAX+\offset-ARGOFFSET
 284         CFI_REL_OFFSET r8, R8+\offset-ARGOFFSET
 285         CFI_REL_OFFSET r9, R9+\offset-ARGOFFSET
 286         CFI_REL_OFFSET r10, R10+\offset-ARGOFFSET
 287         CFI_REL_OFFSET r11, R11+\offset-ARGOFFSET
 288         .endm
 289
 290 /*
 291  * frame that enables passing a complete pt_regs to a C function.
 292  */
 293         .macro DEFAULT_FRAME start=1 offset=0
 294         PARTIAL_FRAME \start, R11+\offset-R15
 295         CFI_REL_OFFSET rbx, RBX+\offset
 296         CFI_REL_OFFSET rbp, RBP+\offset
 297         CFI_REL_OFFSET r12, R12+\offset
 298         CFI_REL_OFFSET r13, R13+\offset
 299         CFI_REL_OFFSET r14, R14+\offset
 300         CFI_REL_OFFSET r15, R15+\offset
 301         .endm
 302
 303 /* save partial stack frame */
 304 ENTRY(save_args)
 305         XCPT_FRAME
 306         cld
 307         movq_cfi rdi, RDI+16-ARGOFFSET
 308         movq_cfi rsi, RSI+16-ARGOFFSET
 309         movq_cfi rdx, RDX+16-ARGOFFSET
 310         movq_cfi rcx, RCX+16-ARGOFFSET
 311         movq_cfi rax, RAX+16-ARGOFFSET
 312         movq_cfi  r8,  R8+16-ARGOFFSET
 313         movq_cfi  r9,  R9+16-ARGOFFSET
 314         movq_cfi r10, R10+16-ARGOFFSET
 315         movq_cfi r11, R11+16-ARGOFFSET
 316
 317         leaq -ARGOFFSET+16(%rsp),%rdi   /* arg1 for handler */
 318         movq_cfi rbp, 8         /* push %rbp */
 319         leaq 8(%rsp), %rbp              /* mov %rsp, %ebp */
 320         testl $3, CS(%rdi)
 321         je 1f
 322         SWAPGS
 323         /*
 324          * irq_count is used to check if a CPU is already on an interrupt stack
 325          * or not. While this is essentially redundant with preempt_count it is
 326          * a little cheaper to use a separate counter in the PDA (short of
 327          * moving irq_enter into assembly, which would be too much work)
 328          */
 329 1:      incl PER_CPU_VAR(irq_count)
 330         jne 2f
 331         popq_cfi %rax                   /* move return address... */
 332         mov PER_CPU_VAR(irq_stack_ptr),%rsp
 333         EMPTY_FRAME 0
 334         pushq_cfi %rbp                  /* backlink for unwinder */
 335         pushq_cfi %rax                  /* ... to the new stack */
 336         /*
 337          * We entered an interrupt context - irqs are off:
 338          */
 339 2:      TRACE_IRQS_OFF
 340         ret
 341         CFI_ENDPROC
 342 END(save_args)
 343
 344 ENTRY(save_rest)
 345         PARTIAL_FRAME 1 REST_SKIP+8
 346         movq 5*8+16(%rsp), %r11 /* save return address */
 347         movq_cfi rbx, RBX+16
 348         movq_cfi rbp, RBP+16
 349         movq_cfi r12, R12+16
 350         movq_cfi r13, R13+16
 351         movq_cfi r14, R14+16
 352         movq_cfi r15, R15+16
 353         movq %r11, 8(%rsp)      /* return address */
 354         FIXUP_TOP_OF_STACK %r11, 16
 355         ret
 356         CFI_ENDPROC
 357 END(save_rest)
 358
 359 /* save complete stack frame */
 360         .pushsection .kprobes.text, "ax"
 361 ENTRY(save_paranoid)
 362         XCPT_FRAME 1 RDI+8
 363         cld
 364         movq_cfi rdi, RDI+8
 365         movq_cfi rsi, RSI+8
 366         movq_cfi rdx, RDX+8
 367         movq_cfi rcx, RCX+8
 368         movq_cfi rax, RAX+8
 369         movq_cfi r8, R8+8
 370         movq_cfi r9, R9+8
 371         movq_cfi r10, R10+8
 372         movq_cfi r11, R11+8
 373         movq_cfi rbx, RBX+8
 374         movq_cfi rbp, RBP+8
 375         movq_cfi r12, R12+8
 376         movq_cfi r13, R13+8
 377         movq_cfi r14, R14+8
 378         movq_cfi r15, R15+8
 379         movl $1,%ebx
 380         movl $MSR_GS_BASE,%ecx
 381         rdmsr
 382         testl %edx,%edx
 383         js 1f   /* negative -> in kernel */
 384         SWAPGS
 385         xorl %ebx,%ebx
 386 1:      ret
 387         CFI_ENDPROC
 388 END(save_paranoid)
 389         .popsection
 390
 391 /*
 392  * A newly forked process directly context switches into this address.
 393  *
 394  * rdi: prev task we switched from
 395  */
 396 ENTRY(ret_from_fork)
 397         DEFAULT_FRAME
 398
 399         LOCK ; btr $TIF_FORK,TI_flags(%r8)
 400
 401         push kernel_eflags(%rip)
 402         CFI_ADJUST_CFA_OFFSET 8
 403         popf                                    # reset kernel eflags
 404         CFI_ADJUST_CFA_OFFSET -8
 405
 406         call schedule_tail                      # rdi: 'prev' task parameter
 407
 408         GET_THREAD_INFO(%rcx)
 409
 410         RESTORE_REST
 411
 412         testl $3, CS-ARGOFFSET(%rsp)            # from kernel_thread?
 413         je   int_ret_from_sys_call
 414
 415         testl $_TIF_IA32, TI_flags(%rcx)        # 32-bit compat task needs IRET
 416         jnz  int_ret_from_sys_call
 417
 418         RESTORE_TOP_OF_STACK %rdi, -ARGOFFSET
 419         jmp ret_from_sys_call                   # go to the SYSRET fastpath
 420
 421         CFI_ENDPROC
 422 END(ret_from_fork)
 423
 424 /*
 425  * System call entry. Upto 6 arguments in registers are supported.
 426  *
 427  * SYSCALL does not save anything on the stack and does not change the
 428  * stack pointer.
 429  */
 430
 431 /*
 432  * Register setup:
 433  * rax  system call number
 434  * rdi  arg0
 435  * rcx  return address for syscall/sysret, C arg3
 436  * rsi  arg1
 437  * rdx  arg2
 438  * r10  arg3    (--> moved to rcx for C)
 439  * r8   arg4
 440  * r9   arg5
 441  * r11  eflags for syscall/sysret, temporary for C
 442  * r12-r15,rbp,rbx saved by C code, not touched.
 443  *
 444  * Interrupts are off on entry.
 445  * Only called from user space.
 446  *
 447  * XXX  if we had a free scratch register we could save the RSP into the stack frame
 448  *      and report it properly in ps. Unfortunately we haven't.
 449  *
 450  * When user can change the frames always force IRET. That is because
 451  * it deals with uncanonical addresses better. SYSRET has trouble
 452  * with them due to bugs in both AMD and Intel CPUs.
 453  */
 454
 455 ENTRY(system_call)
 456         CFI_STARTPROC   simple
 457         CFI_SIGNAL_FRAME
 458         CFI_DEF_CFA     rsp,KERNEL_STACK_OFFSET
 459         CFI_REGISTER    rip,rcx
 460         /*CFI_REGISTER  rflags,r11*/
 461         SWAPGS_UNSAFE_STACK
 462         /*
 463          * A hypervisor implementation might want to use a label
 464          * after the swapgs, so that it can do the swapgs
 465          * for the guest and jump here on syscall.
 466          */
 467 ENTRY(system_call_after_swapgs)
 468
 469         movq    %rsp,PER_CPU_VAR(old_rsp)
 470         movq    PER_CPU_VAR(kernel_stack),%rsp
 471         /*
 472          * No need to follow this irqs off/on section - it's straight
 473          * and short:
 474          */
 475         ENABLE_INTERRUPTS(CLBR_NONE)
 476         SAVE_ARGS 8,1
 477         movq  %rax,ORIG_RAX-ARGOFFSET(%rsp)
 478         movq  %rcx,RIP-ARGOFFSET(%rsp)
 479         CFI_REL_OFFSET rip,RIP-ARGOFFSET
 480         GET_THREAD_INFO(%rcx)
 481         testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags(%rcx)
 482         jnz tracesys
 483 system_call_fastpath:
 484         cmpq $__NR_syscall_max,%rax
 485         ja badsys
 486         movq %r10,%rcx
 487         call *sys_call_table(,%rax,8)  # XXX:    rip relative
 488         movq %rax,RAX-ARGOFFSET(%rsp)
 489 /*
 490  * Syscall return path ending with SYSRET (fast path)
 491  * Has incomplete stack frame and undefined top of stack.
 492  */
 493 ret_from_sys_call:
 494         movl $_TIF_ALLWORK_MASK,%edi
 495         /* edi: flagmask */
 496 sysret_check:
 497         LOCKDEP_SYS_EXIT
 498         GET_THREAD_INFO(%rcx)
 499         DISABLE_INTERRUPTS(CLBR_NONE)
 500         TRACE_IRQS_OFF
 501         movl TI_flags(%rcx),%edx
 502         andl %edi,%edx
 503         jnz  sysret_careful
 504         CFI_REMEMBER_STATE
 505         /*
 506          * sysretq will re-enable interrupts:
 507          */
 508         TRACE_IRQS_ON
 509         movq RIP-ARGOFFSET(%rsp),%rcx
 510         CFI_REGISTER    rip,rcx
 511         RESTORE_ARGS 0,-ARG_SKIP,1
 512         /*CFI_REGISTER  rflags,r11*/
 513         movq    PER_CPU_VAR(old_rsp), %rsp
 514         USERGS_SYSRET64
 515
 516         CFI_RESTORE_STATE
 517         /* Handle reschedules */
 518         /* edx: work, edi: workmask */
 519 sysret_careful:
 520         bt $TIF_NEED_RESCHED,%edx
 521         jnc sysret_signal
 522         TRACE_IRQS_ON
 523         ENABLE_INTERRUPTS(CLBR_NONE)
 524         pushq %rdi
 525         CFI_ADJUST_CFA_OFFSET 8
 526         call schedule
 527         popq  %rdi
 528         CFI_ADJUST_CFA_OFFSET -8
 529         jmp sysret_check
 530
 531         /* Handle a signal */
 532 sysret_signal:
 533         TRACE_IRQS_ON
 534         ENABLE_INTERRUPTS(CLBR_NONE)
 535 #ifdef CONFIG_AUDITSYSCALL
 536         bt $TIF_SYSCALL_AUDIT,%edx
 537         jc sysret_audit
 538 #endif
 539         /*
 540          * We have a signal, or exit tracing or single-step.
 541          * These all wind up with the iret return path anyway,
 542          * so just join that path right now.
 543          */
 544         FIXUP_TOP_OF_STACK %r11, -ARGOFFSET
 545         jmp int_check_syscall_exit_work
 546
 547 badsys:
 548         movq $-ENOSYS,RAX-ARGOFFSET(%rsp)
 549         jmp ret_from_sys_call
 550
 551 #ifdef CONFIG_AUDITSYSCALL
 552         /*
 553          * Fast path for syscall audit without full syscall trace.
 554          * We just call audit_syscall_entry() directly, and then
 555          * jump back to the normal fast path.
 556          */
 557 auditsys:
 558         movq %r10,%r9                   /* 6th arg: 4th syscall arg */
 559         movq %rdx,%r8                   /* 5th arg: 3rd syscall arg */
 560         movq %rsi,%rcx                  /* 4th arg: 2nd syscall arg */
 561         movq %rdi,%rdx                  /* 3rd arg: 1st syscall arg */
 562         movq %rax,%rsi                  /* 2nd arg: syscall number */
 563         movl $AUDIT_ARCH_X86_64,%edi    /* 1st arg: audit arch */
 564         call audit_syscall_entry
 565         LOAD_ARGS 0             /* reload call-clobbered registers */
 566         jmp system_call_fastpath
 567
 568         /*
 569          * Return fast path for syscall audit.  Call audit_syscall_exit()
 570          * directly and then jump back to the fast path with TIF_SYSCALL_AUDIT
 571          * masked off.
 572          */
 573 sysret_audit:
 574         movq %rax,%rsi          /* second arg, syscall return value */
 575         cmpq $0,%rax            /* is it < 0? */
 576         setl %al                /* 1 if so, 0 if not */
 577         movzbl %al,%edi         /* zero-extend that into %edi */
 578         inc %edi /* first arg, 0->1(AUDITSC_SUCCESS), 1->2(AUDITSC_FAILURE) */
 579         call audit_syscall_exit
 580         movl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT),%edi
 581         jmp sysret_check
 582 #endif  /* CONFIG_AUDITSYSCALL */
 583
 584         /* Do syscall tracing */
 585 tracesys:
 586 #ifdef CONFIG_AUDITSYSCALL
 587         testl $(_TIF_WORK_SYSCALL_ENTRY & ~_TIF_SYSCALL_AUDIT),TI_flags(%rcx)
 588         jz auditsys
 589 #endif
 590         SAVE_REST
 591         movq $-ENOSYS,RAX(%rsp) /* ptrace can change this for a bad syscall */
 592         FIXUP_TOP_OF_STACK %rdi
 593         movq %rsp,%rdi
 594         call syscall_trace_enter
 595         /*
 596          * Reload arg registers from stack in case ptrace changed them.
 597          * We don't reload %rax because syscall_trace_enter() returned
 598          * the value it wants us to use in the table lookup.
 599          */
 600         LOAD_ARGS ARGOFFSET, 1
 601         RESTORE_REST
 602         cmpq $__NR_syscall_max,%rax
 603         ja   int_ret_from_sys_call      /* RAX(%rsp) set to -ENOSYS above */
 604         movq %r10,%rcx  /* fixup for C */
 605         call *sys_call_table(,%rax,8)
 606         movq %rax,RAX-ARGOFFSET(%rsp)
 607         /* Use IRET because user could have changed frame */
 608
 609 /*
 610  * Syscall return path ending with IRET.
 611  * Has correct top of stack, but partial stack frame.
 612  */
 613 GLOBAL(int_ret_from_sys_call)
 614         DISABLE_INTERRUPTS(CLBR_NONE)
 615         TRACE_IRQS_OFF
 616         testl $3,CS-ARGOFFSET(%rsp)
 617         je retint_restore_args
 618         movl $_TIF_ALLWORK_MASK,%edi
 619         /* edi: mask to check */
 620 GLOBAL(int_with_check)
 621         LOCKDEP_SYS_EXIT_IRQ
 622         GET_THREAD_INFO(%rcx)
 623         movl TI_flags(%rcx),%edx
 624         andl %edi,%edx
 625         jnz   int_careful
 626         andl    $~TS_COMPAT,TI_status(%rcx)
 627         jmp   retint_swapgs
 628
 629         /* Either reschedule or signal or syscall exit tracking needed. */
 630         /* First do a reschedule test. */
 631         /* edx: work, edi: workmask */
 632 int_careful:
 633         bt $TIF_NEED_RESCHED,%edx
 634         jnc  int_very_careful
 635         TRACE_IRQS_ON
 636         ENABLE_INTERRUPTS(CLBR_NONE)
 637         pushq %rdi
 638         CFI_ADJUST_CFA_OFFSET 8
 639         call schedule
 640         popq %rdi
 641         CFI_ADJUST_CFA_OFFSET -8
 642         DISABLE_INTERRUPTS(CLBR_NONE)
 643         TRACE_IRQS_OFF
 644         jmp int_with_check
 645
 646         /* handle signals and tracing -- both require a full stack frame */
 647 int_very_careful:
 648         TRACE_IRQS_ON
 649         ENABLE_INTERRUPTS(CLBR_NONE)
 650 int_check_syscall_exit_work:
 651         SAVE_REST
 652         /* Check for syscall exit trace */
 653         testl $_TIF_WORK_SYSCALL_EXIT,%edx
 654         jz int_signal
 655         pushq %rdi
 656         CFI_ADJUST_CFA_OFFSET 8
 657         leaq 8(%rsp),%rdi       # &ptregs -> arg1
 658         call syscall_trace_leave
 659         popq %rdi
 660         CFI_ADJUST_CFA_OFFSET -8
 661         andl $~(_TIF_WORK_SYSCALL_EXIT|_TIF_SYSCALL_EMU),%edi
 662         jmp int_restore_rest
 663
 664 int_signal:
 665         testl $_TIF_DO_NOTIFY_MASK,%edx
 666         jz 1f
 667         movq %rsp,%rdi          # &ptregs -> arg1
 668         xorl %esi,%esi          # oldset -> arg2
 669         call do_notify_resume
 670 1:      movl $_TIF_WORK_MASK,%edi
 671 int_restore_rest:
 672         RESTORE_REST
 673         DISABLE_INTERRUPTS(CLBR_NONE)
 674         TRACE_IRQS_OFF
 675         jmp int_with_check
 676         CFI_ENDPROC
 677 END(system_call)
 678
 679 /*
 680  * Certain special system calls that need to save a complete full stack frame.
 681  */
 682         .macro PTREGSCALL label,func,arg
 683 ENTRY(\label)
 684         PARTIAL_FRAME 1 8               /* offset 8: return address */
 685         subq $REST_SKIP, %rsp
 686         CFI_ADJUST_CFA_OFFSET REST_SKIP
 687         call save_rest
 688         DEFAULT_FRAME 0 8               /* offset 8: return address */
 689         leaq 8(%rsp), \arg      /* pt_regs pointer */
 690         call \func
 691         jmp ptregscall_common
 692         CFI_ENDPROC
 693 END(\label)
 694         .endm
 695
 696         PTREGSCALL stub_clone, sys_clone, %r8
 697         PTREGSCALL stub_fork, sys_fork, %rdi
 698         PTREGSCALL stub_vfork, sys_vfork, %rdi
 699         PTREGSCALL stub_sigaltstack, sys_sigaltstack, %rdx
 700         PTREGSCALL stub_iopl, sys_iopl, %rsi
 701
 702 ENTRY(ptregscall_common)
 703         DEFAULT_FRAME 1 8       /* offset 8: return address */
 704         RESTORE_TOP_OF_STACK %r11, 8
 705         movq_cfi_restore R15+8, r15
 706         movq_cfi_restore R14+8, r14
 707         movq_cfi_restore R13+8, r13
 708         movq_cfi_restore R12+8, r12
 709         movq_cfi_restore RBP+8, rbp
 710         movq_cfi_restore RBX+8, rbx
 711         ret $REST_SKIP          /* pop extended registers */
 712         CFI_ENDPROC
 713 END(ptregscall_common)
 714
 715 ENTRY(stub_execve)
 716         CFI_STARTPROC
 717         popq %r11
 718         CFI_ADJUST_CFA_OFFSET -8
 719         CFI_REGISTER rip, r11
 720         SAVE_REST
 721         FIXUP_TOP_OF_STACK %r11
 722         movq %rsp, %rcx
 723         call sys_execve
 724         RESTORE_TOP_OF_STACK %r11
 725         movq %rax,RAX(%rsp)
 726         RESTORE_REST
 727         jmp int_ret_from_sys_call
 728         CFI_ENDPROC
 729 END(stub_execve)
 730
 731 /*
 732  * sigreturn is special because it needs to restore all registers on return.
 733  * This cannot be done with SYSRET, so use the IRET return path instead.
 734  */
 735 ENTRY(stub_rt_sigreturn)
 736         CFI_STARTPROC
 737         addq $8, %rsp
 738         CFI_ADJUST_CFA_OFFSET   -8
 739         SAVE_REST
 740         movq %rsp,%rdi
 741         FIXUP_TOP_OF_STACK %r11
 742         call sys_rt_sigreturn
 743         movq %rax,RAX(%rsp) # fixme, this could be done at the higher layer
 744         RESTORE_REST
 745         jmp int_ret_from_sys_call
 746         CFI_ENDPROC
 747 END(stub_rt_sigreturn)
 748
 749 /*
 750  * Build the entry stubs and pointer table with some assembler magic.
 751  * We pack 7 stubs into a single 32-byte chunk, which will fit in a
 752  * single cache line on all modern x86 implementations.
 753  */
 754         .section .init.rodata,"a"
 755 ENTRY(interrupt)
 756         .text
 757         .p2align 5
 758         .p2align CONFIG_X86_L1_CACHE_SHIFT
 759 ENTRY(irq_entries_start)
 760         INTR_FRAME
 761 vector=FIRST_EXTERNAL_VECTOR
 762 .rept (NR_VECTORS-FIRST_EXTERNAL_VECTOR+6)/7
 763         .balign 32
 764   .rept 7
 765     .if vector < NR_VECTORS
 766       .if vector <> FIRST_EXTERNAL_VECTOR
 767         CFI_ADJUST_CFA_OFFSET -8
 768       .endif
 769 1:      pushq $(~vector+0x80)   /* Note: always in signed byte range */
 770         CFI_ADJUST_CFA_OFFSET 8
 771       .if ((vector-FIRST_EXTERNAL_VECTOR)%7) <> 6
 772         jmp 2f
 773       .endif
 774       .previous
 775         .quad 1b
 776       .text
 777 vector=vector+1
 778     .endif
 779   .endr
 780 2:      jmp common_interrupt
 781 .endr
 782         CFI_ENDPROC
 783 END(irq_entries_start)
 784
 785 .previous
 786 END(interrupt)
 787 .previous
 788
 789 /*
 790  * Interrupt entry/exit.
 791  *
 792  * Interrupt entry points save only callee clobbered registers in fast path.
 793  *
 794  * Entry runs with interrupts off.
 795  */
 796
 797 /* 0(%rsp): ~(interrupt number) */
 798         .macro interrupt func
 799         subq $10*8, %rsp
 800         CFI_ADJUST_CFA_OFFSET 10*8
 801         call save_args
 802         PARTIAL_FRAME 0
 803         call \func
 804         .endm
 805
 806         /*
 807          * The interrupt stubs push (~vector+0x80) onto the stack and
 808          * then jump to common_interrupt.
 809          */
 810         .p2align CONFIG_X86_L1_CACHE_SHIFT
 811 common_interrupt:
 812         XCPT_FRAME
 813         addq $-0x80,(%rsp)              /* Adjust vector to [-256,-1] range */
 814         interrupt do_IRQ
 815         /* 0(%rsp): old_rsp-ARGOFFSET */
 816 ret_from_intr:
 817         DISABLE_INTERRUPTS(CLBR_NONE)
 818         TRACE_IRQS_OFF
 819         decl PER_CPU_VAR(irq_count)
 820         leaveq
 821         CFI_DEF_CFA_REGISTER    rsp
 822         CFI_ADJUST_CFA_OFFSET   -8
 823 exit_intr:
 824         GET_THREAD_INFO(%rcx)
 825         testl $3,CS-ARGOFFSET(%rsp)
 826         je retint_kernel
 827
 828         /* Interrupt came from user space */
 829         /*
 830          * Has a correct top of stack, but a partial stack frame
 831          * %rcx: thread info. Interrupts off.
 832          */
 833 retint_with_reschedule:
 834         movl $_TIF_WORK_MASK,%edi
 835 retint_check:
 836         LOCKDEP_SYS_EXIT_IRQ
 837         movl TI_flags(%rcx),%edx
 838         andl %edi,%edx
 839         CFI_REMEMBER_STATE
 840         jnz  retint_careful
 841
 842 retint_swapgs:          /* return to user-space */
 843         /*
 844          * The iretq could re-enable interrupts:
 845          */
 846         DISABLE_INTERRUPTS(CLBR_ANY)
 847         TRACE_IRQS_IRETQ
 848         SWAPGS
 849         jmp restore_args
 850
 851 retint_restore_args:    /* return to kernel space */
 852         DISABLE_INTERRUPTS(CLBR_ANY)
 853         /*
 854          * The iretq could re-enable interrupts:
 855          */
 856         TRACE_IRQS_IRETQ
 857 restore_args:
 858         RESTORE_ARGS 0,8,0
 859
 860 irq_return:
 861         INTERRUPT_RETURN
 862
 863         .section __ex_table, "a"
 864         .quad irq_return, bad_iret
 865         .previous
 866
 867 #ifdef CONFIG_PARAVIRT
 868 ENTRY(native_iret)
 869         iretq
 870
 871         .section __ex_table,"a"
 872         .quad native_iret, bad_iret
 873         .previous
 874 #endif
 875
 876         .section .fixup,"ax"
 877 bad_iret:
 878         /*
 879          * The iret traps when the %cs or %ss being restored is bogus.
 880          * We've lost the original trap vector and error code.
 881          * #GPF is the most likely one to get for an invalid selector.
 882          * So pretend we completed the iret and took the #GPF in user mode.
 883          *
 884          * We are now running with the kernel GS after exception recovery.
 885          * But error_entry expects us to have user GS to match the user %cs,
 886          * so swap back.
 887          */
 888         pushq $0
 889
 890         SWAPGS
 891         jmp general_protection
 892
 893         .previous
 894
 895         /* edi: workmask, edx: work */
 896 retint_careful:
 897         CFI_RESTORE_STATE
 898         bt    $TIF_NEED_RESCHED,%edx
 899         jnc   retint_signal
 900         TRACE_IRQS_ON
 901         ENABLE_INTERRUPTS(CLBR_NONE)
 902         pushq %rdi
 903         CFI_ADJUST_CFA_OFFSET   8
 904         call  schedule
 905         popq %rdi
 906         CFI_ADJUST_CFA_OFFSET   -8
 907         GET_THREAD_INFO(%rcx)
 908         DISABLE_INTERRUPTS(CLBR_NONE)
 909         TRACE_IRQS_OFF
 910         jmp retint_check
 911
 912 retint_signal:
 913         testl $_TIF_DO_NOTIFY_MASK,%edx
 914         jz    retint_swapgs
 915         TRACE_IRQS_ON
 916         ENABLE_INTERRUPTS(CLBR_NONE)
 917         SAVE_REST
 918         movq $-1,ORIG_RAX(%rsp)
 919         xorl %esi,%esi          # oldset
 920         movq %rsp,%rdi          # &pt_regs
 921         call do_notify_resume
 922         RESTORE_REST
 923         DISABLE_INTERRUPTS(CLBR_NONE)
 924         TRACE_IRQS_OFF
 925         GET_THREAD_INFO(%rcx)
 926         jmp retint_with_reschedule
 927
 928 #ifdef CONFIG_PREEMPT
 929         /* Returning to kernel space. Check if we need preemption */
 930         /* rcx:  threadinfo. interrupts off. */
 931 ENTRY(retint_kernel)
 932         cmpl $0,TI_preempt_count(%rcx)
 933         jnz  retint_restore_args
 934         bt  $TIF_NEED_RESCHED,TI_flags(%rcx)
 935         jnc  retint_restore_args
 936         bt   $9,EFLAGS-ARGOFFSET(%rsp)  /* interrupts off? */
 937         jnc  retint_restore_args
 938         call preempt_schedule_irq
 939         jmp exit_intr
 940 #endif
 941
 942         CFI_ENDPROC
 943 END(common_interrupt)
 944
 945 /*
 946  * APIC interrupts.
 947  */
 948 .macro apicinterrupt num sym do_sym
 949 ENTRY(\sym)
 950         INTR_FRAME
 951         pushq $~(\num)
 952         CFI_ADJUST_CFA_OFFSET 8
 953         interrupt \do_sym
 954         jmp ret_from_intr
 955         CFI_ENDPROC
 956 END(\sym)
 957 .endm
 958
 959 #ifdef CONFIG_SMP
 960 apicinterrupt IRQ_MOVE_CLEANUP_VECTOR \
 961         irq_move_cleanup_interrupt smp_irq_move_cleanup_interrupt
 962 apicinterrupt REBOOT_VECTOR \
 963         reboot_interrupt smp_reboot_interrupt
 964 #endif
 965
 966 #ifdef CONFIG_X86_UV
 967 apicinterrupt UV_BAU_MESSAGE \
 968         uv_bau_message_intr1 uv_bau_message_interrupt
 969 #endif
 970 apicinterrupt LOCAL_TIMER_VECTOR \
 971         apic_timer_interrupt smp_apic_timer_interrupt
 972 apicinterrupt GENERIC_INTERRUPT_VECTOR \
 973         generic_interrupt smp_generic_interrupt
 974
 975 #ifdef CONFIG_SMP
 976 apicinterrupt INVALIDATE_TLB_VECTOR_START+0 \
 977         invalidate_interrupt0 smp_invalidate_interrupt
 978 apicinterrupt INVALIDATE_TLB_VECTOR_START+1 \
 979         invalidate_interrupt1 smp_invalidate_interrupt
 980 apicinterrupt INVALIDATE_TLB_VECTOR_START+2 \
 981         invalidate_interrupt2 smp_invalidate_interrupt
 982 apicinterrupt INVALIDATE_TLB_VECTOR_START+3 \
 983         invalidate_interrupt3 smp_invalidate_interrupt
 984 apicinterrupt INVALIDATE_TLB_VECTOR_START+4 \
 985         invalidate_interrupt4 smp_invalidate_interrupt
 986 apicinterrupt INVALIDATE_TLB_VECTOR_START+5 \
 987         invalidate_interrupt5 smp_invalidate_interrupt
 988 apicinterrupt INVALIDATE_TLB_VECTOR_START+6 \
 989         invalidate_interrupt6 smp_invalidate_interrupt
 990 apicinterrupt INVALIDATE_TLB_VECTOR_START+7 \
 991         invalidate_interrupt7 smp_invalidate_interrupt
 992 #endif
 993
 994 apicinterrupt THRESHOLD_APIC_VECTOR \
 995         threshold_interrupt smp_threshold_interrupt
 996 apicinterrupt THERMAL_APIC_VECTOR \
 997         thermal_interrupt smp_thermal_interrupt
 998
 999 #ifdef CONFIG_X86_MCE
1000 apicinterrupt MCE_SELF_VECTOR \
1001         mce_self_interrupt smp_mce_self_interrupt
1002 #endif
1003
1004 #ifdef CONFIG_SMP
1005 apicinterrupt CALL_FUNCTION_SINGLE_VECTOR \
1006         call_function_single_interrupt smp_call_function_single_interrupt
1007 apicinterrupt CALL_FUNCTION_VECTOR \
1008         call_function_interrupt smp_call_function_interrupt
1009 apicinterrupt RESCHEDULE_VECTOR \
1010         reschedule_interrupt smp_reschedule_interrupt
1011 #endif
1012
1013 apicinterrupt ERROR_APIC_VECTOR \
1014         error_interrupt smp_error_interrupt
1015 apicinterrupt SPURIOUS_APIC_VECTOR \
1016         spurious_interrupt smp_spurious_interrupt
1017
1018 #ifdef CONFIG_PERF_EVENTS
1019 apicinterrupt LOCAL_PENDING_VECTOR \
1020         perf_pending_interrupt smp_perf_pending_interrupt
1021 #endif
1022
1023 /*
1024  * Exception entry points.
1025  */
1026 .macro zeroentry sym do_sym
1027 ENTRY(\sym)
1028         INTR_FRAME
1029         PARAVIRT_ADJUST_EXCEPTION_FRAME
1030         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1031         subq $15*8,%rsp
1032         CFI_ADJUST_CFA_OFFSET 15*8
1033         call error_entry
1034         DEFAULT_FRAME 0
1035         movq %rsp,%rdi          /* pt_regs pointer */
1036         xorl %esi,%esi          /* no error code */
1037         call \do_sym
1038         jmp error_exit          /* %ebx: no swapgs flag */
1039         CFI_ENDPROC
1040 END(\sym)
1041 .endm
1042
1043 .macro paranoidzeroentry sym do_sym
1044 ENTRY(\sym)
1045         INTR_FRAME
1046         PARAVIRT_ADJUST_EXCEPTION_FRAME
1047         pushq $-1               /* ORIG_RAX: no syscall to restart */
1048         CFI_ADJUST_CFA_OFFSET 8
1049         subq $15*8, %rsp
1050         call save_paranoid
1051         TRACE_IRQS_OFF
1052         movq %rsp,%rdi          /* pt_regs pointer */
1053         xorl %esi,%esi          /* no error code */
1054         call \do_sym
1055         jmp paranoid_exit       /* %ebx: no swapgs flag */
1056         CFI_ENDPROC
1057 END(\sym)
1058 .endm
1059
1060 .macro paranoidzeroentry_ist sym do_sym ist
1061 ENTRY(\sym)
1062         INTR_FRAME
1063         PARAVIRT_ADJUST_EXCEPTION_FRAME
1064         pushq $-1               /* ORIG_RAX: no syscall to restart */
1065         CFI_ADJUST_CFA_OFFSET 8
1066         subq $15*8, %rsp
1067         call save_paranoid
1068         TRACE_IRQS_OFF
1069         movq %rsp,%rdi          /* pt_regs pointer */
1070         xorl %esi,%esi          /* no error code */
1071         PER_CPU(init_tss, %rbp)
1072         subq $EXCEPTION_STKSZ, TSS_ist + (\ist - 1) * 8(%rbp)
1073         call \do_sym
1074         addq $EXCEPTION_STKSZ, TSS_ist + (\ist - 1) * 8(%rbp)
1075         jmp paranoid_exit       /* %ebx: no swapgs flag */
1076         CFI_ENDPROC
1077 END(\sym)
1078 .endm
1079
1080 .macro errorentry sym do_sym
1081 ENTRY(\sym)
1082         XCPT_FRAME
1083         PARAVIRT_ADJUST_EXCEPTION_FRAME
1084         subq $15*8,%rsp
1085         CFI_ADJUST_CFA_OFFSET 15*8
1086         call error_entry
1087         DEFAULT_FRAME 0
1088         movq %rsp,%rdi                  /* pt_regs pointer */
1089         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1090         movq $-1,ORIG_RAX(%rsp)         /* no syscall to restart */
1091         call \do_sym
1092         jmp error_exit                  /* %ebx: no swapgs flag */
1093         CFI_ENDPROC
1094 END(\sym)
1095 .endm
1096
1097         /* error code is on the stack already */
1098 .macro paranoiderrorentry sym do_sym
1099 ENTRY(\sym)
1100         XCPT_FRAME
1101         PARAVIRT_ADJUST_EXCEPTION_FRAME
1102         subq $15*8,%rsp
1103         CFI_ADJUST_CFA_OFFSET 15*8
1104         call save_paranoid
1105         DEFAULT_FRAME 0
1106         TRACE_IRQS_OFF
1107         movq %rsp,%rdi                  /* pt_regs pointer */
1108         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1109         movq $-1,ORIG_RAX(%rsp)         /* no syscall to restart */
1110         call \do_sym
1111         jmp paranoid_exit               /* %ebx: no swapgs flag */
1112         CFI_ENDPROC
1113 END(\sym)
1114 .endm
1115
1116 zeroentry divide_error do_divide_error
1117 zeroentry overflow do_overflow
1118 zeroentry bounds do_bounds
1119 zeroentry invalid_op do_invalid_op
1120 zeroentry device_not_available do_device_not_available
1121 paranoiderrorentry double_fault do_double_fault
1122 zeroentry coprocessor_segment_overrun do_coprocessor_segment_overrun
1123 errorentry invalid_TSS do_invalid_TSS
1124 errorentry segment_not_present do_segment_not_present
1125 zeroentry spurious_interrupt_bug do_spurious_interrupt_bug
1126 zeroentry coprocessor_error do_coprocessor_error
1127 errorentry alignment_check do_alignment_check
1128 zeroentry simd_coprocessor_error do_simd_coprocessor_error
1129
1130         /* Reload gs selector with exception handling */
1131         /* edi:  new selector */
1132 ENTRY(native_load_gs_index)
1133         CFI_STARTPROC
1134         pushf
1135         CFI_ADJUST_CFA_OFFSET 8
1136         DISABLE_INTERRUPTS(CLBR_ANY & ~CLBR_RDI)
1137         SWAPGS
1138 gs_change:
1139         movl %edi,%gs
1140 2:      mfence          /* workaround */
1141         SWAPGS
1142         popf
1143         CFI_ADJUST_CFA_OFFSET -8
1144         ret
1145         CFI_ENDPROC
1146 END(native_load_gs_index)
1147
1148         .section __ex_table,"a"
1149         .align 8
1150         .quad gs_change,bad_gs
1151         .previous
1152         .section .fixup,"ax"
1153         /* running with kernelgs */
1154 bad_gs:
1155         SWAPGS                  /* switch back to user gs */
1156         xorl %eax,%eax
1157         movl %eax,%gs
1158         jmp  2b
1159         .previous
1160
1161 /*
1162  * Create a kernel thread.
1163  *
1164  * C extern interface:
1165  *      extern long kernel_thread(int (*fn)(void *), void * arg, unsigned long flags)
1166  *
1167  * asm input arguments:
1168  *      rdi: fn, rsi: arg, rdx: flags
1169  */
1170 ENTRY(kernel_thread)
1171         CFI_STARTPROC
1172         FAKE_STACK_FRAME $child_rip
1173         SAVE_ALL
1174
1175         # rdi: flags, rsi: usp, rdx: will be &pt_regs
1176         movq %rdx,%rdi
1177         orq  kernel_thread_flags(%rip),%rdi
1178         movq $-1, %rsi
1179         movq %rsp, %rdx
1180
1181         xorl %r8d,%r8d
1182         xorl %r9d,%r9d
1183
1184         # clone now
1185         call do_fork
1186         movq %rax,RAX(%rsp)
1187         xorl %edi,%edi
1188
1189         /*
1190          * It isn't worth to check for reschedule here,
1191          * so internally to the x86_64 port you can rely on kernel_thread()
1192          * not to reschedule the child before returning, this avoids the need
1193          * of hacks for example to fork off the per-CPU idle tasks.
1194          * [Hopefully no generic code relies on the reschedule -AK]
1195          */
1196         RESTORE_ALL
1197         UNFAKE_STACK_FRAME
1198         ret
1199         CFI_ENDPROC
1200 END(kernel_thread)
1201
1202 ENTRY(child_rip)
1203         pushq $0                # fake return address
1204         CFI_STARTPROC
1205         /*
1206          * Here we are in the child and the registers are set as they were
1207          * at kernel_thread() invocation in the parent.
1208          */
1209         movq %rdi, %rax
1210         movq %rsi, %rdi
1211         call *%rax
1212         # exit
1213         mov %eax, %edi
1214         call do_exit
1215         ud2                     # padding for call trace
1216         CFI_ENDPROC
1217 END(child_rip)
1218
1219 /*
1220  * execve(). This function needs to use IRET, not SYSRET, to set up all state properly.
1221  *
1222  * C extern interface:
1223  *       extern long execve(char *name, char **argv, char **envp)
1224  *
1225  * asm input arguments:
1226  *      rdi: name, rsi: argv, rdx: envp
1227  *
1228  * We want to fallback into:
1229  *      extern long sys_execve(char *name, char **argv,char **envp, struct pt_regs *regs)
1230  *
1231  * do_sys_execve asm fallback arguments:
1232  *      rdi: name, rsi: argv, rdx: envp, rcx: fake frame on the stack
1233  */
1234 ENTRY(kernel_execve)
1235         CFI_STARTPROC
1236         FAKE_STACK_FRAME $0
1237         SAVE_ALL
1238         movq %rsp,%rcx
1239         call sys_execve
1240         movq %rax, RAX(%rsp)
1241         RESTORE_REST
1242         testq %rax,%rax
1243         je int_ret_from_sys_call
1244         RESTORE_ARGS
1245         UNFAKE_STACK_FRAME
1246         ret
1247         CFI_ENDPROC
1248 END(kernel_execve)
1249
1250 /* Call softirq on interrupt stack. Interrupts are off. */
1251 ENTRY(call_softirq)
1252         CFI_STARTPROC
1253         push %rbp
1254         CFI_ADJUST_CFA_OFFSET   8
1255         CFI_REL_OFFSET rbp,0
1256         mov  %rsp,%rbp
1257         CFI_DEF_CFA_REGISTER rbp
1258         incl PER_CPU_VAR(irq_count)
1259         cmove PER_CPU_VAR(irq_stack_ptr),%rsp
1260         push  %rbp                      # backlink for old unwinder
1261         call __do_softirq
1262         leaveq
1263         CFI_DEF_CFA_REGISTER    rsp
1264         CFI_ADJUST_CFA_OFFSET   -8
1265         decl PER_CPU_VAR(irq_count)
1266         ret
1267         CFI_ENDPROC
1268 END(call_softirq)
1269
1270 #ifdef CONFIG_XEN
1271 zeroentry xen_hypervisor_callback xen_do_hypervisor_callback
1272
1273 /*
1274  * A note on the "critical region" in our callback handler.
1275  * We want to avoid stacking callback handlers due to events occurring
1276  * during handling of the last event. To do this, we keep events disabled
1277  * until we've done all processing. HOWEVER, we must enable events before
1278  * popping the stack frame (can't be done atomically) and so it would still
1279  * be possible to get enough handler activations to overflow the stack.
1280  * Although unlikely, bugs of that kind are hard to track down, so we'd
1281  * like to avoid the possibility.
1282  * So, on entry to the handler we detect whether we interrupted an
1283  * existing activation in its critical region -- if so, we pop the current
1284  * activation and restart the handler using the previous one.
1285  */
1286 ENTRY(xen_do_hypervisor_callback)   # do_hypervisor_callback(struct *pt_regs)
1287         CFI_STARTPROC
1288 /*
1289  * Since we don't modify %rdi, evtchn_do_upall(struct *pt_regs) will
1290  * see the correct pointer to the pt_regs
1291  */
1292         movq %rdi, %rsp            # we don't return, adjust the stack frame
1293         CFI_ENDPROC
1294         DEFAULT_FRAME
1295 11:     incl PER_CPU_VAR(irq_count)
1296         movq %rsp,%rbp
1297         CFI_DEF_CFA_REGISTER rbp
1298         cmovzq PER_CPU_VAR(irq_stack_ptr),%rsp
1299         pushq %rbp                      # backlink for old unwinder
1300         call xen_evtchn_do_upcall
1301         popq %rsp
1302         CFI_DEF_CFA_REGISTER rsp
1303         decl PER_CPU_VAR(irq_count)
1304         jmp  error_exit
1305         CFI_ENDPROC
1306 END(do_hypervisor_callback)
1307
1308 /*
1309  * Hypervisor uses this for application faults while it executes.
1310  * We get here for two reasons:
1311  *  1. Fault while reloading DS, ES, FS or GS
1312  *  2. Fault while executing IRET
1313  * Category 1 we do not need to fix up as Xen has already reloaded all segment
1314  * registers that could be reloaded and zeroed the others.
1315  * Category 2 we fix up by killing the current process. We cannot use the
1316  * normal Linux return path in this case because if we use the IRET hypercall
1317  * to pop the stack frame we end up in an infinite loop of failsafe callbacks.
1318  * We distinguish between categories by comparing each saved segment register
1319  * with its current contents: any discrepancy means we in category 1.
1320  */
1321 ENTRY(xen_failsafe_callback)
1322         INTR_FRAME 1 (6*8)
1323         /*CFI_REL_OFFSET gs,GS*/
1324         /*CFI_REL_OFFSET fs,FS*/
1325         /*CFI_REL_OFFSET es,ES*/
1326         /*CFI_REL_OFFSET ds,DS*/
1327         CFI_REL_OFFSET r11,8
1328         CFI_REL_OFFSET rcx,0
1329         movw %ds,%cx
1330         cmpw %cx,0x10(%rsp)
1331         CFI_REMEMBER_STATE
1332         jne 1f
1333         movw %es,%cx
1334         cmpw %cx,0x18(%rsp)
1335         jne 1f
1336         movw %fs,%cx
1337         cmpw %cx,0x20(%rsp)
1338         jne 1f
1339         movw %gs,%cx
1340         cmpw %cx,0x28(%rsp)
1341         jne 1f
1342         /* All segments match their saved values => Category 2 (Bad IRET). */
1343         movq (%rsp),%rcx
1344         CFI_RESTORE rcx
1345         movq 8(%rsp),%r11
1346         CFI_RESTORE r11
1347         addq $0x30,%rsp
1348         CFI_ADJUST_CFA_OFFSET -0x30
1349         pushq_cfi $0    /* RIP */
1350         pushq_cfi %r11
1351         pushq_cfi %rcx
1352         jmp general_protection
1353         CFI_RESTORE_STATE
1354 1:      /* Segment mismatch => Category 1 (Bad segment). Retry the IRET. */
1355         movq (%rsp),%rcx
1356         CFI_RESTORE rcx
1357         movq 8(%rsp),%r11
1358         CFI_RESTORE r11
1359         addq $0x30,%rsp
1360         CFI_ADJUST_CFA_OFFSET -0x30
1361         pushq_cfi $0
1362         SAVE_ALL
1363         jmp error_exit
1364         CFI_ENDPROC
1365 END(xen_failsafe_callback)
1366
1367 #endif /* CONFIG_XEN */
1368
1369 /*
1370  * Some functions should be protected against kprobes
1371  */
1372         .pushsection .kprobes.text, "ax"
1373
1374 paranoidzeroentry_ist debug do_debug DEBUG_STACK
1375 paranoidzeroentry_ist int3 do_int3 DEBUG_STACK
1376 paranoiderrorentry stack_segment do_stack_segment
1377 #ifdef CONFIG_XEN
1378 zeroentry xen_debug do_debug
1379 zeroentry xen_int3 do_int3
1380 errorentry xen_stack_segment do_stack_segment
1381 #endif
1382 errorentry general_protection do_general_protection
1383 errorentry page_fault do_page_fault
1384 #ifdef CONFIG_X86_MCE
1385 paranoidzeroentry machine_check *machine_check_vector(%rip)
1386 #endif
1387
1388         /*
1389          * "Paranoid" exit path from exception stack.
1390          * Paranoid because this is used by NMIs and cannot take
1391          * any kernel state for granted.
1392          * We don't do kernel preemption checks here, because only
1393          * NMI should be common and it does not enable IRQs and
1394          * cannot get reschedule ticks.
1395          *
1396          * "trace" is 0 for the NMI handler only, because irq-tracing
1397          * is fundamentally NMI-unsafe. (we cannot change the soft and
1398          * hard flags at once, atomically)
1399          */
1400
1401         /* ebx: no swapgs flag */
1402 ENTRY(paranoid_exit)
1403         INTR_FRAME
1404         DISABLE_INTERRUPTS(CLBR_NONE)
1405         TRACE_IRQS_OFF
1406         testl %ebx,%ebx                         /* swapgs needed? */
1407         jnz paranoid_restore
1408         testl $3,CS(%rsp)
1409         jnz   paranoid_userspace
1410 paranoid_swapgs:
1411         TRACE_IRQS_IRETQ 0
1412         SWAPGS_UNSAFE_STACK
1413         RESTORE_ALL 8
1414         jmp irq_return
1415 paranoid_restore:
1416         TRACE_IRQS_IRETQ 0
1417         RESTORE_ALL 8
1418         jmp irq_return
1419 paranoid_userspace:
1420         GET_THREAD_INFO(%rcx)
1421         movl TI_flags(%rcx),%ebx
1422         andl $_TIF_WORK_MASK,%ebx
1423         jz paranoid_swapgs
1424         movq %rsp,%rdi                  /* &pt_regs */
1425         call sync_regs
1426         movq %rax,%rsp                  /* switch stack for scheduling */
1427         testl $_TIF_NEED_RESCHED,%ebx
1428         jnz paranoid_schedule
1429         movl %ebx,%edx                  /* arg3: thread flags */
1430         TRACE_IRQS_ON
1431         ENABLE_INTERRUPTS(CLBR_NONE)
1432         xorl %esi,%esi                  /* arg2: oldset */
1433         movq %rsp,%rdi                  /* arg1: &pt_regs */
1434         call do_notify_resume
1435         DISABLE_INTERRUPTS(CLBR_NONE)
1436         TRACE_IRQS_OFF
1437         jmp paranoid_userspace
1438 paranoid_schedule:
1439         TRACE_IRQS_ON
1440         ENABLE_INTERRUPTS(CLBR_ANY)
1441         call schedule
1442         DISABLE_INTERRUPTS(CLBR_ANY)
1443         TRACE_IRQS_OFF
1444         jmp paranoid_userspace
1445         CFI_ENDPROC
1446 END(paranoid_exit)
1447
1448 /*
1449  * Exception entry point. This expects an error code/orig_rax on the stack.
1450  * returns in "no swapgs flag" in %ebx.
1451  */
1452 ENTRY(error_entry)
1453         XCPT_FRAME
1454         CFI_ADJUST_CFA_OFFSET 15*8
1455         /* oldrax contains error code */
1456         cld
1457         movq_cfi rdi, RDI+8
1458         movq_cfi rsi, RSI+8
1459         movq_cfi rdx, RDX+8
1460         movq_cfi rcx, RCX+8
1461         movq_cfi rax, RAX+8
1462         movq_cfi  r8,  R8+8
1463         movq_cfi  r9,  R9+8
1464         movq_cfi r10, R10+8
1465         movq_cfi r11, R11+8
1466         movq_cfi rbx, RBX+8
1467         movq_cfi rbp, RBP+8
1468         movq_cfi r12, R12+8
1469         movq_cfi r13, R13+8
1470         movq_cfi r14, R14+8
1471         movq_cfi r15, R15+8
1472         xorl %ebx,%ebx
1473         testl $3,CS+8(%rsp)
1474         je error_kernelspace
1475 error_swapgs:
1476         SWAPGS
1477 error_sti:
1478         TRACE_IRQS_OFF
1479         ret
1480         CFI_ENDPROC
1481
1482 /*
1483  * There are two places in the kernel that can potentially fault with
1484  * usergs. Handle them here. The exception handlers after iret run with
1485  * kernel gs again, so don't set the user space flag. B stepping K8s
1486  * sometimes report an truncated RIP for IRET exceptions returning to
1487  * compat mode. Check for these here too.
1488  */
1489 error_kernelspace:
1490         incl %ebx
1491         leaq irq_return(%rip),%rcx
1492         cmpq %rcx,RIP+8(%rsp)
1493         je error_swapgs
1494         movl %ecx,%ecx  /* zero extend */
1495         cmpq %rcx,RIP+8(%rsp)
1496         je error_swapgs
1497         cmpq $gs_change,RIP+8(%rsp)
1498         je error_swapgs
1499         jmp error_sti
1500 END(error_entry)
1501
1502
1503 /* ebx: no swapgs flag (1: don't need swapgs, 0: need it) */
1504 ENTRY(error_exit)
1505         DEFAULT_FRAME
1506         movl %ebx,%eax
1507         RESTORE_REST
1508         DISABLE_INTERRUPTS(CLBR_NONE)
1509         TRACE_IRQS_OFF
1510         GET_THREAD_INFO(%rcx)
1511         testl %eax,%eax
1512         jne retint_kernel
1513         LOCKDEP_SYS_EXIT_IRQ
1514         movl TI_flags(%rcx),%edx
1515         movl $_TIF_WORK_MASK,%edi
1516         andl %edi,%edx
1517         jnz retint_careful
1518         jmp retint_swapgs
1519         CFI_ENDPROC
1520 END(error_exit)
1521
1522
1523         /* runs on exception stack */
1524 ENTRY(nmi)
1525         INTR_FRAME
1526         PARAVIRT_ADJUST_EXCEPTION_FRAME
1527         pushq_cfi $-1
1528         subq $15*8, %rsp
1529         CFI_ADJUST_CFA_OFFSET 15*8
1530         call save_paranoid
1531         DEFAULT_FRAME 0
1532         /* paranoidentry do_nmi, 0; without TRACE_IRQS_OFF */
1533         movq %rsp,%rdi
1534         movq $-1,%rsi
1535         call do_nmi
1536 #ifdef CONFIG_TRACE_IRQFLAGS
1537         /* paranoidexit; without TRACE_IRQS_OFF */
1538         /* ebx: no swapgs flag */
1539         DISABLE_INTERRUPTS(CLBR_NONE)
1540         testl %ebx,%ebx                         /* swapgs needed? */
1541         jnz nmi_restore
1542         testl $3,CS(%rsp)
1543         jnz nmi_userspace
1544 nmi_swapgs:
1545         SWAPGS_UNSAFE_STACK
1546 nmi_restore:
1547         RESTORE_ALL 8
1548         jmp irq_return
1549 nmi_userspace:
1550         GET_THREAD_INFO(%rcx)
1551         movl TI_flags(%rcx),%ebx
1552         andl $_TIF_WORK_MASK,%ebx
1553         jz nmi_swapgs
1554         movq %rsp,%rdi                  /* &pt_regs */
1555         call sync_regs
1556         movq %rax,%rsp                  /* switch stack for scheduling */
1557         testl $_TIF_NEED_RESCHED,%ebx
1558         jnz nmi_schedule
1559         movl %ebx,%edx                  /* arg3: thread flags */
1560         ENABLE_INTERRUPTS(CLBR_NONE)
1561         xorl %esi,%esi                  /* arg2: oldset */
1562         movq %rsp,%rdi                  /* arg1: &pt_regs */
1563         call do_notify_resume
1564         DISABLE_INTERRUPTS(CLBR_NONE)
1565         jmp nmi_userspace
1566 nmi_schedule:
1567         ENABLE_INTERRUPTS(CLBR_ANY)
1568         call schedule
1569         DISABLE_INTERRUPTS(CLBR_ANY)
1570         jmp nmi_userspace
1571         CFI_ENDPROC
1572 #else
1573         jmp paranoid_exit
1574         CFI_ENDPROC
1575 #endif
1576 END(nmi)
1577
1578 ENTRY(ignore_sysret)
1579         CFI_STARTPROC
1580         mov $-ENOSYS,%eax
1581         sysret
1582         CFI_ENDPROC
1583 END(ignore_sysret)
1584
1585 /*
1586  * End of kprobes section
1587  */
1588         .popsection