Get rid of early_init. There's more need to make this form of
[linux-3.10.git] / arch / mips / kernel / vmlinux.lds.S
1 #include <linux/config.h>
2 #include <asm-generic/vmlinux.lds.h>
3
4 #undef mips             /* CPP really sucks for this job  */
5 #define mips mips
6 OUTPUT_ARCH(mips)
7 ENTRY(kernel_entry)
8 jiffies = JIFFIES;
9 SECTIONS
10 {
11 #ifdef CONFIG_BOOT_ELF64
12   /* Read-only sections, merged into text segment: */
13   /* . = 0xc000000000000000; */
14
15   /* This is the value for an Origin kernel, taken from an IRIX kernel.  */
16   /* . = 0xc00000000001c000; */
17
18   /* Set the vaddr for the text segment to a value
19         >= 0xa800 0000 0001 9000 if no symmon is going to configured
20         >= 0xa800 0000 0030 0000 otherwise  */
21
22   /* . = 0xa800000000300000; */
23   /* . = 0xa800000000300000; */
24   . = 0xffffffff80300000;
25 #endif
26   . = LOADADDR;
27   /* read-only */
28   _text = .;                    /* Text and read-only data */
29   .text : {
30     *(.text)
31     SCHED_TEXT
32     LOCK_TEXT
33     *(.fixup)
34     *(.gnu.warning)
35   } =0
36
37   _etext = .;                   /* End of text section */
38
39   . = ALIGN(16);                /* Exception table */
40   __start___ex_table = .;
41   __ex_table : { *(__ex_table) }
42   __stop___ex_table = .;
43
44   __start___dbe_table = .;      /* Exception table for data bus errors */
45   __dbe_table : { *(__dbe_table) }
46   __stop___dbe_table = .;
47
48   RODATA
49
50   /* writeable */
51   .data : {                     /* Data */
52     . = . + DATAOFFSET;         /* for CONFIG_MAPPED_KERNEL */
53     *(.data.init_task)
54
55     *(.data)
56
57    /* Align the initial ramdisk image (INITRD) on page boundaries. */
58    . = ALIGN(4096);
59    __rd_start = .;
60    *(.initrd)
61    . = ALIGN(4096);
62    __rd_end = .;
63
64     CONSTRUCTORS
65   }
66   _gp = . + 0x8000;
67   .lit8 : { *(.lit8) }
68   .lit4 : { *(.lit4) }
69   /* We want the small data sections together, so single-instruction offsets
70      can access them all, and initialized data all before uninitialized, so
71      we can shorten the on-disk segment size.  */
72   .sdata     : { *(.sdata) }
73
74   . = ALIGN(4096);
75   __nosave_begin = .;
76   .data_nosave : { *(.data.nosave) }
77   . = ALIGN(4096);
78   __nosave_end = .;
79
80   . = ALIGN(32);
81   .data.cacheline_aligned : { *(.data.cacheline_aligned) }
82
83   _edata =  .;                  /* End of data section */
84
85   /* will be freed after init */
86   . = ALIGN(4096);              /* Init code and data */
87   __init_begin = .;
88   .init.text : {
89         _sinittext = .;
90         *(.init.text)
91         _einittext = .;
92   }
93   .init.data : { *(.init.data) }
94   . = ALIGN(16);
95   __setup_start = .;
96   .init.setup : { *(.init.setup) }
97   __setup_end = .;
98
99   __initcall_start = .;
100   .initcall.init : {
101         *(.initcall1.init)
102         *(.initcall2.init)
103         *(.initcall3.init)
104         *(.initcall4.init)
105         *(.initcall5.init)
106         *(.initcall6.init)
107         *(.initcall7.init)
108   }
109   __initcall_end = .;
110
111   __con_initcall_start = .;
112   .con_initcall.init : { *(.con_initcall.init) }
113   __con_initcall_end = .;
114   SECURITY_INIT
115   . = ALIGN(4096);
116   __initramfs_start = .;
117   .init.ramfs : { *(.init.ramfs) }
118   __initramfs_end = .;
119   . = ALIGN(32);
120   __per_cpu_start = .;
121   .data.percpu  : { *(.data.percpu) }
122   __per_cpu_end = .;
123   . = ALIGN(4096);
124   __init_end = .;
125   /* freed after init ends here */
126
127   __bss_start = .;              /* BSS */
128   .sbss      : {
129     *(.sbss)
130     *(.scommon)
131   }
132   .bss : {
133     *(.bss)
134     *(COMMON)
135   }
136   __bss_stop = .;
137
138   _end = . ;
139
140   /* Sections to be discarded */
141   /DISCARD/ : {
142         *(.exit.text)
143         *(.exit.data)
144         *(.exitcall.exit)
145
146         /* ABI crap starts here */
147         *(.comment)
148         *(.MIPS.options)
149         *(.note)
150         *(.options)
151         *(.pdr)
152         *(.reginfo)
153         *(.mdebug*)
154   }
155
156   /* This is the MIPS specific mdebug section.  */
157   .mdebug : { *(.mdebug) }
158   /* These are needed for ELF backends which have not yet been
159      converted to the new style linker.  */
160   .stab 0 : { *(.stab) }
161   .stabstr 0 : { *(.stabstr) }
162   /* DWARF debug sections.
163      Symbols in the .debug DWARF section are relative to the beginning of the
164      section so we begin .debug at 0.  It's not clear yet what needs to happen
165      for the others.   */
166   .debug          0 : { *(.debug) }
167   .debug_srcinfo  0 : { *(.debug_srcinfo) }
168   .debug_aranges  0 : { *(.debug_aranges) }
169   .debug_pubnames 0 : { *(.debug_pubnames) }
170   .debug_sfnames  0 : { *(.debug_sfnames) }
171   .line           0 : { *(.line) }
172   /* These must appear regardless of  .  */
173   .gptab.sdata : { *(.gptab.data) *(.gptab.sdata) }
174   .gptab.sbss : { *(.gptab.bss) *(.gptab.sbss) }
175   .comment : { *(.comment) }
176   .note : { *(.note) }
177 }