sh: Add support for 4K stacks.
[linux-2.6.git] / arch / sh / kernel / head.S
1 /* $Id: head.S,v 1.7 2003/09/01 17:58:19 lethal Exp $
2  *
3  *  arch/sh/kernel/head.S
4  *
5  *  Copyright (C) 1999, 2000  Niibe Yutaka & Kaz Kojima
6  *
7  * This file is subject to the terms and conditions of the GNU General Public
8  * License.  See the file "COPYING" in the main directory of this archive
9  * for more details.
10  *
11  * Head.S contains the SH exception handlers and startup code.
12  */
13 #include <linux/linkage.h>
14 #include <asm/thread_info.h>
15
16 #ifdef CONFIG_CPU_SH4A
17 #define SYNCO()         synco
18
19 #define PREFI(label, reg)       \
20         mov.l   label, reg;     \
21         prefi   @reg
22 #else
23 #define SYNCO()
24 #define PREFI(label, reg)
25 #endif
26
27         .section        .empty_zero_page, "aw"
28 ENTRY(empty_zero_page)
29         .long   1               /* MOUNT_ROOT_RDONLY */
30         .long   0               /* RAMDISK_FLAGS */
31         .long   0x0200          /* ORIG_ROOT_DEV */
32         .long   1               /* LOADER_TYPE */
33         .long   0x00360000      /* INITRD_START */
34         .long   0x000a0000      /* INITRD_SIZE */
35         .long   0
36         .balign 4096,0,4096
37
38         .text   
39 /*
40  * Condition at the entry of _stext:
41  *
42  *   BSC has already been initialized.
43  *   INTC may or may not be initialized.
44  *   VBR may or may not be initialized.
45  *   MMU may or may not be initialized.
46  *   Cache may or may not be initialized.
47  *   Hardware (including on-chip modules) may or may not be initialized. 
48  *
49  */
50 ENTRY(_stext)
51         !                       Initialize Status Register
52         mov.l   1f, r0          ! MD=1, RB=0, BL=0, IMASK=0xF
53         ldc     r0, sr
54         !                       Initialize global interrupt mask
55         mov     #0, r0
56         ldc     r0, r6_bank
57
58         /*
59          * Prefetch if possible to reduce cache miss penalty.
60          *
61          * We do this early on for SH-4A as a micro-optimization,
62          * as later on we will have speculative execution enabled
63          * and this will become less of an issue.
64          */
65         PREFI(5f, r0)
66         PREFI(6f, r0)
67
68         !
69         mov.l   2f, r0
70         mov     r0, r15         ! Set initial r15 (stack pointer)
71         mov     #(THREAD_SIZE >> 8), r1
72         shll8   r1              ! r1 = THREAD_SIZE
73         sub     r1, r0          !
74         ldc     r0, r7_bank     ! ... and initial thread_info
75
76         !                       Clear BSS area
77         mov.l   3f, r1
78         add     #4, r1
79         mov.l   4f, r2
80         mov     #0, r0
81 9:      cmp/hs  r2, r1
82         bf/s    9b              ! while (r1 < r2)
83          mov.l  r0,@-r2
84
85         !                       Additional CPU initialization
86         mov.l   6f, r0
87         jsr     @r0
88          nop
89
90         SYNCO()                 ! Wait for pending instructions..
91
92         !                       Start kernel
93         mov.l   5f, r0
94         jmp     @r0
95          nop
96
97         .balign 4
98 1:      .long   0x400080F0              ! MD=1, RB=0, BL=0, FD=1, IMASK=0xF
99 2:      .long   init_thread_union+THREAD_SIZE
100 3:      .long   __bss_start
101 4:      .long   _end
102 5:      .long   start_kernel
103 6:      .long   sh_cpu_init