[SPARC64]: Add CONFIG_DEBUG_PAGEALLOC support.
[linux-2.6.git] / arch / sparc64 / kernel / vmlinux.lds.S
1 /* ld script to make UltraLinux kernel */
2
3 #include <asm-generic/vmlinux.lds.h>
4
5 OUTPUT_FORMAT("elf64-sparc", "elf64-sparc", "elf64-sparc")
6 OUTPUT_ARCH(sparc:v9a)
7 ENTRY(_start)
8
9 jiffies = jiffies_64;
10 SECTIONS
11 {
12   swapper_low_pmd_dir = 0x0000000000402000;
13   . = 0x4000;
14   .text 0x0000000000404000 :
15   {
16     *(.text)
17     SCHED_TEXT
18     LOCK_TEXT
19     KPROBES_TEXT
20     *(.gnu.warning)
21   } =0
22   _etext = .;
23   PROVIDE (etext = .);
24
25   RODATA
26
27   .data    :
28   {
29     *(.data)
30     CONSTRUCTORS
31   }
32   .data1   : { *(.data1) }
33   . = ALIGN(64);
34   .data.cacheline_aligned : { *(.data.cacheline_aligned) }
35   . = ALIGN(64);
36   .data.read_mostly : { *(.data.read_mostly) }
37   _edata  =  .;
38   PROVIDE (edata = .);
39   .fixup   : { *(.fixup) }
40
41   . = ALIGN(16);
42   __start___ex_table = .;
43   __ex_table : { *(__ex_table) }
44   __stop___ex_table = .;
45
46   . = ALIGN(8192);
47   __init_begin = .;
48   .init.text : { 
49         _sinittext = .;
50         *(.init.text)
51         _einittext = .;
52   }
53   .init.data : { *(.init.data) }
54   . = ALIGN(16);
55   __setup_start = .;
56   .init.setup : { *(.init.setup) }
57   __setup_end = .;
58   __initcall_start = .;
59   .initcall.init : {
60         *(.initcall1.init) 
61         *(.initcall2.init) 
62         *(.initcall3.init) 
63         *(.initcall4.init) 
64         *(.initcall5.init) 
65         *(.initcall6.init) 
66         *(.initcall7.init)
67   }
68   __initcall_end = .;
69   __con_initcall_start = .;
70   .con_initcall.init : { *(.con_initcall.init) }
71   __con_initcall_end = .;
72   SECURITY_INIT
73   . = ALIGN(8192); 
74   __initramfs_start = .;
75   .init.ramfs : { *(.init.ramfs) }
76   __initramfs_end = .;
77   . = ALIGN(8192);
78   __per_cpu_start = .;
79   .data.percpu  : { *(.data.percpu) }
80   __per_cpu_end = .;
81   . = ALIGN(8192);
82   __init_end = .;
83   __bss_start = .;
84   .sbss      : { *(.sbss) *(.scommon) }
85   .bss       :
86   {
87    *(.dynbss)
88    *(.bss)
89    *(COMMON)
90   }
91   _end = . ;
92   PROVIDE (end = .);
93   /* Stabs debugging sections.  */
94   .stab 0 : { *(.stab) }
95   .stabstr 0 : { *(.stabstr) }
96   .stab.excl 0 : { *(.stab.excl) }
97   .stab.exclstr 0 : { *(.stab.exclstr) }
98   .stab.index 0 : { *(.stab.index) }
99   .stab.indexstr 0 : { *(.stab.indexstr) }
100   .comment 0 : { *(.comment) }
101   .debug          0 : { *(.debug) }
102   .debug_srcinfo  0 : { *(.debug_srcinfo) }
103   .debug_aranges  0 : { *(.debug_aranges) }
104   .debug_pubnames 0 : { *(.debug_pubnames) }
105   .debug_sfnames  0 : { *(.debug_sfnames) }
106   .line           0 : { *(.line) }
107   /DISCARD/ : { *(.exit.text) *(.exit.data) *(.exitcall.exit) }
108 }