arch/x86/kernel/entry_64.S

   1 /*
   2  *  linux/arch/x86_64/entry.S
   3  *
   4  *  Copyright (C) 1991, 1992  Linus Torvalds
   5  *  Copyright (C) 2000, 2001, 2002  Andi Kleen SuSE Labs
   6  *  Copyright (C) 2000  Pavel Machek <pavel@suse.cz>
   7  */
   8
   9 /*
  10  * entry.S contains the system-call and fault low-level handling routines.
  11  *
  12  * NOTE: This code handles signal-recognition, which happens every time
  13  * after an interrupt and after each system call.
  14  *
  15  * Normal syscalls and interrupts don't save a full stack frame, this is
  16  * only done for syscall tracing, signals or fork/exec et.al.
  17  *
  18  * A note on terminology:
  19  * - top of stack: Architecture defined interrupt frame from SS to RIP
  20  * at the top of the kernel process stack.
  21  * - partial stack frame: partially saved registers upto R11.
  22  * - full stack frame: Like partial stack frame, but all register saved.
  23  *
  24  * Some macro usage:
  25  * - CFI macros are used to generate dwarf2 unwind information for better
  26  * backtraces. They don't change any code.
  27  * - SAVE_ALL/RESTORE_ALL - Save/restore all registers
  28  * - SAVE_ARGS/RESTORE_ARGS - Save/restore registers that C functions modify.
  29  * There are unfortunately lots of special cases where some registers
  30  * not touched. The macro is a big mess that should be cleaned up.
  31  * - SAVE_REST/RESTORE_REST - Handle the registers not saved by SAVE_ARGS.
  32  * Gives a full stack frame.
  33  * - ENTRY/END Define functions in the symbol table.
  34  * - FIXUP_TOP_OF_STACK/RESTORE_TOP_OF_STACK - Fix up the hardware stack
  35  * frame that is otherwise undefined after a SYSCALL
  36  * - TRACE_IRQ_* - Trace hard interrupt state for lock debugging.
  37  * - errorentry/paranoidentry/zeroentry - Define exception entry points.
  38  */
  39
  40 #include <linux/linkage.h>
  41 #include <asm/segment.h>
  42 #include <asm/cache.h>
  43 #include <asm/errno.h>
  44 #include <asm/dwarf2.h>
  45 #include <asm/calling.h>
  46 #include <asm/asm-offsets.h>
  47 #include <asm/msr.h>
  48 #include <asm/unistd.h>
  49 #include <asm/thread_info.h>
  50 #include <asm/hw_irq.h>
  51 #include <asm/page_types.h>
  52 #include <asm/irqflags.h>
  53 #include <asm/paravirt.h>
  54 #include <asm/ftrace.h>
  55 #include <asm/percpu.h>
  56
  57 /* Avoid __ASSEMBLER__'ifying <linux/audit.h> just for this.  */
  58 #include <linux/elf-em.h>
  59 #define AUDIT_ARCH_X86_64       (EM_X86_64|__AUDIT_ARCH_64BIT|__AUDIT_ARCH_LE)
  60 #define __AUDIT_ARCH_64BIT 0x80000000
  61 #define __AUDIT_ARCH_LE    0x40000000
  62
  63         .code64
  64 #ifdef CONFIG_FUNCTION_TRACER
  65 #ifdef CONFIG_DYNAMIC_FTRACE
  66 ENTRY(mcount)
  67         retq
  68 END(mcount)
  69
  70 ENTRY(ftrace_caller)
  71         cmpl $0, function_trace_stop
  72         jne  ftrace_stub
  73
  74         MCOUNT_SAVE_FRAME
  75
  76         movq 0x38(%rsp), %rdi
  77         movq 8(%rbp), %rsi
  78         subq $MCOUNT_INSN_SIZE, %rdi
  79
  80 GLOBAL(ftrace_call)
  81         call ftrace_stub
  82
  83         MCOUNT_RESTORE_FRAME
  84
  85 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
  86 GLOBAL(ftrace_graph_call)
  87         jmp ftrace_stub
  88 #endif
  89
  90 GLOBAL(ftrace_stub)
  91         retq
  92 END(ftrace_caller)
  93
  94 #else /* ! CONFIG_DYNAMIC_FTRACE */
  95 ENTRY(mcount)
  96         cmpl $0, function_trace_stop
  97         jne  ftrace_stub
  98
  99         cmpq $ftrace_stub, ftrace_trace_function
 100         jnz trace
 101
 102 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 103         cmpq $ftrace_stub, ftrace_graph_return
 104         jnz ftrace_graph_caller
 105
 106         cmpq $ftrace_graph_entry_stub, ftrace_graph_entry
 107         jnz ftrace_graph_caller
 108 #endif
 109
 110 GLOBAL(ftrace_stub)
 111         retq
 112
 113 trace:
 114         MCOUNT_SAVE_FRAME
 115
 116         movq 0x38(%rsp), %rdi
 117         movq 8(%rbp), %rsi
 118         subq $MCOUNT_INSN_SIZE, %rdi
 119
 120         call   *ftrace_trace_function
 121
 122         MCOUNT_RESTORE_FRAME
 123
 124         jmp ftrace_stub
 125 END(mcount)
 126 #endif /* CONFIG_DYNAMIC_FTRACE */
 127 #endif /* CONFIG_FUNCTION_TRACER */
 128
 129 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 130 ENTRY(ftrace_graph_caller)
 131         cmpl $0, function_trace_stop
 132         jne ftrace_stub
 133
 134         MCOUNT_SAVE_FRAME
 135
 136         leaq 8(%rbp), %rdi
 137         movq 0x38(%rsp), %rsi
 138         movq (%rbp), %rdx
 139         subq $MCOUNT_INSN_SIZE, %rsi
 140
 141         call    prepare_ftrace_return
 142
 143         MCOUNT_RESTORE_FRAME
 144
 145         retq
 146 END(ftrace_graph_caller)
 147
 148 GLOBAL(return_to_handler)
 149         subq  $24, %rsp
 150
 151         /* Save the return values */
 152         movq %rax, (%rsp)
 153         movq %rdx, 8(%rsp)
 154         movq %rbp, %rdi
 155
 156         call ftrace_return_to_handler
 157
 158         movq %rax, %rdi
 159         movq 8(%rsp), %rdx
 160         movq (%rsp), %rax
 161         addq $24, %rsp
 162         jmp *%rdi
 163 #endif
 164
 165
 166 #ifndef CONFIG_PREEMPT
 167 #define retint_kernel retint_restore_args
 168 #endif
 169
 170 #ifdef CONFIG_PARAVIRT
 171 ENTRY(native_usergs_sysret64)
 172         swapgs
 173         sysretq
 174 ENDPROC(native_usergs_sysret64)
 175 #endif /* CONFIG_PARAVIRT */
 176
 177
 178 .macro TRACE_IRQS_IRETQ offset=ARGOFFSET
 179 #ifdef CONFIG_TRACE_IRQFLAGS
 180         bt   $9,EFLAGS-\offset(%rsp)    /* interrupts off? */
 181         jnc  1f
 182         TRACE_IRQS_ON
 183 1:
 184 #endif
 185 .endm
 186
 187 /*
 188  * C code is not supposed to know about undefined top of stack. Every time
 189  * a C function with an pt_regs argument is called from the SYSCALL based
 190  * fast path FIXUP_TOP_OF_STACK is needed.
 191  * RESTORE_TOP_OF_STACK syncs the syscall state after any possible ptregs
 192  * manipulation.
 193  */
 194
 195         /* %rsp:at FRAMEEND */
 196         .macro FIXUP_TOP_OF_STACK tmp offset=0
 197         movq PER_CPU_VAR(old_rsp),\tmp
 198         movq \tmp,RSP+\offset(%rsp)
 199         movq $__USER_DS,SS+\offset(%rsp)
 200         movq $__USER_CS,CS+\offset(%rsp)
 201         movq $-1,RCX+\offset(%rsp)
 202         movq R11+\offset(%rsp),\tmp  /* get eflags */
 203         movq \tmp,EFLAGS+\offset(%rsp)
 204         .endm
 205
 206         .macro RESTORE_TOP_OF_STACK tmp offset=0
 207         movq RSP+\offset(%rsp),\tmp
 208         movq \tmp,PER_CPU_VAR(old_rsp)
 209         movq EFLAGS+\offset(%rsp),\tmp
 210         movq \tmp,R11+\offset(%rsp)
 211         .endm
 212
 213         .macro FAKE_STACK_FRAME child_rip
 214         /* push in order ss, rsp, eflags, cs, rip */
 215         xorl %eax, %eax
 216         pushq $__KERNEL_DS /* ss */
 217         CFI_ADJUST_CFA_OFFSET   8
 218         /*CFI_REL_OFFSET        ss,0*/
 219         pushq %rax /* rsp */
 220         CFI_ADJUST_CFA_OFFSET   8
 221         CFI_REL_OFFSET  rsp,0
 222         pushq $X86_EFLAGS_IF /* eflags - interrupts on */
 223         CFI_ADJUST_CFA_OFFSET   8
 224         /*CFI_REL_OFFSET        rflags,0*/
 225         pushq $__KERNEL_CS /* cs */
 226         CFI_ADJUST_CFA_OFFSET   8
 227         /*CFI_REL_OFFSET        cs,0*/
 228         pushq \child_rip /* rip */
 229         CFI_ADJUST_CFA_OFFSET   8
 230         CFI_REL_OFFSET  rip,0
 231         pushq   %rax /* orig rax */
 232         CFI_ADJUST_CFA_OFFSET   8
 233         .endm
 234
 235         .macro UNFAKE_STACK_FRAME
 236         addq $8*6, %rsp
 237         CFI_ADJUST_CFA_OFFSET   -(6*8)
 238         .endm
 239
 240 /*
 241  * initial frame state for interrupts (and exceptions without error code)
 242  */
 243         .macro EMPTY_FRAME start=1 offset=0
 244         .if \start
 245         CFI_STARTPROC simple
 246         CFI_SIGNAL_FRAME
 247         CFI_DEF_CFA rsp,8+\offset
 248         .else
 249         CFI_DEF_CFA_OFFSET 8+\offset
 250         .endif
 251         .endm
 252
 253 /*
 254  * initial frame state for interrupts (and exceptions without error code)
 255  */
 256         .macro INTR_FRAME start=1 offset=0
 257         EMPTY_FRAME \start, SS+8+\offset-RIP
 258         /*CFI_REL_OFFSET ss, SS+\offset-RIP*/
 259         CFI_REL_OFFSET rsp, RSP+\offset-RIP
 260         /*CFI_REL_OFFSET rflags, EFLAGS+\offset-RIP*/
 261         /*CFI_REL_OFFSET cs, CS+\offset-RIP*/
 262         CFI_REL_OFFSET rip, RIP+\offset-RIP
 263         .endm
 264
 265 /*
 266  * initial frame state for exceptions with error code (and interrupts
 267  * with vector already pushed)
 268  */
 269         .macro XCPT_FRAME start=1 offset=0
 270         INTR_FRAME \start, RIP+\offset-ORIG_RAX
 271         /*CFI_REL_OFFSET orig_rax, ORIG_RAX-ORIG_RAX*/
 272         .endm
 273
 274 /*
 275  * frame that enables calling into C.
 276  */
 277         .macro PARTIAL_FRAME start=1 offset=0
 278         XCPT_FRAME \start, ORIG_RAX+\offset-ARGOFFSET
 279         CFI_REL_OFFSET rdi, RDI+\offset-ARGOFFSET
 280         CFI_REL_OFFSET rsi, RSI+\offset-ARGOFFSET
 281         CFI_REL_OFFSET rdx, RDX+\offset-ARGOFFSET
 282         CFI_REL_OFFSET rcx, RCX+\offset-ARGOFFSET
 283         CFI_REL_OFFSET rax, RAX+\offset-ARGOFFSET
 284         CFI_REL_OFFSET r8, R8+\offset-ARGOFFSET
 285         CFI_REL_OFFSET r9, R9+\offset-ARGOFFSET
 286         CFI_REL_OFFSET r10, R10+\offset-ARGOFFSET
 287         CFI_REL_OFFSET r11, R11+\offset-ARGOFFSET
 288         .endm
 289
 290 /*
 291  * frame that enables passing a complete pt_regs to a C function.
 292  */
 293         .macro DEFAULT_FRAME start=1 offset=0
 294         PARTIAL_FRAME \start, R11+\offset-R15
 295         CFI_REL_OFFSET rbx, RBX+\offset
 296         CFI_REL_OFFSET rbp, RBP+\offset
 297         CFI_REL_OFFSET r12, R12+\offset
 298         CFI_REL_OFFSET r13, R13+\offset
 299         CFI_REL_OFFSET r14, R14+\offset
 300         CFI_REL_OFFSET r15, R15+\offset
 301         .endm
 302
 303 /* save partial stack frame */
 304 ENTRY(save_args)
 305         XCPT_FRAME
 306         cld
 307         movq_cfi rdi, RDI+16-ARGOFFSET
 308         movq_cfi rsi, RSI+16-ARGOFFSET
 309         movq_cfi rdx, RDX+16-ARGOFFSET
 310         movq_cfi rcx, RCX+16-ARGOFFSET
 311         movq_cfi rax, RAX+16-ARGOFFSET
 312         movq_cfi  r8,  R8+16-ARGOFFSET
 313         movq_cfi  r9,  R9+16-ARGOFFSET
 314         movq_cfi r10, R10+16-ARGOFFSET
 315         movq_cfi r11, R11+16-ARGOFFSET
 316
 317         leaq -ARGOFFSET+16(%rsp),%rdi   /* arg1 for handler */
 318         movq_cfi rbp, 8         /* push %rbp */
 319         leaq 8(%rsp), %rbp              /* mov %rsp, %ebp */
 320         testl $3, CS(%rdi)
 321         je 1f
 322         SWAPGS
 323         /*
 324          * irq_count is used to check if a CPU is already on an interrupt stack
 325          * or not. While this is essentially redundant with preempt_count it is
 326          * a little cheaper to use a separate counter in the PDA (short of
 327          * moving irq_enter into assembly, which would be too much work)
 328          */
 329 1:      incl PER_CPU_VAR(irq_count)
 330         jne 2f
 331         popq_cfi %rax                   /* move return address... */
 332         mov PER_CPU_VAR(irq_stack_ptr),%rsp
 333         EMPTY_FRAME 0
 334         pushq_cfi %rbp                  /* backlink for unwinder */
 335         pushq_cfi %rax                  /* ... to the new stack */
 336         /*
 337          * We entered an interrupt context - irqs are off:
 338          */
 339 2:      TRACE_IRQS_OFF
 340         ret
 341         CFI_ENDPROC
 342 END(save_args)
 343
 344 ENTRY(save_rest)
 345         PARTIAL_FRAME 1 REST_SKIP+8
 346         movq 5*8+16(%rsp), %r11 /* save return address */
 347         movq_cfi rbx, RBX+16
 348         movq_cfi rbp, RBP+16
 349         movq_cfi r12, R12+16
 350         movq_cfi r13, R13+16
 351         movq_cfi r14, R14+16
 352         movq_cfi r15, R15+16
 353         movq %r11, 8(%rsp)      /* return address */
 354         FIXUP_TOP_OF_STACK %r11, 16
 355         ret
 356         CFI_ENDPROC
 357 END(save_rest)
 358
 359 /* save complete stack frame */
 360         .pushsection .kprobes.text, "ax"
 361 ENTRY(save_paranoid)
 362         XCPT_FRAME 1 RDI+8
 363         cld
 364         movq_cfi rdi, RDI+8
 365         movq_cfi rsi, RSI+8
 366         movq_cfi rdx, RDX+8
 367         movq_cfi rcx, RCX+8
 368         movq_cfi rax, RAX+8
 369         movq_cfi r8, R8+8
 370         movq_cfi r9, R9+8
 371         movq_cfi r10, R10+8
 372         movq_cfi r11, R11+8
 373         movq_cfi rbx, RBX+8
 374         movq_cfi rbp, RBP+8
 375         movq_cfi r12, R12+8
 376         movq_cfi r13, R13+8
 377         movq_cfi r14, R14+8
 378         movq_cfi r15, R15+8
 379         movl $1,%ebx
 380         movl $MSR_GS_BASE,%ecx
 381         rdmsr
 382         testl %edx,%edx
 383         js 1f   /* negative -> in kernel */
 384         SWAPGS
 385         xorl %ebx,%ebx
 386 1:      ret
 387         CFI_ENDPROC
 388 END(save_paranoid)
 389         .popsection
 390
 391 /*
 392  * A newly forked process directly context switches into this address.
 393  *
 394  * rdi: prev task we switched from
 395  */
 396 ENTRY(ret_from_fork)
 397         DEFAULT_FRAME
 398
 399         LOCK ; btr $TIF_FORK,TI_flags(%r8)
 400
 401         push kernel_eflags(%rip)
 402         CFI_ADJUST_CFA_OFFSET 8
 403         popf                                    # reset kernel eflags
 404         CFI_ADJUST_CFA_OFFSET -8
 405
 406         call schedule_tail                      # rdi: 'prev' task parameter
 407
 408         GET_THREAD_INFO(%rcx)
 409
 410         RESTORE_REST
 411
 412         testl $3, CS-ARGOFFSET(%rsp)            # from kernel_thread?
 413         je   int_ret_from_sys_call
 414
 415         testl $_TIF_IA32, TI_flags(%rcx)        # 32-bit compat task needs IRET
 416         jnz  int_ret_from_sys_call
 417
 418         RESTORE_TOP_OF_STACK %rdi, -ARGOFFSET
 419         jmp ret_from_sys_call                   # go to the SYSRET fastpath
 420
 421         CFI_ENDPROC
 422 END(ret_from_fork)
 423
 424 /*
 425  * System call entry. Upto 6 arguments in registers are supported.
 426  *
 427  * SYSCALL does not save anything on the stack and does not change the
 428  * stack pointer.
 429  */
 430
 431 /*
 432  * Register setup:
 433  * rax  system call number
 434  * rdi  arg0
 435  * rcx  return address for syscall/sysret, C arg3
 436  * rsi  arg1
 437  * rdx  arg2
 438  * r10  arg3    (--> moved to rcx for C)
 439  * r8   arg4
 440  * r9   arg5
 441  * r11  eflags for syscall/sysret, temporary for C
 442  * r12-r15,rbp,rbx saved by C code, not touched.
 443  *
 444  * Interrupts are off on entry.
 445  * Only called from user space.
 446  *
 447  * XXX  if we had a free scratch register we could save the RSP into the stack frame
 448  *      and report it properly in ps. Unfortunately we haven't.
 449  *
 450  * When user can change the frames always force IRET. That is because
 451  * it deals with uncanonical addresses better. SYSRET has trouble
 452  * with them due to bugs in both AMD and Intel CPUs.
 453  */
 454
 455 ENTRY(system_call)
 456         CFI_STARTPROC   simple
 457         CFI_SIGNAL_FRAME
 458         CFI_DEF_CFA     rsp,KERNEL_STACK_OFFSET
 459         CFI_REGISTER    rip,rcx
 460         /*CFI_REGISTER  rflags,r11*/
 461         SWAPGS_UNSAFE_STACK
 462         /*
 463          * A hypervisor implementation might want to use a label
 464          * after the swapgs, so that it can do the swapgs
 465          * for the guest and jump here on syscall.
 466          */
 467 ENTRY(system_call_after_swapgs)
 468
 469         movq    %rsp,PER_CPU_VAR(old_rsp)
 470         movq    PER_CPU_VAR(kernel_stack),%rsp
 471         /*
 472          * No need to follow this irqs off/on section - it's straight
 473          * and short:
 474          */
 475         ENABLE_INTERRUPTS(CLBR_NONE)
 476         SAVE_ARGS 8,1
 477         movq  %rax,ORIG_RAX-ARGOFFSET(%rsp)
 478         movq  %rcx,RIP-ARGOFFSET(%rsp)
 479         CFI_REL_OFFSET rip,RIP-ARGOFFSET
 480         GET_THREAD_INFO(%rcx)
 481         testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags(%rcx)
 482         jnz tracesys
 483 system_call_fastpath:
 484         cmpq $__NR_syscall_max,%rax
 485         ja badsys
 486         movq %r10,%rcx
 487         call *sys_call_table(,%rax,8)  # XXX:    rip relative
 488         movq %rax,RAX-ARGOFFSET(%rsp)
 489 /*
 490  * Syscall return path ending with SYSRET (fast path)
 491  * Has incomplete stack frame and undefined top of stack.
 492  */
 493 ret_from_sys_call:
 494         movl $_TIF_ALLWORK_MASK,%edi
 495         /* edi: flagmask */
 496 sysret_check:
 497         LOCKDEP_SYS_EXIT
 498         GET_THREAD_INFO(%rcx)
 499         DISABLE_INTERRUPTS(CLBR_NONE)
 500         TRACE_IRQS_OFF
 501         movl TI_flags(%rcx),%edx
 502         andl %edi,%edx
 503         jnz  sysret_careful
 504         CFI_REMEMBER_STATE
 505         /*
 506          * sysretq will re-enable interrupts:
 507          */
 508         TRACE_IRQS_ON
 509         movq RIP-ARGOFFSET(%rsp),%rcx
 510         CFI_REGISTER    rip,rcx
 511         RESTORE_ARGS 0,-ARG_SKIP,1
 512         /*CFI_REGISTER  rflags,r11*/
 513         movq    PER_CPU_VAR(old_rsp), %rsp
 514         USERGS_SYSRET64
 515
 516         CFI_RESTORE_STATE
 517         /* Handle reschedules */
 518         /* edx: work, edi: workmask */
 519 sysret_careful:
 520         bt $TIF_NEED_RESCHED,%edx
 521         jnc sysret_signal
 522         TRACE_IRQS_ON
 523         ENABLE_INTERRUPTS(CLBR_NONE)
 524         pushq %rdi
 525         CFI_ADJUST_CFA_OFFSET 8
 526         call schedule
 527         popq  %rdi
 528         CFI_ADJUST_CFA_OFFSET -8
 529         jmp sysret_check
 530
 531         /* Handle a signal */
 532 sysret_signal:
 533         TRACE_IRQS_ON
 534         ENABLE_INTERRUPTS(CLBR_NONE)
 535 #ifdef CONFIG_AUDITSYSCALL
 536         bt $TIF_SYSCALL_AUDIT,%edx
 537         jc sysret_audit
 538 #endif
 539         /*
 540          * We have a signal, or exit tracing or single-step.
 541          * These all wind up with the iret return path anyway,
 542          * so just join that path right now.
 543          */
 544         FIXUP_TOP_OF_STACK %r11, -ARGOFFSET
 545         jmp int_check_syscall_exit_work
 546
 547 badsys:
 548         movq $-ENOSYS,RAX-ARGOFFSET(%rsp)
 549         jmp ret_from_sys_call
 550
 551 #ifdef CONFIG_AUDITSYSCALL
 552         /*
 553          * Fast path for syscall audit without full syscall trace.
 554          * We just call audit_syscall_entry() directly, and then
 555          * jump back to the normal fast path.
 556          */
 557 auditsys:
 558         movq %r10,%r9                   /* 6th arg: 4th syscall arg */
 559         movq %rdx,%r8                   /* 5th arg: 3rd syscall arg */
 560         movq %rsi,%rcx                  /* 4th arg: 2nd syscall arg */
 561         movq %rdi,%rdx                  /* 3rd arg: 1st syscall arg */
 562         movq %rax,%rsi                  /* 2nd arg: syscall number */
 563         movl $AUDIT_ARCH_X86_64,%edi    /* 1st arg: audit arch */
 564         call audit_syscall_entry
 565         LOAD_ARGS 0             /* reload call-clobbered registers */
 566         jmp system_call_fastpath
 567
 568         /*
 569          * Return fast path for syscall audit.  Call audit_syscall_exit()
 570          * directly and then jump back to the fast path with TIF_SYSCALL_AUDIT
 571          * masked off.
 572          */
 573 sysret_audit:
 574         movq %rax,%rsi          /* second arg, syscall return value */
 575         cmpq $0,%rax            /* is it < 0? */
 576         setl %al                /* 1 if so, 0 if not */
 577         movzbl %al,%edi         /* zero-extend that into %edi */
 578         inc %edi /* first arg, 0->1(AUDITSC_SUCCESS), 1->2(AUDITSC_FAILURE) */
 579         call audit_syscall_exit
 580         movl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT),%edi
 581         jmp sysret_check
 582 #endif  /* CONFIG_AUDITSYSCALL */
 583
 584         /* Do syscall tracing */
 585 tracesys:
 586 #ifdef CONFIG_AUDITSYSCALL
 587         testl $(_TIF_WORK_SYSCALL_ENTRY & ~_TIF_SYSCALL_AUDIT),TI_flags(%rcx)
 588         jz auditsys
 589 #endif
 590         SAVE_REST
 591         movq $-ENOSYS,RAX(%rsp) /* ptrace can change this for a bad syscall */
 592         FIXUP_TOP_OF_STACK %rdi
 593         movq %rsp,%rdi
 594         call syscall_trace_enter
 595         /*
 596          * Reload arg registers from stack in case ptrace changed them.
 597          * We don't reload %rax because syscall_trace_enter() returned
 598          * the value it wants us to use in the table lookup.
 599          */
 600         LOAD_ARGS ARGOFFSET, 1
 601         RESTORE_REST
 602         cmpq $__NR_syscall_max,%rax
 603         ja   int_ret_from_sys_call      /* RAX(%rsp) set to -ENOSYS above */
 604         movq %r10,%rcx  /* fixup for C */
 605         call *sys_call_table(,%rax,8)
 606         movq %rax,RAX-ARGOFFSET(%rsp)
 607         /* Use IRET because user could have changed frame */
 608
 609 /*
 610  * Syscall return path ending with IRET.
 611  * Has correct top of stack, but partial stack frame.
 612  */
 613 GLOBAL(int_ret_from_sys_call)
 614         DISABLE_INTERRUPTS(CLBR_NONE)
 615         TRACE_IRQS_OFF
 616         testl $3,CS-ARGOFFSET(%rsp)
 617         je retint_restore_args
 618         movl $_TIF_ALLWORK_MASK,%edi
 619         /* edi: mask to check */
 620 GLOBAL(int_with_check)
 621         LOCKDEP_SYS_EXIT_IRQ
 622         GET_THREAD_INFO(%rcx)
 623         movl TI_flags(%rcx),%edx
 624         andl %edi,%edx
 625         jnz   int_careful
 626         andl    $~TS_COMPAT,TI_status(%rcx)
 627         jmp   retint_swapgs
 628
 629         /* Either reschedule or signal or syscall exit tracking needed. */
 630         /* First do a reschedule test. */
 631         /* edx: work, edi: workmask */
 632 int_careful:
 633         bt $TIF_NEED_RESCHED,%edx
 634         jnc  int_very_careful
 635         TRACE_IRQS_ON
 636         ENABLE_INTERRUPTS(CLBR_NONE)
 637         pushq %rdi
 638         CFI_ADJUST_CFA_OFFSET 8
 639         call schedule
 640         popq %rdi
 641         CFI_ADJUST_CFA_OFFSET -8
 642         DISABLE_INTERRUPTS(CLBR_NONE)
 643         TRACE_IRQS_OFF
 644         jmp int_with_check
 645
 646         /* handle signals and tracing -- both require a full stack frame */
 647 int_very_careful:
 648         TRACE_IRQS_ON
 649         ENABLE_INTERRUPTS(CLBR_NONE)
 650 int_check_syscall_exit_work:
 651         SAVE_REST
 652         /* Check for syscall exit trace */
 653         testl $_TIF_WORK_SYSCALL_EXIT,%edx
 654         jz int_signal
 655         pushq %rdi
 656         CFI_ADJUST_CFA_OFFSET 8
 657         leaq 8(%rsp),%rdi       # &ptregs -> arg1
 658         call syscall_trace_leave
 659         popq %rdi
 660         CFI_ADJUST_CFA_OFFSET -8
 661         andl $~(_TIF_WORK_SYSCALL_EXIT|_TIF_SYSCALL_EMU),%edi
 662         jmp int_restore_rest
 663
 664 int_signal:
 665         testl $_TIF_DO_NOTIFY_MASK,%edx
 666         jz 1f
 667         movq %rsp,%rdi          # &ptregs -> arg1
 668         xorl %esi,%esi          # oldset -> arg2
 669         call do_notify_resume
 670 1:      movl $_TIF_WORK_MASK,%edi
 671 int_restore_rest:
 672         RESTORE_REST
 673         DISABLE_INTERRUPTS(CLBR_NONE)
 674         TRACE_IRQS_OFF
 675         jmp int_with_check
 676         CFI_ENDPROC
 677 END(system_call)
 678
 679 /*
 680  * Certain special system calls that need to save a complete full stack frame.
 681  */
 682         .macro PTREGSCALL label,func,arg
 683 ENTRY(\label)
 684         PARTIAL_FRAME 1 8               /* offset 8: return address */
 685         subq $REST_SKIP, %rsp
 686         CFI_ADJUST_CFA_OFFSET REST_SKIP
 687         call save_rest
 688         DEFAULT_FRAME 0 8               /* offset 8: return address */
 689         leaq 8(%rsp), \arg      /* pt_regs pointer */
 690         call \func
 691         jmp ptregscall_common
 692         CFI_ENDPROC
 693 END(\label)
 694         .endm
 695
 696         PTREGSCALL stub_clone, sys_clone, %r8
 697         PTREGSCALL stub_fork, sys_fork, %rdi
 698         PTREGSCALL stub_vfork, sys_vfork, %rdi
 699         PTREGSCALL stub_sigaltstack, sys_sigaltstack, %rdx
 700         PTREGSCALL stub_iopl, sys_iopl, %rsi
 701
 702 ENTRY(ptregscall_common)
 703         DEFAULT_FRAME 1 8       /* offset 8: return address */
 704         RESTORE_TOP_OF_STACK %r11, 8
 705         movq_cfi_restore R15+8, r15
 706         movq_cfi_restore R14+8, r14
 707         movq_cfi_restore R13+8, r13
 708         movq_cfi_restore R12+8, r12
 709         movq_cfi_restore RBP+8, rbp
 710         movq_cfi_restore RBX+8, rbx
 711         ret $REST_SKIP          /* pop extended registers */
 712         CFI_ENDPROC
 713 END(ptregscall_common)
 714
 715 ENTRY(stub_execve)
 716         CFI_STARTPROC
 717         popq %r11
 718         CFI_ADJUST_CFA_OFFSET -8
 719         CFI_REGISTER rip, r11
 720         SAVE_REST
 721         FIXUP_TOP_OF_STACK %r11
 722         movq %rsp, %rcx
 723         call sys_execve
 724         RESTORE_TOP_OF_STACK %r11
 725         movq %rax,RAX(%rsp)
 726         RESTORE_REST
 727         jmp int_ret_from_sys_call
 728         CFI_ENDPROC
 729 END(stub_execve)
 730
 731 /*
 732  * sigreturn is special because it needs to restore all registers on return.
 733  * This cannot be done with SYSRET, so use the IRET return path instead.
 734  */
 735 ENTRY(stub_rt_sigreturn)
 736         CFI_STARTPROC
 737         addq $8, %rsp
 738         CFI_ADJUST_CFA_OFFSET   -8
 739         SAVE_REST
 740         movq %rsp,%rdi
 741         FIXUP_TOP_OF_STACK %r11
 742         call sys_rt_sigreturn
 743         movq %rax,RAX(%rsp) # fixme, this could be done at the higher layer
 744         RESTORE_REST
 745         jmp int_ret_from_sys_call
 746         CFI_ENDPROC
 747 END(stub_rt_sigreturn)
 748
 749 /*
 750  * Build the entry stubs and pointer table with some assembler magic.
 751  * We pack 7 stubs into a single 32-byte chunk, which will fit in a
 752  * single cache line on all modern x86 implementations.
 753  */
 754         .section .init.rodata,"a"
 755 ENTRY(interrupt)
 756         .text
 757         .p2align 5
 758         .p2align CONFIG_X86_L1_CACHE_SHIFT
 759 ENTRY(irq_entries_start)
 760         INTR_FRAME
 761 vector=FIRST_EXTERNAL_VECTOR
 762 .rept (NR_VECTORS-FIRST_EXTERNAL_VECTOR+6)/7
 763         .balign 32
 764   .rept 7
 765     .if vector < NR_VECTORS
 766       .if vector <> FIRST_EXTERNAL_VECTOR
 767         CFI_ADJUST_CFA_OFFSET -8
 768       .endif
 769 1:      pushq $(~vector+0x80)   /* Note: always in signed byte range */
 770         CFI_ADJUST_CFA_OFFSET 8
 771       .if ((vector-FIRST_EXTERNAL_VECTOR)%7) <> 6
 772         jmp 2f
 773       .endif
 774       .previous
 775         .quad 1b
 776       .text
 777 vector=vector+1
 778     .endif
 779   .endr
 780 2:      jmp common_interrupt
 781 .endr
 782         CFI_ENDPROC
 783 END(irq_entries_start)
 784
 785 .previous
 786 END(interrupt)
 787 .previous
 788
 789 /*
 790  * Interrupt entry/exit.
 791  *
 792  * Interrupt entry points save only callee clobbered registers in fast path.
 793  *
 794  * Entry runs with interrupts off.
 795  */
 796
 797 /* 0(%rsp): ~(interrupt number) */
 798         .macro interrupt func
 799         subq $10*8, %rsp
 800         CFI_ADJUST_CFA_OFFSET 10*8
 801         call save_args
 802         PARTIAL_FRAME 0
 803         call \func
 804         .endm
 805
 806 /*
 807  * Interrupt entry/exit should be protected against kprobes
 808  */
 809         .pushsection .kprobes.text, "ax"
 810         /*
 811          * The interrupt stubs push (~vector+0x80) onto the stack and
 812          * then jump to common_interrupt.
 813          */
 814         .p2align CONFIG_X86_L1_CACHE_SHIFT
 815 common_interrupt:
 816         XCPT_FRAME
 817         addq $-0x80,(%rsp)              /* Adjust vector to [-256,-1] range */
 818         interrupt do_IRQ
 819         /* 0(%rsp): old_rsp-ARGOFFSET */
 820 ret_from_intr:
 821         DISABLE_INTERRUPTS(CLBR_NONE)
 822         TRACE_IRQS_OFF
 823         decl PER_CPU_VAR(irq_count)
 824         leaveq
 825         CFI_DEF_CFA_REGISTER    rsp
 826         CFI_ADJUST_CFA_OFFSET   -8
 827 exit_intr:
 828         GET_THREAD_INFO(%rcx)
 829         testl $3,CS-ARGOFFSET(%rsp)
 830         je retint_kernel
 831
 832         /* Interrupt came from user space */
 833         /*
 834          * Has a correct top of stack, but a partial stack frame
 835          * %rcx: thread info. Interrupts off.
 836          */
 837 retint_with_reschedule:
 838         movl $_TIF_WORK_MASK,%edi
 839 retint_check:
 840         LOCKDEP_SYS_EXIT_IRQ
 841         movl TI_flags(%rcx),%edx
 842         andl %edi,%edx
 843         CFI_REMEMBER_STATE
 844         jnz  retint_careful
 845
 846 retint_swapgs:          /* return to user-space */
 847         /*
 848          * The iretq could re-enable interrupts:
 849          */
 850         DISABLE_INTERRUPTS(CLBR_ANY)
 851         TRACE_IRQS_IRETQ
 852         SWAPGS
 853         jmp restore_args
 854
 855 retint_restore_args:    /* return to kernel space */
 856         DISABLE_INTERRUPTS(CLBR_ANY)
 857         /*
 858          * The iretq could re-enable interrupts:
 859          */
 860         TRACE_IRQS_IRETQ
 861 restore_args:
 862         RESTORE_ARGS 0,8,0
 863
 864 irq_return:
 865         INTERRUPT_RETURN
 866
 867         .section __ex_table, "a"
 868         .quad irq_return, bad_iret
 869         .previous
 870
 871 #ifdef CONFIG_PARAVIRT
 872 ENTRY(native_iret)
 873         iretq
 874
 875         .section __ex_table,"a"
 876         .quad native_iret, bad_iret
 877         .previous
 878 #endif
 879
 880         .section .fixup,"ax"
 881 bad_iret:
 882         /*
 883          * The iret traps when the %cs or %ss being restored is bogus.
 884          * We've lost the original trap vector and error code.
 885          * #GPF is the most likely one to get for an invalid selector.
 886          * So pretend we completed the iret and took the #GPF in user mode.
 887          *
 888          * We are now running with the kernel GS after exception recovery.
 889          * But error_entry expects us to have user GS to match the user %cs,
 890          * so swap back.
 891          */
 892         pushq $0
 893
 894         SWAPGS
 895         jmp general_protection
 896
 897         .previous
 898
 899         /* edi: workmask, edx: work */
 900 retint_careful:
 901         CFI_RESTORE_STATE
 902         bt    $TIF_NEED_RESCHED,%edx
 903         jnc   retint_signal
 904         TRACE_IRQS_ON
 905         ENABLE_INTERRUPTS(CLBR_NONE)
 906         pushq %rdi
 907         CFI_ADJUST_CFA_OFFSET   8
 908         call  schedule
 909         popq %rdi
 910         CFI_ADJUST_CFA_OFFSET   -8
 911         GET_THREAD_INFO(%rcx)
 912         DISABLE_INTERRUPTS(CLBR_NONE)
 913         TRACE_IRQS_OFF
 914         jmp retint_check
 915
 916 retint_signal:
 917         testl $_TIF_DO_NOTIFY_MASK,%edx
 918         jz    retint_swapgs
 919         TRACE_IRQS_ON
 920         ENABLE_INTERRUPTS(CLBR_NONE)
 921         SAVE_REST
 922         movq $-1,ORIG_RAX(%rsp)
 923         xorl %esi,%esi          # oldset
 924         movq %rsp,%rdi          # &pt_regs
 925         call do_notify_resume
 926         RESTORE_REST
 927         DISABLE_INTERRUPTS(CLBR_NONE)
 928         TRACE_IRQS_OFF
 929         GET_THREAD_INFO(%rcx)
 930         jmp retint_with_reschedule
 931
 932 #ifdef CONFIG_PREEMPT
 933         /* Returning to kernel space. Check if we need preemption */
 934         /* rcx:  threadinfo. interrupts off. */
 935 ENTRY(retint_kernel)
 936         cmpl $0,TI_preempt_count(%rcx)
 937         jnz  retint_restore_args
 938         bt  $TIF_NEED_RESCHED,TI_flags(%rcx)
 939         jnc  retint_restore_args
 940         bt   $9,EFLAGS-ARGOFFSET(%rsp)  /* interrupts off? */
 941         jnc  retint_restore_args
 942         call preempt_schedule_irq
 943         jmp exit_intr
 944 #endif
 945
 946         CFI_ENDPROC
 947 END(common_interrupt)
 948 /*
 949  * End of kprobes section
 950  */
 951        .popsection
 952
 953 /*
 954  * APIC interrupts.
 955  */
 956 .macro apicinterrupt num sym do_sym
 957 ENTRY(\sym)
 958         INTR_FRAME
 959         pushq $~(\num)
 960         CFI_ADJUST_CFA_OFFSET 8
 961         interrupt \do_sym
 962         jmp ret_from_intr
 963         CFI_ENDPROC
 964 END(\sym)
 965 .endm
 966
 967 #ifdef CONFIG_SMP
 968 apicinterrupt IRQ_MOVE_CLEANUP_VECTOR \
 969         irq_move_cleanup_interrupt smp_irq_move_cleanup_interrupt
 970 apicinterrupt REBOOT_VECTOR \
 971         reboot_interrupt smp_reboot_interrupt
 972 #endif
 973
 974 #ifdef CONFIG_X86_UV
 975 apicinterrupt UV_BAU_MESSAGE \
 976         uv_bau_message_intr1 uv_bau_message_interrupt
 977 #endif
 978 apicinterrupt LOCAL_TIMER_VECTOR \
 979         apic_timer_interrupt smp_apic_timer_interrupt
 980 apicinterrupt X86_PLATFORM_IPI_VECTOR \
 981         x86_platform_ipi smp_x86_platform_ipi
 982
 983 #ifdef CONFIG_SMP
 984 apicinterrupt INVALIDATE_TLB_VECTOR_START+0 \
 985         invalidate_interrupt0 smp_invalidate_interrupt
 986 apicinterrupt INVALIDATE_TLB_VECTOR_START+1 \
 987         invalidate_interrupt1 smp_invalidate_interrupt
 988 apicinterrupt INVALIDATE_TLB_VECTOR_START+2 \
 989         invalidate_interrupt2 smp_invalidate_interrupt
 990 apicinterrupt INVALIDATE_TLB_VECTOR_START+3 \
 991         invalidate_interrupt3 smp_invalidate_interrupt
 992 apicinterrupt INVALIDATE_TLB_VECTOR_START+4 \
 993         invalidate_interrupt4 smp_invalidate_interrupt
 994 apicinterrupt INVALIDATE_TLB_VECTOR_START+5 \
 995         invalidate_interrupt5 smp_invalidate_interrupt
 996 apicinterrupt INVALIDATE_TLB_VECTOR_START+6 \
 997         invalidate_interrupt6 smp_invalidate_interrupt
 998 apicinterrupt INVALIDATE_TLB_VECTOR_START+7 \
 999         invalidate_interrupt7 smp_invalidate_interrupt
1000 #endif
1001
1002 apicinterrupt THRESHOLD_APIC_VECTOR \
1003         threshold_interrupt smp_threshold_interrupt
1004 apicinterrupt THERMAL_APIC_VECTOR \
1005         thermal_interrupt smp_thermal_interrupt
1006
1007 #ifdef CONFIG_X86_MCE
1008 apicinterrupt MCE_SELF_VECTOR \
1009         mce_self_interrupt smp_mce_self_interrupt
1010 #endif
1011
1012 #ifdef CONFIG_SMP
1013 apicinterrupt CALL_FUNCTION_SINGLE_VECTOR \
1014         call_function_single_interrupt smp_call_function_single_interrupt
1015 apicinterrupt CALL_FUNCTION_VECTOR \
1016         call_function_interrupt smp_call_function_interrupt
1017 apicinterrupt RESCHEDULE_VECTOR \
1018         reschedule_interrupt smp_reschedule_interrupt
1019 #endif
1020
1021 apicinterrupt ERROR_APIC_VECTOR \
1022         error_interrupt smp_error_interrupt
1023 apicinterrupt SPURIOUS_APIC_VECTOR \
1024         spurious_interrupt smp_spurious_interrupt
1025
1026 #ifdef CONFIG_PERF_EVENTS
1027 apicinterrupt LOCAL_PENDING_VECTOR \
1028         perf_pending_interrupt smp_perf_pending_interrupt
1029 #endif
1030
1031 /*
1032  * Exception entry points.
1033  */
1034 .macro zeroentry sym do_sym
1035 ENTRY(\sym)
1036         INTR_FRAME
1037         PARAVIRT_ADJUST_EXCEPTION_FRAME
1038         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1039         subq $15*8,%rsp
1040         CFI_ADJUST_CFA_OFFSET 15*8
1041         call error_entry
1042         DEFAULT_FRAME 0
1043         movq %rsp,%rdi          /* pt_regs pointer */
1044         xorl %esi,%esi          /* no error code */
1045         call \do_sym
1046         jmp error_exit          /* %ebx: no swapgs flag */
1047         CFI_ENDPROC
1048 END(\sym)
1049 .endm
1050
1051 .macro paranoidzeroentry sym do_sym
1052 ENTRY(\sym)
1053         INTR_FRAME
1054         PARAVIRT_ADJUST_EXCEPTION_FRAME
1055         pushq $-1               /* ORIG_RAX: no syscall to restart */
1056         CFI_ADJUST_CFA_OFFSET 8
1057         subq $15*8, %rsp
1058         call save_paranoid
1059         TRACE_IRQS_OFF
1060         movq %rsp,%rdi          /* pt_regs pointer */
1061         xorl %esi,%esi          /* no error code */
1062         call \do_sym
1063         jmp paranoid_exit       /* %ebx: no swapgs flag */
1064         CFI_ENDPROC
1065 END(\sym)
1066 .endm
1067
1068 .macro paranoidzeroentry_ist sym do_sym ist
1069 ENTRY(\sym)
1070         INTR_FRAME
1071         PARAVIRT_ADJUST_EXCEPTION_FRAME
1072         pushq $-1               /* ORIG_RAX: no syscall to restart */
1073         CFI_ADJUST_CFA_OFFSET 8
1074         subq $15*8, %rsp
1075         call save_paranoid
1076         TRACE_IRQS_OFF
1077         movq %rsp,%rdi          /* pt_regs pointer */
1078         xorl %esi,%esi          /* no error code */
1079         PER_CPU(init_tss, %rbp)
1080         subq $EXCEPTION_STKSZ, TSS_ist + (\ist - 1) * 8(%rbp)
1081         call \do_sym
1082         addq $EXCEPTION_STKSZ, TSS_ist + (\ist - 1) * 8(%rbp)
1083         jmp paranoid_exit       /* %ebx: no swapgs flag */
1084         CFI_ENDPROC
1085 END(\sym)
1086 .endm
1087
1088 .macro errorentry sym do_sym
1089 ENTRY(\sym)
1090         XCPT_FRAME
1091         PARAVIRT_ADJUST_EXCEPTION_FRAME
1092         subq $15*8,%rsp
1093         CFI_ADJUST_CFA_OFFSET 15*8
1094         call error_entry
1095         DEFAULT_FRAME 0
1096         movq %rsp,%rdi                  /* pt_regs pointer */
1097         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1098         movq $-1,ORIG_RAX(%rsp)         /* no syscall to restart */
1099         call \do_sym
1100         jmp error_exit                  /* %ebx: no swapgs flag */
1101         CFI_ENDPROC
1102 END(\sym)
1103 .endm
1104
1105         /* error code is on the stack already */
1106 .macro paranoiderrorentry sym do_sym
1107 ENTRY(\sym)
1108         XCPT_FRAME
1109         PARAVIRT_ADJUST_EXCEPTION_FRAME
1110         subq $15*8,%rsp
1111         CFI_ADJUST_CFA_OFFSET 15*8
1112         call save_paranoid
1113         DEFAULT_FRAME 0
1114         TRACE_IRQS_OFF
1115         movq %rsp,%rdi                  /* pt_regs pointer */
1116         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1117         movq $-1,ORIG_RAX(%rsp)         /* no syscall to restart */
1118         call \do_sym
1119         jmp paranoid_exit               /* %ebx: no swapgs flag */
1120         CFI_ENDPROC
1121 END(\sym)
1122 .endm
1123
1124 zeroentry divide_error do_divide_error
1125 zeroentry overflow do_overflow
1126 zeroentry bounds do_bounds
1127 zeroentry invalid_op do_invalid_op
1128 zeroentry device_not_available do_device_not_available
1129 paranoiderrorentry double_fault do_double_fault
1130 zeroentry coprocessor_segment_overrun do_coprocessor_segment_overrun
1131 errorentry invalid_TSS do_invalid_TSS
1132 errorentry segment_not_present do_segment_not_present
1133 zeroentry spurious_interrupt_bug do_spurious_interrupt_bug
1134 zeroentry coprocessor_error do_coprocessor_error
1135 errorentry alignment_check do_alignment_check
1136 zeroentry simd_coprocessor_error do_simd_coprocessor_error
1137
1138         /* Reload gs selector with exception handling */
1139         /* edi:  new selector */
1140 ENTRY(native_load_gs_index)
1141         CFI_STARTPROC
1142         pushf
1143         CFI_ADJUST_CFA_OFFSET 8
1144         DISABLE_INTERRUPTS(CLBR_ANY & ~CLBR_RDI)
1145         SWAPGS
1146 gs_change:
1147         movl %edi,%gs
1148 2:      mfence          /* workaround */
1149         SWAPGS
1150         popf
1151         CFI_ADJUST_CFA_OFFSET -8
1152         ret
1153         CFI_ENDPROC
1154 END(native_load_gs_index)
1155
1156         .section __ex_table,"a"
1157         .align 8
1158         .quad gs_change,bad_gs
1159         .previous
1160         .section .fixup,"ax"
1161         /* running with kernelgs */
1162 bad_gs:
1163         SWAPGS                  /* switch back to user gs */
1164         xorl %eax,%eax
1165         movl %eax,%gs
1166         jmp  2b
1167         .previous
1168
1169 /*
1170  * Create a kernel thread.
1171  *
1172  * C extern interface:
1173  *      extern long kernel_thread(int (*fn)(void *), void * arg, unsigned long flags)
1174  *
1175  * asm input arguments:
1176  *      rdi: fn, rsi: arg, rdx: flags
1177  */
1178 ENTRY(kernel_thread)
1179         CFI_STARTPROC
1180         FAKE_STACK_FRAME $child_rip
1181         SAVE_ALL
1182
1183         # rdi: flags, rsi: usp, rdx: will be &pt_regs
1184         movq %rdx,%rdi
1185         orq  kernel_thread_flags(%rip),%rdi
1186         movq $-1, %rsi
1187         movq %rsp, %rdx
1188
1189         xorl %r8d,%r8d
1190         xorl %r9d,%r9d
1191
1192         # clone now
1193         call do_fork
1194         movq %rax,RAX(%rsp)
1195         xorl %edi,%edi
1196
1197         /*
1198          * It isn't worth to check for reschedule here,
1199          * so internally to the x86_64 port you can rely on kernel_thread()
1200          * not to reschedule the child before returning, this avoids the need
1201          * of hacks for example to fork off the per-CPU idle tasks.
1202          * [Hopefully no generic code relies on the reschedule -AK]
1203          */
1204         RESTORE_ALL
1205         UNFAKE_STACK_FRAME
1206         ret
1207         CFI_ENDPROC
1208 END(kernel_thread)
1209
1210 ENTRY(child_rip)
1211         pushq $0                # fake return address
1212         CFI_STARTPROC
1213         /*
1214          * Here we are in the child and the registers are set as they were
1215          * at kernel_thread() invocation in the parent.
1216          */
1217         movq %rdi, %rax
1218         movq %rsi, %rdi
1219         call *%rax
1220         # exit
1221         mov %eax, %edi
1222         call do_exit
1223         ud2                     # padding for call trace
1224         CFI_ENDPROC
1225 END(child_rip)
1226
1227 /*
1228  * execve(). This function needs to use IRET, not SYSRET, to set up all state properly.
1229  *
1230  * C extern interface:
1231  *       extern long execve(char *name, char **argv, char **envp)
1232  *
1233  * asm input arguments:
1234  *      rdi: name, rsi: argv, rdx: envp
1235  *
1236  * We want to fallback into:
1237  *      extern long sys_execve(char *name, char **argv,char **envp, struct pt_regs *regs)
1238  *
1239  * do_sys_execve asm fallback arguments:
1240  *      rdi: name, rsi: argv, rdx: envp, rcx: fake frame on the stack
1241  */
1242 ENTRY(kernel_execve)
1243         CFI_STARTPROC
1244         FAKE_STACK_FRAME $0
1245         SAVE_ALL
1246         movq %rsp,%rcx
1247         call sys_execve
1248         movq %rax, RAX(%rsp)
1249         RESTORE_REST
1250         testq %rax,%rax
1251         je int_ret_from_sys_call
1252         RESTORE_ARGS
1253         UNFAKE_STACK_FRAME
1254         ret
1255         CFI_ENDPROC
1256 END(kernel_execve)
1257
1258 /* Call softirq on interrupt stack. Interrupts are off. */
1259 ENTRY(call_softirq)
1260         CFI_STARTPROC
1261         push %rbp
1262         CFI_ADJUST_CFA_OFFSET   8
1263         CFI_REL_OFFSET rbp,0
1264         mov  %rsp,%rbp
1265         CFI_DEF_CFA_REGISTER rbp
1266         incl PER_CPU_VAR(irq_count)
1267         cmove PER_CPU_VAR(irq_stack_ptr),%rsp
1268         push  %rbp                      # backlink for old unwinder
1269         call __do_softirq
1270         leaveq
1271         CFI_DEF_CFA_REGISTER    rsp
1272         CFI_ADJUST_CFA_OFFSET   -8
1273         decl PER_CPU_VAR(irq_count)
1274         ret
1275         CFI_ENDPROC
1276 END(call_softirq)
1277
1278 #ifdef CONFIG_XEN
1279 zeroentry xen_hypervisor_callback xen_do_hypervisor_callback
1280
1281 /*
1282  * A note on the "critical region" in our callback handler.
1283  * We want to avoid stacking callback handlers due to events occurring
1284  * during handling of the last event. To do this, we keep events disabled
1285  * until we've done all processing. HOWEVER, we must enable events before
1286  * popping the stack frame (can't be done atomically) and so it would still
1287  * be possible to get enough handler activations to overflow the stack.
1288  * Although unlikely, bugs of that kind are hard to track down, so we'd
1289  * like to avoid the possibility.
1290  * So, on entry to the handler we detect whether we interrupted an
1291  * existing activation in its critical region -- if so, we pop the current
1292  * activation and restart the handler using the previous one.
1293  */
1294 ENTRY(xen_do_hypervisor_callback)   # do_hypervisor_callback(struct *pt_regs)
1295         CFI_STARTPROC
1296 /*
1297  * Since we don't modify %rdi, evtchn_do_upall(struct *pt_regs) will
1298  * see the correct pointer to the pt_regs
1299  */
1300         movq %rdi, %rsp            # we don't return, adjust the stack frame
1301         CFI_ENDPROC
1302         DEFAULT_FRAME
1303 11:     incl PER_CPU_VAR(irq_count)
1304         movq %rsp,%rbp
1305         CFI_DEF_CFA_REGISTER rbp
1306         cmovzq PER_CPU_VAR(irq_stack_ptr),%rsp
1307         pushq %rbp                      # backlink for old unwinder
1308         call xen_evtchn_do_upcall
1309         popq %rsp
1310         CFI_DEF_CFA_REGISTER rsp
1311         decl PER_CPU_VAR(irq_count)
1312         jmp  error_exit
1313         CFI_ENDPROC
1314 END(do_hypervisor_callback)
1315
1316 /*
1317  * Hypervisor uses this for application faults while it executes.
1318  * We get here for two reasons:
1319  *  1. Fault while reloading DS, ES, FS or GS
1320  *  2. Fault while executing IRET
1321  * Category 1 we do not need to fix up as Xen has already reloaded all segment
1322  * registers that could be reloaded and zeroed the others.
1323  * Category 2 we fix up by killing the current process. We cannot use the
1324  * normal Linux return path in this case because if we use the IRET hypercall
1325  * to pop the stack frame we end up in an infinite loop of failsafe callbacks.
1326  * We distinguish between categories by comparing each saved segment register
1327  * with its current contents: any discrepancy means we in category 1.
1328  */
1329 ENTRY(xen_failsafe_callback)
1330         INTR_FRAME 1 (6*8)
1331         /*CFI_REL_OFFSET gs,GS*/
1332         /*CFI_REL_OFFSET fs,FS*/
1333         /*CFI_REL_OFFSET es,ES*/
1334         /*CFI_REL_OFFSET ds,DS*/
1335         CFI_REL_OFFSET r11,8
1336         CFI_REL_OFFSET rcx,0
1337         movw %ds,%cx
1338         cmpw %cx,0x10(%rsp)
1339         CFI_REMEMBER_STATE
1340         jne 1f
1341         movw %es,%cx
1342         cmpw %cx,0x18(%rsp)
1343         jne 1f
1344         movw %fs,%cx
1345         cmpw %cx,0x20(%rsp)
1346         jne 1f
1347         movw %gs,%cx
1348         cmpw %cx,0x28(%rsp)
1349         jne 1f
1350         /* All segments match their saved values => Category 2 (Bad IRET). */
1351         movq (%rsp),%rcx
1352         CFI_RESTORE rcx
1353         movq 8(%rsp),%r11
1354         CFI_RESTORE r11
1355         addq $0x30,%rsp
1356         CFI_ADJUST_CFA_OFFSET -0x30
1357         pushq_cfi $0    /* RIP */
1358         pushq_cfi %r11
1359         pushq_cfi %rcx
1360         jmp general_protection
1361         CFI_RESTORE_STATE
1362 1:      /* Segment mismatch => Category 1 (Bad segment). Retry the IRET. */
1363         movq (%rsp),%rcx
1364         CFI_RESTORE rcx
1365         movq 8(%rsp),%r11
1366         CFI_RESTORE r11
1367         addq $0x30,%rsp
1368         CFI_ADJUST_CFA_OFFSET -0x30
1369         pushq_cfi $0
1370         SAVE_ALL
1371         jmp error_exit
1372         CFI_ENDPROC
1373 END(xen_failsafe_callback)
1374
1375 #endif /* CONFIG_XEN */
1376
1377 /*
1378  * Some functions should be protected against kprobes
1379  */
1380         .pushsection .kprobes.text, "ax"
1381
1382 paranoidzeroentry_ist debug do_debug DEBUG_STACK
1383 paranoidzeroentry_ist int3 do_int3 DEBUG_STACK
1384 paranoiderrorentry stack_segment do_stack_segment
1385 #ifdef CONFIG_XEN
1386 zeroentry xen_debug do_debug
1387 zeroentry xen_int3 do_int3
1388 errorentry xen_stack_segment do_stack_segment
1389 #endif
1390 errorentry general_protection do_general_protection
1391 errorentry page_fault do_page_fault
1392 #ifdef CONFIG_X86_MCE
1393 paranoidzeroentry machine_check *machine_check_vector(%rip)
1394 #endif
1395
1396         /*
1397          * "Paranoid" exit path from exception stack.
1398          * Paranoid because this is used by NMIs and cannot take
1399          * any kernel state for granted.
1400          * We don't do kernel preemption checks here, because only
1401          * NMI should be common and it does not enable IRQs and
1402          * cannot get reschedule ticks.
1403          *
1404          * "trace" is 0 for the NMI handler only, because irq-tracing
1405          * is fundamentally NMI-unsafe. (we cannot change the soft and
1406          * hard flags at once, atomically)
1407          */
1408
1409         /* ebx: no swapgs flag */
1410 ENTRY(paranoid_exit)
1411         INTR_FRAME
1412         DISABLE_INTERRUPTS(CLBR_NONE)
1413         TRACE_IRQS_OFF
1414         testl %ebx,%ebx                         /* swapgs needed? */
1415         jnz paranoid_restore
1416         testl $3,CS(%rsp)
1417         jnz   paranoid_userspace
1418 paranoid_swapgs:
1419         TRACE_IRQS_IRETQ 0
1420         SWAPGS_UNSAFE_STACK
1421         RESTORE_ALL 8
1422         jmp irq_return
1423 paranoid_restore:
1424         TRACE_IRQS_IRETQ 0
1425         RESTORE_ALL 8
1426         jmp irq_return
1427 paranoid_userspace:
1428         GET_THREAD_INFO(%rcx)
1429         movl TI_flags(%rcx),%ebx
1430         andl $_TIF_WORK_MASK,%ebx
1431         jz paranoid_swapgs
1432         movq %rsp,%rdi                  /* &pt_regs */
1433         call sync_regs
1434         movq %rax,%rsp                  /* switch stack for scheduling */
1435         testl $_TIF_NEED_RESCHED,%ebx
1436         jnz paranoid_schedule
1437         movl %ebx,%edx                  /* arg3: thread flags */
1438         TRACE_IRQS_ON
1439         ENABLE_INTERRUPTS(CLBR_NONE)
1440         xorl %esi,%esi                  /* arg2: oldset */
1441         movq %rsp,%rdi                  /* arg1: &pt_regs */
1442         call do_notify_resume
1443         DISABLE_INTERRUPTS(CLBR_NONE)
1444         TRACE_IRQS_OFF
1445         jmp paranoid_userspace
1446 paranoid_schedule:
1447         TRACE_IRQS_ON
1448         ENABLE_INTERRUPTS(CLBR_ANY)
1449         call schedule
1450         DISABLE_INTERRUPTS(CLBR_ANY)
1451         TRACE_IRQS_OFF
1452         jmp paranoid_userspace
1453         CFI_ENDPROC
1454 END(paranoid_exit)
1455
1456 /*
1457  * Exception entry point. This expects an error code/orig_rax on the stack.
1458  * returns in "no swapgs flag" in %ebx.
1459  */
1460 ENTRY(error_entry)
1461         XCPT_FRAME
1462         CFI_ADJUST_CFA_OFFSET 15*8
1463         /* oldrax contains error code */
1464         cld
1465         movq_cfi rdi, RDI+8
1466         movq_cfi rsi, RSI+8
1467         movq_cfi rdx, RDX+8
1468         movq_cfi rcx, RCX+8
1469         movq_cfi rax, RAX+8
1470         movq_cfi  r8,  R8+8
1471         movq_cfi  r9,  R9+8
1472         movq_cfi r10, R10+8
1473         movq_cfi r11, R11+8
1474         movq_cfi rbx, RBX+8
1475         movq_cfi rbp, RBP+8
1476         movq_cfi r12, R12+8
1477         movq_cfi r13, R13+8
1478         movq_cfi r14, R14+8
1479         movq_cfi r15, R15+8
1480         xorl %ebx,%ebx
1481         testl $3,CS+8(%rsp)
1482         je error_kernelspace
1483 error_swapgs:
1484         SWAPGS
1485 error_sti:
1486         TRACE_IRQS_OFF
1487         ret
1488         CFI_ENDPROC
1489
1490 /*
1491  * There are two places in the kernel that can potentially fault with
1492  * usergs. Handle them here. The exception handlers after iret run with
1493  * kernel gs again, so don't set the user space flag. B stepping K8s
1494  * sometimes report an truncated RIP for IRET exceptions returning to
1495  * compat mode. Check for these here too.
1496  */
1497 error_kernelspace:
1498         incl %ebx
1499         leaq irq_return(%rip),%rcx
1500         cmpq %rcx,RIP+8(%rsp)
1501         je error_swapgs
1502         movl %ecx,%eax  /* zero extend */
1503         cmpq %rax,RIP+8(%rsp)
1504         je bstep_iret
1505         cmpq $gs_change,RIP+8(%rsp)
1506         je error_swapgs
1507         jmp error_sti
1508
1509 bstep_iret:
1510         /* Fix truncated RIP */
1511         movq %rcx,RIP+8(%rsp)
1512         jmp error_swapgs
1513 END(error_entry)
1514
1515
1516 /* ebx: no swapgs flag (1: don't need swapgs, 0: need it) */
1517 ENTRY(error_exit)
1518         DEFAULT_FRAME
1519         movl %ebx,%eax
1520         RESTORE_REST
1521         DISABLE_INTERRUPTS(CLBR_NONE)
1522         TRACE_IRQS_OFF
1523         GET_THREAD_INFO(%rcx)
1524         testl %eax,%eax
1525         jne retint_kernel
1526         LOCKDEP_SYS_EXIT_IRQ
1527         movl TI_flags(%rcx),%edx
1528         movl $_TIF_WORK_MASK,%edi
1529         andl %edi,%edx
1530         jnz retint_careful
1531         jmp retint_swapgs
1532         CFI_ENDPROC
1533 END(error_exit)
1534
1535
1536         /* runs on exception stack */
1537 ENTRY(nmi)
1538         INTR_FRAME
1539         PARAVIRT_ADJUST_EXCEPTION_FRAME
1540         pushq_cfi $-1
1541         subq $15*8, %rsp
1542         CFI_ADJUST_CFA_OFFSET 15*8
1543         call save_paranoid
1544         DEFAULT_FRAME 0
1545         /* paranoidentry do_nmi, 0; without TRACE_IRQS_OFF */
1546         movq %rsp,%rdi
1547         movq $-1,%rsi
1548         call do_nmi
1549 #ifdef CONFIG_TRACE_IRQFLAGS
1550         /* paranoidexit; without TRACE_IRQS_OFF */
1551         /* ebx: no swapgs flag */
1552         DISABLE_INTERRUPTS(CLBR_NONE)
1553         testl %ebx,%ebx                         /* swapgs needed? */
1554         jnz nmi_restore
1555         testl $3,CS(%rsp)
1556         jnz nmi_userspace
1557 nmi_swapgs:
1558         SWAPGS_UNSAFE_STACK
1559 nmi_restore:
1560         RESTORE_ALL 8
1561         jmp irq_return
1562 nmi_userspace:
1563         GET_THREAD_INFO(%rcx)
1564         movl TI_flags(%rcx),%ebx
1565         andl $_TIF_WORK_MASK,%ebx
1566         jz nmi_swapgs
1567         movq %rsp,%rdi                  /* &pt_regs */
1568         call sync_regs
1569         movq %rax,%rsp                  /* switch stack for scheduling */
1570         testl $_TIF_NEED_RESCHED,%ebx
1571         jnz nmi_schedule
1572         movl %ebx,%edx                  /* arg3: thread flags */
1573         ENABLE_INTERRUPTS(CLBR_NONE)
1574         xorl %esi,%esi                  /* arg2: oldset */
1575         movq %rsp,%rdi                  /* arg1: &pt_regs */
1576         call do_notify_resume
1577         DISABLE_INTERRUPTS(CLBR_NONE)
1578         jmp nmi_userspace
1579 nmi_schedule:
1580         ENABLE_INTERRUPTS(CLBR_ANY)
1581         call schedule
1582         DISABLE_INTERRUPTS(CLBR_ANY)
1583         jmp nmi_userspace
1584         CFI_ENDPROC
1585 #else
1586         jmp paranoid_exit
1587         CFI_ENDPROC
1588 #endif
1589 END(nmi)
1590
1591 ENTRY(ignore_sysret)
1592         CFI_STARTPROC
1593         mov $-ENOSYS,%eax
1594         sysret
1595         CFI_ENDPROC
1596 END(ignore_sysret)
1597
1598 /*
1599  * End of kprobes section
1600  */
1601         .popsection