[PATCH] m68knommu: use configurable RAM setup in start up code
[linux-2.6.git] / arch / m68knommu / platform / 5307 / head.S
1 /*****************************************************************************/
2
3 /*
4  *      head.S -- common startup code for ColdFire CPUs.
5  *
6  *      (C) Copyright 1999-2006, Greg Ungerer <gerg@snapgear.com>.
7  */
8
9 /*****************************************************************************/
10
11 #include <linux/config.h>
12 #include <linux/sys.h>
13 #include <linux/linkage.h>
14 #include <asm/asm-offsets.h>
15 #include <asm/coldfire.h>
16 #include <asm/mcfcache.h>
17 #include <asm/mcfsim.h>
18
19 /*****************************************************************************/
20
21 /*
22  *      If we don't have a fixed memory size, then lets build in code
23  *      to auto detect the DRAM size. Obviously this is the prefered
24  *      method, and should work for most boards. It won't work for those
25  *      that do not have their RAM starting at address 0, and it only
26  *      works on SDRAM (not boards fitted with SRAM).
27  */
28 #if CONFIG_RAMSIZE != 0
29 .macro GET_MEM_SIZE
30         movel   #CONFIG_RAMSIZE,%d0     /* hard coded memory size */
31 .endm
32
33 #elif defined(CONFIG_M5206) || defined(CONFIG_M5206e) || \
34       defined(CONFIG_M5249) || defined(CONFIG_M527x) || \
35       defined(CONFIG_M528x) || defined(CONFIG_M5307) || \
36       defined(CONFIG_M5407)
37 /*
38  *      Not all these devices have exactly the same DRAM controller,
39  *      but the DCMR register is virtually identical - give or take
40  *      a couple of bits. The only exception is the 5272 devices, their
41  *      DRAM controller is quite different.
42  */
43 .macro GET_MEM_SIZE
44         movel   MCF_MBAR+MCFSIM_DMR0,%d0 /* get mask for 1st bank */
45         btst    #0,%d0                  /* check if region enabled */
46         beq     1f
47         andl    #0xfffc0000,%d0
48         beq     1f
49         addl    #0x00040000,%d0         /* convert mask to size */
50 1:
51         movel   MCF_MBAR+MCFSIM_DMR1,%d1 /* get mask for 2nd bank */
52         btst    #0,%d1                  /* check if region enabled */
53         beq     2f
54         andl    #0xfffc0000, %d1
55         beq     2f
56         addl    #0x00040000,%d1
57         addl    %d1,%d0                 /* total mem size in d0 */
58 2:
59 .endm
60
61 #elif defined(CONFIG_M5272)
62 .macro GET_MEM_SIZE
63         movel   MCF_MBAR+MCFSIM_CSOR7,%d0 /* get SDRAM address mask */
64         andil   #0xfffff000,%d0         /* mask out chip select options */
65         negl    %d0                     /* negate bits */
66 .endm
67
68 #else
69 #error "ERROR: I don't know how to probe your boards memory size?"
70 #endif
71
72 /*****************************************************************************/
73
74 /*
75  *      Boards and platforms can do specific early hardware setup if
76  *      they need to. Most don't need this, define away if not required.
77  */
78 #ifndef PLATFORM_SETUP
79 #define PLATFORM_SETUP
80 #endif
81
82 /*****************************************************************************/
83
84 .global _start
85 .global _rambase
86 .global _ramvec
87 .global _ramstart
88 .global _ramend
89
90 /*****************************************************************************/
91
92 .data
93
94 /*
95  *      During startup we store away the RAM setup. These are not in the
96  *      bss, since their values are determined and written before the bss
97  *      has been cleared.
98  */
99 _rambase:
100 .long   0
101 _ramvec:
102 .long   0
103 _ramstart:
104 .long   0
105 _ramend:
106 .long   0
107
108 /*****************************************************************************/
109
110 .text
111
112 /*
113  *      This is the codes first entry point. This is where it all
114  *      begins...
115  */
116
117 _start:
118         nop                                     /* filler */
119         movew   #0x2700, %sr                    /* no interrupts */
120
121         /*
122          *      Do any platform or board specific setup now. Most boards
123          *      don't need anything. Those exceptions are define this in
124          *      their board specific includes.
125          */
126         PLATFORM_SETUP
127
128         /*
129          *      Create basic memory configuration. Set VBR accordingly,
130          *      and size memory.
131          */
132         movel   #CONFIG_VECTORBASE,%a7
133         movec   %a7,%VBR                        /* set vectors addr */
134         movel   %a7,_ramvec
135
136         movel   #CONFIG_RAMBASE,%a7             /* mark the base of RAM */
137         movel   %a7,_rambase
138
139         GET_MEM_SIZE                            /* macro code determines size */
140         addl    %a7,%d0
141         movel   %d0,_ramend                     /* set end ram addr */
142
143         /*
144          *      Now that we know what the memory is, lets enable cache
145          *      and get things moving. This is Coldfire CPU specific.
146          */
147         CACHE_ENABLE                            /* enable CPU cache */
148
149
150 #ifdef CONFIG_ROMFS_FS
151         /*
152          *      Move ROM filesystem above bss :-)
153          */
154         lea     _sbss,%a0                       /* get start of bss */
155         lea     _ebss,%a1                       /* set up destination  */
156         movel   %a0,%a2                         /* copy of bss start */
157
158         movel   8(%a0),%d0                      /* get size of ROMFS */
159         addql   #8,%d0                          /* allow for rounding */
160         andl    #0xfffffffc, %d0                /* whole words */
161
162         addl    %d0,%a0                         /* copy from end */
163         addl    %d0,%a1                         /* copy from end */
164         movel   %a1,_ramstart                   /* set start of ram */
165
166 _copy_romfs:
167         movel   -(%a0),%d0                      /* copy dword */
168         movel   %d0,-(%a1)
169         cmpl    %a0,%a2                         /* check if at end */
170         bne     _copy_romfs
171
172 #else /* CONFIG_ROMFS_FS */
173         lea     _ebss,%a1
174         movel   %a1,_ramstart
175 #endif /* CONFIG_ROMFS_FS */
176
177
178         /*
179          *      Zero out the bss region.
180          */
181         lea     _sbss,%a0                       /* get start of bss */
182         lea     _ebss,%a1                       /* get end of bss */
183         clrl    %d0                             /* set value */
184 _clear_bss:
185         movel   %d0,(%a0)+                      /* clear each word */
186         cmpl    %a0,%a1                         /* check if at end */
187         bne     _clear_bss
188
189         /*
190          *      Load the current task pointer and stack.
191          */
192         lea     init_thread_union,%a0
193         lea     THREAD_SIZE(%a0),%sp
194
195         /*
196          *      Assember start up done, start code proper.
197          */
198         jsr     start_kernel                    /* start Linux kernel */
199
200 _exit:
201         jmp     _exit                           /* should never get here */
202
203 /*****************************************************************************/