Add 'discard' request handling
[linux-2.6.git] / arch / blackfin / mach-bf537 / head.S
1 /*
2  * File:         arch/blackfin/mach-bf537/head.S
3  * Based on:     arch/blackfin/mach-bf533/head.S
4  * Author:       Jeff Dionne <jeff@uclinux.org> COPYRIGHT 1998 D. Jeff Dionne
5  *
6  * Created:      1998
7  * Description:  Startup code for Blackfin BF537
8  *
9  * Modified:
10  *               Copyright 2004-2006 Analog Devices Inc.
11  *
12  * Bugs:         Enter bugs at http://blackfin.uclinux.org/
13  *
14  * This program is free software; you can redistribute it and/or modify
15  * it under the terms of the GNU General Public License as published by
16  * the Free Software Foundation; either version 2 of the License, or
17  * (at your option) any later version.
18  *
19  * This program is distributed in the hope that it will be useful,
20  * but WITHOUT ANY WARRANTY; without even the implied warranty of
21  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
22  * GNU General Public License for more details.
23  *
24  * You should have received a copy of the GNU General Public License
25  * along with this program; if not, see the file COPYING, or write
26  * to the Free Software Foundation, Inc.,
27  * 51 Franklin St, Fifth Floor, Boston, MA  02110-1301  USA
28  */
29
30 #include <linux/linkage.h>
31 #include <linux/init.h>
32 #include <asm/blackfin.h>
33 #ifdef CONFIG_BFIN_KERNEL_CLOCK
34 #include <asm/clocks.h>
35 #include <mach/mem_init.h>
36 #endif
37
38 .section .l1.text
39 #ifdef CONFIG_BFIN_KERNEL_CLOCK
40 ENTRY(_start_dma_code)
41
42         /* Enable PHY CLK buffer output */
43         p0.h = hi(VR_CTL);
44         p0.l = lo(VR_CTL);
45         r0.l = w[p0];
46         bitset(r0, 14);
47         w[p0] = r0.l;
48         ssync;
49
50         p0.h = hi(SIC_IWR);
51         p0.l = lo(SIC_IWR);
52         r0.l = 0x1;
53         r0.h = 0x0;
54         [p0] = r0;
55         SSYNC;
56
57         /*
58          *  Set PLL_CTL
59          *   - [14:09] = MSEL[5:0] : CLKIN / VCO multiplication factors
60          *   - [8]     = BYPASS    : BYPASS the PLL, run CLKIN into CCLK/SCLK
61          *   - [7]     = output delay (add 200ps of delay to mem signals)
62          *   - [6]     = input delay (add 200ps of input delay to mem signals)
63          *   - [5]     = PDWN      : 1=All Clocks off
64          *   - [3]     = STOPCK    : 1=Core Clock off
65          *   - [1]     = PLL_OFF   : 1=Disable Power to PLL
66          *   - [0]     = DF        : 1=Pass CLKIN/2 to PLL / 0=Pass CLKIN to PLL
67          *   all other bits set to zero
68          */
69
70         p0.h = hi(PLL_LOCKCNT);
71         p0.l = lo(PLL_LOCKCNT);
72         r0 = 0x300(Z);
73         w[p0] = r0.l;
74         ssync;
75
76         P2.H = hi(EBIU_SDGCTL);
77         P2.L = lo(EBIU_SDGCTL);
78         R0 = [P2];
79         BITSET (R0, 24);
80         [P2] = R0;
81         SSYNC;
82
83         r0 = CONFIG_VCO_MULT & 63;       /* Load the VCO multiplier         */
84         r0 = r0 << 9;                    /* Shift it over,                  */
85         r1 = CLKIN_HALF;                 /* Do we need to divide CLKIN by 2?*/
86         r0 = r1 | r0;
87         r1 = PLL_BYPASS;                 /* Bypass the PLL?                 */
88         r1 = r1 << 8;                    /* Shift it over                   */
89         r0 = r1 | r0;                    /* add them all together           */
90
91         p0.h = hi(PLL_CTL);
92         p0.l = lo(PLL_CTL);              /* Load the address                */
93         cli r2;                          /* Disable interrupts              */
94         ssync;
95         w[p0] = r0.l;                    /* Set the value                   */
96         idle;                            /* Wait for the PLL to stablize    */
97         sti r2;                          /* Enable interrupts               */
98
99 .Lcheck_again:
100         p0.h = hi(PLL_STAT);
101         p0.l = lo(PLL_STAT);
102         R0 = W[P0](Z);
103         CC = BITTST(R0,5);
104         if ! CC jump .Lcheck_again;
105
106         /* Configure SCLK & CCLK Dividers */
107         r0 = (CONFIG_CCLK_ACT_DIV | CONFIG_SCLK_DIV);
108         p0.h = hi(PLL_DIV);
109         p0.l = lo(PLL_DIV);
110         w[p0] = r0.l;
111         ssync;
112
113         p0.l = lo(EBIU_SDRRC);
114         p0.h = hi(EBIU_SDRRC);
115         r0 = mem_SDRRC;
116         w[p0] = r0.l;
117         ssync;
118
119         P2.H = hi(EBIU_SDGCTL);
120         P2.L = lo(EBIU_SDGCTL);
121         R0 = [P2];
122         BITCLR (R0, 24);
123         p0.h = hi(EBIU_SDSTAT);
124         p0.l = lo(EBIU_SDSTAT);
125         r2.l = w[p0];
126         cc = bittst(r2,3);
127         if !cc jump .Lskip;
128         NOP;
129         BITSET (R0, 23);
130 .Lskip:
131         [P2] = R0;
132         SSYNC;
133
134         R0.L = lo(mem_SDGCTL);
135         R0.H = hi(mem_SDGCTL);
136         R1 = [p2];
137         R1 = R1 | R0;
138         [P2] = R1;
139         SSYNC;
140
141         RTS;
142 ENDPROC(_start_dma_code)
143 #endif /* CONFIG_BFIN_KERNEL_CLOCK */