arch/s390/kernel/entry64.S

   1 /*
   2  *  arch/s390/kernel/entry64.S
   3  *    S390 low-level entry points.
   4  *
   5  *    Copyright (C) IBM Corp. 1999,2006
   6  *    Author(s): Martin Schwidefsky (schwidefsky@de.ibm.com),
   7  *               Hartmut Penner (hp@de.ibm.com),
   8  *               Denis Joseph Barrow (djbarrow@de.ibm.com,barrow_dj@yahoo.com),
   9  *               Heiko Carstens <heiko.carstens@de.ibm.com>
  10  */
  11
  12 #include <linux/linkage.h>
  13 #include <linux/init.h>
  14 #include <asm/cache.h>
  15 #include <asm/errno.h>
  16 #include <asm/ptrace.h>
  17 #include <asm/thread_info.h>
  18 #include <asm/asm-offsets.h>
  19 #include <asm/unistd.h>
  20 #include <asm/page.h>
  21
  22 /*
  23  * Stack layout for the system_call stack entry.
  24  * The first few entries are identical to the user_regs_struct.
  25  */
  26 SP_PTREGS    =  STACK_FRAME_OVERHEAD
  27 SP_ARGS      =  STACK_FRAME_OVERHEAD + __PT_ARGS
  28 SP_PSW       =  STACK_FRAME_OVERHEAD + __PT_PSW
  29 SP_R0        =  STACK_FRAME_OVERHEAD + __PT_GPRS
  30 SP_R1        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 8
  31 SP_R2        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 16
  32 SP_R3        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 24
  33 SP_R4        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 32
  34 SP_R5        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 40
  35 SP_R6        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 48
  36 SP_R7        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 56
  37 SP_R8        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 64
  38 SP_R9        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 72
  39 SP_R10       =  STACK_FRAME_OVERHEAD + __PT_GPRS + 80
  40 SP_R11       =  STACK_FRAME_OVERHEAD + __PT_GPRS + 88
  41 SP_R12       =  STACK_FRAME_OVERHEAD + __PT_GPRS + 96
  42 SP_R13       =  STACK_FRAME_OVERHEAD + __PT_GPRS + 104
  43 SP_R14       =  STACK_FRAME_OVERHEAD + __PT_GPRS + 112
  44 SP_R15       =  STACK_FRAME_OVERHEAD + __PT_GPRS + 120
  45 SP_ORIG_R2   =  STACK_FRAME_OVERHEAD + __PT_ORIG_GPR2
  46 SP_ILC       =  STACK_FRAME_OVERHEAD + __PT_ILC
  47 SP_SVCNR      = STACK_FRAME_OVERHEAD + __PT_SVCNR
  48 SP_SIZE      =  STACK_FRAME_OVERHEAD + __PT_SIZE
  49
  50 STACK_SHIFT = PAGE_SHIFT + THREAD_ORDER
  51 STACK_SIZE  = 1 << STACK_SHIFT
  52
  53 _TIF_WORK_SVC = (_TIF_SIGPENDING | _TIF_NOTIFY_RESUME | _TIF_NEED_RESCHED | \
  54                  _TIF_MCCK_PENDING | _TIF_RESTART_SVC | _TIF_SINGLE_STEP )
  55 _TIF_WORK_INT = (_TIF_SIGPENDING | _TIF_NOTIFY_RESUME | _TIF_NEED_RESCHED | \
  56                  _TIF_MCCK_PENDING)
  57 _TIF_SYSCALL = (_TIF_SYSCALL_TRACE>>8 | _TIF_SYSCALL_AUDIT>>8 | \
  58                 _TIF_SECCOMP>>8 | _TIF_SYSCALL_TRACEPOINT>>8)
  59
  60 #define BASED(name) name-system_call(%r13)
  61
  62 #ifdef CONFIG_TRACE_IRQFLAGS
  63         .macro  TRACE_IRQS_ON
  64          basr   %r2,%r0
  65          brasl  %r14,trace_hardirqs_on_caller
  66         .endm
  67
  68         .macro  TRACE_IRQS_OFF
  69          basr   %r2,%r0
  70          brasl  %r14,trace_hardirqs_off_caller
  71         .endm
  72
  73         .macro TRACE_IRQS_CHECK
  74         basr    %r2,%r0
  75         tm      SP_PSW(%r15),0x03       # irqs enabled?
  76         jz      0f
  77         brasl   %r14,trace_hardirqs_on_caller
  78         j       1f
  79 0:      brasl   %r14,trace_hardirqs_off_caller
  80 1:
  81         .endm
  82 #else
  83 #define TRACE_IRQS_ON
  84 #define TRACE_IRQS_OFF
  85 #define TRACE_IRQS_CHECK
  86 #endif
  87
  88 #ifdef CONFIG_LOCKDEP
  89         .macro  LOCKDEP_SYS_EXIT
  90         tm      SP_PSW+1(%r15),0x01     # returning to user ?
  91         jz      0f
  92         brasl   %r14,lockdep_sys_exit
  93 0:
  94         .endm
  95 #else
  96 #define LOCKDEP_SYS_EXIT
  97 #endif
  98
  99         .macro  UPDATE_VTIME lc_from,lc_to,lc_sum
 100         lg      %r10,\lc_from
 101         slg     %r10,\lc_to
 102         alg     %r10,\lc_sum
 103         stg     %r10,\lc_sum
 104         .endm
 105
 106 /*
 107  * Register usage in interrupt handlers:
 108  *    R9  - pointer to current task structure
 109  *    R13 - pointer to literal pool
 110  *    R14 - return register for function calls
 111  *    R15 - kernel stack pointer
 112  */
 113
 114         .macro  SAVE_ALL_BASE savearea
 115         stmg    %r12,%r15,\savearea
 116         larl    %r13,system_call
 117         .endm
 118
 119         .macro  SAVE_ALL_SVC psworg,savearea
 120         la      %r12,\psworg
 121         lg      %r15,__LC_KERNEL_STACK  # problem state -> load ksp
 122         .endm
 123
 124         .macro  SAVE_ALL_SYNC psworg,savearea
 125         la      %r12,\psworg
 126         tm      \psworg+1,0x01          # test problem state bit
 127         jz      2f                      # skip stack setup save
 128         lg      %r15,__LC_KERNEL_STACK  # problem state -> load ksp
 129 #ifdef CONFIG_CHECK_STACK
 130         j       3f
 131 2:      tml     %r15,STACK_SIZE - CONFIG_STACK_GUARD
 132         jz      stack_overflow
 133 3:
 134 #endif
 135 2:
 136         .endm
 137
 138         .macro  SAVE_ALL_ASYNC psworg,savearea
 139         la      %r12,\psworg
 140         tm      \psworg+1,0x01          # test problem state bit
 141         jnz     1f                      # from user -> load kernel stack
 142         clc     \psworg+8(8),BASED(.Lcritical_end)
 143         jhe     0f
 144         clc     \psworg+8(8),BASED(.Lcritical_start)
 145         jl      0f
 146         brasl   %r14,cleanup_critical
 147         tm      1(%r12),0x01            # retest problem state after cleanup
 148         jnz     1f
 149 0:      lg      %r14,__LC_ASYNC_STACK   # are we already on the async. stack ?
 150         slgr    %r14,%r15
 151         srag    %r14,%r14,STACK_SHIFT
 152         jz      2f
 153 1:      lg      %r15,__LC_ASYNC_STACK   # load async stack
 154 #ifdef CONFIG_CHECK_STACK
 155         j       3f
 156 2:      tml     %r15,STACK_SIZE - CONFIG_STACK_GUARD
 157         jz      stack_overflow
 158 3:
 159 #endif
 160 2:
 161         .endm
 162
 163         .macro  CREATE_STACK_FRAME psworg,savearea
 164         aghi    %r15,-SP_SIZE           # make room for registers & psw
 165         mvc     SP_PSW(16,%r15),0(%r12) # move user PSW to stack
 166         stg     %r2,SP_ORIG_R2(%r15)    # store original content of gpr 2
 167         icm     %r12,3,__LC_SVC_ILC
 168         stmg    %r0,%r11,SP_R0(%r15)    # store gprs %r0-%r11 to kernel stack
 169         st      %r12,SP_SVCNR(%r15)
 170         mvc     SP_R12(32,%r15),\savearea # move %r12-%r15 to stack
 171         la      %r12,0
 172         stg     %r12,__SF_BACKCHAIN(%r15)
 173         .endm
 174
 175         .macro  RESTORE_ALL psworg,sync
 176         mvc     \psworg(16),SP_PSW(%r15) # move user PSW to lowcore
 177         .if !\sync
 178         ni      \psworg+1,0xfd          # clear wait state bit
 179         .endif
 180         lg      %r14,__LC_VDSO_PER_CPU
 181         lmg     %r0,%r13,SP_R0(%r15)    # load gprs 0-13 of user
 182         stpt    __LC_EXIT_TIMER
 183         mvc     __VDSO_ECTG_BASE(16,%r14),__LC_EXIT_TIMER
 184         lmg     %r14,%r15,SP_R14(%r15)  # load grps 14-15 of user
 185         lpswe   \psworg                 # back to caller
 186         .endm
 187
 188 /*
 189  * Scheduler resume function, called by switch_to
 190  *  gpr2 = (task_struct *) prev
 191  *  gpr3 = (task_struct *) next
 192  * Returns:
 193  *  gpr2 = prev
 194  */
 195         .globl  __switch_to
 196 __switch_to:
 197         tm      __THREAD_per+4(%r3),0xe8 # is the new process using per ?
 198         jz      __switch_to_noper               # if not we're fine
 199         stctg   %c9,%c11,__SF_EMPTY(%r15)# We are using per stuff
 200         clc     __THREAD_per(24,%r3),__SF_EMPTY(%r15)
 201         je      __switch_to_noper            # we got away without bashing TLB's
 202         lctlg   %c9,%c11,__THREAD_per(%r3)      # Nope we didn't
 203 __switch_to_noper:
 204         lg      %r4,__THREAD_info(%r2)              # get thread_info of prev
 205         tm      __TI_flags+7(%r4),_TIF_MCCK_PENDING # machine check pending?
 206         jz      __switch_to_no_mcck
 207         ni      __TI_flags+7(%r4),255-_TIF_MCCK_PENDING # clear flag in prev
 208         lg      %r4,__THREAD_info(%r3)              # get thread_info of next
 209         oi      __TI_flags+7(%r4),_TIF_MCCK_PENDING # set it in next
 210 __switch_to_no_mcck:
 211         stmg    %r6,%r15,__SF_GPRS(%r15)# store __switch_to registers of prev task
 212         stg     %r15,__THREAD_ksp(%r2)  # store kernel stack to prev->tss.ksp
 213         lg      %r15,__THREAD_ksp(%r3)  # load kernel stack from next->tss.ksp
 214         lmg     %r6,%r15,__SF_GPRS(%r15)# load __switch_to registers of next task
 215         stg     %r3,__LC_CURRENT        # __LC_CURRENT = current task struct
 216         lctl    %c4,%c4,__TASK_pid(%r3) # load pid to control reg. 4
 217         lg      %r3,__THREAD_info(%r3)  # load thread_info from task struct
 218         stg     %r3,__LC_THREAD_INFO
 219         aghi    %r3,STACK_SIZE
 220         stg     %r3,__LC_KERNEL_STACK   # __LC_KERNEL_STACK = new kernel stack
 221         br      %r14
 222
 223 __critical_start:
 224 /*
 225  * SVC interrupt handler routine. System calls are synchronous events and
 226  * are executed with interrupts enabled.
 227  */
 228
 229         .globl  system_call
 230 system_call:
 231         stpt    __LC_SYNC_ENTER_TIMER
 232 sysc_saveall:
 233         SAVE_ALL_BASE __LC_SAVE_AREA
 234         SAVE_ALL_SVC __LC_SVC_OLD_PSW,__LC_SAVE_AREA
 235         CREATE_STACK_FRAME __LC_SVC_OLD_PSW,__LC_SAVE_AREA
 236         llgh    %r7,__LC_SVC_INT_CODE   # get svc number from lowcore
 237 sysc_vtime:
 238         UPDATE_VTIME __LC_EXIT_TIMER,__LC_SYNC_ENTER_TIMER,__LC_USER_TIMER
 239 sysc_stime:
 240         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
 241 sysc_update:
 242         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
 243 sysc_do_svc:
 244         lg      %r9,__LC_THREAD_INFO    # load pointer to thread_info struct
 245         ltgr    %r7,%r7         # test for svc 0
 246         jnz     sysc_nr_ok
 247         # svc 0: system call number in %r1
 248         cl      %r1,BASED(.Lnr_syscalls)
 249         jnl     sysc_nr_ok
 250         lgfr    %r7,%r1         # clear high word in r1
 251 sysc_nr_ok:
 252         mvc     SP_ARGS(8,%r15),SP_R7(%r15)
 253 sysc_do_restart:
 254         sth     %r7,SP_SVCNR(%r15)
 255         sllg    %r7,%r7,2       # svc number * 4
 256         larl    %r10,sys_call_table
 257 #ifdef CONFIG_COMPAT
 258         tm      __TI_flags+5(%r9),(_TIF_31BIT>>16)  # running in 31 bit mode ?
 259         jno     sysc_noemu
 260         larl    %r10,sys_call_table_emu  # use 31 bit emulation system calls
 261 sysc_noemu:
 262 #endif
 263         tm      __TI_flags+6(%r9),_TIF_SYSCALL
 264         lgf     %r8,0(%r7,%r10) # load address of system call routine
 265         jnz     sysc_tracesys
 266         basr    %r14,%r8        # call sys_xxxx
 267         stg     %r2,SP_R2(%r15) # store return value (change R2 on stack)
 268
 269 sysc_return:
 270         tm      __TI_flags+7(%r9),_TIF_WORK_SVC
 271         jnz     sysc_work       # there is work to do (signals etc.)
 272 sysc_restore:
 273 #ifdef CONFIG_TRACE_IRQFLAGS
 274         larl    %r1,sysc_restore_trace_psw
 275         lpswe   0(%r1)
 276 sysc_restore_trace:
 277         TRACE_IRQS_CHECK
 278         LOCKDEP_SYS_EXIT
 279 #endif
 280 sysc_leave:
 281         RESTORE_ALL __LC_RETURN_PSW,1
 282 sysc_done:
 283
 284 #ifdef CONFIG_TRACE_IRQFLAGS
 285         .section .data,"aw",@progbits
 286         .align  8
 287         .globl sysc_restore_trace_psw
 288 sysc_restore_trace_psw:
 289         .quad   0, sysc_restore_trace
 290         .previous
 291 #endif
 292
 293 #
 294 # There is work to do, but first we need to check if we return to userspace.
 295 #
 296 sysc_work:
 297         tm      SP_PSW+1(%r15),0x01     # returning to user ?
 298         jno     sysc_restore
 299
 300 #
 301 # One of the work bits is on. Find out which one.
 302 #
 303 sysc_work_loop:
 304         tm      __TI_flags+7(%r9),_TIF_MCCK_PENDING
 305         jo      sysc_mcck_pending
 306         tm      __TI_flags+7(%r9),_TIF_NEED_RESCHED
 307         jo      sysc_reschedule
 308         tm      __TI_flags+7(%r9),_TIF_SIGPENDING
 309         jo      sysc_sigpending
 310         tm      __TI_flags+7(%r9),_TIF_NOTIFY_RESUME
 311         jo      sysc_notify_resume
 312         tm      __TI_flags+7(%r9),_TIF_RESTART_SVC
 313         jo      sysc_restart
 314         tm      __TI_flags+7(%r9),_TIF_SINGLE_STEP
 315         jo      sysc_singlestep
 316         j       sysc_return             # beware of critical section cleanup
 317
 318 #
 319 # _TIF_NEED_RESCHED is set, call schedule
 320 #
 321 sysc_reschedule:
 322         larl    %r14,sysc_work_loop
 323         jg      schedule                # return point is sysc_work_loop
 324
 325 #
 326 # _TIF_MCCK_PENDING is set, call handler
 327 #
 328 sysc_mcck_pending:
 329         larl    %r14,sysc_work_loop
 330         jg      s390_handle_mcck        # TIF bit will be cleared by handler
 331
 332 #
 333 # _TIF_SIGPENDING is set, call do_signal
 334 #
 335 sysc_sigpending:
 336         ni      __TI_flags+7(%r9),255-_TIF_SINGLE_STEP # clear TIF_SINGLE_STEP
 337         la      %r2,SP_PTREGS(%r15)     # load pt_regs
 338         brasl   %r14,do_signal          # call do_signal
 339         tm      __TI_flags+7(%r9),_TIF_RESTART_SVC
 340         jo      sysc_restart
 341         tm      __TI_flags+7(%r9),_TIF_SINGLE_STEP
 342         jo      sysc_singlestep
 343         j       sysc_work_loop
 344
 345 #
 346 # _TIF_NOTIFY_RESUME is set, call do_notify_resume
 347 #
 348 sysc_notify_resume:
 349         la      %r2,SP_PTREGS(%r15)     # load pt_regs
 350         larl    %r14,sysc_work_loop
 351         jg      do_notify_resume        # call do_notify_resume
 352
 353 #
 354 # _TIF_RESTART_SVC is set, set up registers and restart svc
 355 #
 356 sysc_restart:
 357         ni      __TI_flags+7(%r9),255-_TIF_RESTART_SVC # clear TIF_RESTART_SVC
 358         lg      %r7,SP_R2(%r15)         # load new svc number
 359         mvc     SP_R2(8,%r15),SP_ORIG_R2(%r15) # restore first argument
 360         lmg     %r2,%r6,SP_R2(%r15)     # load svc arguments
 361         j       sysc_do_restart         # restart svc
 362
 363 #
 364 # _TIF_SINGLE_STEP is set, call do_single_step
 365 #
 366 sysc_singlestep:
 367         ni      __TI_flags+7(%r9),255-_TIF_SINGLE_STEP  # clear TIF_SINGLE_STEP
 368         xc      SP_SVCNR(2,%r15),SP_SVCNR(%r15)         # clear svc number
 369         la      %r2,SP_PTREGS(%r15)     # address of register-save area
 370         larl    %r14,sysc_work_loop     # load adr. of system return
 371         jg      do_single_step          # branch to do_sigtrap
 372
 373 #
 374 # call tracehook_report_syscall_entry/tracehook_report_syscall_exit before
 375 # and after the system call
 376 #
 377 sysc_tracesys:
 378         la      %r2,SP_PTREGS(%r15)     # load pt_regs
 379         la      %r3,0
 380         srl     %r7,2
 381         stg     %r7,SP_R2(%r15)
 382         brasl   %r14,do_syscall_trace_enter
 383         lghi    %r0,NR_syscalls
 384         clgr    %r0,%r2
 385         jnh     sysc_tracenogo
 386         sllg    %r7,%r2,2               # svc number *4
 387         lgf     %r8,0(%r7,%r10)
 388 sysc_tracego:
 389         lmg     %r3,%r6,SP_R3(%r15)
 390         lg      %r2,SP_ORIG_R2(%r15)
 391         basr    %r14,%r8                # call sys_xxx
 392         stg     %r2,SP_R2(%r15)         # store return value
 393 sysc_tracenogo:
 394         tm      __TI_flags+6(%r9),_TIF_SYSCALL
 395         jz      sysc_return
 396         la      %r2,SP_PTREGS(%r15)     # load pt_regs
 397         larl    %r14,sysc_return        # return point is sysc_return
 398         jg      do_syscall_trace_exit
 399
 400 #
 401 # a new process exits the kernel with ret_from_fork
 402 #
 403         .globl  ret_from_fork
 404 ret_from_fork:
 405         lg      %r13,__LC_SVC_NEW_PSW+8
 406         lg      %r9,__LC_THREAD_INFO    # load pointer to thread_info struct
 407         tm      SP_PSW+1(%r15),0x01     # forking a kernel thread ?
 408         jo      0f
 409         stg     %r15,SP_R15(%r15)       # store stack pointer for new kthread
 410 0:      brasl   %r14,schedule_tail
 411         TRACE_IRQS_ON
 412         stosm   24(%r15),0x03           # reenable interrupts
 413         j       sysc_tracenogo
 414
 415 #
 416 # kernel_execve function needs to deal with pt_regs that is not
 417 # at the usual place
 418 #
 419         .globl  kernel_execve
 420 kernel_execve:
 421         stmg    %r12,%r15,96(%r15)
 422         lgr     %r14,%r15
 423         aghi    %r15,-SP_SIZE
 424         stg     %r14,__SF_BACKCHAIN(%r15)
 425         la      %r12,SP_PTREGS(%r15)
 426         xc      0(__PT_SIZE,%r12),0(%r12)
 427         lgr     %r5,%r12
 428         brasl   %r14,do_execve
 429         ltgfr   %r2,%r2
 430         je      0f
 431         aghi    %r15,SP_SIZE
 432         lmg     %r12,%r15,96(%r15)
 433         br      %r14
 434         # execve succeeded.
 435 0:      stnsm   __SF_EMPTY(%r15),0xfc   # disable interrupts
 436         lg      %r15,__LC_KERNEL_STACK  # load ksp
 437         aghi    %r15,-SP_SIZE           # make room for registers & psw
 438         lg      %r13,__LC_SVC_NEW_PSW+8
 439         lg      %r9,__LC_THREAD_INFO
 440         mvc     SP_PTREGS(__PT_SIZE,%r15),0(%r12)       # copy pt_regs
 441         xc      __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
 442         stosm   __SF_EMPTY(%r15),0x03   # reenable interrupts
 443         brasl   %r14,execve_tail
 444         j       sysc_return
 445
 446 /*
 447  * Program check handler routine
 448  */
 449
 450         .globl  pgm_check_handler
 451 pgm_check_handler:
 452 /*
 453  * First we need to check for a special case:
 454  * Single stepping an instruction that disables the PER event mask will
 455  * cause a PER event AFTER the mask has been set. Example: SVC or LPSW.
 456  * For a single stepped SVC the program check handler gets control after
 457  * the SVC new PSW has been loaded. But we want to execute the SVC first and
 458  * then handle the PER event. Therefore we update the SVC old PSW to point
 459  * to the pgm_check_handler and branch to the SVC handler after we checked
 460  * if we have to load the kernel stack register.
 461  * For every other possible cause for PER event without the PER mask set
 462  * we just ignore the PER event (FIXME: is there anything we have to do
 463  * for LPSW?).
 464  */
 465         stpt    __LC_SYNC_ENTER_TIMER
 466         SAVE_ALL_BASE __LC_SAVE_AREA
 467         tm      __LC_PGM_INT_CODE+1,0x80 # check whether we got a per exception
 468         jnz     pgm_per                  # got per exception -> special case
 469         SAVE_ALL_SYNC __LC_PGM_OLD_PSW,__LC_SAVE_AREA
 470         CREATE_STACK_FRAME __LC_PGM_OLD_PSW,__LC_SAVE_AREA
 471         tm      SP_PSW+1(%r15),0x01     # interrupting from user ?
 472         jz      pgm_no_vtime
 473         UPDATE_VTIME __LC_EXIT_TIMER,__LC_SYNC_ENTER_TIMER,__LC_USER_TIMER
 474         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
 475         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
 476 pgm_no_vtime:
 477         lg      %r9,__LC_THREAD_INFO    # load pointer to thread_info struct
 478         mvc     SP_ARGS(8,%r15),__LC_LAST_BREAK
 479         TRACE_IRQS_OFF
 480         lgf     %r3,__LC_PGM_ILC        # load program interruption code
 481         lghi    %r8,0x7f
 482         ngr     %r8,%r3
 483 pgm_do_call:
 484         sll     %r8,3
 485         larl    %r1,pgm_check_table
 486         lg      %r1,0(%r8,%r1)          # load address of handler routine
 487         la      %r2,SP_PTREGS(%r15)     # address of register-save area
 488         larl    %r14,sysc_return
 489         br      %r1                     # branch to interrupt-handler
 490
 491 #
 492 # handle per exception
 493 #
 494 pgm_per:
 495         tm      __LC_PGM_OLD_PSW,0x40   # test if per event recording is on
 496         jnz     pgm_per_std             # ok, normal per event from user space
 497 # ok its one of the special cases, now we need to find out which one
 498         clc     __LC_PGM_OLD_PSW(16),__LC_SVC_NEW_PSW
 499         je      pgm_svcper
 500 # no interesting special case, ignore PER event
 501         lmg     %r12,%r15,__LC_SAVE_AREA
 502         lpswe   __LC_PGM_OLD_PSW
 503
 504 #
 505 # Normal per exception
 506 #
 507 pgm_per_std:
 508         SAVE_ALL_SYNC __LC_PGM_OLD_PSW,__LC_SAVE_AREA
 509         CREATE_STACK_FRAME __LC_PGM_OLD_PSW,__LC_SAVE_AREA
 510         tm      SP_PSW+1(%r15),0x01     # interrupting from user ?
 511         jz      pgm_no_vtime2
 512         UPDATE_VTIME __LC_EXIT_TIMER,__LC_SYNC_ENTER_TIMER,__LC_USER_TIMER
 513         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
 514         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
 515 pgm_no_vtime2:
 516         lg      %r9,__LC_THREAD_INFO    # load pointer to thread_info struct
 517         TRACE_IRQS_OFF
 518         lg      %r1,__TI_task(%r9)
 519         tm      SP_PSW+1(%r15),0x01     # kernel per event ?
 520         jz      kernel_per
 521         mvc     __THREAD_per+__PER_atmid(2,%r1),__LC_PER_ATMID
 522         mvc     __THREAD_per+__PER_address(8,%r1),__LC_PER_ADDRESS
 523         mvc     __THREAD_per+__PER_access_id(1,%r1),__LC_PER_ACCESS_ID
 524         oi      __TI_flags+7(%r9),_TIF_SINGLE_STEP # set TIF_SINGLE_STEP
 525         lgf     %r3,__LC_PGM_ILC        # load program interruption code
 526         lghi    %r8,0x7f
 527         ngr     %r8,%r3                 # clear per-event-bit and ilc
 528         je      sysc_return
 529         j       pgm_do_call
 530
 531 #
 532 # it was a single stepped SVC that is causing all the trouble
 533 #
 534 pgm_svcper:
 535         SAVE_ALL_SYNC __LC_SVC_OLD_PSW,__LC_SAVE_AREA
 536         CREATE_STACK_FRAME __LC_SVC_OLD_PSW,__LC_SAVE_AREA
 537         UPDATE_VTIME __LC_EXIT_TIMER,__LC_SYNC_ENTER_TIMER,__LC_USER_TIMER
 538         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
 539         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
 540         llgh    %r7,__LC_SVC_INT_CODE   # get svc number from lowcore
 541         lg      %r9,__LC_THREAD_INFO    # load pointer to thread_info struct
 542         lg      %r8,__TI_task(%r9)
 543         mvc     __THREAD_per+__PER_atmid(2,%r8),__LC_PER_ATMID
 544         mvc     __THREAD_per+__PER_address(8,%r8),__LC_PER_ADDRESS
 545         mvc     __THREAD_per+__PER_access_id(1,%r8),__LC_PER_ACCESS_ID
 546         oi      __TI_flags+7(%r9),_TIF_SINGLE_STEP # set TIF_SINGLE_STEP
 547         TRACE_IRQS_ON
 548         lmg     %r2,%r6,SP_R2(%r15)     # load svc arguments
 549         stosm   __SF_EMPTY(%r15),0x03   # reenable interrupts
 550         j       sysc_do_svc
 551
 552 #
 553 # per was called from kernel, must be kprobes
 554 #
 555 kernel_per:
 556         xc      SP_SVCNR(2,%r15),SP_SVCNR(%r15) # clear svc number
 557         la      %r2,SP_PTREGS(%r15)     # address of register-save area
 558         larl    %r14,sysc_restore       # load adr. of system ret, no work
 559         jg      do_single_step          # branch to do_single_step
 560
 561 /*
 562  * IO interrupt handler routine
 563  */
 564         .globl io_int_handler
 565 io_int_handler:
 566         stck    __LC_INT_CLOCK
 567         stpt    __LC_ASYNC_ENTER_TIMER
 568         SAVE_ALL_BASE __LC_SAVE_AREA+32
 569         SAVE_ALL_ASYNC __LC_IO_OLD_PSW,__LC_SAVE_AREA+32
 570         CREATE_STACK_FRAME __LC_IO_OLD_PSW,__LC_SAVE_AREA+32
 571         tm      SP_PSW+1(%r15),0x01     # interrupting from user ?
 572         jz      io_no_vtime
 573         UPDATE_VTIME __LC_EXIT_TIMER,__LC_ASYNC_ENTER_TIMER,__LC_USER_TIMER
 574         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
 575         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_ASYNC_ENTER_TIMER
 576 io_no_vtime:
 577         lg      %r9,__LC_THREAD_INFO    # load pointer to thread_info struct
 578         TRACE_IRQS_OFF
 579         la      %r2,SP_PTREGS(%r15)     # address of register-save area
 580         brasl   %r14,do_IRQ             # call standard irq handler
 581 io_return:
 582         tm      __TI_flags+7(%r9),_TIF_WORK_INT
 583         jnz     io_work                 # there is work to do (signals etc.)
 584 io_restore:
 585 #ifdef CONFIG_TRACE_IRQFLAGS
 586         larl    %r1,io_restore_trace_psw
 587         lpswe   0(%r1)
 588 io_restore_trace:
 589         TRACE_IRQS_CHECK
 590         LOCKDEP_SYS_EXIT
 591 #endif
 592 io_leave:
 593         RESTORE_ALL __LC_RETURN_PSW,0
 594 io_done:
 595
 596 #ifdef CONFIG_TRACE_IRQFLAGS
 597         .section .data,"aw",@progbits
 598         .align  8
 599         .globl io_restore_trace_psw
 600 io_restore_trace_psw:
 601         .quad   0, io_restore_trace
 602         .previous
 603 #endif
 604
 605 #
 606 # There is work todo, find out in which context we have been interrupted:
 607 # 1) if we return to user space we can do all _TIF_WORK_INT work
 608 # 2) if we return to kernel code and kvm is enabled check if we need to
 609 #    modify the psw to leave SIE
 610 # 3) if we return to kernel code and preemptive scheduling is enabled check
 611 #    the preemption counter and if it is zero call preempt_schedule_irq
 612 # Before any work can be done, a switch to the kernel stack is required.
 613 #
 614 io_work:
 615         tm      SP_PSW+1(%r15),0x01     # returning to user ?
 616         jo      io_work_user            # yes -> do resched & signal
 617 #if defined(CONFIG_KVM) || defined(CONFIG_KVM_MODULE)
 618         lg      %r2,SP_PSW+8(%r15)      # check if current instruction is SIE
 619         lh      %r1,0(%r2)
 620         chi     %r1,-19948              # signed 16 bit compare with 0xb214
 621         jne     0f                      # no -> leave PSW alone
 622         aghi    %r2,4                   # yes-> add 4 bytes to leave SIE
 623         stg     %r2,SP_PSW+8(%r15)
 624 0:
 625 #endif
 626 #ifdef CONFIG_PREEMPT
 627         # check for preemptive scheduling
 628         icm     %r0,15,__TI_precount(%r9)
 629         jnz     io_restore              # preemption is disabled
 630         # switch to kernel stack
 631         lg      %r1,SP_R15(%r15)
 632         aghi    %r1,-SP_SIZE
 633         mvc     SP_PTREGS(__PT_SIZE,%r1),SP_PTREGS(%r15)
 634         xc      __SF_BACKCHAIN(8,%r1),__SF_BACKCHAIN(%r1) # clear back chain
 635         lgr     %r15,%r1
 636 io_resume_loop:
 637         larl    %r14,io_resume_loop
 638         tm      __TI_flags+7(%r12),_TIF_NEED_RESCHED
 639         jgo     preempt_schedule_irq
 640 #endif
 641         j       io_restore
 642
 643 #
 644 # Need to do work before returning to userspace, switch to kernel stack
 645 #
 646 io_work_user:
 647         lg      %r1,__LC_KERNEL_STACK
 648         aghi    %r1,-SP_SIZE
 649         mvc     SP_PTREGS(__PT_SIZE,%r1),SP_PTREGS(%r15)
 650         xc      __SF_BACKCHAIN(8,%r1),__SF_BACKCHAIN(%r1) # clear back chain
 651         lgr     %r15,%r1
 652
 653 #
 654 # One of the work bits is on. Find out which one.
 655 # Checked are: _TIF_SIGPENDING, _TIF_NOTIFY_RESUME, _TIF_NEED_RESCHED
 656 #              and _TIF_MCCK_PENDING
 657 #
 658 io_work_loop:
 659         tm      __TI_flags+7(%r9),_TIF_MCCK_PENDING
 660         jo      io_mcck_pending
 661         tm      __TI_flags+7(%r9),_TIF_NEED_RESCHED
 662         jo      io_reschedule
 663         tm      __TI_flags+7(%r9),_TIF_SIGPENDING
 664         jo      io_sigpending
 665         tm      __TI_flags+7(%r9),_TIF_NOTIFY_RESUME
 666         jo      io_notify_resume
 667         j       io_return               # beware of critical section cleanup
 668
 669 #
 670 # _TIF_MCCK_PENDING is set, call handler
 671 #
 672 io_mcck_pending:
 673         brasl   %r14,s390_handle_mcck   # TIF bit will be cleared by handler
 674         j       io_work_loop
 675
 676 #
 677 # _TIF_NEED_RESCHED is set, call schedule
 678 #
 679 io_reschedule:
 680         TRACE_IRQS_ON
 681         stosm   __SF_EMPTY(%r15),0x03   # reenable interrupts
 682         brasl   %r14,schedule           # call scheduler
 683         stnsm   __SF_EMPTY(%r15),0xfc   # disable I/O and ext. interrupts
 684         TRACE_IRQS_OFF
 685         j       io_work_loop
 686
 687 #
 688 # _TIF_SIGPENDING or is set, call do_signal
 689 #
 690 io_sigpending:
 691         TRACE_IRQS_ON
 692         stosm   __SF_EMPTY(%r15),0x03   # reenable interrupts
 693         la      %r2,SP_PTREGS(%r15)     # load pt_regs
 694         brasl   %r14,do_signal          # call do_signal
 695         stnsm   __SF_EMPTY(%r15),0xfc   # disable I/O and ext. interrupts
 696         TRACE_IRQS_OFF
 697         j       io_work_loop
 698
 699 #
 700 # _TIF_NOTIFY_RESUME or is set, call do_notify_resume
 701 #
 702 io_notify_resume:
 703         TRACE_IRQS_ON
 704         stosm   __SF_EMPTY(%r15),0x03   # reenable interrupts
 705         la      %r2,SP_PTREGS(%r15)     # load pt_regs
 706         brasl   %r14,do_notify_resume   # call do_notify_resume
 707         stnsm   __SF_EMPTY(%r15),0xfc   # disable I/O and ext. interrupts
 708         TRACE_IRQS_OFF
 709         j       io_work_loop
 710
 711 /*
 712  * External interrupt handler routine
 713  */
 714         .globl  ext_int_handler
 715 ext_int_handler:
 716         stck    __LC_INT_CLOCK
 717         stpt    __LC_ASYNC_ENTER_TIMER
 718         SAVE_ALL_BASE __LC_SAVE_AREA+32
 719         SAVE_ALL_ASYNC __LC_EXT_OLD_PSW,__LC_SAVE_AREA+32
 720         CREATE_STACK_FRAME __LC_EXT_OLD_PSW,__LC_SAVE_AREA+32
 721         tm      SP_PSW+1(%r15),0x01     # interrupting from user ?
 722         jz      ext_no_vtime
 723         UPDATE_VTIME __LC_EXIT_TIMER,__LC_ASYNC_ENTER_TIMER,__LC_USER_TIMER
 724         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
 725         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_ASYNC_ENTER_TIMER
 726 ext_no_vtime:
 727         lg      %r9,__LC_THREAD_INFO    # load pointer to thread_info struct
 728         TRACE_IRQS_OFF
 729         la      %r2,SP_PTREGS(%r15)     # address of register-save area
 730         llgh    %r3,__LC_EXT_INT_CODE   # get interruption code
 731         brasl   %r14,do_extint
 732         j       io_return
 733
 734 __critical_end:
 735
 736 /*
 737  * Machine check handler routines
 738  */
 739         .globl mcck_int_handler
 740 mcck_int_handler:
 741         stck    __LC_INT_CLOCK
 742         la      %r1,4095                # revalidate r1
 743         spt     __LC_CPU_TIMER_SAVE_AREA-4095(%r1)      # revalidate cpu timer
 744         lmg     %r0,%r15,__LC_GPREGS_SAVE_AREA-4095(%r1)# revalidate gprs
 745         SAVE_ALL_BASE __LC_SAVE_AREA+64
 746         la      %r12,__LC_MCK_OLD_PSW
 747         tm      __LC_MCCK_CODE,0x80     # system damage?
 748         jo      mcck_int_main           # yes -> rest of mcck code invalid
 749         la      %r14,4095
 750         mvc     __LC_SAVE_AREA+104(8),__LC_ASYNC_ENTER_TIMER
 751         mvc     __LC_ASYNC_ENTER_TIMER(8),__LC_CPU_TIMER_SAVE_AREA-4095(%r14)
 752         tm      __LC_MCCK_CODE+5,0x02   # stored cpu timer value valid?
 753         jo      1f
 754         la      %r14,__LC_SYNC_ENTER_TIMER
 755         clc     0(8,%r14),__LC_ASYNC_ENTER_TIMER
 756         jl      0f
 757         la      %r14,__LC_ASYNC_ENTER_TIMER
 758 0:      clc     0(8,%r14),__LC_EXIT_TIMER
 759         jl      0f
 760         la      %r14,__LC_EXIT_TIMER
 761 0:      clc     0(8,%r14),__LC_LAST_UPDATE_TIMER
 762         jl      0f
 763         la      %r14,__LC_LAST_UPDATE_TIMER
 764 0:      spt     0(%r14)
 765         mvc     __LC_ASYNC_ENTER_TIMER(8),0(%r14)
 766 1:      tm      __LC_MCCK_CODE+2,0x09   # mwp + ia of old psw valid?
 767         jno     mcck_int_main           # no -> skip cleanup critical
 768         tm      __LC_MCK_OLD_PSW+1,0x01 # test problem state bit
 769         jnz     mcck_int_main           # from user -> load kernel stack
 770         clc     __LC_MCK_OLD_PSW+8(8),BASED(.Lcritical_end)
 771         jhe     mcck_int_main
 772         clc     __LC_MCK_OLD_PSW+8(8),BASED(.Lcritical_start)
 773         jl      mcck_int_main
 774         brasl   %r14,cleanup_critical
 775 mcck_int_main:
 776         lg      %r14,__LC_PANIC_STACK   # are we already on the panic stack?
 777         slgr    %r14,%r15
 778         srag    %r14,%r14,PAGE_SHIFT
 779         jz      0f
 780         lg      %r15,__LC_PANIC_STACK   # load panic stack
 781 0:      CREATE_STACK_FRAME __LC_MCK_OLD_PSW,__LC_SAVE_AREA+64
 782         tm      __LC_MCCK_CODE+2,0x08   # mwp of old psw valid?
 783         jno     mcck_no_vtime           # no -> no timer update
 784         tm      SP_PSW+1(%r15),0x01     # interrupting from user ?
 785         jz      mcck_no_vtime
 786         UPDATE_VTIME __LC_EXIT_TIMER,__LC_ASYNC_ENTER_TIMER,__LC_USER_TIMER
 787         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
 788         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_ASYNC_ENTER_TIMER
 789 mcck_no_vtime:
 790         lg      %r9,__LC_THREAD_INFO    # load pointer to thread_info struct
 791         la      %r2,SP_PTREGS(%r15)     # load pt_regs
 792         brasl   %r14,s390_do_machine_check
 793         tm      SP_PSW+1(%r15),0x01     # returning to user ?
 794         jno     mcck_return
 795         lg      %r1,__LC_KERNEL_STACK   # switch to kernel stack
 796         aghi    %r1,-SP_SIZE
 797         mvc     SP_PTREGS(__PT_SIZE,%r1),SP_PTREGS(%r15)
 798         xc      __SF_BACKCHAIN(8,%r1),__SF_BACKCHAIN(%r1) # clear back chain
 799         lgr     %r15,%r1
 800         stosm   __SF_EMPTY(%r15),0x04   # turn dat on
 801         tm      __TI_flags+7(%r9),_TIF_MCCK_PENDING
 802         jno     mcck_return
 803         TRACE_IRQS_OFF
 804         brasl   %r14,s390_handle_mcck
 805         TRACE_IRQS_ON
 806 mcck_return:
 807         mvc     __LC_RETURN_MCCK_PSW(16),SP_PSW(%r15) # move return PSW
 808         ni      __LC_RETURN_MCCK_PSW+1,0xfd # clear wait state bit
 809         lmg     %r0,%r15,SP_R0(%r15)    # load gprs 0-15
 810         mvc     __LC_ASYNC_ENTER_TIMER(8),__LC_SAVE_AREA+104
 811         tm      __LC_RETURN_MCCK_PSW+1,0x01 # returning to user ?
 812         jno     0f
 813         stpt    __LC_EXIT_TIMER
 814 0:      lpswe   __LC_RETURN_MCCK_PSW    # back to caller
 815
 816 /*
 817  * Restart interruption handler, kick starter for additional CPUs
 818  */
 819 #ifdef CONFIG_SMP
 820         __CPUINIT
 821         .globl restart_int_handler
 822 restart_int_handler:
 823         basr    %r1,0
 824 restart_base:
 825         spt     restart_vtime-restart_base(%r1)
 826         stck    __LC_LAST_UPDATE_CLOCK
 827         mvc     __LC_LAST_UPDATE_TIMER(8),restart_vtime-restart_base(%r1)
 828         mvc     __LC_EXIT_TIMER(8),restart_vtime-restart_base(%r1)
 829         lg      %r15,__LC_SAVE_AREA+120 # load ksp
 830         lghi    %r10,__LC_CREGS_SAVE_AREA
 831         lctlg   %c0,%c15,0(%r10) # get new ctl regs
 832         lghi    %r10,__LC_AREGS_SAVE_AREA
 833         lam     %a0,%a15,0(%r10)
 834         lmg     %r6,%r15,__SF_GPRS(%r15) # load registers from clone
 835         lg      %r1,__LC_THREAD_INFO
 836         mvc     __LC_USER_TIMER(8),__TI_user_timer(%r1)
 837         mvc     __LC_SYSTEM_TIMER(8),__TI_system_timer(%r1)
 838         xc      __LC_STEAL_TIMER(8),__LC_STEAL_TIMER
 839         stosm   __SF_EMPTY(%r15),0x04   # now we can turn dat on
 840         jg      start_secondary
 841         .align  8
 842 restart_vtime:
 843         .long   0x7fffffff,0xffffffff
 844         .previous
 845 #else
 846 /*
 847  * If we do not run with SMP enabled, let the new CPU crash ...
 848  */
 849         .globl restart_int_handler
 850 restart_int_handler:
 851         basr    %r1,0
 852 restart_base:
 853         lpswe   restart_crash-restart_base(%r1)
 854         .align 8
 855 restart_crash:
 856         .long  0x000a0000,0x00000000,0x00000000,0x00000000
 857 restart_go:
 858 #endif
 859
 860 #ifdef CONFIG_CHECK_STACK
 861 /*
 862  * The synchronous or the asynchronous stack overflowed. We are dead.
 863  * No need to properly save the registers, we are going to panic anyway.
 864  * Setup a pt_regs so that show_trace can provide a good call trace.
 865  */
 866 stack_overflow:
 867         lg      %r15,__LC_PANIC_STACK   # change to panic stack
 868         aghi    %r15,-SP_SIZE
 869         mvc     SP_PSW(16,%r15),0(%r12) # move user PSW to stack
 870         stmg    %r0,%r11,SP_R0(%r15)    # store gprs %r0-%r11 to kernel stack
 871         la      %r1,__LC_SAVE_AREA
 872         chi     %r12,__LC_SVC_OLD_PSW
 873         je      0f
 874         chi     %r12,__LC_PGM_OLD_PSW
 875         je      0f
 876         la      %r1,__LC_SAVE_AREA+32
 877 0:      mvc     SP_R12(32,%r15),0(%r1)  # move %r12-%r15 to stack
 878         mvc     SP_ARGS(8,%r15),__LC_LAST_BREAK
 879         xc      __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15) # clear back chain
 880         la      %r2,SP_PTREGS(%r15)     # load pt_regs
 881         jg      kernel_stack_overflow
 882 #endif
 883
 884 cleanup_table_system_call:
 885         .quad   system_call, sysc_do_svc
 886 cleanup_table_sysc_return:
 887         .quad   sysc_return, sysc_leave
 888 cleanup_table_sysc_leave:
 889         .quad   sysc_leave, sysc_done
 890 cleanup_table_io_return:
 891         .quad   io_return, io_leave
 892 cleanup_table_io_leave:
 893         .quad   io_leave, io_done
 894
 895 cleanup_critical:
 896         clc     8(8,%r12),BASED(cleanup_table_system_call)
 897         jl      0f
 898         clc     8(8,%r12),BASED(cleanup_table_system_call+8)
 899         jl      cleanup_system_call
 900 0:
 901         clc     8(8,%r12),BASED(cleanup_table_sysc_return)
 902         jl      0f
 903         clc     8(8,%r12),BASED(cleanup_table_sysc_return+8)
 904         jl      cleanup_sysc_return
 905 0:
 906         clc     8(8,%r12),BASED(cleanup_table_sysc_leave)
 907         jl      0f
 908         clc     8(8,%r12),BASED(cleanup_table_sysc_leave+8)
 909         jl      cleanup_sysc_leave
 910 0:
 911         clc     8(8,%r12),BASED(cleanup_table_io_return)
 912         jl      0f
 913         clc     8(8,%r12),BASED(cleanup_table_io_return+8)
 914         jl      cleanup_io_return
 915 0:
 916         clc     8(8,%r12),BASED(cleanup_table_io_leave)
 917         jl      0f
 918         clc     8(8,%r12),BASED(cleanup_table_io_leave+8)
 919         jl      cleanup_io_leave
 920 0:
 921         br      %r14
 922
 923 cleanup_system_call:
 924         mvc     __LC_RETURN_PSW(16),0(%r12)
 925         cghi    %r12,__LC_MCK_OLD_PSW
 926         je      0f
 927         la      %r12,__LC_SAVE_AREA+32
 928         j       1f
 929 0:      la      %r12,__LC_SAVE_AREA+64
 930 1:
 931         clc     __LC_RETURN_PSW+8(8),BASED(cleanup_system_call_insn+8)
 932         jh      0f
 933         mvc     __LC_SYNC_ENTER_TIMER(8),__LC_ASYNC_ENTER_TIMER
 934 0:      clc     __LC_RETURN_PSW+8(8),BASED(cleanup_system_call_insn+16)
 935         jhe     cleanup_vtime
 936         clc     __LC_RETURN_PSW+8(8),BASED(cleanup_system_call_insn)
 937         jh      0f
 938         mvc     __LC_SAVE_AREA(32),0(%r12)
 939 0:      stg     %r13,8(%r12)
 940         stg     %r12,__LC_SAVE_AREA+96  # argh
 941         SAVE_ALL_SYNC __LC_SVC_OLD_PSW,__LC_SAVE_AREA
 942         CREATE_STACK_FRAME __LC_SVC_OLD_PSW,__LC_SAVE_AREA
 943         lg      %r12,__LC_SAVE_AREA+96  # argh
 944         stg     %r15,24(%r12)
 945         llgh    %r7,__LC_SVC_INT_CODE
 946 cleanup_vtime:
 947         clc     __LC_RETURN_PSW+8(8),BASED(cleanup_system_call_insn+24)
 948         jhe     cleanup_stime
 949         UPDATE_VTIME __LC_EXIT_TIMER,__LC_SYNC_ENTER_TIMER,__LC_USER_TIMER
 950 cleanup_stime:
 951         clc     __LC_RETURN_PSW+8(8),BASED(cleanup_system_call_insn+32)
 952         jh      cleanup_update
 953         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
 954 cleanup_update:
 955         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
 956         mvc     __LC_RETURN_PSW+8(8),BASED(cleanup_table_system_call+8)
 957         la      %r12,__LC_RETURN_PSW
 958         br      %r14
 959 cleanup_system_call_insn:
 960         .quad   sysc_saveall
 961         .quad   system_call
 962         .quad   sysc_vtime
 963         .quad   sysc_stime
 964         .quad   sysc_update
 965
 966 cleanup_sysc_return:
 967         mvc     __LC_RETURN_PSW(8),0(%r12)
 968         mvc     __LC_RETURN_PSW+8(8),BASED(cleanup_table_sysc_return)
 969         la      %r12,__LC_RETURN_PSW
 970         br      %r14
 971
 972 cleanup_sysc_leave:
 973         clc     8(8,%r12),BASED(cleanup_sysc_leave_insn)
 974         je      3f
 975         clc     8(8,%r12),BASED(cleanup_sysc_leave_insn+8)
 976         jhe     0f
 977         mvc     __LC_EXIT_TIMER(8),__LC_ASYNC_ENTER_TIMER
 978 0:      mvc     __LC_RETURN_PSW(16),SP_PSW(%r15)
 979         cghi    %r12,__LC_MCK_OLD_PSW
 980         jne     1f
 981         mvc     __LC_SAVE_AREA+64(32),SP_R12(%r15)
 982         j       2f
 983 1:      mvc     __LC_SAVE_AREA+32(32),SP_R12(%r15)
 984 2:      lmg     %r0,%r11,SP_R0(%r15)
 985         lg      %r15,SP_R15(%r15)
 986 3:      la      %r12,__LC_RETURN_PSW
 987         br      %r14
 988 cleanup_sysc_leave_insn:
 989         .quad   sysc_done - 4
 990         .quad   sysc_done - 16
 991
 992 cleanup_io_return:
 993         mvc     __LC_RETURN_PSW(8),0(%r12)
 994         mvc     __LC_RETURN_PSW+8(8),BASED(cleanup_table_io_return)
 995         la      %r12,__LC_RETURN_PSW
 996         br      %r14
 997
 998 cleanup_io_leave:
 999         clc     8(8,%r12),BASED(cleanup_io_leave_insn)
1000         je      3f
1001         clc     8(8,%r12),BASED(cleanup_io_leave_insn+8)
1002         jhe     0f
1003         mvc     __LC_EXIT_TIMER(8),__LC_ASYNC_ENTER_TIMER
1004 0:      mvc     __LC_RETURN_PSW(16),SP_PSW(%r15)
1005         cghi    %r12,__LC_MCK_OLD_PSW
1006         jne     1f
1007         mvc     __LC_SAVE_AREA+64(32),SP_R12(%r15)
1008         j       2f
1009 1:      mvc     __LC_SAVE_AREA+32(32),SP_R12(%r15)
1010 2:      lmg     %r0,%r11,SP_R0(%r15)
1011         lg      %r15,SP_R15(%r15)
1012 3:      la      %r12,__LC_RETURN_PSW
1013         br      %r14
1014 cleanup_io_leave_insn:
1015         .quad   io_done - 4
1016         .quad   io_done - 16
1017
1018 /*
1019  * Integer constants
1020  */
1021                 .align  4
1022 .Lconst:
1023 .Lnr_syscalls:  .long   NR_syscalls
1024 .L0x0130:       .short  0x130
1025 .L0x0140:       .short  0x140
1026 .L0x0150:       .short  0x150
1027 .L0x0160:       .short  0x160
1028 .L0x0170:       .short  0x170
1029 .Lcritical_start:
1030                 .quad   __critical_start
1031 .Lcritical_end:
1032                 .quad   __critical_end
1033
1034                 .section .rodata, "a"
1035 #define SYSCALL(esa,esame,emu)  .long esame
1036         .globl  sys_call_table
1037 sys_call_table:
1038 #include "syscalls.S"
1039 #undef SYSCALL
1040
1041 #ifdef CONFIG_COMPAT
1042
1043 #define SYSCALL(esa,esame,emu)  .long emu
1044 sys_call_table_emu:
1045 #include "syscalls.S"
1046 #undef SYSCALL
1047 #endif