Add some basic resume trace facilities
[linux-2.6.git] / arch / i386 / kernel / vmlinux.lds.S
1 /* ld script to make i386 Linux kernel
2  * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>;
3  */
4
5 #define LOAD_OFFSET __PAGE_OFFSET
6
7 #include <asm-generic/vmlinux.lds.h>
8 #include <asm/thread_info.h>
9 #include <asm/page.h>
10 #include <asm/cache.h>
11
12 OUTPUT_FORMAT("elf32-i386", "elf32-i386", "elf32-i386")
13 OUTPUT_ARCH(i386)
14 ENTRY(phys_startup_32)
15 jiffies = jiffies_64;
16 SECTIONS
17 {
18   . = __KERNEL_START;
19   phys_startup_32 = startup_32 - LOAD_OFFSET;
20   /* read-only */
21   _text = .;                    /* Text and read-only data */
22   .text : AT(ADDR(.text) - LOAD_OFFSET) {
23         *(.text)
24         SCHED_TEXT
25         LOCK_TEXT
26         KPROBES_TEXT
27         *(.fixup)
28         *(.gnu.warning)
29         } = 0x9090
30
31   _etext = .;                   /* End of text section */
32
33   . = ALIGN(16);                /* Exception table */
34   __start___ex_table = .;
35   __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET) { *(__ex_table) }
36   __stop___ex_table = .;
37
38   RODATA
39
40   . = ALIGN(4);
41   __tracedata_start = .;
42   .tracedata : AT(ADDR(.tracedata) - LOAD_OFFSET) {
43         *(.tracedata)
44   }
45   __tracedata_end = .;
46
47   /* writeable */
48   .data : AT(ADDR(.data) - LOAD_OFFSET) {       /* Data */
49         *(.data)
50         CONSTRUCTORS
51         }
52
53   . = ALIGN(4096);
54   __nosave_begin = .;
55   .data_nosave : AT(ADDR(.data_nosave) - LOAD_OFFSET) { *(.data.nosave) }
56   . = ALIGN(4096);
57   __nosave_end = .;
58
59   . = ALIGN(4096);
60   .data.page_aligned : AT(ADDR(.data.page_aligned) - LOAD_OFFSET) {
61         *(.data.idt)
62   }
63
64   . = ALIGN(32);
65   .data.cacheline_aligned : AT(ADDR(.data.cacheline_aligned) - LOAD_OFFSET) {
66         *(.data.cacheline_aligned)
67   }
68
69   /* rarely changed data like cpu maps */
70   . = ALIGN(32);
71   .data.read_mostly : AT(ADDR(.data.read_mostly) - LOAD_OFFSET) { *(.data.read_mostly) }
72   _edata = .;                   /* End of data section */
73
74   . = ALIGN(THREAD_SIZE);       /* init_task */
75   .data.init_task : AT(ADDR(.data.init_task) - LOAD_OFFSET) {
76         *(.data.init_task)
77   }
78
79   /* might get freed after init */
80   . = ALIGN(4096);
81   __smp_alt_begin = .;
82   __smp_alt_instructions = .;
83   .smp_altinstructions : AT(ADDR(.smp_altinstructions) - LOAD_OFFSET) {
84         *(.smp_altinstructions)
85   }
86   __smp_alt_instructions_end = .;
87   . = ALIGN(4);
88   __smp_locks = .;
89   .smp_locks : AT(ADDR(.smp_locks) - LOAD_OFFSET) {
90         *(.smp_locks)
91   }
92   __smp_locks_end = .;
93   .smp_altinstr_replacement : AT(ADDR(.smp_altinstr_replacement) - LOAD_OFFSET) {
94         *(.smp_altinstr_replacement)
95   }
96   . = ALIGN(4096);
97   __smp_alt_end = .;
98
99   /* will be freed after init */
100   . = ALIGN(4096);              /* Init code and data */
101   __init_begin = .;
102   .init.text : AT(ADDR(.init.text) - LOAD_OFFSET) {
103         _sinittext = .;
104         *(.init.text)
105         _einittext = .;
106   }
107   .init.data : AT(ADDR(.init.data) - LOAD_OFFSET) { *(.init.data) }
108   . = ALIGN(16);
109   __setup_start = .;
110   .init.setup : AT(ADDR(.init.setup) - LOAD_OFFSET) { *(.init.setup) }
111   __setup_end = .;
112   __initcall_start = .;
113   .initcall.init : AT(ADDR(.initcall.init) - LOAD_OFFSET) {
114         *(.initcall1.init) 
115         *(.initcall2.init) 
116         *(.initcall3.init) 
117         *(.initcall4.init) 
118         *(.initcall5.init) 
119         *(.initcall6.init) 
120         *(.initcall7.init)
121   }
122   __initcall_end = .;
123   __con_initcall_start = .;
124   .con_initcall.init : AT(ADDR(.con_initcall.init) - LOAD_OFFSET) {
125         *(.con_initcall.init)
126   }
127   __con_initcall_end = .;
128   SECURITY_INIT
129   . = ALIGN(4);
130   __alt_instructions = .;
131   .altinstructions : AT(ADDR(.altinstructions) - LOAD_OFFSET) {
132         *(.altinstructions)
133   }
134   __alt_instructions_end = .; 
135   .altinstr_replacement : AT(ADDR(.altinstr_replacement) - LOAD_OFFSET) {
136         *(.altinstr_replacement)
137   }
138   /* .exit.text is discard at runtime, not link time, to deal with references
139      from .altinstructions and .eh_frame */
140   .exit.text : AT(ADDR(.exit.text) - LOAD_OFFSET) { *(.exit.text) }
141   .exit.data : AT(ADDR(.exit.data) - LOAD_OFFSET) { *(.exit.data) }
142   . = ALIGN(4096);
143   __initramfs_start = .;
144   .init.ramfs : AT(ADDR(.init.ramfs) - LOAD_OFFSET) { *(.init.ramfs) }
145   __initramfs_end = .;
146   . = ALIGN(L1_CACHE_BYTES);
147   __per_cpu_start = .;
148   .data.percpu  : AT(ADDR(.data.percpu) - LOAD_OFFSET) { *(.data.percpu) }
149   __per_cpu_end = .;
150   . = ALIGN(4096);
151   __init_end = .;
152   /* freed after init ends here */
153         
154   __bss_start = .;              /* BSS */
155   .bss.page_aligned : AT(ADDR(.bss.page_aligned) - LOAD_OFFSET) {
156         *(.bss.page_aligned)
157   }
158   .bss : AT(ADDR(.bss) - LOAD_OFFSET) {
159         *(.bss)
160   }
161   . = ALIGN(4);
162   __bss_stop = .; 
163
164   _end = . ;
165
166   /* This is where the kernel creates the early boot page tables */
167   . = ALIGN(4096);
168   pg0 = .;
169
170   /* Sections to be discarded */
171   /DISCARD/ : {
172         *(.exitcall.exit)
173         }
174
175   STABS_DEBUG
176
177   DWARF_DEBUG
178 }