x86, asm: Fix CFI macro invocations to deal with shortcomings in gas
[linux-2.6.git] / arch / x86 / kernel / entry_64.S
1 /*
2  *  linux/arch/x86_64/entry.S
3  *
4  *  Copyright (C) 1991, 1992  Linus Torvalds
5  *  Copyright (C) 2000, 2001, 2002  Andi Kleen SuSE Labs
6  *  Copyright (C) 2000  Pavel Machek <pavel@suse.cz>
7  */
8
9 /*
10  * entry.S contains the system-call and fault low-level handling routines.
11  *
12  * NOTE: This code handles signal-recognition, which happens every time
13  * after an interrupt and after each system call.
14  *
15  * Normal syscalls and interrupts don't save a full stack frame, this is
16  * only done for syscall tracing, signals or fork/exec et.al.
17  *
18  * A note on terminology:
19  * - top of stack: Architecture defined interrupt frame from SS to RIP
20  * at the top of the kernel process stack.
21  * - partial stack frame: partially saved registers upto R11.
22  * - full stack frame: Like partial stack frame, but all register saved.
23  *
24  * Some macro usage:
25  * - CFI macros are used to generate dwarf2 unwind information for better
26  * backtraces. They don't change any code.
27  * - SAVE_ALL/RESTORE_ALL - Save/restore all registers
28  * - SAVE_ARGS/RESTORE_ARGS - Save/restore registers that C functions modify.
29  * There are unfortunately lots of special cases where some registers
30  * not touched. The macro is a big mess that should be cleaned up.
31  * - SAVE_REST/RESTORE_REST - Handle the registers not saved by SAVE_ARGS.
32  * Gives a full stack frame.
33  * - ENTRY/END Define functions in the symbol table.
34  * - FIXUP_TOP_OF_STACK/RESTORE_TOP_OF_STACK - Fix up the hardware stack
35  * frame that is otherwise undefined after a SYSCALL
36  * - TRACE_IRQ_* - Trace hard interrupt state for lock debugging.
37  * - errorentry/paranoidentry/zeroentry - Define exception entry points.
38  */
39
40 #include <linux/linkage.h>
41 #include <asm/segment.h>
42 #include <asm/cache.h>
43 #include <asm/errno.h>
44 #include <asm/dwarf2.h>
45 #include <asm/calling.h>
46 #include <asm/asm-offsets.h>
47 #include <asm/msr.h>
48 #include <asm/unistd.h>
49 #include <asm/thread_info.h>
50 #include <asm/hw_irq.h>
51 #include <asm/page_types.h>
52 #include <asm/irqflags.h>
53 #include <asm/paravirt.h>
54 #include <asm/ftrace.h>
55 #include <asm/percpu.h>
56
57 /* Avoid __ASSEMBLER__'ifying <linux/audit.h> just for this.  */
58 #include <linux/elf-em.h>
59 #define AUDIT_ARCH_X86_64       (EM_X86_64|__AUDIT_ARCH_64BIT|__AUDIT_ARCH_LE)
60 #define __AUDIT_ARCH_64BIT 0x80000000
61 #define __AUDIT_ARCH_LE    0x40000000
62
63         .code64
64 #ifdef CONFIG_FUNCTION_TRACER
65 #ifdef CONFIG_DYNAMIC_FTRACE
66 ENTRY(mcount)
67         retq
68 END(mcount)
69
70 ENTRY(ftrace_caller)
71         cmpl $0, function_trace_stop
72         jne  ftrace_stub
73
74         MCOUNT_SAVE_FRAME
75
76         movq 0x38(%rsp), %rdi
77         movq 8(%rbp), %rsi
78         subq $MCOUNT_INSN_SIZE, %rdi
79
80 GLOBAL(ftrace_call)
81         call ftrace_stub
82
83         MCOUNT_RESTORE_FRAME
84
85 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
86 GLOBAL(ftrace_graph_call)
87         jmp ftrace_stub
88 #endif
89
90 GLOBAL(ftrace_stub)
91         retq
92 END(ftrace_caller)
93
94 #else /* ! CONFIG_DYNAMIC_FTRACE */
95 ENTRY(mcount)
96         cmpl $0, function_trace_stop
97         jne  ftrace_stub
98
99         cmpq $ftrace_stub, ftrace_trace_function
100         jnz trace
101
102 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
103         cmpq $ftrace_stub, ftrace_graph_return
104         jnz ftrace_graph_caller
105
106         cmpq $ftrace_graph_entry_stub, ftrace_graph_entry
107         jnz ftrace_graph_caller
108 #endif
109
110 GLOBAL(ftrace_stub)
111         retq
112
113 trace:
114         MCOUNT_SAVE_FRAME
115
116         movq 0x38(%rsp), %rdi
117         movq 8(%rbp), %rsi
118         subq $MCOUNT_INSN_SIZE, %rdi
119
120         call   *ftrace_trace_function
121
122         MCOUNT_RESTORE_FRAME
123
124         jmp ftrace_stub
125 END(mcount)
126 #endif /* CONFIG_DYNAMIC_FTRACE */
127 #endif /* CONFIG_FUNCTION_TRACER */
128
129 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
130 ENTRY(ftrace_graph_caller)
131         cmpl $0, function_trace_stop
132         jne ftrace_stub
133
134         MCOUNT_SAVE_FRAME
135
136         leaq 8(%rbp), %rdi
137         movq 0x38(%rsp), %rsi
138         movq (%rbp), %rdx
139         subq $MCOUNT_INSN_SIZE, %rsi
140
141         call    prepare_ftrace_return
142
143         MCOUNT_RESTORE_FRAME
144
145         retq
146 END(ftrace_graph_caller)
147
148 GLOBAL(return_to_handler)
149         subq  $24, %rsp
150
151         /* Save the return values */
152         movq %rax, (%rsp)
153         movq %rdx, 8(%rsp)
154         movq %rbp, %rdi
155
156         call ftrace_return_to_handler
157
158         movq %rax, %rdi
159         movq 8(%rsp), %rdx
160         movq (%rsp), %rax
161         addq $24, %rsp
162         jmp *%rdi
163 #endif
164
165
166 #ifndef CONFIG_PREEMPT
167 #define retint_kernel retint_restore_args
168 #endif
169
170 #ifdef CONFIG_PARAVIRT
171 ENTRY(native_usergs_sysret64)
172         swapgs
173         sysretq
174 ENDPROC(native_usergs_sysret64)
175 #endif /* CONFIG_PARAVIRT */
176
177
178 .macro TRACE_IRQS_IRETQ offset=ARGOFFSET
179 #ifdef CONFIG_TRACE_IRQFLAGS
180         bt   $9,EFLAGS-\offset(%rsp)    /* interrupts off? */
181         jnc  1f
182         TRACE_IRQS_ON
183 1:
184 #endif
185 .endm
186
187 /*
188  * C code is not supposed to know about undefined top of stack. Every time
189  * a C function with an pt_regs argument is called from the SYSCALL based
190  * fast path FIXUP_TOP_OF_STACK is needed.
191  * RESTORE_TOP_OF_STACK syncs the syscall state after any possible ptregs
192  * manipulation.
193  */
194
195         /* %rsp:at FRAMEEND */
196         .macro FIXUP_TOP_OF_STACK tmp offset=0
197         movq PER_CPU_VAR(old_rsp),\tmp
198         movq \tmp,RSP+\offset(%rsp)
199         movq $__USER_DS,SS+\offset(%rsp)
200         movq $__USER_CS,CS+\offset(%rsp)
201         movq $-1,RCX+\offset(%rsp)
202         movq R11+\offset(%rsp),\tmp  /* get eflags */
203         movq \tmp,EFLAGS+\offset(%rsp)
204         .endm
205
206         .macro RESTORE_TOP_OF_STACK tmp offset=0
207         movq RSP+\offset(%rsp),\tmp
208         movq \tmp,PER_CPU_VAR(old_rsp)
209         movq EFLAGS+\offset(%rsp),\tmp
210         movq \tmp,R11+\offset(%rsp)
211         .endm
212
213         .macro FAKE_STACK_FRAME child_rip
214         /* push in order ss, rsp, eflags, cs, rip */
215         xorl %eax, %eax
216         pushq_cfi $__KERNEL_DS /* ss */
217         /*CFI_REL_OFFSET        ss,0*/
218         pushq_cfi %rax /* rsp */
219         CFI_REL_OFFSET  rsp,0
220         pushq_cfi $X86_EFLAGS_IF /* eflags - interrupts on */
221         /*CFI_REL_OFFSET        rflags,0*/
222         pushq_cfi $__KERNEL_CS /* cs */
223         /*CFI_REL_OFFSET        cs,0*/
224         pushq_cfi \child_rip /* rip */
225         CFI_REL_OFFSET  rip,0
226         pushq_cfi %rax /* orig rax */
227         .endm
228
229         .macro UNFAKE_STACK_FRAME
230         addq $8*6, %rsp
231         CFI_ADJUST_CFA_OFFSET   -(6*8)
232         .endm
233
234 /*
235  * initial frame state for interrupts (and exceptions without error code)
236  */
237         .macro EMPTY_FRAME start=1 offset=0
238         .if \start
239         CFI_STARTPROC simple
240         CFI_SIGNAL_FRAME
241         CFI_DEF_CFA rsp,8+\offset
242         .else
243         CFI_DEF_CFA_OFFSET 8+\offset
244         .endif
245         .endm
246
247 /*
248  * initial frame state for interrupts (and exceptions without error code)
249  */
250         .macro INTR_FRAME start=1 offset=0
251         EMPTY_FRAME \start, SS+8+\offset-RIP
252         /*CFI_REL_OFFSET ss, SS+\offset-RIP*/
253         CFI_REL_OFFSET rsp, RSP+\offset-RIP
254         /*CFI_REL_OFFSET rflags, EFLAGS+\offset-RIP*/
255         /*CFI_REL_OFFSET cs, CS+\offset-RIP*/
256         CFI_REL_OFFSET rip, RIP+\offset-RIP
257         .endm
258
259 /*
260  * initial frame state for exceptions with error code (and interrupts
261  * with vector already pushed)
262  */
263         .macro XCPT_FRAME start=1 offset=0
264         INTR_FRAME \start, RIP+\offset-ORIG_RAX
265         /*CFI_REL_OFFSET orig_rax, ORIG_RAX-ORIG_RAX*/
266         .endm
267
268 /*
269  * frame that enables calling into C.
270  */
271         .macro PARTIAL_FRAME start=1 offset=0
272         XCPT_FRAME \start, ORIG_RAX+\offset-ARGOFFSET
273         CFI_REL_OFFSET rdi, RDI+\offset-ARGOFFSET
274         CFI_REL_OFFSET rsi, RSI+\offset-ARGOFFSET
275         CFI_REL_OFFSET rdx, RDX+\offset-ARGOFFSET
276         CFI_REL_OFFSET rcx, RCX+\offset-ARGOFFSET
277         CFI_REL_OFFSET rax, RAX+\offset-ARGOFFSET
278         CFI_REL_OFFSET r8, R8+\offset-ARGOFFSET
279         CFI_REL_OFFSET r9, R9+\offset-ARGOFFSET
280         CFI_REL_OFFSET r10, R10+\offset-ARGOFFSET
281         CFI_REL_OFFSET r11, R11+\offset-ARGOFFSET
282         .endm
283
284 /*
285  * frame that enables passing a complete pt_regs to a C function.
286  */
287         .macro DEFAULT_FRAME start=1 offset=0
288         PARTIAL_FRAME \start, R11+\offset-R15
289         CFI_REL_OFFSET rbx, RBX+\offset
290         CFI_REL_OFFSET rbp, RBP+\offset
291         CFI_REL_OFFSET r12, R12+\offset
292         CFI_REL_OFFSET r13, R13+\offset
293         CFI_REL_OFFSET r14, R14+\offset
294         CFI_REL_OFFSET r15, R15+\offset
295         .endm
296
297 /* save partial stack frame */
298 ENTRY(save_args)
299         XCPT_FRAME
300         cld
301         movq_cfi rdi, RDI+16-ARGOFFSET
302         movq_cfi rsi, RSI+16-ARGOFFSET
303         movq_cfi rdx, RDX+16-ARGOFFSET
304         movq_cfi rcx, RCX+16-ARGOFFSET
305         movq_cfi rax, RAX+16-ARGOFFSET
306         movq_cfi  r8,  R8+16-ARGOFFSET
307         movq_cfi  r9,  R9+16-ARGOFFSET
308         movq_cfi r10, R10+16-ARGOFFSET
309         movq_cfi r11, R11+16-ARGOFFSET
310
311         leaq -ARGOFFSET+16(%rsp),%rdi   /* arg1 for handler */
312         movq_cfi rbp, 8         /* push %rbp */
313         leaq 8(%rsp), %rbp              /* mov %rsp, %ebp */
314         testl $3, CS(%rdi)
315         je 1f
316         SWAPGS
317         /*
318          * irq_count is used to check if a CPU is already on an interrupt stack
319          * or not. While this is essentially redundant with preempt_count it is
320          * a little cheaper to use a separate counter in the PDA (short of
321          * moving irq_enter into assembly, which would be too much work)
322          */
323 1:      incl PER_CPU_VAR(irq_count)
324         jne 2f
325         popq_cfi %rax                   /* move return address... */
326         mov PER_CPU_VAR(irq_stack_ptr),%rsp
327         EMPTY_FRAME 0
328         pushq_cfi %rbp                  /* backlink for unwinder */
329         pushq_cfi %rax                  /* ... to the new stack */
330         /*
331          * We entered an interrupt context - irqs are off:
332          */
333 2:      TRACE_IRQS_OFF
334         ret
335         CFI_ENDPROC
336 END(save_args)
337
338 ENTRY(save_rest)
339         PARTIAL_FRAME 1 REST_SKIP+8
340         movq 5*8+16(%rsp), %r11 /* save return address */
341         movq_cfi rbx, RBX+16
342         movq_cfi rbp, RBP+16
343         movq_cfi r12, R12+16
344         movq_cfi r13, R13+16
345         movq_cfi r14, R14+16
346         movq_cfi r15, R15+16
347         movq %r11, 8(%rsp)      /* return address */
348         FIXUP_TOP_OF_STACK %r11, 16
349         ret
350         CFI_ENDPROC
351 END(save_rest)
352
353 /* save complete stack frame */
354         .pushsection .kprobes.text, "ax"
355 ENTRY(save_paranoid)
356         XCPT_FRAME 1 RDI+8
357         cld
358         movq_cfi rdi, RDI+8
359         movq_cfi rsi, RSI+8
360         movq_cfi rdx, RDX+8
361         movq_cfi rcx, RCX+8
362         movq_cfi rax, RAX+8
363         movq_cfi r8, R8+8
364         movq_cfi r9, R9+8
365         movq_cfi r10, R10+8
366         movq_cfi r11, R11+8
367         movq_cfi rbx, RBX+8
368         movq_cfi rbp, RBP+8
369         movq_cfi r12, R12+8
370         movq_cfi r13, R13+8
371         movq_cfi r14, R14+8
372         movq_cfi r15, R15+8
373         movl $1,%ebx
374         movl $MSR_GS_BASE,%ecx
375         rdmsr
376         testl %edx,%edx
377         js 1f   /* negative -> in kernel */
378         SWAPGS
379         xorl %ebx,%ebx
380 1:      ret
381         CFI_ENDPROC
382 END(save_paranoid)
383         .popsection
384
385 /*
386  * A newly forked process directly context switches into this address.
387  *
388  * rdi: prev task we switched from
389  */
390 ENTRY(ret_from_fork)
391         DEFAULT_FRAME
392
393         LOCK ; btr $TIF_FORK,TI_flags(%r8)
394
395         pushq_cfi kernel_eflags(%rip)
396         popfq_cfi                               # reset kernel eflags
397
398         call schedule_tail                      # rdi: 'prev' task parameter
399
400         GET_THREAD_INFO(%rcx)
401
402         RESTORE_REST
403
404         testl $3, CS-ARGOFFSET(%rsp)            # from kernel_thread?
405         je   int_ret_from_sys_call
406
407         testl $_TIF_IA32, TI_flags(%rcx)        # 32-bit compat task needs IRET
408         jnz  int_ret_from_sys_call
409
410         RESTORE_TOP_OF_STACK %rdi, -ARGOFFSET
411         jmp ret_from_sys_call                   # go to the SYSRET fastpath
412
413         CFI_ENDPROC
414 END(ret_from_fork)
415
416 /*
417  * System call entry. Upto 6 arguments in registers are supported.
418  *
419  * SYSCALL does not save anything on the stack and does not change the
420  * stack pointer.
421  */
422
423 /*
424  * Register setup:
425  * rax  system call number
426  * rdi  arg0
427  * rcx  return address for syscall/sysret, C arg3
428  * rsi  arg1
429  * rdx  arg2
430  * r10  arg3    (--> moved to rcx for C)
431  * r8   arg4
432  * r9   arg5
433  * r11  eflags for syscall/sysret, temporary for C
434  * r12-r15,rbp,rbx saved by C code, not touched.
435  *
436  * Interrupts are off on entry.
437  * Only called from user space.
438  *
439  * XXX  if we had a free scratch register we could save the RSP into the stack frame
440  *      and report it properly in ps. Unfortunately we haven't.
441  *
442  * When user can change the frames always force IRET. That is because
443  * it deals with uncanonical addresses better. SYSRET has trouble
444  * with them due to bugs in both AMD and Intel CPUs.
445  */
446
447 ENTRY(system_call)
448         CFI_STARTPROC   simple
449         CFI_SIGNAL_FRAME
450         CFI_DEF_CFA     rsp,KERNEL_STACK_OFFSET
451         CFI_REGISTER    rip,rcx
452         /*CFI_REGISTER  rflags,r11*/
453         SWAPGS_UNSAFE_STACK
454         /*
455          * A hypervisor implementation might want to use a label
456          * after the swapgs, so that it can do the swapgs
457          * for the guest and jump here on syscall.
458          */
459 ENTRY(system_call_after_swapgs)
460
461         movq    %rsp,PER_CPU_VAR(old_rsp)
462         movq    PER_CPU_VAR(kernel_stack),%rsp
463         /*
464          * No need to follow this irqs off/on section - it's straight
465          * and short:
466          */
467         ENABLE_INTERRUPTS(CLBR_NONE)
468         SAVE_ARGS 8,1
469         movq  %rax,ORIG_RAX-ARGOFFSET(%rsp)
470         movq  %rcx,RIP-ARGOFFSET(%rsp)
471         CFI_REL_OFFSET rip,RIP-ARGOFFSET
472         GET_THREAD_INFO(%rcx)
473         testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags(%rcx)
474         jnz tracesys
475 system_call_fastpath:
476         cmpq $__NR_syscall_max,%rax
477         ja badsys
478         movq %r10,%rcx
479         call *sys_call_table(,%rax,8)  # XXX:    rip relative
480         movq %rax,RAX-ARGOFFSET(%rsp)
481 /*
482  * Syscall return path ending with SYSRET (fast path)
483  * Has incomplete stack frame and undefined top of stack.
484  */
485 ret_from_sys_call:
486         movl $_TIF_ALLWORK_MASK,%edi
487         /* edi: flagmask */
488 sysret_check:
489         LOCKDEP_SYS_EXIT
490         GET_THREAD_INFO(%rcx)
491         DISABLE_INTERRUPTS(CLBR_NONE)
492         TRACE_IRQS_OFF
493         movl TI_flags(%rcx),%edx
494         andl %edi,%edx
495         jnz  sysret_careful
496         CFI_REMEMBER_STATE
497         /*
498          * sysretq will re-enable interrupts:
499          */
500         TRACE_IRQS_ON
501         movq RIP-ARGOFFSET(%rsp),%rcx
502         CFI_REGISTER    rip,rcx
503         RESTORE_ARGS 0,-ARG_SKIP,1
504         /*CFI_REGISTER  rflags,r11*/
505         movq    PER_CPU_VAR(old_rsp), %rsp
506         USERGS_SYSRET64
507
508         CFI_RESTORE_STATE
509         /* Handle reschedules */
510         /* edx: work, edi: workmask */
511 sysret_careful:
512         bt $TIF_NEED_RESCHED,%edx
513         jnc sysret_signal
514         TRACE_IRQS_ON
515         ENABLE_INTERRUPTS(CLBR_NONE)
516         pushq_cfi %rdi
517         call schedule
518         popq_cfi %rdi
519         jmp sysret_check
520
521         /* Handle a signal */
522 sysret_signal:
523         TRACE_IRQS_ON
524         ENABLE_INTERRUPTS(CLBR_NONE)
525 #ifdef CONFIG_AUDITSYSCALL
526         bt $TIF_SYSCALL_AUDIT,%edx
527         jc sysret_audit
528 #endif
529         /*
530          * We have a signal, or exit tracing or single-step.
531          * These all wind up with the iret return path anyway,
532          * so just join that path right now.
533          */
534         FIXUP_TOP_OF_STACK %r11, -ARGOFFSET
535         jmp int_check_syscall_exit_work
536
537 badsys:
538         movq $-ENOSYS,RAX-ARGOFFSET(%rsp)
539         jmp ret_from_sys_call
540
541 #ifdef CONFIG_AUDITSYSCALL
542         /*
543          * Fast path for syscall audit without full syscall trace.
544          * We just call audit_syscall_entry() directly, and then
545          * jump back to the normal fast path.
546          */
547 auditsys:
548         movq %r10,%r9                   /* 6th arg: 4th syscall arg */
549         movq %rdx,%r8                   /* 5th arg: 3rd syscall arg */
550         movq %rsi,%rcx                  /* 4th arg: 2nd syscall arg */
551         movq %rdi,%rdx                  /* 3rd arg: 1st syscall arg */
552         movq %rax,%rsi                  /* 2nd arg: syscall number */
553         movl $AUDIT_ARCH_X86_64,%edi    /* 1st arg: audit arch */
554         call audit_syscall_entry
555         LOAD_ARGS 0             /* reload call-clobbered registers */
556         jmp system_call_fastpath
557
558         /*
559          * Return fast path for syscall audit.  Call audit_syscall_exit()
560          * directly and then jump back to the fast path with TIF_SYSCALL_AUDIT
561          * masked off.
562          */
563 sysret_audit:
564         movq RAX-ARGOFFSET(%rsp),%rsi   /* second arg, syscall return value */
565         cmpq $0,%rsi            /* is it < 0? */
566         setl %al                /* 1 if so, 0 if not */
567         movzbl %al,%edi         /* zero-extend that into %edi */
568         inc %edi /* first arg, 0->1(AUDITSC_SUCCESS), 1->2(AUDITSC_FAILURE) */
569         call audit_syscall_exit
570         movl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT),%edi
571         jmp sysret_check
572 #endif  /* CONFIG_AUDITSYSCALL */
573
574         /* Do syscall tracing */
575 tracesys:
576 #ifdef CONFIG_AUDITSYSCALL
577         testl $(_TIF_WORK_SYSCALL_ENTRY & ~_TIF_SYSCALL_AUDIT),TI_flags(%rcx)
578         jz auditsys
579 #endif
580         SAVE_REST
581         movq $-ENOSYS,RAX(%rsp) /* ptrace can change this for a bad syscall */
582         FIXUP_TOP_OF_STACK %rdi
583         movq %rsp,%rdi
584         call syscall_trace_enter
585         /*
586          * Reload arg registers from stack in case ptrace changed them.
587          * We don't reload %rax because syscall_trace_enter() returned
588          * the value it wants us to use in the table lookup.
589          */
590         LOAD_ARGS ARGOFFSET, 1
591         RESTORE_REST
592         cmpq $__NR_syscall_max,%rax
593         ja   int_ret_from_sys_call      /* RAX(%rsp) set to -ENOSYS above */
594         movq %r10,%rcx  /* fixup for C */
595         call *sys_call_table(,%rax,8)
596         movq %rax,RAX-ARGOFFSET(%rsp)
597         /* Use IRET because user could have changed frame */
598
599 /*
600  * Syscall return path ending with IRET.
601  * Has correct top of stack, but partial stack frame.
602  */
603 GLOBAL(int_ret_from_sys_call)
604         DISABLE_INTERRUPTS(CLBR_NONE)
605         TRACE_IRQS_OFF
606         testl $3,CS-ARGOFFSET(%rsp)
607         je retint_restore_args
608         movl $_TIF_ALLWORK_MASK,%edi
609         /* edi: mask to check */
610 GLOBAL(int_with_check)
611         LOCKDEP_SYS_EXIT_IRQ
612         GET_THREAD_INFO(%rcx)
613         movl TI_flags(%rcx),%edx
614         andl %edi,%edx
615         jnz   int_careful
616         andl    $~TS_COMPAT,TI_status(%rcx)
617         jmp   retint_swapgs
618
619         /* Either reschedule or signal or syscall exit tracking needed. */
620         /* First do a reschedule test. */
621         /* edx: work, edi: workmask */
622 int_careful:
623         bt $TIF_NEED_RESCHED,%edx
624         jnc  int_very_careful
625         TRACE_IRQS_ON
626         ENABLE_INTERRUPTS(CLBR_NONE)
627         pushq_cfi %rdi
628         call schedule
629         popq_cfi %rdi
630         DISABLE_INTERRUPTS(CLBR_NONE)
631         TRACE_IRQS_OFF
632         jmp int_with_check
633
634         /* handle signals and tracing -- both require a full stack frame */
635 int_very_careful:
636         TRACE_IRQS_ON
637         ENABLE_INTERRUPTS(CLBR_NONE)
638 int_check_syscall_exit_work:
639         SAVE_REST
640         /* Check for syscall exit trace */
641         testl $_TIF_WORK_SYSCALL_EXIT,%edx
642         jz int_signal
643         pushq_cfi %rdi
644         leaq 8(%rsp),%rdi       # &ptregs -> arg1
645         call syscall_trace_leave
646         popq_cfi %rdi
647         andl $~(_TIF_WORK_SYSCALL_EXIT|_TIF_SYSCALL_EMU),%edi
648         jmp int_restore_rest
649
650 int_signal:
651         testl $_TIF_DO_NOTIFY_MASK,%edx
652         jz 1f
653         movq %rsp,%rdi          # &ptregs -> arg1
654         xorl %esi,%esi          # oldset -> arg2
655         call do_notify_resume
656 1:      movl $_TIF_WORK_MASK,%edi
657 int_restore_rest:
658         RESTORE_REST
659         DISABLE_INTERRUPTS(CLBR_NONE)
660         TRACE_IRQS_OFF
661         jmp int_with_check
662         CFI_ENDPROC
663 END(system_call)
664
665 /*
666  * Certain special system calls that need to save a complete full stack frame.
667  */
668         .macro PTREGSCALL label,func,arg
669 ENTRY(\label)
670         PARTIAL_FRAME 1 8               /* offset 8: return address */
671         subq $REST_SKIP, %rsp
672         CFI_ADJUST_CFA_OFFSET REST_SKIP
673         call save_rest
674         DEFAULT_FRAME 0 8               /* offset 8: return address */
675         leaq 8(%rsp), \arg      /* pt_regs pointer */
676         call \func
677         jmp ptregscall_common
678         CFI_ENDPROC
679 END(\label)
680         .endm
681
682         PTREGSCALL stub_clone, sys_clone, %r8
683         PTREGSCALL stub_fork, sys_fork, %rdi
684         PTREGSCALL stub_vfork, sys_vfork, %rdi
685         PTREGSCALL stub_sigaltstack, sys_sigaltstack, %rdx
686         PTREGSCALL stub_iopl, sys_iopl, %rsi
687
688 ENTRY(ptregscall_common)
689         DEFAULT_FRAME 1 8       /* offset 8: return address */
690         RESTORE_TOP_OF_STACK %r11, 8
691         movq_cfi_restore R15+8, r15
692         movq_cfi_restore R14+8, r14
693         movq_cfi_restore R13+8, r13
694         movq_cfi_restore R12+8, r12
695         movq_cfi_restore RBP+8, rbp
696         movq_cfi_restore RBX+8, rbx
697         ret $REST_SKIP          /* pop extended registers */
698         CFI_ENDPROC
699 END(ptregscall_common)
700
701 ENTRY(stub_execve)
702         CFI_STARTPROC
703         addq $8, %rsp
704         PARTIAL_FRAME 0
705         SAVE_REST
706         FIXUP_TOP_OF_STACK %r11
707         movq %rsp, %rcx
708         call sys_execve
709         RESTORE_TOP_OF_STACK %r11
710         movq %rax,RAX(%rsp)
711         RESTORE_REST
712         jmp int_ret_from_sys_call
713         CFI_ENDPROC
714 END(stub_execve)
715
716 /*
717  * sigreturn is special because it needs to restore all registers on return.
718  * This cannot be done with SYSRET, so use the IRET return path instead.
719  */
720 ENTRY(stub_rt_sigreturn)
721         CFI_STARTPROC
722         addq $8, %rsp
723         PARTIAL_FRAME 0
724         SAVE_REST
725         movq %rsp,%rdi
726         FIXUP_TOP_OF_STACK %r11
727         call sys_rt_sigreturn
728         movq %rax,RAX(%rsp) # fixme, this could be done at the higher layer
729         RESTORE_REST
730         jmp int_ret_from_sys_call
731         CFI_ENDPROC
732 END(stub_rt_sigreturn)
733
734 /*
735  * Build the entry stubs and pointer table with some assembler magic.
736  * We pack 7 stubs into a single 32-byte chunk, which will fit in a
737  * single cache line on all modern x86 implementations.
738  */
739         .section .init.rodata,"a"
740 ENTRY(interrupt)
741         .text
742         .p2align 5
743         .p2align CONFIG_X86_L1_CACHE_SHIFT
744 ENTRY(irq_entries_start)
745         INTR_FRAME
746 vector=FIRST_EXTERNAL_VECTOR
747 .rept (NR_VECTORS-FIRST_EXTERNAL_VECTOR+6)/7
748         .balign 32
749   .rept 7
750     .if vector < NR_VECTORS
751       .if vector <> FIRST_EXTERNAL_VECTOR
752         CFI_ADJUST_CFA_OFFSET -8
753       .endif
754 1:      pushq_cfi $(~vector+0x80)       /* Note: always in signed byte range */
755       .if ((vector-FIRST_EXTERNAL_VECTOR)%7) <> 6
756         jmp 2f
757       .endif
758       .previous
759         .quad 1b
760       .text
761 vector=vector+1
762     .endif
763   .endr
764 2:      jmp common_interrupt
765 .endr
766         CFI_ENDPROC
767 END(irq_entries_start)
768
769 .previous
770 END(interrupt)
771 .previous
772
773 /*
774  * Interrupt entry/exit.
775  *
776  * Interrupt entry points save only callee clobbered registers in fast path.
777  *
778  * Entry runs with interrupts off.
779  */
780
781 /* 0(%rsp): ~(interrupt number) */
782         .macro interrupt func
783         subq $ORIG_RAX-ARGOFFSET+8, %rsp
784         CFI_ADJUST_CFA_OFFSET ORIG_RAX-ARGOFFSET+8
785         call save_args
786         PARTIAL_FRAME 0
787         call \func
788         .endm
789
790 /*
791  * Interrupt entry/exit should be protected against kprobes
792  */
793         .pushsection .kprobes.text, "ax"
794         /*
795          * The interrupt stubs push (~vector+0x80) onto the stack and
796          * then jump to common_interrupt.
797          */
798         .p2align CONFIG_X86_L1_CACHE_SHIFT
799 common_interrupt:
800         XCPT_FRAME
801         addq $-0x80,(%rsp)              /* Adjust vector to [-256,-1] range */
802         interrupt do_IRQ
803         /* 0(%rsp): old_rsp-ARGOFFSET */
804 ret_from_intr:
805         DISABLE_INTERRUPTS(CLBR_NONE)
806         TRACE_IRQS_OFF
807         decl PER_CPU_VAR(irq_count)
808         leaveq
809         CFI_RESTORE             rbp
810         CFI_DEF_CFA_REGISTER    rsp
811         CFI_ADJUST_CFA_OFFSET   -8
812 exit_intr:
813         GET_THREAD_INFO(%rcx)
814         testl $3,CS-ARGOFFSET(%rsp)
815         je retint_kernel
816
817         /* Interrupt came from user space */
818         /*
819          * Has a correct top of stack, but a partial stack frame
820          * %rcx: thread info. Interrupts off.
821          */
822 retint_with_reschedule:
823         movl $_TIF_WORK_MASK,%edi
824 retint_check:
825         LOCKDEP_SYS_EXIT_IRQ
826         movl TI_flags(%rcx),%edx
827         andl %edi,%edx
828         CFI_REMEMBER_STATE
829         jnz  retint_careful
830
831 retint_swapgs:          /* return to user-space */
832         /*
833          * The iretq could re-enable interrupts:
834          */
835         DISABLE_INTERRUPTS(CLBR_ANY)
836         TRACE_IRQS_IRETQ
837         SWAPGS
838         jmp restore_args
839
840 retint_restore_args:    /* return to kernel space */
841         DISABLE_INTERRUPTS(CLBR_ANY)
842         /*
843          * The iretq could re-enable interrupts:
844          */
845         TRACE_IRQS_IRETQ
846 restore_args:
847         RESTORE_ARGS 0,8,0
848
849 irq_return:
850         INTERRUPT_RETURN
851
852         .section __ex_table, "a"
853         .quad irq_return, bad_iret
854         .previous
855
856 #ifdef CONFIG_PARAVIRT
857 ENTRY(native_iret)
858         iretq
859
860         .section __ex_table,"a"
861         .quad native_iret, bad_iret
862         .previous
863 #endif
864
865         .section .fixup,"ax"
866 bad_iret:
867         /*
868          * The iret traps when the %cs or %ss being restored is bogus.
869          * We've lost the original trap vector and error code.
870          * #GPF is the most likely one to get for an invalid selector.
871          * So pretend we completed the iret and took the #GPF in user mode.
872          *
873          * We are now running with the kernel GS after exception recovery.
874          * But error_entry expects us to have user GS to match the user %cs,
875          * so swap back.
876          */
877         pushq $0
878
879         SWAPGS
880         jmp general_protection
881
882         .previous
883
884         /* edi: workmask, edx: work */
885 retint_careful:
886         CFI_RESTORE_STATE
887         bt    $TIF_NEED_RESCHED,%edx
888         jnc   retint_signal
889         TRACE_IRQS_ON
890         ENABLE_INTERRUPTS(CLBR_NONE)
891         pushq_cfi %rdi
892         call  schedule
893         popq_cfi %rdi
894         GET_THREAD_INFO(%rcx)
895         DISABLE_INTERRUPTS(CLBR_NONE)
896         TRACE_IRQS_OFF
897         jmp retint_check
898
899 retint_signal:
900         testl $_TIF_DO_NOTIFY_MASK,%edx
901         jz    retint_swapgs
902         TRACE_IRQS_ON
903         ENABLE_INTERRUPTS(CLBR_NONE)
904         SAVE_REST
905         movq $-1,ORIG_RAX(%rsp)
906         xorl %esi,%esi          # oldset
907         movq %rsp,%rdi          # &pt_regs
908         call do_notify_resume
909         RESTORE_REST
910         DISABLE_INTERRUPTS(CLBR_NONE)
911         TRACE_IRQS_OFF
912         GET_THREAD_INFO(%rcx)
913         jmp retint_with_reschedule
914
915 #ifdef CONFIG_PREEMPT
916         /* Returning to kernel space. Check if we need preemption */
917         /* rcx:  threadinfo. interrupts off. */
918 ENTRY(retint_kernel)
919         cmpl $0,TI_preempt_count(%rcx)
920         jnz  retint_restore_args
921         bt  $TIF_NEED_RESCHED,TI_flags(%rcx)
922         jnc  retint_restore_args
923         bt   $9,EFLAGS-ARGOFFSET(%rsp)  /* interrupts off? */
924         jnc  retint_restore_args
925         call preempt_schedule_irq
926         jmp exit_intr
927 #endif
928
929         CFI_ENDPROC
930 END(common_interrupt)
931 /*
932  * End of kprobes section
933  */
934        .popsection
935
936 /*
937  * APIC interrupts.
938  */
939 .macro apicinterrupt num sym do_sym
940 ENTRY(\sym)
941         INTR_FRAME
942         pushq_cfi $~(\num)
943         interrupt \do_sym
944         jmp ret_from_intr
945         CFI_ENDPROC
946 END(\sym)
947 .endm
948
949 #ifdef CONFIG_SMP
950 apicinterrupt IRQ_MOVE_CLEANUP_VECTOR \
951         irq_move_cleanup_interrupt smp_irq_move_cleanup_interrupt
952 apicinterrupt REBOOT_VECTOR \
953         reboot_interrupt smp_reboot_interrupt
954 #endif
955
956 #ifdef CONFIG_X86_UV
957 apicinterrupt UV_BAU_MESSAGE \
958         uv_bau_message_intr1 uv_bau_message_interrupt
959 #endif
960 apicinterrupt LOCAL_TIMER_VECTOR \
961         apic_timer_interrupt smp_apic_timer_interrupt
962 apicinterrupt X86_PLATFORM_IPI_VECTOR \
963         x86_platform_ipi smp_x86_platform_ipi
964
965 #ifdef CONFIG_SMP
966 .irpc idx, "01234567"
967 apicinterrupt (INVALIDATE_TLB_VECTOR_START)+\idx \
968         invalidate_interrupt\idx smp_invalidate_interrupt
969 .endr
970 #endif
971
972 apicinterrupt THRESHOLD_APIC_VECTOR \
973         threshold_interrupt smp_threshold_interrupt
974 apicinterrupt THERMAL_APIC_VECTOR \
975         thermal_interrupt smp_thermal_interrupt
976
977 #ifdef CONFIG_X86_MCE
978 apicinterrupt MCE_SELF_VECTOR \
979         mce_self_interrupt smp_mce_self_interrupt
980 #endif
981
982 #ifdef CONFIG_SMP
983 apicinterrupt CALL_FUNCTION_SINGLE_VECTOR \
984         call_function_single_interrupt smp_call_function_single_interrupt
985 apicinterrupt CALL_FUNCTION_VECTOR \
986         call_function_interrupt smp_call_function_interrupt
987 apicinterrupt RESCHEDULE_VECTOR \
988         reschedule_interrupt smp_reschedule_interrupt
989 #endif
990
991 apicinterrupt ERROR_APIC_VECTOR \
992         error_interrupt smp_error_interrupt
993 apicinterrupt SPURIOUS_APIC_VECTOR \
994         spurious_interrupt smp_spurious_interrupt
995
996 #ifdef CONFIG_PERF_EVENTS
997 apicinterrupt LOCAL_PENDING_VECTOR \
998         perf_pending_interrupt smp_perf_pending_interrupt
999 #endif
1000
1001 /*
1002  * Exception entry points.
1003  */
1004 .macro zeroentry sym do_sym
1005 ENTRY(\sym)
1006         INTR_FRAME
1007         PARAVIRT_ADJUST_EXCEPTION_FRAME
1008         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1009         subq $ORIG_RAX-R15, %rsp
1010         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1011         call error_entry
1012         DEFAULT_FRAME 0
1013         movq %rsp,%rdi          /* pt_regs pointer */
1014         xorl %esi,%esi          /* no error code */
1015         call \do_sym
1016         jmp error_exit          /* %ebx: no swapgs flag */
1017         CFI_ENDPROC
1018 END(\sym)
1019 .endm
1020
1021 .macro paranoidzeroentry sym do_sym
1022 ENTRY(\sym)
1023         INTR_FRAME
1024         PARAVIRT_ADJUST_EXCEPTION_FRAME
1025         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1026         subq $ORIG_RAX-R15, %rsp
1027         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1028         call save_paranoid
1029         TRACE_IRQS_OFF
1030         movq %rsp,%rdi          /* pt_regs pointer */
1031         xorl %esi,%esi          /* no error code */
1032         call \do_sym
1033         jmp paranoid_exit       /* %ebx: no swapgs flag */
1034         CFI_ENDPROC
1035 END(\sym)
1036 .endm
1037
1038 #define INIT_TSS_IST(x) PER_CPU_VAR(init_tss) + (TSS_ist + ((x) - 1) * 8)
1039 .macro paranoidzeroentry_ist sym do_sym ist
1040 ENTRY(\sym)
1041         INTR_FRAME
1042         PARAVIRT_ADJUST_EXCEPTION_FRAME
1043         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1044         subq $ORIG_RAX-R15, %rsp
1045         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1046         call save_paranoid
1047         TRACE_IRQS_OFF
1048         movq %rsp,%rdi          /* pt_regs pointer */
1049         xorl %esi,%esi          /* no error code */
1050         subq $EXCEPTION_STKSZ, INIT_TSS_IST(\ist)
1051         call \do_sym
1052         addq $EXCEPTION_STKSZ, INIT_TSS_IST(\ist)
1053         jmp paranoid_exit       /* %ebx: no swapgs flag */
1054         CFI_ENDPROC
1055 END(\sym)
1056 .endm
1057
1058 .macro errorentry sym do_sym
1059 ENTRY(\sym)
1060         XCPT_FRAME
1061         PARAVIRT_ADJUST_EXCEPTION_FRAME
1062         subq $ORIG_RAX-R15, %rsp
1063         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1064         call error_entry
1065         DEFAULT_FRAME 0
1066         movq %rsp,%rdi                  /* pt_regs pointer */
1067         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1068         movq $-1,ORIG_RAX(%rsp)         /* no syscall to restart */
1069         call \do_sym
1070         jmp error_exit                  /* %ebx: no swapgs flag */
1071         CFI_ENDPROC
1072 END(\sym)
1073 .endm
1074
1075         /* error code is on the stack already */
1076 .macro paranoiderrorentry sym do_sym
1077 ENTRY(\sym)
1078         XCPT_FRAME
1079         PARAVIRT_ADJUST_EXCEPTION_FRAME
1080         subq $ORIG_RAX-R15, %rsp
1081         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1082         call save_paranoid
1083         DEFAULT_FRAME 0
1084         TRACE_IRQS_OFF
1085         movq %rsp,%rdi                  /* pt_regs pointer */
1086         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1087         movq $-1,ORIG_RAX(%rsp)         /* no syscall to restart */
1088         call \do_sym
1089         jmp paranoid_exit               /* %ebx: no swapgs flag */
1090         CFI_ENDPROC
1091 END(\sym)
1092 .endm
1093
1094 zeroentry divide_error do_divide_error
1095 zeroentry overflow do_overflow
1096 zeroentry bounds do_bounds
1097 zeroentry invalid_op do_invalid_op
1098 zeroentry device_not_available do_device_not_available
1099 paranoiderrorentry double_fault do_double_fault
1100 zeroentry coprocessor_segment_overrun do_coprocessor_segment_overrun
1101 errorentry invalid_TSS do_invalid_TSS
1102 errorentry segment_not_present do_segment_not_present
1103 zeroentry spurious_interrupt_bug do_spurious_interrupt_bug
1104 zeroentry coprocessor_error do_coprocessor_error
1105 errorentry alignment_check do_alignment_check
1106 zeroentry simd_coprocessor_error do_simd_coprocessor_error
1107
1108         /* Reload gs selector with exception handling */
1109         /* edi:  new selector */
1110 ENTRY(native_load_gs_index)
1111         CFI_STARTPROC
1112         pushfq_cfi
1113         DISABLE_INTERRUPTS(CLBR_ANY & ~CLBR_RDI)
1114         SWAPGS
1115 gs_change:
1116         movl %edi,%gs
1117 2:      mfence          /* workaround */
1118         SWAPGS
1119         popfq_cfi
1120         ret
1121         CFI_ENDPROC
1122 END(native_load_gs_index)
1123
1124         .section __ex_table,"a"
1125         .align 8
1126         .quad gs_change,bad_gs
1127         .previous
1128         .section .fixup,"ax"
1129         /* running with kernelgs */
1130 bad_gs:
1131         SWAPGS                  /* switch back to user gs */
1132         xorl %eax,%eax
1133         movl %eax,%gs
1134         jmp  2b
1135         .previous
1136
1137 ENTRY(kernel_thread_helper)
1138         pushq $0                # fake return address
1139         CFI_STARTPROC
1140         /*
1141          * Here we are in the child and the registers are set as they were
1142          * at kernel_thread() invocation in the parent.
1143          */
1144         call *%rsi
1145         # exit
1146         mov %eax, %edi
1147         call do_exit
1148         ud2                     # padding for call trace
1149         CFI_ENDPROC
1150 END(kernel_thread_helper)
1151
1152 /*
1153  * execve(). This function needs to use IRET, not SYSRET, to set up all state properly.
1154  *
1155  * C extern interface:
1156  *       extern long execve(const char *name, char **argv, char **envp)
1157  *
1158  * asm input arguments:
1159  *      rdi: name, rsi: argv, rdx: envp
1160  *
1161  * We want to fallback into:
1162  *      extern long sys_execve(const char *name, char **argv,char **envp, struct pt_regs *regs)
1163  *
1164  * do_sys_execve asm fallback arguments:
1165  *      rdi: name, rsi: argv, rdx: envp, rcx: fake frame on the stack
1166  */
1167 ENTRY(kernel_execve)
1168         CFI_STARTPROC
1169         FAKE_STACK_FRAME $0
1170         SAVE_ALL
1171         movq %rsp,%rcx
1172         call sys_execve
1173         movq %rax, RAX(%rsp)
1174         RESTORE_REST
1175         testq %rax,%rax
1176         je int_ret_from_sys_call
1177         RESTORE_ARGS
1178         UNFAKE_STACK_FRAME
1179         ret
1180         CFI_ENDPROC
1181 END(kernel_execve)
1182
1183 /* Call softirq on interrupt stack. Interrupts are off. */
1184 ENTRY(call_softirq)
1185         CFI_STARTPROC
1186         pushq_cfi %rbp
1187         CFI_REL_OFFSET rbp,0
1188         mov  %rsp,%rbp
1189         CFI_DEF_CFA_REGISTER rbp
1190         incl PER_CPU_VAR(irq_count)
1191         cmove PER_CPU_VAR(irq_stack_ptr),%rsp
1192         push  %rbp                      # backlink for old unwinder
1193         call __do_softirq
1194         leaveq
1195         CFI_RESTORE             rbp
1196         CFI_DEF_CFA_REGISTER    rsp
1197         CFI_ADJUST_CFA_OFFSET   -8
1198         decl PER_CPU_VAR(irq_count)
1199         ret
1200         CFI_ENDPROC
1201 END(call_softirq)
1202
1203 #ifdef CONFIG_XEN
1204 zeroentry xen_hypervisor_callback xen_do_hypervisor_callback
1205
1206 /*
1207  * A note on the "critical region" in our callback handler.
1208  * We want to avoid stacking callback handlers due to events occurring
1209  * during handling of the last event. To do this, we keep events disabled
1210  * until we've done all processing. HOWEVER, we must enable events before
1211  * popping the stack frame (can't be done atomically) and so it would still
1212  * be possible to get enough handler activations to overflow the stack.
1213  * Although unlikely, bugs of that kind are hard to track down, so we'd
1214  * like to avoid the possibility.
1215  * So, on entry to the handler we detect whether we interrupted an
1216  * existing activation in its critical region -- if so, we pop the current
1217  * activation and restart the handler using the previous one.
1218  */
1219 ENTRY(xen_do_hypervisor_callback)   # do_hypervisor_callback(struct *pt_regs)
1220         CFI_STARTPROC
1221 /*
1222  * Since we don't modify %rdi, evtchn_do_upall(struct *pt_regs) will
1223  * see the correct pointer to the pt_regs
1224  */
1225         movq %rdi, %rsp            # we don't return, adjust the stack frame
1226         CFI_ENDPROC
1227         DEFAULT_FRAME
1228 11:     incl PER_CPU_VAR(irq_count)
1229         movq %rsp,%rbp
1230         CFI_DEF_CFA_REGISTER rbp
1231         cmovzq PER_CPU_VAR(irq_stack_ptr),%rsp
1232         pushq %rbp                      # backlink for old unwinder
1233         call xen_evtchn_do_upcall
1234         popq %rsp
1235         CFI_DEF_CFA_REGISTER rsp
1236         decl PER_CPU_VAR(irq_count)
1237         jmp  error_exit
1238         CFI_ENDPROC
1239 END(do_hypervisor_callback)
1240
1241 /*
1242  * Hypervisor uses this for application faults while it executes.
1243  * We get here for two reasons:
1244  *  1. Fault while reloading DS, ES, FS or GS
1245  *  2. Fault while executing IRET
1246  * Category 1 we do not need to fix up as Xen has already reloaded all segment
1247  * registers that could be reloaded and zeroed the others.
1248  * Category 2 we fix up by killing the current process. We cannot use the
1249  * normal Linux return path in this case because if we use the IRET hypercall
1250  * to pop the stack frame we end up in an infinite loop of failsafe callbacks.
1251  * We distinguish between categories by comparing each saved segment register
1252  * with its current contents: any discrepancy means we in category 1.
1253  */
1254 ENTRY(xen_failsafe_callback)
1255         INTR_FRAME 1 (6*8)
1256         /*CFI_REL_OFFSET gs,GS*/
1257         /*CFI_REL_OFFSET fs,FS*/
1258         /*CFI_REL_OFFSET es,ES*/
1259         /*CFI_REL_OFFSET ds,DS*/
1260         CFI_REL_OFFSET r11,8
1261         CFI_REL_OFFSET rcx,0
1262         movw %ds,%cx
1263         cmpw %cx,0x10(%rsp)
1264         CFI_REMEMBER_STATE
1265         jne 1f
1266         movw %es,%cx
1267         cmpw %cx,0x18(%rsp)
1268         jne 1f
1269         movw %fs,%cx
1270         cmpw %cx,0x20(%rsp)
1271         jne 1f
1272         movw %gs,%cx
1273         cmpw %cx,0x28(%rsp)
1274         jne 1f
1275         /* All segments match their saved values => Category 2 (Bad IRET). */
1276         movq (%rsp),%rcx
1277         CFI_RESTORE rcx
1278         movq 8(%rsp),%r11
1279         CFI_RESTORE r11
1280         addq $0x30,%rsp
1281         CFI_ADJUST_CFA_OFFSET -0x30
1282         pushq_cfi $0    /* RIP */
1283         pushq_cfi %r11
1284         pushq_cfi %rcx
1285         jmp general_protection
1286         CFI_RESTORE_STATE
1287 1:      /* Segment mismatch => Category 1 (Bad segment). Retry the IRET. */
1288         movq (%rsp),%rcx
1289         CFI_RESTORE rcx
1290         movq 8(%rsp),%r11
1291         CFI_RESTORE r11
1292         addq $0x30,%rsp
1293         CFI_ADJUST_CFA_OFFSET -0x30
1294         pushq_cfi $0
1295         SAVE_ALL
1296         jmp error_exit
1297         CFI_ENDPROC
1298 END(xen_failsafe_callback)
1299
1300 apicinterrupt XEN_HVM_EVTCHN_CALLBACK \
1301         xen_hvm_callback_vector xen_evtchn_do_upcall
1302
1303 #endif /* CONFIG_XEN */
1304
1305 /*
1306  * Some functions should be protected against kprobes
1307  */
1308         .pushsection .kprobes.text, "ax"
1309
1310 paranoidzeroentry_ist debug do_debug DEBUG_STACK
1311 paranoidzeroentry_ist int3 do_int3 DEBUG_STACK
1312 paranoiderrorentry stack_segment do_stack_segment
1313 #ifdef CONFIG_XEN
1314 zeroentry xen_debug do_debug
1315 zeroentry xen_int3 do_int3
1316 errorentry xen_stack_segment do_stack_segment
1317 #endif
1318 errorentry general_protection do_general_protection
1319 errorentry page_fault do_page_fault
1320 #ifdef CONFIG_X86_MCE
1321 paranoidzeroentry machine_check *machine_check_vector(%rip)
1322 #endif
1323
1324         /*
1325          * "Paranoid" exit path from exception stack.
1326          * Paranoid because this is used by NMIs and cannot take
1327          * any kernel state for granted.
1328          * We don't do kernel preemption checks here, because only
1329          * NMI should be common and it does not enable IRQs and
1330          * cannot get reschedule ticks.
1331          *
1332          * "trace" is 0 for the NMI handler only, because irq-tracing
1333          * is fundamentally NMI-unsafe. (we cannot change the soft and
1334          * hard flags at once, atomically)
1335          */
1336
1337         /* ebx: no swapgs flag */
1338 ENTRY(paranoid_exit)
1339         DEFAULT_FRAME
1340         DISABLE_INTERRUPTS(CLBR_NONE)
1341         TRACE_IRQS_OFF
1342         testl %ebx,%ebx                         /* swapgs needed? */
1343         jnz paranoid_restore
1344         testl $3,CS(%rsp)
1345         jnz   paranoid_userspace
1346 paranoid_swapgs:
1347         TRACE_IRQS_IRETQ 0
1348         SWAPGS_UNSAFE_STACK
1349         RESTORE_ALL 8
1350         jmp irq_return
1351 paranoid_restore:
1352         TRACE_IRQS_IRETQ 0
1353         RESTORE_ALL 8
1354         jmp irq_return
1355 paranoid_userspace:
1356         GET_THREAD_INFO(%rcx)
1357         movl TI_flags(%rcx),%ebx
1358         andl $_TIF_WORK_MASK,%ebx
1359         jz paranoid_swapgs
1360         movq %rsp,%rdi                  /* &pt_regs */
1361         call sync_regs
1362         movq %rax,%rsp                  /* switch stack for scheduling */
1363         testl $_TIF_NEED_RESCHED,%ebx
1364         jnz paranoid_schedule
1365         movl %ebx,%edx                  /* arg3: thread flags */
1366         TRACE_IRQS_ON
1367         ENABLE_INTERRUPTS(CLBR_NONE)
1368         xorl %esi,%esi                  /* arg2: oldset */
1369         movq %rsp,%rdi                  /* arg1: &pt_regs */
1370         call do_notify_resume
1371         DISABLE_INTERRUPTS(CLBR_NONE)
1372         TRACE_IRQS_OFF
1373         jmp paranoid_userspace
1374 paranoid_schedule:
1375         TRACE_IRQS_ON
1376         ENABLE_INTERRUPTS(CLBR_ANY)
1377         call schedule
1378         DISABLE_INTERRUPTS(CLBR_ANY)
1379         TRACE_IRQS_OFF
1380         jmp paranoid_userspace
1381         CFI_ENDPROC
1382 END(paranoid_exit)
1383
1384 /*
1385  * Exception entry point. This expects an error code/orig_rax on the stack.
1386  * returns in "no swapgs flag" in %ebx.
1387  */
1388 ENTRY(error_entry)
1389         XCPT_FRAME
1390         CFI_ADJUST_CFA_OFFSET 15*8
1391         /* oldrax contains error code */
1392         cld
1393         movq_cfi rdi, RDI+8
1394         movq_cfi rsi, RSI+8
1395         movq_cfi rdx, RDX+8
1396         movq_cfi rcx, RCX+8
1397         movq_cfi rax, RAX+8
1398         movq_cfi  r8,  R8+8
1399         movq_cfi  r9,  R9+8
1400         movq_cfi r10, R10+8
1401         movq_cfi r11, R11+8
1402         movq_cfi rbx, RBX+8
1403         movq_cfi rbp, RBP+8
1404         movq_cfi r12, R12+8
1405         movq_cfi r13, R13+8
1406         movq_cfi r14, R14+8
1407         movq_cfi r15, R15+8
1408         xorl %ebx,%ebx
1409         testl $3,CS+8(%rsp)
1410         je error_kernelspace
1411 error_swapgs:
1412         SWAPGS
1413 error_sti:
1414         TRACE_IRQS_OFF
1415         ret
1416
1417 /*
1418  * There are two places in the kernel that can potentially fault with
1419  * usergs. Handle them here. The exception handlers after iret run with
1420  * kernel gs again, so don't set the user space flag. B stepping K8s
1421  * sometimes report an truncated RIP for IRET exceptions returning to
1422  * compat mode. Check for these here too.
1423  */
1424 error_kernelspace:
1425         incl %ebx
1426         leaq irq_return(%rip),%rcx
1427         cmpq %rcx,RIP+8(%rsp)
1428         je error_swapgs
1429         movl %ecx,%eax  /* zero extend */
1430         cmpq %rax,RIP+8(%rsp)
1431         je bstep_iret
1432         cmpq $gs_change,RIP+8(%rsp)
1433         je error_swapgs
1434         jmp error_sti
1435
1436 bstep_iret:
1437         /* Fix truncated RIP */
1438         movq %rcx,RIP+8(%rsp)
1439         jmp error_swapgs
1440         CFI_ENDPROC
1441 END(error_entry)
1442
1443
1444 /* ebx: no swapgs flag (1: don't need swapgs, 0: need it) */
1445 ENTRY(error_exit)
1446         DEFAULT_FRAME
1447         movl %ebx,%eax
1448         RESTORE_REST
1449         DISABLE_INTERRUPTS(CLBR_NONE)
1450         TRACE_IRQS_OFF
1451         GET_THREAD_INFO(%rcx)
1452         testl %eax,%eax
1453         jne retint_kernel
1454         LOCKDEP_SYS_EXIT_IRQ
1455         movl TI_flags(%rcx),%edx
1456         movl $_TIF_WORK_MASK,%edi
1457         andl %edi,%edx
1458         jnz retint_careful
1459         jmp retint_swapgs
1460         CFI_ENDPROC
1461 END(error_exit)
1462
1463
1464         /* runs on exception stack */
1465 ENTRY(nmi)
1466         INTR_FRAME
1467         PARAVIRT_ADJUST_EXCEPTION_FRAME
1468         pushq_cfi $-1
1469         subq $ORIG_RAX-R15, %rsp
1470         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1471         call save_paranoid
1472         DEFAULT_FRAME 0
1473         /* paranoidentry do_nmi, 0; without TRACE_IRQS_OFF */
1474         movq %rsp,%rdi
1475         movq $-1,%rsi
1476         call do_nmi
1477 #ifdef CONFIG_TRACE_IRQFLAGS
1478         /* paranoidexit; without TRACE_IRQS_OFF */
1479         /* ebx: no swapgs flag */
1480         DISABLE_INTERRUPTS(CLBR_NONE)
1481         testl %ebx,%ebx                         /* swapgs needed? */
1482         jnz nmi_restore
1483         testl $3,CS(%rsp)
1484         jnz nmi_userspace
1485 nmi_swapgs:
1486         SWAPGS_UNSAFE_STACK
1487 nmi_restore:
1488         RESTORE_ALL 8
1489         jmp irq_return
1490 nmi_userspace:
1491         GET_THREAD_INFO(%rcx)
1492         movl TI_flags(%rcx),%ebx
1493         andl $_TIF_WORK_MASK,%ebx
1494         jz nmi_swapgs
1495         movq %rsp,%rdi                  /* &pt_regs */
1496         call sync_regs
1497         movq %rax,%rsp                  /* switch stack for scheduling */
1498         testl $_TIF_NEED_RESCHED,%ebx
1499         jnz nmi_schedule
1500         movl %ebx,%edx                  /* arg3: thread flags */
1501         ENABLE_INTERRUPTS(CLBR_NONE)
1502         xorl %esi,%esi                  /* arg2: oldset */
1503         movq %rsp,%rdi                  /* arg1: &pt_regs */
1504         call do_notify_resume
1505         DISABLE_INTERRUPTS(CLBR_NONE)
1506         jmp nmi_userspace
1507 nmi_schedule:
1508         ENABLE_INTERRUPTS(CLBR_ANY)
1509         call schedule
1510         DISABLE_INTERRUPTS(CLBR_ANY)
1511         jmp nmi_userspace
1512         CFI_ENDPROC
1513 #else
1514         jmp paranoid_exit
1515         CFI_ENDPROC
1516 #endif
1517 END(nmi)
1518
1519 ENTRY(ignore_sysret)
1520         CFI_STARTPROC
1521         mov $-ENOSYS,%eax
1522         sysret
1523         CFI_ENDPROC
1524 END(ignore_sysret)
1525
1526 /*
1527  * End of kprobes section
1528  */
1529         .popsection