linker script: unify usage of discard definition
[linux-2.6.git] / include / asm-generic / vmlinux.lds.h
1 /*
2  * Helper macros to support writing architecture specific
3  * linker scripts.
4  *
5  * A minimal linker scripts has following content:
6  * [This is a sample, architectures may have special requiriements]
7  *
8  * OUTPUT_FORMAT(...)
9  * OUTPUT_ARCH(...)
10  * ENTRY(...)
11  * SECTIONS
12  * {
13  *      . = START;
14  *      __init_begin = .;
15  *      HEAD_TEXT_SECTION
16  *      INIT_TEXT_SECTION(PAGE_SIZE)
17  *      INIT_DATA_SECTION(...)
18  *      PERCPU(PAGE_SIZE)
19  *      __init_end = .;
20  *
21  *      _stext = .;
22  *      TEXT_SECTION = 0
23  *      _etext = .;
24  *
25  *      _sdata = .;
26  *      RO_DATA_SECTION(PAGE_SIZE)
27  *      RW_DATA_SECTION(...)
28  *      _edata = .;
29  *
30  *      EXCEPTION_TABLE(...)
31  *      NOTES
32  *
33  *      __bss_start = .;
34  *      BSS_SECTION(0, 0)
35  *      __bss_stop = .;
36  *      _end = .;
37  *
38  *      STABS_DEBUG
39  *      DWARF_DEBUG
40  *
41  *      DISCARDS                // must be the last
42  * }
43  *
44  * [__init_begin, __init_end] is the init section that may be freed after init
45  * [_stext, _etext] is the text section
46  * [_sdata, _edata] is the data section
47  *
48  * Some of the included output section have their own set of constants.
49  * Examples are: [__initramfs_start, __initramfs_end] for initramfs and
50  *               [__nosave_begin, __nosave_end] for the nosave data
51  */
52
53 #ifndef LOAD_OFFSET
54 #define LOAD_OFFSET 0
55 #endif
56
57 #ifndef VMLINUX_SYMBOL
58 #define VMLINUX_SYMBOL(_sym_) _sym_
59 #endif
60
61 /* Align . to a 8 byte boundary equals to maximum function alignment. */
62 #define ALIGN_FUNCTION()  . = ALIGN(8)
63
64 /* The actual configuration determine if the init/exit sections
65  * are handled as text/data or they can be discarded (which
66  * often happens at runtime)
67  */
68 #ifdef CONFIG_HOTPLUG
69 #define DEV_KEEP(sec)    *(.dev##sec)
70 #define DEV_DISCARD(sec)
71 #else
72 #define DEV_KEEP(sec)
73 #define DEV_DISCARD(sec) *(.dev##sec)
74 #endif
75
76 #ifdef CONFIG_HOTPLUG_CPU
77 #define CPU_KEEP(sec)    *(.cpu##sec)
78 #define CPU_DISCARD(sec)
79 #else
80 #define CPU_KEEP(sec)
81 #define CPU_DISCARD(sec) *(.cpu##sec)
82 #endif
83
84 #if defined(CONFIG_MEMORY_HOTPLUG)
85 #define MEM_KEEP(sec)    *(.mem##sec)
86 #define MEM_DISCARD(sec)
87 #else
88 #define MEM_KEEP(sec)
89 #define MEM_DISCARD(sec) *(.mem##sec)
90 #endif
91
92 #ifdef CONFIG_FTRACE_MCOUNT_RECORD
93 #define MCOUNT_REC()    VMLINUX_SYMBOL(__start_mcount_loc) = .; \
94                         *(__mcount_loc)                         \
95                         VMLINUX_SYMBOL(__stop_mcount_loc) = .;
96 #else
97 #define MCOUNT_REC()
98 #endif
99
100 #ifdef CONFIG_TRACE_BRANCH_PROFILING
101 #define LIKELY_PROFILE()        VMLINUX_SYMBOL(__start_annotated_branch_profile) = .; \
102                                 *(_ftrace_annotated_branch)                           \
103                                 VMLINUX_SYMBOL(__stop_annotated_branch_profile) = .;
104 #else
105 #define LIKELY_PROFILE()
106 #endif
107
108 #ifdef CONFIG_PROFILE_ALL_BRANCHES
109 #define BRANCH_PROFILE()        VMLINUX_SYMBOL(__start_branch_profile) = .;   \
110                                 *(_ftrace_branch)                             \
111                                 VMLINUX_SYMBOL(__stop_branch_profile) = .;
112 #else
113 #define BRANCH_PROFILE()
114 #endif
115
116 #ifdef CONFIG_EVENT_TRACING
117 #define FTRACE_EVENTS() VMLINUX_SYMBOL(__start_ftrace_events) = .;      \
118                         *(_ftrace_events)                               \
119                         VMLINUX_SYMBOL(__stop_ftrace_events) = .;
120 #else
121 #define FTRACE_EVENTS()
122 #endif
123
124 #ifdef CONFIG_TRACING
125 #define TRACE_PRINTKS() VMLINUX_SYMBOL(__start___trace_bprintk_fmt) = .;      \
126                          *(__trace_printk_fmt) /* Trace_printk fmt' pointer */ \
127                          VMLINUX_SYMBOL(__stop___trace_bprintk_fmt) = .;
128 #else
129 #define TRACE_PRINTKS()
130 #endif
131
132 #ifdef CONFIG_FTRACE_SYSCALLS
133 #define TRACE_SYSCALLS() VMLINUX_SYMBOL(__start_syscalls_metadata) = .; \
134                          *(__syscalls_metadata)                         \
135                          VMLINUX_SYMBOL(__stop_syscalls_metadata) = .;
136 #else
137 #define TRACE_SYSCALLS()
138 #endif
139
140 /* .data section */
141 #define DATA_DATA                                                       \
142         *(.data)                                                        \
143         *(.ref.data)                                                    \
144         DEV_KEEP(init.data)                                             \
145         DEV_KEEP(exit.data)                                             \
146         CPU_KEEP(init.data)                                             \
147         CPU_KEEP(exit.data)                                             \
148         MEM_KEEP(init.data)                                             \
149         MEM_KEEP(exit.data)                                             \
150         . = ALIGN(8);                                                   \
151         VMLINUX_SYMBOL(__start___markers) = .;                          \
152         *(__markers)                                                    \
153         VMLINUX_SYMBOL(__stop___markers) = .;                           \
154         . = ALIGN(32);                                                  \
155         VMLINUX_SYMBOL(__start___tracepoints) = .;                      \
156         *(__tracepoints)                                                \
157         VMLINUX_SYMBOL(__stop___tracepoints) = .;                       \
158         /* implement dynamic printk debug */                            \
159         . = ALIGN(8);                                                   \
160         VMLINUX_SYMBOL(__start___verbose) = .;                          \
161         *(__verbose)                                                    \
162         VMLINUX_SYMBOL(__stop___verbose) = .;                           \
163         LIKELY_PROFILE()                                                \
164         BRANCH_PROFILE()                                                \
165         TRACE_PRINTKS()                                                 \
166         FTRACE_EVENTS()                                                 \
167         TRACE_SYSCALLS()
168
169 /*
170  * Data section helpers
171  */
172 #define NOSAVE_DATA                                                     \
173         . = ALIGN(PAGE_SIZE);                                           \
174         VMLINUX_SYMBOL(__nosave_begin) = .;                             \
175         *(.data.nosave)                                                 \
176         . = ALIGN(PAGE_SIZE);                                           \
177         VMLINUX_SYMBOL(__nosave_end) = .;
178
179 #define PAGE_ALIGNED_DATA(page_align)                                   \
180         . = ALIGN(page_align);                                          \
181         *(.data.page_aligned)
182
183 #define READ_MOSTLY_DATA(align)                                         \
184         . = ALIGN(align);                                               \
185         *(.data.read_mostly)
186
187 #define CACHELINE_ALIGNED_DATA(align)                                   \
188         . = ALIGN(align);                                               \
189         *(.data.cacheline_aligned)
190
191 #define INIT_TASK(align)                                                \
192         . = ALIGN(align);                                               \
193         *(.data.init_task)
194
195 /*
196  * Read only Data
197  */
198 #define RO_DATA_SECTION(align)                                          \
199         . = ALIGN((align));                                             \
200         .rodata           : AT(ADDR(.rodata) - LOAD_OFFSET) {           \
201                 VMLINUX_SYMBOL(__start_rodata) = .;                     \
202                 *(.rodata) *(.rodata.*)                                 \
203                 *(__vermagic)           /* Kernel version magic */      \
204                 *(__markers_strings)    /* Markers: strings */          \
205                 *(__tracepoints_strings)/* Tracepoints: strings */      \
206         }                                                               \
207                                                                         \
208         .rodata1          : AT(ADDR(.rodata1) - LOAD_OFFSET) {          \
209                 *(.rodata1)                                             \
210         }                                                               \
211                                                                         \
212         BUG_TABLE                                                       \
213                                                                         \
214         /* PCI quirks */                                                \
215         .pci_fixup        : AT(ADDR(.pci_fixup) - LOAD_OFFSET) {        \
216                 VMLINUX_SYMBOL(__start_pci_fixups_early) = .;           \
217                 *(.pci_fixup_early)                                     \
218                 VMLINUX_SYMBOL(__end_pci_fixups_early) = .;             \
219                 VMLINUX_SYMBOL(__start_pci_fixups_header) = .;          \
220                 *(.pci_fixup_header)                                    \
221                 VMLINUX_SYMBOL(__end_pci_fixups_header) = .;            \
222                 VMLINUX_SYMBOL(__start_pci_fixups_final) = .;           \
223                 *(.pci_fixup_final)                                     \
224                 VMLINUX_SYMBOL(__end_pci_fixups_final) = .;             \
225                 VMLINUX_SYMBOL(__start_pci_fixups_enable) = .;          \
226                 *(.pci_fixup_enable)                                    \
227                 VMLINUX_SYMBOL(__end_pci_fixups_enable) = .;            \
228                 VMLINUX_SYMBOL(__start_pci_fixups_resume) = .;          \
229                 *(.pci_fixup_resume)                                    \
230                 VMLINUX_SYMBOL(__end_pci_fixups_resume) = .;            \
231                 VMLINUX_SYMBOL(__start_pci_fixups_resume_early) = .;    \
232                 *(.pci_fixup_resume_early)                              \
233                 VMLINUX_SYMBOL(__end_pci_fixups_resume_early) = .;      \
234                 VMLINUX_SYMBOL(__start_pci_fixups_suspend) = .;         \
235                 *(.pci_fixup_suspend)                                   \
236                 VMLINUX_SYMBOL(__end_pci_fixups_suspend) = .;           \
237         }                                                               \
238                                                                         \
239         /* Built-in firmware blobs */                                   \
240         .builtin_fw        : AT(ADDR(.builtin_fw) - LOAD_OFFSET) {      \
241                 VMLINUX_SYMBOL(__start_builtin_fw) = .;                 \
242                 *(.builtin_fw)                                          \
243                 VMLINUX_SYMBOL(__end_builtin_fw) = .;                   \
244         }                                                               \
245                                                                         \
246         /* RapidIO route ops */                                         \
247         .rio_route        : AT(ADDR(.rio_route) - LOAD_OFFSET) {        \
248                 VMLINUX_SYMBOL(__start_rio_route_ops) = .;              \
249                 *(.rio_route_ops)                                       \
250                 VMLINUX_SYMBOL(__end_rio_route_ops) = .;                \
251         }                                                               \
252                                                                         \
253         TRACEDATA                                                       \
254                                                                         \
255         /* Kernel symbol table: Normal symbols */                       \
256         __ksymtab         : AT(ADDR(__ksymtab) - LOAD_OFFSET) {         \
257                 VMLINUX_SYMBOL(__start___ksymtab) = .;                  \
258                 *(__ksymtab)                                            \
259                 VMLINUX_SYMBOL(__stop___ksymtab) = .;                   \
260         }                                                               \
261                                                                         \
262         /* Kernel symbol table: GPL-only symbols */                     \
263         __ksymtab_gpl     : AT(ADDR(__ksymtab_gpl) - LOAD_OFFSET) {     \
264                 VMLINUX_SYMBOL(__start___ksymtab_gpl) = .;              \
265                 *(__ksymtab_gpl)                                        \
266                 VMLINUX_SYMBOL(__stop___ksymtab_gpl) = .;               \
267         }                                                               \
268                                                                         \
269         /* Kernel symbol table: Normal unused symbols */                \
270         __ksymtab_unused  : AT(ADDR(__ksymtab_unused) - LOAD_OFFSET) {  \
271                 VMLINUX_SYMBOL(__start___ksymtab_unused) = .;           \
272                 *(__ksymtab_unused)                                     \
273                 VMLINUX_SYMBOL(__stop___ksymtab_unused) = .;            \
274         }                                                               \
275                                                                         \
276         /* Kernel symbol table: GPL-only unused symbols */              \
277         __ksymtab_unused_gpl : AT(ADDR(__ksymtab_unused_gpl) - LOAD_OFFSET) { \
278                 VMLINUX_SYMBOL(__start___ksymtab_unused_gpl) = .;       \
279                 *(__ksymtab_unused_gpl)                                 \
280                 VMLINUX_SYMBOL(__stop___ksymtab_unused_gpl) = .;        \
281         }                                                               \
282                                                                         \
283         /* Kernel symbol table: GPL-future-only symbols */              \
284         __ksymtab_gpl_future : AT(ADDR(__ksymtab_gpl_future) - LOAD_OFFSET) { \
285                 VMLINUX_SYMBOL(__start___ksymtab_gpl_future) = .;       \
286                 *(__ksymtab_gpl_future)                                 \
287                 VMLINUX_SYMBOL(__stop___ksymtab_gpl_future) = .;        \
288         }                                                               \
289                                                                         \
290         /* Kernel symbol table: Normal symbols */                       \
291         __kcrctab         : AT(ADDR(__kcrctab) - LOAD_OFFSET) {         \
292                 VMLINUX_SYMBOL(__start___kcrctab) = .;                  \
293                 *(__kcrctab)                                            \
294                 VMLINUX_SYMBOL(__stop___kcrctab) = .;                   \
295         }                                                               \
296                                                                         \
297         /* Kernel symbol table: GPL-only symbols */                     \
298         __kcrctab_gpl     : AT(ADDR(__kcrctab_gpl) - LOAD_OFFSET) {     \
299                 VMLINUX_SYMBOL(__start___kcrctab_gpl) = .;              \
300                 *(__kcrctab_gpl)                                        \
301                 VMLINUX_SYMBOL(__stop___kcrctab_gpl) = .;               \
302         }                                                               \
303                                                                         \
304         /* Kernel symbol table: Normal unused symbols */                \
305         __kcrctab_unused  : AT(ADDR(__kcrctab_unused) - LOAD_OFFSET) {  \
306                 VMLINUX_SYMBOL(__start___kcrctab_unused) = .;           \
307                 *(__kcrctab_unused)                                     \
308                 VMLINUX_SYMBOL(__stop___kcrctab_unused) = .;            \
309         }                                                               \
310                                                                         \
311         /* Kernel symbol table: GPL-only unused symbols */              \
312         __kcrctab_unused_gpl : AT(ADDR(__kcrctab_unused_gpl) - LOAD_OFFSET) { \
313                 VMLINUX_SYMBOL(__start___kcrctab_unused_gpl) = .;       \
314                 *(__kcrctab_unused_gpl)                                 \
315                 VMLINUX_SYMBOL(__stop___kcrctab_unused_gpl) = .;        \
316         }                                                               \
317                                                                         \
318         /* Kernel symbol table: GPL-future-only symbols */              \
319         __kcrctab_gpl_future : AT(ADDR(__kcrctab_gpl_future) - LOAD_OFFSET) { \
320                 VMLINUX_SYMBOL(__start___kcrctab_gpl_future) = .;       \
321                 *(__kcrctab_gpl_future)                                 \
322                 VMLINUX_SYMBOL(__stop___kcrctab_gpl_future) = .;        \
323         }                                                               \
324                                                                         \
325         /* Kernel symbol table: strings */                              \
326         __ksymtab_strings : AT(ADDR(__ksymtab_strings) - LOAD_OFFSET) { \
327                 *(__ksymtab_strings)                                    \
328         }                                                               \
329                                                                         \
330         /* __*init sections */                                          \
331         __init_rodata : AT(ADDR(__init_rodata) - LOAD_OFFSET) {         \
332                 *(.ref.rodata)                                          \
333                 MCOUNT_REC()                                            \
334                 DEV_KEEP(init.rodata)                                   \
335                 DEV_KEEP(exit.rodata)                                   \
336                 CPU_KEEP(init.rodata)                                   \
337                 CPU_KEEP(exit.rodata)                                   \
338                 MEM_KEEP(init.rodata)                                   \
339                 MEM_KEEP(exit.rodata)                                   \
340         }                                                               \
341                                                                         \
342         /* Built-in module parameters. */                               \
343         __param : AT(ADDR(__param) - LOAD_OFFSET) {                     \
344                 VMLINUX_SYMBOL(__start___param) = .;                    \
345                 *(__param)                                              \
346                 VMLINUX_SYMBOL(__stop___param) = .;                     \
347                 . = ALIGN((align));                                     \
348                 VMLINUX_SYMBOL(__end_rodata) = .;                       \
349         }                                                               \
350         . = ALIGN((align));
351
352 /* RODATA & RO_DATA provided for backward compatibility.
353  * All archs are supposed to use RO_DATA() */
354 #define RODATA          RO_DATA_SECTION(4096)
355 #define RO_DATA(align)  RO_DATA_SECTION(align)
356
357 #define SECURITY_INIT                                                   \
358         .security_initcall.init : AT(ADDR(.security_initcall.init) - LOAD_OFFSET) { \
359                 VMLINUX_SYMBOL(__security_initcall_start) = .;          \
360                 *(.security_initcall.init)                              \
361                 VMLINUX_SYMBOL(__security_initcall_end) = .;            \
362         }
363
364 /* .text section. Map to function alignment to avoid address changes
365  * during second ld run in second ld pass when generating System.map */
366 #define TEXT_TEXT                                                       \
367                 ALIGN_FUNCTION();                                       \
368                 *(.text.hot)                                            \
369                 *(.text)                                                \
370                 *(.ref.text)                                            \
371         DEV_KEEP(init.text)                                             \
372         DEV_KEEP(exit.text)                                             \
373         CPU_KEEP(init.text)                                             \
374         CPU_KEEP(exit.text)                                             \
375         MEM_KEEP(init.text)                                             \
376         MEM_KEEP(exit.text)                                             \
377                 *(.text.unlikely)
378
379
380 /* sched.text is aling to function alignment to secure we have same
381  * address even at second ld pass when generating System.map */
382 #define SCHED_TEXT                                                      \
383                 ALIGN_FUNCTION();                                       \
384                 VMLINUX_SYMBOL(__sched_text_start) = .;                 \
385                 *(.sched.text)                                          \
386                 VMLINUX_SYMBOL(__sched_text_end) = .;
387
388 /* spinlock.text is aling to function alignment to secure we have same
389  * address even at second ld pass when generating System.map */
390 #define LOCK_TEXT                                                       \
391                 ALIGN_FUNCTION();                                       \
392                 VMLINUX_SYMBOL(__lock_text_start) = .;                  \
393                 *(.spinlock.text)                                       \
394                 VMLINUX_SYMBOL(__lock_text_end) = .;
395
396 #define KPROBES_TEXT                                                    \
397                 ALIGN_FUNCTION();                                       \
398                 VMLINUX_SYMBOL(__kprobes_text_start) = .;               \
399                 *(.kprobes.text)                                        \
400                 VMLINUX_SYMBOL(__kprobes_text_end) = .;
401
402 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
403 #define IRQENTRY_TEXT                                                   \
404                 ALIGN_FUNCTION();                                       \
405                 VMLINUX_SYMBOL(__irqentry_text_start) = .;              \
406                 *(.irqentry.text)                                       \
407                 VMLINUX_SYMBOL(__irqentry_text_end) = .;
408 #else
409 #define IRQENTRY_TEXT
410 #endif
411
412 /* Section used for early init (in .S files) */
413 #define HEAD_TEXT  *(.head.text)
414
415 #define HEAD_TEXT_SECTION                                                       \
416         .head.text : AT(ADDR(.head.text) - LOAD_OFFSET) {               \
417                 HEAD_TEXT                                               \
418         }
419
420 /*
421  * Exception table
422  */
423 #define EXCEPTION_TABLE(align)                                          \
424         . = ALIGN(align);                                               \
425         __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET) {               \
426                 VMLINUX_SYMBOL(__start___ex_table) = .;                 \
427                 *(__ex_table)                                           \
428                 VMLINUX_SYMBOL(__stop___ex_table) = .;                  \
429         }
430
431 /*
432  * Init task
433  */
434 #define INIT_TASK_DATA(align)                                           \
435         . = ALIGN(align);                                               \
436         .data.init_task : {                                             \
437                 INIT_TASK                                               \
438         }
439
440 #ifdef CONFIG_CONSTRUCTORS
441 #define KERNEL_CTORS()  . = ALIGN(8);                      \
442                         VMLINUX_SYMBOL(__ctors_start) = .; \
443                         *(.ctors)                          \
444                         VMLINUX_SYMBOL(__ctors_end) = .;
445 #else
446 #define KERNEL_CTORS()
447 #endif
448
449 /* init and exit section handling */
450 #define INIT_DATA                                                       \
451         *(.init.data)                                                   \
452         DEV_DISCARD(init.data)                                          \
453         CPU_DISCARD(init.data)                                          \
454         MEM_DISCARD(init.data)                                          \
455         KERNEL_CTORS()                                                  \
456         *(.init.rodata)                                                 \
457         DEV_DISCARD(init.rodata)                                        \
458         CPU_DISCARD(init.rodata)                                        \
459         MEM_DISCARD(init.rodata)
460
461 #define INIT_TEXT                                                       \
462         *(.init.text)                                                   \
463         DEV_DISCARD(init.text)                                          \
464         CPU_DISCARD(init.text)                                          \
465         MEM_DISCARD(init.text)
466
467 #define EXIT_DATA                                                       \
468         *(.exit.data)                                                   \
469         DEV_DISCARD(exit.data)                                          \
470         DEV_DISCARD(exit.rodata)                                        \
471         CPU_DISCARD(exit.data)                                          \
472         CPU_DISCARD(exit.rodata)                                        \
473         MEM_DISCARD(exit.data)                                          \
474         MEM_DISCARD(exit.rodata)
475
476 #define EXIT_TEXT                                                       \
477         *(.exit.text)                                                   \
478         DEV_DISCARD(exit.text)                                          \
479         CPU_DISCARD(exit.text)                                          \
480         MEM_DISCARD(exit.text)
481
482 #define EXIT_CALL                                                       \
483         *(.exitcall.exit)
484
485 /*
486  * bss (Block Started by Symbol) - uninitialized data
487  * zeroed during startup
488  */
489 #define SBSS                                                            \
490         .sbss : AT(ADDR(.sbss) - LOAD_OFFSET) {                         \
491                 *(.sbss)                                                \
492                 *(.scommon)                                             \
493         }
494
495 #define BSS(bss_align)                                                  \
496         . = ALIGN(bss_align);                                           \
497         .bss : AT(ADDR(.bss) - LOAD_OFFSET) {                           \
498                 VMLINUX_SYMBOL(__bss_start) = .;                        \
499                 *(.bss.page_aligned)                                    \
500                 *(.dynbss)                                              \
501                 *(.bss)                                                 \
502                 *(COMMON)                                               \
503                 VMLINUX_SYMBOL(__bss_stop) = .;                         \
504         }
505
506 /*
507  * DWARF debug sections.
508  * Symbols in the DWARF debugging sections are relative to
509  * the beginning of the section so we begin them at 0.
510  */
511 #define DWARF_DEBUG                                                     \
512                 /* DWARF 1 */                                           \
513                 .debug          0 : { *(.debug) }                       \
514                 .line           0 : { *(.line) }                        \
515                 /* GNU DWARF 1 extensions */                            \
516                 .debug_srcinfo  0 : { *(.debug_srcinfo) }               \
517                 .debug_sfnames  0 : { *(.debug_sfnames) }               \
518                 /* DWARF 1.1 and DWARF 2 */                             \
519                 .debug_aranges  0 : { *(.debug_aranges) }               \
520                 .debug_pubnames 0 : { *(.debug_pubnames) }              \
521                 /* DWARF 2 */                                           \
522                 .debug_info     0 : { *(.debug_info                     \
523                                 .gnu.linkonce.wi.*) }                   \
524                 .debug_abbrev   0 : { *(.debug_abbrev) }                \
525                 .debug_line     0 : { *(.debug_line) }                  \
526                 .debug_frame    0 : { *(.debug_frame) }                 \
527                 .debug_str      0 : { *(.debug_str) }                   \
528                 .debug_loc      0 : { *(.debug_loc) }                   \
529                 .debug_macinfo  0 : { *(.debug_macinfo) }               \
530                 /* SGI/MIPS DWARF 2 extensions */                       \
531                 .debug_weaknames 0 : { *(.debug_weaknames) }            \
532                 .debug_funcnames 0 : { *(.debug_funcnames) }            \
533                 .debug_typenames 0 : { *(.debug_typenames) }            \
534                 .debug_varnames  0 : { *(.debug_varnames) }             \
535
536                 /* Stabs debugging sections.  */
537 #define STABS_DEBUG                                                     \
538                 .stab 0 : { *(.stab) }                                  \
539                 .stabstr 0 : { *(.stabstr) }                            \
540                 .stab.excl 0 : { *(.stab.excl) }                        \
541                 .stab.exclstr 0 : { *(.stab.exclstr) }                  \
542                 .stab.index 0 : { *(.stab.index) }                      \
543                 .stab.indexstr 0 : { *(.stab.indexstr) }                \
544                 .comment 0 : { *(.comment) }
545
546 #ifdef CONFIG_GENERIC_BUG
547 #define BUG_TABLE                                                       \
548         . = ALIGN(8);                                                   \
549         __bug_table : AT(ADDR(__bug_table) - LOAD_OFFSET) {             \
550                 VMLINUX_SYMBOL(__start___bug_table) = .;                \
551                 *(__bug_table)                                          \
552                 VMLINUX_SYMBOL(__stop___bug_table) = .;                 \
553         }
554 #else
555 #define BUG_TABLE
556 #endif
557
558 #ifdef CONFIG_PM_TRACE
559 #define TRACEDATA                                                       \
560         . = ALIGN(4);                                                   \
561         .tracedata : AT(ADDR(.tracedata) - LOAD_OFFSET) {               \
562                 VMLINUX_SYMBOL(__tracedata_start) = .;                  \
563                 *(.tracedata)                                           \
564                 VMLINUX_SYMBOL(__tracedata_end) = .;                    \
565         }
566 #else
567 #define TRACEDATA
568 #endif
569
570 #define NOTES                                                           \
571         .notes : AT(ADDR(.notes) - LOAD_OFFSET) {                       \
572                 VMLINUX_SYMBOL(__start_notes) = .;                      \
573                 *(.note.*)                                              \
574                 VMLINUX_SYMBOL(__stop_notes) = .;                       \
575         }
576
577 #define INIT_SETUP(initsetup_align)                                     \
578                 . = ALIGN(initsetup_align);                             \
579                 VMLINUX_SYMBOL(__setup_start) = .;                      \
580                 *(.init.setup)                                          \
581                 VMLINUX_SYMBOL(__setup_end) = .;
582
583 #define INITCALLS                                                       \
584         *(.initcallearly.init)                                          \
585         VMLINUX_SYMBOL(__early_initcall_end) = .;                       \
586         *(.initcall0.init)                                              \
587         *(.initcall0s.init)                                             \
588         *(.initcall1.init)                                              \
589         *(.initcall1s.init)                                             \
590         *(.initcall2.init)                                              \
591         *(.initcall2s.init)                                             \
592         *(.initcall3.init)                                              \
593         *(.initcall3s.init)                                             \
594         *(.initcall4.init)                                              \
595         *(.initcall4s.init)                                             \
596         *(.initcall5.init)                                              \
597         *(.initcall5s.init)                                             \
598         *(.initcallrootfs.init)                                         \
599         *(.initcall6.init)                                              \
600         *(.initcall6s.init)                                             \
601         *(.initcall7.init)                                              \
602         *(.initcall7s.init)
603
604 #define INIT_CALLS                                                      \
605                 VMLINUX_SYMBOL(__initcall_start) = .;                   \
606                 INITCALLS                                               \
607                 VMLINUX_SYMBOL(__initcall_end) = .;
608
609 #define CON_INITCALL                                                    \
610                 VMLINUX_SYMBOL(__con_initcall_start) = .;               \
611                 *(.con_initcall.init)                                   \
612                 VMLINUX_SYMBOL(__con_initcall_end) = .;
613
614 #define SECURITY_INITCALL                                               \
615                 VMLINUX_SYMBOL(__security_initcall_start) = .;          \
616                 *(.security_initcall.init)                              \
617                 VMLINUX_SYMBOL(__security_initcall_end) = .;
618
619 #ifdef CONFIG_BLK_DEV_INITRD
620 #define INIT_RAM_FS                                                     \
621         . = ALIGN(PAGE_SIZE);                                           \
622         VMLINUX_SYMBOL(__initramfs_start) = .;                          \
623         *(.init.ramfs)                                                  \
624         VMLINUX_SYMBOL(__initramfs_end) = .;
625 #else
626 #define INIT_RAM_FS
627 #endif
628
629 /*
630  * Default discarded sections.
631  *
632  * Some archs want to discard exit text/data at runtime rather than
633  * link time due to cross-section references such as alt instructions,
634  * bug table, eh_frame, etc.  DISCARDS must be the last of output
635  * section definitions so that such archs put those in earlier section
636  * definitions.
637  */
638 #define DISCARDS                                                        \
639         /DISCARD/ : {                                                   \
640         EXIT_TEXT                                                       \
641         EXIT_DATA                                                       \
642         EXIT_CALL                                                       \
643         *(.discard)                                                     \
644         }
645
646 /**
647  * PERCPU_VADDR - define output section for percpu area
648  * @vaddr: explicit base address (optional)
649  * @phdr: destination PHDR (optional)
650  *
651  * Macro which expands to output section for percpu area.  If @vaddr
652  * is not blank, it specifies explicit base address and all percpu
653  * symbols will be offset from the given address.  If blank, @vaddr
654  * always equals @laddr + LOAD_OFFSET.
655  *
656  * @phdr defines the output PHDR to use if not blank.  Be warned that
657  * output PHDR is sticky.  If @phdr is specified, the next output
658  * section in the linker script will go there too.  @phdr should have
659  * a leading colon.
660  *
661  * Note that this macros defines __per_cpu_load as an absolute symbol.
662  * If there is no need to put the percpu section at a predetermined
663  * address, use PERCPU().
664  */
665 #define PERCPU_VADDR(vaddr, phdr)                                       \
666         VMLINUX_SYMBOL(__per_cpu_load) = .;                             \
667         .data.percpu vaddr : AT(VMLINUX_SYMBOL(__per_cpu_load)          \
668                                 - LOAD_OFFSET) {                        \
669                 VMLINUX_SYMBOL(__per_cpu_start) = .;                    \
670                 *(.data.percpu.first)                                   \
671                 *(.data.percpu.page_aligned)                            \
672                 *(.data.percpu)                                         \
673                 *(.data.percpu.shared_aligned)                          \
674                 VMLINUX_SYMBOL(__per_cpu_end) = .;                      \
675         } phdr                                                          \
676         . = VMLINUX_SYMBOL(__per_cpu_load) + SIZEOF(.data.percpu);
677
678 /**
679  * PERCPU - define output section for percpu area, simple version
680  * @align: required alignment
681  *
682  * Align to @align and outputs output section for percpu area.  This
683  * macro doesn't maniuplate @vaddr or @phdr and __per_cpu_load and
684  * __per_cpu_start will be identical.
685  *
686  * This macro is equivalent to ALIGN(align); PERCPU_VADDR( , ) except
687  * that __per_cpu_load is defined as a relative symbol against
688  * .data.percpu which is required for relocatable x86_32
689  * configuration.
690  */
691 #define PERCPU(align)                                                   \
692         . = ALIGN(align);                                               \
693         .data.percpu    : AT(ADDR(.data.percpu) - LOAD_OFFSET) {        \
694                 VMLINUX_SYMBOL(__per_cpu_load) = .;                     \
695                 VMLINUX_SYMBOL(__per_cpu_start) = .;                    \
696                 *(.data.percpu.first)                                   \
697                 *(.data.percpu.page_aligned)                            \
698                 *(.data.percpu)                                         \
699                 *(.data.percpu.shared_aligned)                          \
700                 VMLINUX_SYMBOL(__per_cpu_end) = .;                      \
701         }
702
703
704 /*
705  * Definition of the high level *_SECTION macros
706  * They will fit only a subset of the architectures
707  */
708
709
710 /*
711  * Writeable data.
712  * All sections are combined in a single .data section.
713  * The sections following CONSTRUCTORS are arranged so their
714  * typical alignment matches.
715  * A cacheline is typical/always less than a PAGE_SIZE so
716  * the sections that has this restriction (or similar)
717  * is located before the ones requiring PAGE_SIZE alignment.
718  * NOSAVE_DATA starts and ends with a PAGE_SIZE alignment which
719  * matches the requirment of PAGE_ALIGNED_DATA.
720  *
721  * use 0 as page_align if page_aligned data is not used */
722 #define RW_DATA_SECTION(cacheline, nosave, pagealigned, inittask)       \
723         . = ALIGN(PAGE_SIZE);                                           \
724         .data : AT(ADDR(.data) - LOAD_OFFSET) {                         \
725                 INIT_TASK(inittask)                                     \
726                 CACHELINE_ALIGNED_DATA(cacheline)                       \
727                 READ_MOSTLY_DATA(cacheline)                             \
728                 DATA_DATA                                               \
729                 CONSTRUCTORS                                            \
730                 NOSAVE_DATA(nosave)                                     \
731                 PAGE_ALIGNED_DATA(pagealigned)                          \
732         }
733
734 #define INIT_TEXT_SECTION(inittext_align)                               \
735         . = ALIGN(inittext_align);                                      \
736         .init.text : AT(ADDR(.init.text) - LOAD_OFFSET) {               \
737                 VMLINUX_SYMBOL(_sinittext) = .;                         \
738                 INIT_TEXT                                               \
739                 VMLINUX_SYMBOL(_einittext) = .;                         \
740         }
741
742 #define INIT_DATA_SECTION(initsetup_align)                              \
743         .init.data : AT(ADDR(.init.data) - LOAD_OFFSET) {               \
744                 INIT_DATA                                               \
745                 INIT_SETUP(initsetup_align)                             \
746                 INIT_CALLS                                              \
747                 CON_INITCALL                                            \
748                 SECURITY_INITCALL                                       \
749                 INIT_RAM_FS                                             \
750         }
751
752 #define BSS_SECTION(sbss_align, bss_align)                              \
753         SBSS                                                            \
754         BSS(bss_align)                                                  \
755         . = ALIGN(4);
756