[PATCH] i386/x86-64: Work around gcc bug with noreturn functions in unwinder
[linux-2.6.git] / arch / x86_64 / ia32 / ia32entry.S
1 /*
2  * Compatibility mode system call entry point for x86-64. 
3  *              
4  * Copyright 2000-2002 Andi Kleen, SuSE Labs.
5  */              
6
7 #include <asm/dwarf2.h>
8 #include <asm/calling.h>
9 #include <asm/asm-offsets.h>
10 #include <asm/current.h>
11 #include <asm/errno.h>
12 #include <asm/ia32_unistd.h>    
13 #include <asm/thread_info.h>    
14 #include <asm/segment.h>
15 #include <asm/vsyscall32.h>
16 #include <asm/irqflags.h>
17 #include <linux/linkage.h>
18
19 #define IA32_NR_syscalls ((ia32_syscall_end - ia32_sys_call_table)/8)
20
21         .macro IA32_ARG_FIXUP noebp=0
22         movl    %edi,%r8d
23         .if \noebp
24         .else
25         movl    %ebp,%r9d
26         .endif
27         xchg    %ecx,%esi
28         movl    %ebx,%edi
29         movl    %edx,%edx       /* zero extension */
30         .endm 
31
32         /* clobbers %eax */     
33         .macro  CLEAR_RREGS
34         xorl    %eax,%eax
35         movq    %rax,R11(%rsp)
36         movq    %rax,R10(%rsp)
37         movq    %rax,R9(%rsp)
38         movq    %rax,R8(%rsp)
39         .endm
40
41         .macro CFI_STARTPROC32 simple
42         CFI_STARTPROC   \simple
43         CFI_UNDEFINED   r8
44         CFI_UNDEFINED   r9
45         CFI_UNDEFINED   r10
46         CFI_UNDEFINED   r11
47         CFI_UNDEFINED   r12
48         CFI_UNDEFINED   r13
49         CFI_UNDEFINED   r14
50         CFI_UNDEFINED   r15
51         .endm
52
53 /*
54  * 32bit SYSENTER instruction entry.
55  *
56  * Arguments:
57  * %eax System call number.
58  * %ebx Arg1
59  * %ecx Arg2
60  * %edx Arg3
61  * %esi Arg4
62  * %edi Arg5
63  * %ebp user stack
64  * 0(%ebp) Arg6 
65  *      
66  * Interrupts off.
67  *      
68  * This is purely a fast path. For anything complicated we use the int 0x80
69  * path below.  Set up a complete hardware stack frame to share code
70  * with the int 0x80 path.
71  */     
72 ENTRY(ia32_sysenter_target)
73         CFI_STARTPROC32 simple
74         CFI_SIGNAL_FRAME
75         CFI_DEF_CFA     rsp,0
76         CFI_REGISTER    rsp,rbp
77         swapgs
78         movq    %gs:pda_kernelstack, %rsp
79         addq    $(PDA_STACKOFFSET),%rsp 
80         /*
81          * No need to follow this irqs on/off section: the syscall
82          * disabled irqs, here we enable it straight after entry:
83          */
84         sti     
85         movl    %ebp,%ebp               /* zero extension */
86         pushq   $__USER32_DS
87         CFI_ADJUST_CFA_OFFSET 8
88         /*CFI_REL_OFFSET ss,0*/
89         pushq   %rbp
90         CFI_ADJUST_CFA_OFFSET 8
91         CFI_REL_OFFSET rsp,0
92         pushfq
93         CFI_ADJUST_CFA_OFFSET 8
94         /*CFI_REL_OFFSET rflags,0*/
95         movl    $VSYSCALL32_SYSEXIT, %r10d
96         CFI_REGISTER rip,r10
97         pushq   $__USER32_CS
98         CFI_ADJUST_CFA_OFFSET 8
99         /*CFI_REL_OFFSET cs,0*/
100         movl    %eax, %eax
101         pushq   %r10
102         CFI_ADJUST_CFA_OFFSET 8
103         CFI_REL_OFFSET rip,0
104         pushq   %rax
105         CFI_ADJUST_CFA_OFFSET 8
106         cld
107         SAVE_ARGS 0,0,0
108         /* no need to do an access_ok check here because rbp has been
109            32bit zero extended */ 
110 1:      movl    (%rbp),%r9d
111         .section __ex_table,"a"
112         .quad 1b,ia32_badarg
113         .previous       
114         GET_THREAD_INFO(%r10)
115         orl    $TS_COMPAT,threadinfo_status(%r10)
116         testl  $(_TIF_SYSCALL_TRACE|_TIF_SYSCALL_AUDIT|_TIF_SECCOMP),threadinfo_flags(%r10)
117         CFI_REMEMBER_STATE
118         jnz  sysenter_tracesys
119 sysenter_do_call:       
120         cmpl    $(IA32_NR_syscalls-1),%eax
121         ja      ia32_badsys
122         IA32_ARG_FIXUP 1
123         call    *ia32_sys_call_table(,%rax,8)
124         movq    %rax,RAX-ARGOFFSET(%rsp)
125         GET_THREAD_INFO(%r10)
126         cli
127         TRACE_IRQS_OFF
128         testl   $_TIF_ALLWORK_MASK,threadinfo_flags(%r10)
129         jnz     int_ret_from_sys_call
130         andl    $~TS_COMPAT,threadinfo_status(%r10)
131         /* clear IF, that popfq doesn't enable interrupts early */
132         andl  $~0x200,EFLAGS-R11(%rsp) 
133         RESTORE_ARGS 1,24,1,1,1,1
134         popfq
135         CFI_ADJUST_CFA_OFFSET -8
136         /*CFI_RESTORE rflags*/
137         popq    %rcx                            /* User %esp */
138         CFI_ADJUST_CFA_OFFSET -8
139         CFI_REGISTER rsp,rcx
140         movl    $VSYSCALL32_SYSEXIT,%edx        /* User %eip */
141         CFI_REGISTER rip,rdx
142         TRACE_IRQS_ON
143         swapgs
144         sti             /* sti only takes effect after the next instruction */
145         /* sysexit */
146         .byte   0xf, 0x35
147
148 sysenter_tracesys:
149         CFI_RESTORE_STATE
150         SAVE_REST
151         CLEAR_RREGS
152         movq    $-ENOSYS,RAX(%rsp)      /* really needed? */
153         movq    %rsp,%rdi        /* &pt_regs -> arg1 */
154         call    syscall_trace_enter
155         LOAD_ARGS ARGOFFSET  /* reload args from stack in case ptrace changed it */
156         RESTORE_REST
157         movl    %ebp, %ebp
158         /* no need to do an access_ok check here because rbp has been
159            32bit zero extended */ 
160 1:      movl    (%rbp),%r9d
161         .section __ex_table,"a"
162         .quad 1b,ia32_badarg
163         .previous
164         jmp     sysenter_do_call
165         CFI_ENDPROC
166 ENDPROC(ia32_sysenter_target)
167
168 /*
169  * 32bit SYSCALL instruction entry.
170  *
171  * Arguments:
172  * %eax System call number.
173  * %ebx Arg1
174  * %ecx return EIP 
175  * %edx Arg3
176  * %esi Arg4
177  * %edi Arg5
178  * %ebp Arg2    [note: not saved in the stack frame, should not be touched]
179  * %esp user stack 
180  * 0(%esp) Arg6
181  *      
182  * Interrupts off.
183  *      
184  * This is purely a fast path. For anything complicated we use the int 0x80
185  * path below.  Set up a complete hardware stack frame to share code
186  * with the int 0x80 path.      
187  */     
188 ENTRY(ia32_cstar_target)
189         CFI_STARTPROC32 simple
190         CFI_SIGNAL_FRAME
191         CFI_DEF_CFA     rsp,PDA_STACKOFFSET
192         CFI_REGISTER    rip,rcx
193         /*CFI_REGISTER  rflags,r11*/
194         swapgs
195         movl    %esp,%r8d
196         CFI_REGISTER    rsp,r8
197         movq    %gs:pda_kernelstack,%rsp
198         /*
199          * No need to follow this irqs on/off section: the syscall
200          * disabled irqs and here we enable it straight after entry:
201          */
202         sti
203         SAVE_ARGS 8,1,1
204         movl    %eax,%eax       /* zero extension */
205         movq    %rax,ORIG_RAX-ARGOFFSET(%rsp)
206         movq    %rcx,RIP-ARGOFFSET(%rsp)
207         CFI_REL_OFFSET rip,RIP-ARGOFFSET
208         movq    %rbp,RCX-ARGOFFSET(%rsp) /* this lies slightly to ptrace */
209         movl    %ebp,%ecx
210         movq    $__USER32_CS,CS-ARGOFFSET(%rsp)
211         movq    $__USER32_DS,SS-ARGOFFSET(%rsp)
212         movq    %r11,EFLAGS-ARGOFFSET(%rsp)
213         /*CFI_REL_OFFSET rflags,EFLAGS-ARGOFFSET*/
214         movq    %r8,RSP-ARGOFFSET(%rsp) 
215         CFI_REL_OFFSET rsp,RSP-ARGOFFSET
216         /* no need to do an access_ok check here because r8 has been
217            32bit zero extended */ 
218         /* hardware stack frame is complete now */      
219 1:      movl    (%r8),%r9d
220         .section __ex_table,"a"
221         .quad 1b,ia32_badarg
222         .previous       
223         GET_THREAD_INFO(%r10)
224         orl   $TS_COMPAT,threadinfo_status(%r10)
225         testl $(_TIF_SYSCALL_TRACE|_TIF_SYSCALL_AUDIT|_TIF_SECCOMP),threadinfo_flags(%r10)
226         CFI_REMEMBER_STATE
227         jnz   cstar_tracesys
228 cstar_do_call:  
229         cmpl $IA32_NR_syscalls-1,%eax
230         ja  ia32_badsys
231         IA32_ARG_FIXUP 1
232         call *ia32_sys_call_table(,%rax,8)
233         movq %rax,RAX-ARGOFFSET(%rsp)
234         GET_THREAD_INFO(%r10)
235         cli
236         TRACE_IRQS_OFF
237         testl $_TIF_ALLWORK_MASK,threadinfo_flags(%r10)
238         jnz  int_ret_from_sys_call
239         andl $~TS_COMPAT,threadinfo_status(%r10)
240         RESTORE_ARGS 1,-ARG_SKIP,1,1,1
241         movl RIP-ARGOFFSET(%rsp),%ecx
242         CFI_REGISTER rip,rcx
243         movl EFLAGS-ARGOFFSET(%rsp),%r11d       
244         /*CFI_REGISTER rflags,r11*/
245         TRACE_IRQS_ON
246         movl RSP-ARGOFFSET(%rsp),%esp
247         CFI_RESTORE rsp
248         swapgs
249         sysretl
250         
251 cstar_tracesys: 
252         CFI_RESTORE_STATE
253         SAVE_REST
254         CLEAR_RREGS
255         movq $-ENOSYS,RAX(%rsp) /* really needed? */
256         movq %rsp,%rdi        /* &pt_regs -> arg1 */
257         call syscall_trace_enter
258         LOAD_ARGS ARGOFFSET  /* reload args from stack in case ptrace changed it */
259         RESTORE_REST
260         movl RSP-ARGOFFSET(%rsp), %r8d
261         /* no need to do an access_ok check here because r8 has been
262            32bit zero extended */ 
263 1:      movl    (%r8),%r9d
264         .section __ex_table,"a"
265         .quad 1b,ia32_badarg
266         .previous
267         jmp cstar_do_call
268 END(ia32_cstar_target)
269                                 
270 ia32_badarg:
271         movq $-EFAULT,%rax
272         jmp ia32_sysret
273         CFI_ENDPROC
274
275 /* 
276  * Emulated IA32 system calls via int 0x80. 
277  *
278  * Arguments:    
279  * %eax System call number.
280  * %ebx Arg1
281  * %ecx Arg2
282  * %edx Arg3
283  * %esi Arg4
284  * %edi Arg5
285  * %ebp Arg6    [note: not saved in the stack frame, should not be touched]
286  *
287  * Notes:
288  * Uses the same stack frame as the x86-64 version.     
289  * All registers except %eax must be saved (but ptrace may violate that)
290  * Arguments are zero extended. For system calls that want sign extension and
291  * take long arguments a wrapper is needed. Most calls can just be called
292  * directly.
293  * Assumes it is only called from user space and entered with interrupts off.   
294  */                             
295
296 ENTRY(ia32_syscall)
297         CFI_STARTPROC   simple
298         CFI_SIGNAL_FRAME
299         CFI_DEF_CFA     rsp,SS+8-RIP
300         /*CFI_REL_OFFSET        ss,SS-RIP*/
301         CFI_REL_OFFSET  rsp,RSP-RIP
302         /*CFI_REL_OFFSET        rflags,EFLAGS-RIP*/
303         /*CFI_REL_OFFSET        cs,CS-RIP*/
304         CFI_REL_OFFSET  rip,RIP-RIP
305         swapgs
306         /*
307          * No need to follow this irqs on/off section: the syscall
308          * disabled irqs and here we enable it straight after entry:
309          */
310         sti
311         movl %eax,%eax
312         pushq %rax
313         CFI_ADJUST_CFA_OFFSET 8
314         cld
315         /* note the registers are not zero extended to the sf.
316            this could be a problem. */
317         SAVE_ARGS 0,0,1
318         GET_THREAD_INFO(%r10)
319         orl   $TS_COMPAT,threadinfo_status(%r10)
320         testl $(_TIF_SYSCALL_TRACE|_TIF_SYSCALL_AUDIT|_TIF_SECCOMP),threadinfo_flags(%r10)
321         jnz ia32_tracesys
322 ia32_do_syscall:        
323         cmpl $(IA32_NR_syscalls-1),%eax
324         ja  ia32_badsys
325         IA32_ARG_FIXUP
326         call *ia32_sys_call_table(,%rax,8) # xxx: rip relative
327 ia32_sysret:
328         movq %rax,RAX-ARGOFFSET(%rsp)
329         jmp int_ret_from_sys_call 
330
331 ia32_tracesys:                   
332         SAVE_REST
333         movq $-ENOSYS,RAX(%rsp) /* really needed? */
334         movq %rsp,%rdi        /* &pt_regs -> arg1 */
335         call syscall_trace_enter
336         LOAD_ARGS ARGOFFSET  /* reload args from stack in case ptrace changed it */
337         RESTORE_REST
338         jmp ia32_do_syscall
339 END(ia32_syscall)
340
341 ia32_badsys:
342         movq $0,ORIG_RAX-ARGOFFSET(%rsp)
343         movq $-ENOSYS,RAX-ARGOFFSET(%rsp)
344         jmp int_ret_from_sys_call
345
346 quiet_ni_syscall:
347         movq $-ENOSYS,%rax
348         ret
349         CFI_ENDPROC
350         
351         .macro PTREGSCALL label, func, arg
352         .globl \label
353 \label:
354         leaq \func(%rip),%rax
355         leaq -ARGOFFSET+8(%rsp),\arg    /* 8 for return address */
356         jmp  ia32_ptregs_common 
357         .endm
358
359         CFI_STARTPROC32
360
361         PTREGSCALL stub32_rt_sigreturn, sys32_rt_sigreturn, %rdi
362         PTREGSCALL stub32_sigreturn, sys32_sigreturn, %rdi
363         PTREGSCALL stub32_sigaltstack, sys32_sigaltstack, %rdx
364         PTREGSCALL stub32_sigsuspend, sys32_sigsuspend, %rcx
365         PTREGSCALL stub32_execve, sys32_execve, %rcx
366         PTREGSCALL stub32_fork, sys_fork, %rdi
367         PTREGSCALL stub32_clone, sys32_clone, %rdx
368         PTREGSCALL stub32_vfork, sys_vfork, %rdi
369         PTREGSCALL stub32_iopl, sys_iopl, %rsi
370         PTREGSCALL stub32_rt_sigsuspend, sys_rt_sigsuspend, %rdx
371
372 ENTRY(ia32_ptregs_common)
373         popq %r11
374         CFI_ENDPROC
375         CFI_STARTPROC32 simple
376         CFI_SIGNAL_FRAME
377         CFI_DEF_CFA     rsp,SS+8-ARGOFFSET
378         CFI_REL_OFFSET  rax,RAX-ARGOFFSET
379         CFI_REL_OFFSET  rcx,RCX-ARGOFFSET
380         CFI_REL_OFFSET  rdx,RDX-ARGOFFSET
381         CFI_REL_OFFSET  rsi,RSI-ARGOFFSET
382         CFI_REL_OFFSET  rdi,RDI-ARGOFFSET
383         CFI_REL_OFFSET  rip,RIP-ARGOFFSET
384 /*      CFI_REL_OFFSET  cs,CS-ARGOFFSET*/
385 /*      CFI_REL_OFFSET  rflags,EFLAGS-ARGOFFSET*/
386         CFI_REL_OFFSET  rsp,RSP-ARGOFFSET
387 /*      CFI_REL_OFFSET  ss,SS-ARGOFFSET*/
388         SAVE_REST
389         call *%rax
390         RESTORE_REST
391         jmp  ia32_sysret        /* misbalances the return cache */
392         CFI_ENDPROC
393 END(ia32_ptregs_common)
394
395         .section .rodata,"a"
396         .align 8
397 ia32_sys_call_table:
398         .quad sys_restart_syscall
399         .quad sys_exit
400         .quad stub32_fork
401         .quad sys_read
402         .quad sys_write
403         .quad compat_sys_open           /* 5 */
404         .quad sys_close
405         .quad sys32_waitpid
406         .quad sys_creat
407         .quad sys_link
408         .quad sys_unlink                /* 10 */
409         .quad stub32_execve
410         .quad sys_chdir
411         .quad compat_sys_time
412         .quad sys_mknod
413         .quad sys_chmod         /* 15 */
414         .quad sys_lchown16
415         .quad quiet_ni_syscall                  /* old break syscall holder */
416         .quad sys_stat
417         .quad sys32_lseek
418         .quad sys_getpid                /* 20 */
419         .quad compat_sys_mount  /* mount  */
420         .quad sys_oldumount     /* old_umount  */
421         .quad sys_setuid16
422         .quad sys_getuid16
423         .quad compat_sys_stime  /* stime */             /* 25 */
424         .quad sys32_ptrace      /* ptrace */
425         .quad sys_alarm
426         .quad sys_fstat /* (old)fstat */
427         .quad sys_pause
428         .quad compat_sys_utime  /* 30 */
429         .quad quiet_ni_syscall  /* old stty syscall holder */
430         .quad quiet_ni_syscall  /* old gtty syscall holder */
431         .quad sys_access
432         .quad sys_nice  
433         .quad quiet_ni_syscall  /* 35 */        /* old ftime syscall holder */
434         .quad sys_sync
435         .quad sys32_kill
436         .quad sys_rename
437         .quad sys_mkdir
438         .quad sys_rmdir         /* 40 */
439         .quad sys_dup
440         .quad sys32_pipe
441         .quad compat_sys_times
442         .quad quiet_ni_syscall                  /* old prof syscall holder */
443         .quad sys_brk           /* 45 */
444         .quad sys_setgid16
445         .quad sys_getgid16
446         .quad sys_signal
447         .quad sys_geteuid16
448         .quad sys_getegid16     /* 50 */
449         .quad sys_acct
450         .quad sys_umount                        /* new_umount */
451         .quad quiet_ni_syscall                  /* old lock syscall holder */
452         .quad compat_sys_ioctl
453         .quad compat_sys_fcntl64                /* 55 */
454         .quad quiet_ni_syscall                  /* old mpx syscall holder */
455         .quad sys_setpgid
456         .quad quiet_ni_syscall                  /* old ulimit syscall holder */
457         .quad sys32_olduname
458         .quad sys_umask         /* 60 */
459         .quad sys_chroot
460         .quad sys32_ustat
461         .quad sys_dup2
462         .quad sys_getppid
463         .quad sys_getpgrp               /* 65 */
464         .quad sys_setsid
465         .quad sys32_sigaction
466         .quad sys_sgetmask
467         .quad sys_ssetmask
468         .quad sys_setreuid16    /* 70 */
469         .quad sys_setregid16
470         .quad stub32_sigsuspend
471         .quad compat_sys_sigpending
472         .quad sys_sethostname
473         .quad compat_sys_setrlimit      /* 75 */
474         .quad compat_sys_old_getrlimit  /* old_getrlimit */
475         .quad compat_sys_getrusage
476         .quad sys32_gettimeofday
477         .quad sys32_settimeofday
478         .quad sys_getgroups16   /* 80 */
479         .quad sys_setgroups16
480         .quad sys32_old_select
481         .quad sys_symlink
482         .quad sys_lstat
483         .quad sys_readlink              /* 85 */
484 #ifdef CONFIG_IA32_AOUT
485         .quad sys_uselib
486 #else
487         .quad quiet_ni_syscall
488 #endif
489         .quad sys_swapon
490         .quad sys_reboot
491         .quad compat_sys_old_readdir
492         .quad sys32_mmap                /* 90 */
493         .quad sys_munmap
494         .quad sys_truncate
495         .quad sys_ftruncate
496         .quad sys_fchmod
497         .quad sys_fchown16              /* 95 */
498         .quad sys_getpriority
499         .quad sys_setpriority
500         .quad quiet_ni_syscall                  /* old profil syscall holder */
501         .quad compat_sys_statfs
502         .quad compat_sys_fstatfs                /* 100 */
503         .quad sys_ioperm
504         .quad compat_sys_socketcall
505         .quad sys_syslog
506         .quad compat_sys_setitimer
507         .quad compat_sys_getitimer      /* 105 */
508         .quad compat_sys_newstat
509         .quad compat_sys_newlstat
510         .quad compat_sys_newfstat
511         .quad sys32_uname
512         .quad stub32_iopl               /* 110 */
513         .quad sys_vhangup
514         .quad quiet_ni_syscall  /* old "idle" system call */
515         .quad sys32_vm86_warning        /* vm86old */ 
516         .quad compat_sys_wait4
517         .quad sys_swapoff               /* 115 */
518         .quad sys32_sysinfo
519         .quad sys32_ipc
520         .quad sys_fsync
521         .quad stub32_sigreturn
522         .quad stub32_clone              /* 120 */
523         .quad sys_setdomainname
524         .quad sys_uname
525         .quad sys_modify_ldt
526         .quad compat_sys_adjtimex
527         .quad sys32_mprotect            /* 125 */
528         .quad compat_sys_sigprocmask
529         .quad quiet_ni_syscall          /* create_module */
530         .quad sys_init_module
531         .quad sys_delete_module
532         .quad quiet_ni_syscall          /* 130  get_kernel_syms */
533         .quad sys_quotactl
534         .quad sys_getpgid
535         .quad sys_fchdir
536         .quad quiet_ni_syscall  /* bdflush */
537         .quad sys_sysfs         /* 135 */
538         .quad sys_personality
539         .quad quiet_ni_syscall  /* for afs_syscall */
540         .quad sys_setfsuid16
541         .quad sys_setfsgid16
542         .quad sys_llseek                /* 140 */
543         .quad compat_sys_getdents
544         .quad compat_sys_select
545         .quad sys_flock
546         .quad sys_msync
547         .quad compat_sys_readv          /* 145 */
548         .quad compat_sys_writev
549         .quad sys_getsid
550         .quad sys_fdatasync
551         .quad sys32_sysctl      /* sysctl */
552         .quad sys_mlock         /* 150 */
553         .quad sys_munlock
554         .quad sys_mlockall
555         .quad sys_munlockall
556         .quad sys_sched_setparam
557         .quad sys_sched_getparam   /* 155 */
558         .quad sys_sched_setscheduler
559         .quad sys_sched_getscheduler
560         .quad sys_sched_yield
561         .quad sys_sched_get_priority_max
562         .quad sys_sched_get_priority_min  /* 160 */
563         .quad sys_sched_rr_get_interval
564         .quad compat_sys_nanosleep
565         .quad sys_mremap
566         .quad sys_setresuid16
567         .quad sys_getresuid16   /* 165 */
568         .quad sys32_vm86_warning        /* vm86 */ 
569         .quad quiet_ni_syscall  /* query_module */
570         .quad sys_poll
571         .quad compat_sys_nfsservctl
572         .quad sys_setresgid16   /* 170 */
573         .quad sys_getresgid16
574         .quad sys_prctl
575         .quad stub32_rt_sigreturn
576         .quad sys32_rt_sigaction
577         .quad sys32_rt_sigprocmask      /* 175 */
578         .quad sys32_rt_sigpending
579         .quad compat_sys_rt_sigtimedwait
580         .quad sys32_rt_sigqueueinfo
581         .quad stub32_rt_sigsuspend
582         .quad sys32_pread               /* 180 */
583         .quad sys32_pwrite
584         .quad sys_chown16
585         .quad sys_getcwd
586         .quad sys_capget
587         .quad sys_capset
588         .quad stub32_sigaltstack
589         .quad sys32_sendfile
590         .quad quiet_ni_syscall          /* streams1 */
591         .quad quiet_ni_syscall          /* streams2 */
592         .quad stub32_vfork            /* 190 */
593         .quad compat_sys_getrlimit
594         .quad sys32_mmap2
595         .quad sys32_truncate64
596         .quad sys32_ftruncate64
597         .quad sys32_stat64              /* 195 */
598         .quad sys32_lstat64
599         .quad sys32_fstat64
600         .quad sys_lchown
601         .quad sys_getuid
602         .quad sys_getgid                /* 200 */
603         .quad sys_geteuid
604         .quad sys_getegid
605         .quad sys_setreuid
606         .quad sys_setregid
607         .quad sys_getgroups     /* 205 */
608         .quad sys_setgroups
609         .quad sys_fchown
610         .quad sys_setresuid
611         .quad sys_getresuid
612         .quad sys_setresgid     /* 210 */
613         .quad sys_getresgid
614         .quad sys_chown
615         .quad sys_setuid
616         .quad sys_setgid
617         .quad sys_setfsuid              /* 215 */
618         .quad sys_setfsgid
619         .quad sys_pivot_root
620         .quad sys_mincore
621         .quad sys_madvise
622         .quad compat_sys_getdents64     /* 220 getdents64 */
623         .quad compat_sys_fcntl64        
624         .quad quiet_ni_syscall          /* tux */
625         .quad quiet_ni_syscall          /* security */
626         .quad sys_gettid        
627         .quad sys_readahead     /* 225 */
628         .quad sys_setxattr
629         .quad sys_lsetxattr
630         .quad sys_fsetxattr
631         .quad sys_getxattr
632         .quad sys_lgetxattr     /* 230 */
633         .quad sys_fgetxattr
634         .quad sys_listxattr
635         .quad sys_llistxattr
636         .quad sys_flistxattr
637         .quad sys_removexattr   /* 235 */
638         .quad sys_lremovexattr
639         .quad sys_fremovexattr
640         .quad sys_tkill
641         .quad sys_sendfile64 
642         .quad compat_sys_futex          /* 240 */
643         .quad compat_sys_sched_setaffinity
644         .quad compat_sys_sched_getaffinity
645         .quad sys32_set_thread_area
646         .quad sys32_get_thread_area
647         .quad compat_sys_io_setup       /* 245 */
648         .quad sys_io_destroy
649         .quad compat_sys_io_getevents
650         .quad compat_sys_io_submit
651         .quad sys_io_cancel
652         .quad sys_fadvise64             /* 250 */
653         .quad quiet_ni_syscall  /* free_huge_pages */
654         .quad sys_exit_group
655         .quad sys32_lookup_dcookie
656         .quad sys_epoll_create
657         .quad sys_epoll_ctl             /* 255 */
658         .quad sys_epoll_wait
659         .quad sys_remap_file_pages
660         .quad sys_set_tid_address
661         .quad compat_sys_timer_create
662         .quad compat_sys_timer_settime  /* 260 */
663         .quad compat_sys_timer_gettime
664         .quad sys_timer_getoverrun
665         .quad sys_timer_delete
666         .quad compat_sys_clock_settime
667         .quad compat_sys_clock_gettime  /* 265 */
668         .quad compat_sys_clock_getres
669         .quad compat_sys_clock_nanosleep
670         .quad compat_sys_statfs64
671         .quad compat_sys_fstatfs64
672         .quad sys_tgkill                /* 270 */
673         .quad compat_sys_utimes
674         .quad sys32_fadvise64_64
675         .quad quiet_ni_syscall  /* sys_vserver */
676         .quad sys_mbind
677         .quad compat_sys_get_mempolicy  /* 275 */
678         .quad sys_set_mempolicy
679         .quad compat_sys_mq_open
680         .quad sys_mq_unlink
681         .quad compat_sys_mq_timedsend
682         .quad compat_sys_mq_timedreceive        /* 280 */
683         .quad compat_sys_mq_notify
684         .quad compat_sys_mq_getsetattr
685         .quad compat_sys_kexec_load     /* reserved for kexec */
686         .quad compat_sys_waitid
687         .quad quiet_ni_syscall          /* 285: sys_altroot */
688         .quad sys_add_key
689         .quad sys_request_key
690         .quad sys_keyctl
691         .quad sys_ioprio_set
692         .quad sys_ioprio_get            /* 290 */
693         .quad sys_inotify_init
694         .quad sys_inotify_add_watch
695         .quad sys_inotify_rm_watch
696         .quad sys_migrate_pages
697         .quad compat_sys_openat         /* 295 */
698         .quad sys_mkdirat
699         .quad sys_mknodat
700         .quad sys_fchownat
701         .quad compat_sys_futimesat
702         .quad sys32_fstatat             /* 300 */
703         .quad sys_unlinkat
704         .quad sys_renameat
705         .quad sys_linkat
706         .quad sys_symlinkat
707         .quad sys_readlinkat            /* 305 */
708         .quad sys_fchmodat
709         .quad sys_faccessat
710         .quad compat_sys_pselect6
711         .quad compat_sys_ppoll
712         .quad sys_unshare               /* 310 */
713         .quad compat_sys_set_robust_list
714         .quad compat_sys_get_robust_list
715         .quad sys_splice
716         .quad sys_sync_file_range
717         .quad sys_tee
718         .quad compat_sys_vmsplice
719         .quad compat_sys_move_pages
720         .quad sys_getcpu
721 ia32_syscall_end: