[S390] improve irq tracing code in entry[64].S
[linux-2.6.git] / arch / s390 / kernel / entry.S
1 /*
2  *  arch/s390/kernel/entry.S
3  *    S390 low-level entry points.
4  *
5  *    Copyright (C) IBM Corp. 1999,2006
6  *    Author(s): Martin Schwidefsky (schwidefsky@de.ibm.com),
7  *               Hartmut Penner (hp@de.ibm.com),
8  *               Denis Joseph Barrow (djbarrow@de.ibm.com,barrow_dj@yahoo.com),
9  *               Heiko Carstens <heiko.carstens@de.ibm.com>
10  */
11
12 #include <linux/sys.h>
13 #include <linux/linkage.h>
14 #include <linux/init.h>
15 #include <asm/cache.h>
16 #include <asm/errno.h>
17 #include <asm/ptrace.h>
18 #include <asm/thread_info.h>
19 #include <asm/asm-offsets.h>
20 #include <asm/unistd.h>
21 #include <asm/page.h>
22
23 /*
24  * Stack layout for the system_call stack entry.
25  * The first few entries are identical to the user_regs_struct.
26  */
27 SP_PTREGS    =  STACK_FRAME_OVERHEAD
28 SP_ARGS      =  STACK_FRAME_OVERHEAD + __PT_ARGS
29 SP_PSW       =  STACK_FRAME_OVERHEAD + __PT_PSW
30 SP_R0        =  STACK_FRAME_OVERHEAD + __PT_GPRS
31 SP_R1        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 4
32 SP_R2        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 8
33 SP_R3        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 12
34 SP_R4        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 16
35 SP_R5        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 20
36 SP_R6        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 24
37 SP_R7        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 28
38 SP_R8        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 32
39 SP_R9        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 36
40 SP_R10       =  STACK_FRAME_OVERHEAD + __PT_GPRS + 40
41 SP_R11       =  STACK_FRAME_OVERHEAD + __PT_GPRS + 44
42 SP_R12       =  STACK_FRAME_OVERHEAD + __PT_GPRS + 48
43 SP_R13       =  STACK_FRAME_OVERHEAD + __PT_GPRS + 52
44 SP_R14       =  STACK_FRAME_OVERHEAD + __PT_GPRS + 56
45 SP_R15       =  STACK_FRAME_OVERHEAD + __PT_GPRS + 60
46 SP_ORIG_R2   =  STACK_FRAME_OVERHEAD + __PT_ORIG_GPR2
47 SP_ILC       =  STACK_FRAME_OVERHEAD + __PT_ILC
48 SP_SVCNR     =  STACK_FRAME_OVERHEAD + __PT_SVCNR
49 SP_SIZE      =  STACK_FRAME_OVERHEAD + __PT_SIZE
50
51 _TIF_WORK_SVC = (_TIF_SIGPENDING | _TIF_NOTIFY_RESUME | _TIF_NEED_RESCHED | \
52                  _TIF_MCCK_PENDING | _TIF_RESTART_SVC | _TIF_SINGLE_STEP )
53 _TIF_WORK_INT = (_TIF_SIGPENDING | _TIF_NOTIFY_RESUME | _TIF_NEED_RESCHED | \
54                  _TIF_MCCK_PENDING)
55 _TIF_SYSCALL = (_TIF_SYSCALL_TRACE>>8 | _TIF_SYSCALL_AUDIT>>8 | \
56                 _TIF_SECCOMP>>8 | _TIF_SYSCALL_TRACEPOINT>>8)
57
58 STACK_SHIFT = PAGE_SHIFT + THREAD_ORDER
59 STACK_SIZE  = 1 << STACK_SHIFT
60
61 #define BASED(name) name-system_call(%r13)
62
63 #ifdef CONFIG_TRACE_IRQFLAGS
64         .macro  TRACE_IRQS_ON
65         basr    %r2,%r0
66         l       %r1,BASED(.Ltrace_irq_on_caller)
67         basr    %r14,%r1
68         .endm
69
70         .macro  TRACE_IRQS_OFF
71         basr    %r2,%r0
72         l       %r1,BASED(.Ltrace_irq_off_caller)
73         basr    %r14,%r1
74         .endm
75
76         .macro  TRACE_IRQS_CHECK_ON
77         tm      SP_PSW(%r15),0x03       # irqs enabled?
78         bz      BASED(0f)
79         TRACE_IRQS_ON
80 0:
81         .endm
82
83         .macro  TRACE_IRQS_CHECK_OFF
84         tm      SP_PSW(%r15),0x03       # irqs enabled?
85         bz      BASED(0f)
86         TRACE_IRQS_OFF
87 0:
88         .endm
89 #else
90 #define TRACE_IRQS_ON
91 #define TRACE_IRQS_OFF
92 #define TRACE_IRQS_CHECK_ON
93 #define TRACE_IRQS_CHECK_OFF
94 #endif
95
96 #ifdef CONFIG_LOCKDEP
97         .macro  LOCKDEP_SYS_EXIT
98         tm      SP_PSW+1(%r15),0x01     # returning to user ?
99         jz      0f
100         l       %r1,BASED(.Llockdep_sys_exit)
101         basr    %r14,%r1
102 0:
103         .endm
104 #else
105 #define LOCKDEP_SYS_EXIT
106 #endif
107
108 /*
109  * Register usage in interrupt handlers:
110  *    R9  - pointer to current task structure
111  *    R13 - pointer to literal pool
112  *    R14 - return register for function calls
113  *    R15 - kernel stack pointer
114  */
115
116         .macro  UPDATE_VTIME lc_from,lc_to,lc_sum
117         lm      %r10,%r11,\lc_from
118         sl      %r10,\lc_to
119         sl      %r11,\lc_to+4
120         bc      3,BASED(0f)
121         sl      %r10,BASED(.Lc_1)
122 0:      al      %r10,\lc_sum
123         al      %r11,\lc_sum+4
124         bc      12,BASED(1f)
125         al      %r10,BASED(.Lc_1)
126 1:      stm     %r10,%r11,\lc_sum
127         .endm
128
129         .macro  SAVE_ALL_BASE savearea
130         stm     %r12,%r15,\savearea
131         l       %r13,__LC_SVC_NEW_PSW+4 # load &system_call to %r13
132         .endm
133
134         .macro  SAVE_ALL_SVC psworg,savearea
135         la      %r12,\psworg
136         l       %r15,__LC_KERNEL_STACK  # problem state -> load ksp
137         .endm
138
139         .macro  SAVE_ALL_SYNC psworg,savearea
140         la      %r12,\psworg
141         tm      \psworg+1,0x01          # test problem state bit
142         bz      BASED(2f)               # skip stack setup save
143         l       %r15,__LC_KERNEL_STACK  # problem state -> load ksp
144 #ifdef CONFIG_CHECK_STACK
145         b       BASED(3f)
146 2:      tml     %r15,STACK_SIZE - CONFIG_STACK_GUARD
147         bz      BASED(stack_overflow)
148 3:
149 #endif
150 2:
151         .endm
152
153         .macro  SAVE_ALL_ASYNC psworg,savearea
154         la      %r12,\psworg
155         tm      \psworg+1,0x01          # test problem state bit
156         bnz     BASED(1f)               # from user -> load async stack
157         clc     \psworg+4(4),BASED(.Lcritical_end)
158         bhe     BASED(0f)
159         clc     \psworg+4(4),BASED(.Lcritical_start)
160         bl      BASED(0f)
161         l       %r14,BASED(.Lcleanup_critical)
162         basr    %r14,%r14
163         tm      1(%r12),0x01            # retest problem state after cleanup
164         bnz     BASED(1f)
165 0:      l       %r14,__LC_ASYNC_STACK   # are we already on the async stack ?
166         slr     %r14,%r15
167         sra     %r14,STACK_SHIFT
168         be      BASED(2f)
169 1:      l       %r15,__LC_ASYNC_STACK
170 #ifdef CONFIG_CHECK_STACK
171         b       BASED(3f)
172 2:      tml     %r15,STACK_SIZE - CONFIG_STACK_GUARD
173         bz      BASED(stack_overflow)
174 3:
175 #endif
176 2:
177         .endm
178
179         .macro  CREATE_STACK_FRAME psworg,savearea
180         s       %r15,BASED(.Lc_spsize)  # make room for registers & psw
181         mvc     SP_PSW(8,%r15),0(%r12)  # move user PSW to stack
182         st      %r2,SP_ORIG_R2(%r15)    # store original content of gpr 2
183         icm     %r12,3,__LC_SVC_ILC
184         stm     %r0,%r11,SP_R0(%r15)    # store gprs %r0-%r11 to kernel stack
185         st      %r12,SP_SVCNR(%r15)
186         mvc     SP_R12(16,%r15),\savearea # move %r12-%r15 to stack
187         la      %r12,0
188         st      %r12,__SF_BACKCHAIN(%r15)       # clear back chain
189         .endm
190
191         .macro  RESTORE_ALL psworg,sync
192         mvc     \psworg(8),SP_PSW(%r15) # move user PSW to lowcore
193         .if !\sync
194         ni      \psworg+1,0xfd          # clear wait state bit
195         .endif
196         lm      %r0,%r15,SP_R0(%r15)    # load gprs 0-15 of user
197         stpt    __LC_EXIT_TIMER
198         lpsw    \psworg                 # back to caller
199         .endm
200
201 /*
202  * Scheduler resume function, called by switch_to
203  *  gpr2 = (task_struct *) prev
204  *  gpr3 = (task_struct *) next
205  * Returns:
206  *  gpr2 = prev
207  */
208         .globl  __switch_to
209 __switch_to:
210         basr    %r1,0
211 __switch_to_base:
212         tm      __THREAD_per(%r3),0xe8          # new process is using per ?
213         bz      __switch_to_noper-__switch_to_base(%r1) # if not we're fine
214         stctl   %c9,%c11,__SF_EMPTY(%r15)       # We are using per stuff
215         clc     __THREAD_per(12,%r3),__SF_EMPTY(%r15)
216         be      __switch_to_noper-__switch_to_base(%r1) # we got away w/o bashing TLB's
217         lctl    %c9,%c11,__THREAD_per(%r3)      # Nope we didn't
218 __switch_to_noper:
219         l       %r4,__THREAD_info(%r2)          # get thread_info of prev
220         tm      __TI_flags+3(%r4),_TIF_MCCK_PENDING # machine check pending?
221         bz      __switch_to_no_mcck-__switch_to_base(%r1)
222         ni      __TI_flags+3(%r4),255-_TIF_MCCK_PENDING # clear flag in prev
223         l       %r4,__THREAD_info(%r3)          # get thread_info of next
224         oi      __TI_flags+3(%r4),_TIF_MCCK_PENDING # set it in next
225 __switch_to_no_mcck:
226         stm     %r6,%r15,__SF_GPRS(%r15)# store __switch_to registers of prev task
227         st      %r15,__THREAD_ksp(%r2)  # store kernel stack to prev->tss.ksp
228         l       %r15,__THREAD_ksp(%r3)  # load kernel stack from next->tss.ksp
229         lm      %r6,%r15,__SF_GPRS(%r15)# load __switch_to registers of next task
230         st      %r3,__LC_CURRENT        # __LC_CURRENT = current task struct
231         lctl    %c4,%c4,__TASK_pid(%r3) # load pid to control reg. 4
232         l       %r3,__THREAD_info(%r3)  # load thread_info from task struct
233         st      %r3,__LC_THREAD_INFO
234         ahi     %r3,STACK_SIZE
235         st      %r3,__LC_KERNEL_STACK   # __LC_KERNEL_STACK = new kernel stack
236         br      %r14
237
238 __critical_start:
239 /*
240  * SVC interrupt handler routine. System calls are synchronous events and
241  * are executed with interrupts enabled.
242  */
243
244         .globl  system_call
245 system_call:
246         stpt    __LC_SYNC_ENTER_TIMER
247 sysc_saveall:
248         SAVE_ALL_BASE __LC_SAVE_AREA
249         SAVE_ALL_SVC __LC_SVC_OLD_PSW,__LC_SAVE_AREA
250         CREATE_STACK_FRAME __LC_SVC_OLD_PSW,__LC_SAVE_AREA
251         lh      %r7,0x8a          # get svc number from lowcore
252 sysc_vtime:
253         UPDATE_VTIME __LC_EXIT_TIMER,__LC_SYNC_ENTER_TIMER,__LC_USER_TIMER
254 sysc_stime:
255         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
256 sysc_update:
257         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
258 sysc_do_svc:
259         l       %r9,__LC_THREAD_INFO    # load pointer to thread_info struct
260         ltr     %r7,%r7                 # test for svc 0
261         bnz     BASED(sysc_nr_ok)       # svc number > 0
262         # svc 0: system call number in %r1
263         cl      %r1,BASED(.Lnr_syscalls)
264         bnl     BASED(sysc_nr_ok)
265         lr      %r7,%r1           # copy svc number to %r7
266 sysc_nr_ok:
267         mvc     SP_ARGS(4,%r15),SP_R7(%r15)
268 sysc_do_restart:
269         sth     %r7,SP_SVCNR(%r15)
270         sll     %r7,2             # svc number *4
271         l       %r8,BASED(.Lsysc_table)
272         tm      __TI_flags+2(%r9),_TIF_SYSCALL
273         l       %r8,0(%r7,%r8)    # get system call addr.
274         bnz     BASED(sysc_tracesys)
275         basr    %r14,%r8          # call sys_xxxx
276         st      %r2,SP_R2(%r15)   # store return value (change R2 on stack)
277
278 sysc_return:
279         LOCKDEP_SYS_EXIT
280 sysc_tif:
281         tm      __TI_flags+3(%r9),_TIF_WORK_SVC
282         bnz     BASED(sysc_work)  # there is work to do (signals etc.)
283 sysc_restore:
284         RESTORE_ALL __LC_RETURN_PSW,1
285 sysc_done:
286
287 #
288 # There is work to do, but first we need to check if we return to userspace.
289 #
290 sysc_work:
291         tm      SP_PSW+1(%r15),0x01     # returning to user ?
292         bno     BASED(sysc_restore)
293
294 #
295 # One of the work bits is on. Find out which one.
296 #
297 sysc_work_tif:
298         tm      __TI_flags+3(%r9),_TIF_MCCK_PENDING
299         bo      BASED(sysc_mcck_pending)
300         tm      __TI_flags+3(%r9),_TIF_NEED_RESCHED
301         bo      BASED(sysc_reschedule)
302         tm      __TI_flags+3(%r9),_TIF_SIGPENDING
303         bo      BASED(sysc_sigpending)
304         tm      __TI_flags+3(%r9),_TIF_NOTIFY_RESUME
305         bo      BASED(sysc_notify_resume)
306         tm      __TI_flags+3(%r9),_TIF_RESTART_SVC
307         bo      BASED(sysc_restart)
308         tm      __TI_flags+3(%r9),_TIF_SINGLE_STEP
309         bo      BASED(sysc_singlestep)
310         b       BASED(sysc_return)      # beware of critical section cleanup
311
312 #
313 # _TIF_NEED_RESCHED is set, call schedule
314 #
315 sysc_reschedule:
316         l       %r1,BASED(.Lschedule)
317         la      %r14,BASED(sysc_return)
318         br      %r1                     # call scheduler
319
320 #
321 # _TIF_MCCK_PENDING is set, call handler
322 #
323 sysc_mcck_pending:
324         l       %r1,BASED(.Ls390_handle_mcck)
325         la      %r14,BASED(sysc_return)
326         br      %r1                     # TIF bit will be cleared by handler
327
328 #
329 # _TIF_SIGPENDING is set, call do_signal
330 #
331 sysc_sigpending:
332         ni      __TI_flags+3(%r9),255-_TIF_SINGLE_STEP # clear TIF_SINGLE_STEP
333         la      %r2,SP_PTREGS(%r15)     # load pt_regs
334         l       %r1,BASED(.Ldo_signal)
335         basr    %r14,%r1                # call do_signal
336         tm      __TI_flags+3(%r9),_TIF_RESTART_SVC
337         bo      BASED(sysc_restart)
338         tm      __TI_flags+3(%r9),_TIF_SINGLE_STEP
339         bo      BASED(sysc_singlestep)
340         b       BASED(sysc_return)
341
342 #
343 # _TIF_NOTIFY_RESUME is set, call do_notify_resume
344 #
345 sysc_notify_resume:
346         la      %r2,SP_PTREGS(%r15)     # load pt_regs
347         l       %r1,BASED(.Ldo_notify_resume)
348         la      %r14,BASED(sysc_return)
349         br      %r1                     # call do_notify_resume
350
351
352 #
353 # _TIF_RESTART_SVC is set, set up registers and restart svc
354 #
355 sysc_restart:
356         ni      __TI_flags+3(%r9),255-_TIF_RESTART_SVC # clear TIF_RESTART_SVC
357         l       %r7,SP_R2(%r15)         # load new svc number
358         mvc     SP_R2(4,%r15),SP_ORIG_R2(%r15) # restore first argument
359         lm      %r2,%r6,SP_R2(%r15)     # load svc arguments
360         b       BASED(sysc_do_restart)  # restart svc
361
362 #
363 # _TIF_SINGLE_STEP is set, call do_single_step
364 #
365 sysc_singlestep:
366         ni      __TI_flags+3(%r9),255-_TIF_SINGLE_STEP # clear TIF_SINGLE_STEP
367         mvi     SP_SVCNR(%r15),0xff     # set trap indication to pgm check
368         mvi     SP_SVCNR+1(%r15),0xff
369         la      %r2,SP_PTREGS(%r15)     # address of register-save area
370         l       %r1,BASED(.Lhandle_per) # load adr. of per handler
371         la      %r14,BASED(sysc_return) # load adr. of system return
372         br      %r1                     # branch to do_single_step
373
374 #
375 # call tracehook_report_syscall_entry/tracehook_report_syscall_exit before
376 # and after the system call
377 #
378 sysc_tracesys:
379         l       %r1,BASED(.Ltrace_entry)
380         la      %r2,SP_PTREGS(%r15)     # load pt_regs
381         la      %r3,0
382         srl     %r7,2
383         st      %r7,SP_R2(%r15)
384         basr    %r14,%r1
385         cl      %r2,BASED(.Lnr_syscalls)
386         bnl     BASED(sysc_tracenogo)
387         l       %r8,BASED(.Lsysc_table)
388         lr      %r7,%r2
389         sll     %r7,2                   # svc number *4
390         l       %r8,0(%r7,%r8)
391 sysc_tracego:
392         lm      %r3,%r6,SP_R3(%r15)
393         l       %r2,SP_ORIG_R2(%r15)
394         basr    %r14,%r8                # call sys_xxx
395         st      %r2,SP_R2(%r15)         # store return value
396 sysc_tracenogo:
397         tm      __TI_flags+2(%r9),_TIF_SYSCALL
398         bz      BASED(sysc_return)
399         l       %r1,BASED(.Ltrace_exit)
400         la      %r2,SP_PTREGS(%r15)     # load pt_regs
401         la      %r14,BASED(sysc_return)
402         br      %r1
403
404 #
405 # a new process exits the kernel with ret_from_fork
406 #
407         .globl  ret_from_fork
408 ret_from_fork:
409         l       %r13,__LC_SVC_NEW_PSW+4
410         l       %r9,__LC_THREAD_INFO    # load pointer to thread_info struct
411         tm      SP_PSW+1(%r15),0x01     # forking a kernel thread ?
412         bo      BASED(0f)
413         st      %r15,SP_R15(%r15)       # store stack pointer for new kthread
414 0:      l       %r1,BASED(.Lschedtail)
415         basr    %r14,%r1
416         TRACE_IRQS_ON
417         stosm   __SF_EMPTY(%r15),0x03   # reenable interrupts
418         b       BASED(sysc_tracenogo)
419
420 #
421 # kernel_execve function needs to deal with pt_regs that is not
422 # at the usual place
423 #
424         .globl  kernel_execve
425 kernel_execve:
426         stm     %r12,%r15,48(%r15)
427         lr      %r14,%r15
428         l       %r13,__LC_SVC_NEW_PSW+4
429         s       %r15,BASED(.Lc_spsize)
430         st      %r14,__SF_BACKCHAIN(%r15)
431         la      %r12,SP_PTREGS(%r15)
432         xc      0(__PT_SIZE,%r12),0(%r12)
433         l       %r1,BASED(.Ldo_execve)
434         lr      %r5,%r12
435         basr    %r14,%r1
436         ltr     %r2,%r2
437         be      BASED(0f)
438         a       %r15,BASED(.Lc_spsize)
439         lm      %r12,%r15,48(%r15)
440         br      %r14
441         # execve succeeded.
442 0:      stnsm   __SF_EMPTY(%r15),0xfc   # disable interrupts
443         TRACE_IRQS_OFF
444         l       %r15,__LC_KERNEL_STACK  # load ksp
445         s       %r15,BASED(.Lc_spsize)  # make room for registers & psw
446         l       %r9,__LC_THREAD_INFO
447         mvc     SP_PTREGS(__PT_SIZE,%r15),0(%r12)       # copy pt_regs
448         xc      __SF_BACKCHAIN(4,%r15),__SF_BACKCHAIN(%r15)
449         TRACE_IRQS_ON
450         stosm   __SF_EMPTY(%r15),0x03   # reenable interrupts
451         l       %r1,BASED(.Lexecve_tail)
452         basr    %r14,%r1
453         b       BASED(sysc_return)
454
455 /*
456  * Program check handler routine
457  */
458
459         .globl  pgm_check_handler
460 pgm_check_handler:
461 /*
462  * First we need to check for a special case:
463  * Single stepping an instruction that disables the PER event mask will
464  * cause a PER event AFTER the mask has been set. Example: SVC or LPSW.
465  * For a single stepped SVC the program check handler gets control after
466  * the SVC new PSW has been loaded. But we want to execute the SVC first and
467  * then handle the PER event. Therefore we update the SVC old PSW to point
468  * to the pgm_check_handler and branch to the SVC handler after we checked
469  * if we have to load the kernel stack register.
470  * For every other possible cause for PER event without the PER mask set
471  * we just ignore the PER event (FIXME: is there anything we have to do
472  * for LPSW?).
473  */
474         stpt    __LC_SYNC_ENTER_TIMER
475         SAVE_ALL_BASE __LC_SAVE_AREA
476         tm      __LC_PGM_INT_CODE+1,0x80 # check whether we got a per exception
477         bnz     BASED(pgm_per)          # got per exception -> special case
478         SAVE_ALL_SYNC __LC_PGM_OLD_PSW,__LC_SAVE_AREA
479         CREATE_STACK_FRAME __LC_PGM_OLD_PSW,__LC_SAVE_AREA
480         tm      SP_PSW+1(%r15),0x01     # interrupting from user ?
481         bz      BASED(pgm_no_vtime)
482         UPDATE_VTIME __LC_EXIT_TIMER,__LC_SYNC_ENTER_TIMER,__LC_USER_TIMER
483         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
484         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
485 pgm_no_vtime:
486         TRACE_IRQS_CHECK_OFF
487         l       %r9,__LC_THREAD_INFO    # load pointer to thread_info struct
488         l       %r3,__LC_PGM_ILC        # load program interruption code
489         la      %r8,0x7f
490         nr      %r8,%r3
491 pgm_do_call:
492         l       %r7,BASED(.Ljump_table)
493         sll     %r8,2
494         l       %r7,0(%r8,%r7)          # load address of handler routine
495         la      %r2,SP_PTREGS(%r15)     # address of register-save area
496         basr    %r14,%r7                # branch to interrupt-handler
497 pgm_exit:
498         TRACE_IRQS_CHECK_ON
499         b       BASED(sysc_return)
500
501 #
502 # handle per exception
503 #
504 pgm_per:
505         tm      __LC_PGM_OLD_PSW,0x40   # test if per event recording is on
506         bnz     BASED(pgm_per_std)      # ok, normal per event from user space
507 # ok its one of the special cases, now we need to find out which one
508         clc     __LC_PGM_OLD_PSW(8),__LC_SVC_NEW_PSW
509         be      BASED(pgm_svcper)
510 # no interesting special case, ignore PER event
511         lm      %r12,%r15,__LC_SAVE_AREA
512         lpsw    0x28
513
514 #
515 # Normal per exception
516 #
517 pgm_per_std:
518         SAVE_ALL_SYNC __LC_PGM_OLD_PSW,__LC_SAVE_AREA
519         CREATE_STACK_FRAME __LC_PGM_OLD_PSW,__LC_SAVE_AREA
520         tm      SP_PSW+1(%r15),0x01     # interrupting from user ?
521         bz      BASED(pgm_no_vtime2)
522         UPDATE_VTIME __LC_EXIT_TIMER,__LC_SYNC_ENTER_TIMER,__LC_USER_TIMER
523         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
524         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
525 pgm_no_vtime2:
526         TRACE_IRQS_CHECK_OFF
527         l       %r9,__LC_THREAD_INFO    # load pointer to thread_info struct
528         l       %r1,__TI_task(%r9)
529         tm      SP_PSW+1(%r15),0x01     # kernel per event ?
530         bz      BASED(kernel_per)
531         mvc     __THREAD_per+__PER_atmid(2,%r1),__LC_PER_ATMID
532         mvc     __THREAD_per+__PER_address(4,%r1),__LC_PER_ADDRESS
533         mvc     __THREAD_per+__PER_access_id(1,%r1),__LC_PER_ACCESS_ID
534         oi      __TI_flags+3(%r9),_TIF_SINGLE_STEP # set TIF_SINGLE_STEP
535         l       %r3,__LC_PGM_ILC        # load program interruption code
536         la      %r8,0x7f
537         nr      %r8,%r3                 # clear per-event-bit and ilc
538         be      BASED(pgm_exit)         # only per or per+check ?
539         b       BASED(pgm_do_call)
540
541 #
542 # it was a single stepped SVC that is causing all the trouble
543 #
544 pgm_svcper:
545         SAVE_ALL_SYNC __LC_SVC_OLD_PSW,__LC_SAVE_AREA
546         CREATE_STACK_FRAME __LC_SVC_OLD_PSW,__LC_SAVE_AREA
547         UPDATE_VTIME __LC_EXIT_TIMER,__LC_SYNC_ENTER_TIMER,__LC_USER_TIMER
548         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
549         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
550         lh      %r7,0x8a                # get svc number from lowcore
551         l       %r9,__LC_THREAD_INFO    # load pointer to thread_info struct
552         TRACE_IRQS_OFF
553         l       %r8,__TI_task(%r9)
554         mvc     __THREAD_per+__PER_atmid(2,%r8),__LC_PER_ATMID
555         mvc     __THREAD_per+__PER_address(4,%r8),__LC_PER_ADDRESS
556         mvc     __THREAD_per+__PER_access_id(1,%r8),__LC_PER_ACCESS_ID
557         oi      __TI_flags+3(%r9),_TIF_SINGLE_STEP # set TIF_SINGLE_STEP
558         TRACE_IRQS_ON
559         stosm   __SF_EMPTY(%r15),0x03   # reenable interrupts
560         lm      %r2,%r6,SP_R2(%r15)     # load svc arguments
561         b       BASED(sysc_do_svc)
562
563 #
564 # per was called from kernel, must be kprobes
565 #
566 kernel_per:
567         mvi     SP_SVCNR(%r15),0xff     # set trap indication to pgm check
568         mvi     SP_SVCNR+1(%r15),0xff
569         la      %r2,SP_PTREGS(%r15)     # address of register-save area
570         l       %r1,BASED(.Lhandle_per) # load adr. of per handler
571         basr    %r14,%r1                # branch to do_single_step
572         b       BASED(pgm_exit)
573
574 /*
575  * IO interrupt handler routine
576  */
577
578         .globl io_int_handler
579 io_int_handler:
580         stck    __LC_INT_CLOCK
581         stpt    __LC_ASYNC_ENTER_TIMER
582         SAVE_ALL_BASE __LC_SAVE_AREA+16
583         SAVE_ALL_ASYNC __LC_IO_OLD_PSW,__LC_SAVE_AREA+16
584         CREATE_STACK_FRAME __LC_IO_OLD_PSW,__LC_SAVE_AREA+16
585         tm      SP_PSW+1(%r15),0x01     # interrupting from user ?
586         bz      BASED(io_no_vtime)
587         UPDATE_VTIME __LC_EXIT_TIMER,__LC_ASYNC_ENTER_TIMER,__LC_USER_TIMER
588         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
589         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_ASYNC_ENTER_TIMER
590 io_no_vtime:
591         TRACE_IRQS_OFF
592         l       %r9,__LC_THREAD_INFO    # load pointer to thread_info struct
593         l       %r1,BASED(.Ldo_IRQ)     # load address of do_IRQ
594         la      %r2,SP_PTREGS(%r15)     # address of register-save area
595         basr    %r14,%r1                # branch to standard irq handler
596 io_return:
597         LOCKDEP_SYS_EXIT
598         TRACE_IRQS_ON
599 io_tif:
600         tm      __TI_flags+3(%r9),_TIF_WORK_INT
601         bnz     BASED(io_work)          # there is work to do (signals etc.)
602 io_restore:
603         RESTORE_ALL __LC_RETURN_PSW,0
604 io_done:
605
606 #
607 # There is work todo, find out in which context we have been interrupted:
608 # 1) if we return to user space we can do all _TIF_WORK_INT work
609 # 2) if we return to kernel code and preemptive scheduling is enabled check
610 #    the preemption counter and if it is zero call preempt_schedule_irq
611 # Before any work can be done, a switch to the kernel stack is required.
612 #
613 io_work:
614         tm      SP_PSW+1(%r15),0x01     # returning to user ?
615         bo      BASED(io_work_user)     # yes -> do resched & signal
616 #ifdef CONFIG_PREEMPT
617         # check for preemptive scheduling
618         icm     %r0,15,__TI_precount(%r9)
619         bnz     BASED(io_restore)       # preemption disabled
620         tm      __TI_flags+3(%r9),_TIF_NEED_RESCHED
621         bno     BASED(io_restore)
622         # switch to kernel stack
623         l       %r1,SP_R15(%r15)
624         s       %r1,BASED(.Lc_spsize)
625         mvc     SP_PTREGS(__PT_SIZE,%r1),SP_PTREGS(%r15)
626         xc      __SF_BACKCHAIN(4,%r1),__SF_BACKCHAIN(%r1) # clear back chain
627         lr      %r15,%r1
628         # TRACE_IRQS_ON already done at io_return, call
629         # TRACE_IRQS_OFF to keep things symmetrical
630         TRACE_IRQS_OFF
631         l       %r1,BASED(.Lpreempt_schedule_irq)
632         basr    %r14,%r1                # call preempt_schedule_irq
633         b       BASED(io_return)
634 #else
635         b       BASED(io_restore)
636 #endif
637
638 #
639 # Need to do work before returning to userspace, switch to kernel stack
640 #
641 io_work_user:
642         l       %r1,__LC_KERNEL_STACK
643         s       %r1,BASED(.Lc_spsize)
644         mvc     SP_PTREGS(__PT_SIZE,%r1),SP_PTREGS(%r15)
645         xc      __SF_BACKCHAIN(4,%r1),__SF_BACKCHAIN(%r1) # clear back chain
646         lr      %r15,%r1
647
648 #
649 # One of the work bits is on. Find out which one.
650 # Checked are: _TIF_SIGPENDING, _TIF_NOTIFY_RESUME, _TIF_NEED_RESCHED
651 #               and _TIF_MCCK_PENDING
652 #
653 io_work_tif:
654         tm      __TI_flags+3(%r9),_TIF_MCCK_PENDING
655         bo      BASED(io_mcck_pending)
656         tm      __TI_flags+3(%r9),_TIF_NEED_RESCHED
657         bo      BASED(io_reschedule)
658         tm      __TI_flags+3(%r9),_TIF_SIGPENDING
659         bo      BASED(io_sigpending)
660         tm      __TI_flags+3(%r9),_TIF_NOTIFY_RESUME
661         bo      BASED(io_notify_resume)
662         b       BASED(io_return)        # beware of critical section cleanup
663
664 #
665 # _TIF_MCCK_PENDING is set, call handler
666 #
667 io_mcck_pending:
668         # TRACE_IRQS_ON already done at io_return
669         l       %r1,BASED(.Ls390_handle_mcck)
670         basr    %r14,%r1                # TIF bit will be cleared by handler
671         TRACE_IRQS_OFF
672         b       BASED(io_return)
673
674 #
675 # _TIF_NEED_RESCHED is set, call schedule
676 #
677 io_reschedule:
678         # TRACE_IRQS_ON already done at io_return
679         l       %r1,BASED(.Lschedule)
680         stosm   __SF_EMPTY(%r15),0x03   # reenable interrupts
681         basr    %r14,%r1                # call scheduler
682         stnsm   __SF_EMPTY(%r15),0xfc   # disable I/O and ext. interrupts
683         TRACE_IRQS_OFF
684         b       BASED(io_return)
685
686 #
687 # _TIF_SIGPENDING is set, call do_signal
688 #
689 io_sigpending:
690         # TRACE_IRQS_ON already done at io_return
691         stosm   __SF_EMPTY(%r15),0x03   # reenable interrupts
692         la      %r2,SP_PTREGS(%r15)     # load pt_regs
693         l       %r1,BASED(.Ldo_signal)
694         basr    %r14,%r1                # call do_signal
695         stnsm   __SF_EMPTY(%r15),0xfc   # disable I/O and ext. interrupts
696         TRACE_IRQS_OFF
697         b       BASED(io_return)
698
699 #
700 # _TIF_SIGPENDING is set, call do_signal
701 #
702 io_notify_resume:
703         # TRACE_IRQS_ON already done at io_return
704         stosm   __SF_EMPTY(%r15),0x03   # reenable interrupts
705         la      %r2,SP_PTREGS(%r15)     # load pt_regs
706         l       %r1,BASED(.Ldo_notify_resume)
707         basr    %r14,%r1                # call do_signal
708         stnsm   __SF_EMPTY(%r15),0xfc   # disable I/O and ext. interrupts
709         TRACE_IRQS_OFF
710         b       BASED(io_return)
711
712 /*
713  * External interrupt handler routine
714  */
715
716         .globl  ext_int_handler
717 ext_int_handler:
718         stck    __LC_INT_CLOCK
719         stpt    __LC_ASYNC_ENTER_TIMER
720         SAVE_ALL_BASE __LC_SAVE_AREA+16
721         SAVE_ALL_ASYNC __LC_EXT_OLD_PSW,__LC_SAVE_AREA+16
722         CREATE_STACK_FRAME __LC_EXT_OLD_PSW,__LC_SAVE_AREA+16
723         tm      SP_PSW+1(%r15),0x01     # interrupting from user ?
724         bz      BASED(ext_no_vtime)
725         UPDATE_VTIME __LC_EXIT_TIMER,__LC_ASYNC_ENTER_TIMER,__LC_USER_TIMER
726         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
727         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_ASYNC_ENTER_TIMER
728 ext_no_vtime:
729         l       %r9,__LC_THREAD_INFO    # load pointer to thread_info struct
730         TRACE_IRQS_OFF
731         la      %r2,SP_PTREGS(%r15)     # address of register-save area
732         lh      %r3,__LC_EXT_INT_CODE   # get interruption code
733         l       %r1,BASED(.Ldo_extint)
734         basr    %r14,%r1
735         b       BASED(io_return)
736
737 __critical_end:
738
739 /*
740  * Machine check handler routines
741  */
742
743         .globl mcck_int_handler
744 mcck_int_handler:
745         stck    __LC_INT_CLOCK
746         spt     __LC_CPU_TIMER_SAVE_AREA        # revalidate cpu timer
747         lm      %r0,%r15,__LC_GPREGS_SAVE_AREA  # revalidate gprs
748         SAVE_ALL_BASE __LC_SAVE_AREA+32
749         la      %r12,__LC_MCK_OLD_PSW
750         tm      __LC_MCCK_CODE,0x80     # system damage?
751         bo      BASED(mcck_int_main)    # yes -> rest of mcck code invalid
752         mvc     __LC_SAVE_AREA+52(8),__LC_ASYNC_ENTER_TIMER
753         mvc     __LC_ASYNC_ENTER_TIMER(8),__LC_CPU_TIMER_SAVE_AREA
754         tm      __LC_MCCK_CODE+5,0x02   # stored cpu timer value valid?
755         bo      BASED(1f)
756         la      %r14,__LC_SYNC_ENTER_TIMER
757         clc     0(8,%r14),__LC_ASYNC_ENTER_TIMER
758         bl      BASED(0f)
759         la      %r14,__LC_ASYNC_ENTER_TIMER
760 0:      clc     0(8,%r14),__LC_EXIT_TIMER
761         bl      BASED(0f)
762         la      %r14,__LC_EXIT_TIMER
763 0:      clc     0(8,%r14),__LC_LAST_UPDATE_TIMER
764         bl      BASED(0f)
765         la      %r14,__LC_LAST_UPDATE_TIMER
766 0:      spt     0(%r14)
767         mvc     __LC_ASYNC_ENTER_TIMER(8),0(%r14)
768 1:      tm      __LC_MCCK_CODE+2,0x09   # mwp + ia of old psw valid?
769         bno     BASED(mcck_int_main)    # no -> skip cleanup critical
770         tm      __LC_MCK_OLD_PSW+1,0x01 # test problem state bit
771         bnz     BASED(mcck_int_main)    # from user -> load async stack
772         clc     __LC_MCK_OLD_PSW+4(4),BASED(.Lcritical_end)
773         bhe     BASED(mcck_int_main)
774         clc     __LC_MCK_OLD_PSW+4(4),BASED(.Lcritical_start)
775         bl      BASED(mcck_int_main)
776         l       %r14,BASED(.Lcleanup_critical)
777         basr    %r14,%r14
778 mcck_int_main:
779         l       %r14,__LC_PANIC_STACK   # are we already on the panic stack?
780         slr     %r14,%r15
781         sra     %r14,PAGE_SHIFT
782         be      BASED(0f)
783         l       %r15,__LC_PANIC_STACK   # load panic stack
784 0:      CREATE_STACK_FRAME __LC_MCK_OLD_PSW,__LC_SAVE_AREA+32
785         tm      __LC_MCCK_CODE+2,0x08   # mwp of old psw valid?
786         bno     BASED(mcck_no_vtime)    # no -> skip cleanup critical
787         tm      SP_PSW+1(%r15),0x01     # interrupting from user ?
788         bz      BASED(mcck_no_vtime)
789         UPDATE_VTIME __LC_EXIT_TIMER,__LC_ASYNC_ENTER_TIMER,__LC_USER_TIMER
790         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
791         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_ASYNC_ENTER_TIMER
792 mcck_no_vtime:
793         l       %r9,__LC_THREAD_INFO    # load pointer to thread_info struct
794         la      %r2,SP_PTREGS(%r15)     # load pt_regs
795         l       %r1,BASED(.Ls390_mcck)
796         basr    %r14,%r1                # call machine check handler
797         tm      SP_PSW+1(%r15),0x01     # returning to user ?
798         bno     BASED(mcck_return)
799         l       %r1,__LC_KERNEL_STACK   # switch to kernel stack
800         s       %r1,BASED(.Lc_spsize)
801         mvc     SP_PTREGS(__PT_SIZE,%r1),SP_PTREGS(%r15)
802         xc      __SF_BACKCHAIN(4,%r1),__SF_BACKCHAIN(%r1) # clear back chain
803         lr      %r15,%r1
804         stosm   __SF_EMPTY(%r15),0x04   # turn dat on
805         tm      __TI_flags+3(%r9),_TIF_MCCK_PENDING
806         bno     BASED(mcck_return)
807         TRACE_IRQS_OFF
808         l       %r1,BASED(.Ls390_handle_mcck)
809         basr    %r14,%r1                # call machine check handler
810         TRACE_IRQS_ON
811 mcck_return:
812         mvc     __LC_RETURN_MCCK_PSW(8),SP_PSW(%r15) # move return PSW
813         ni      __LC_RETURN_MCCK_PSW+1,0xfd # clear wait state bit
814         mvc     __LC_ASYNC_ENTER_TIMER(8),__LC_SAVE_AREA+52
815         tm      __LC_RETURN_MCCK_PSW+1,0x01 # returning to user ?
816         bno     BASED(0f)
817         lm      %r0,%r15,SP_R0(%r15)    # load gprs 0-15
818         stpt    __LC_EXIT_TIMER
819         lpsw    __LC_RETURN_MCCK_PSW    # back to caller
820 0:      lm      %r0,%r15,SP_R0(%r15)    # load gprs 0-15
821         lpsw    __LC_RETURN_MCCK_PSW    # back to caller
822
823         RESTORE_ALL __LC_RETURN_MCCK_PSW,0
824
825 /*
826  * Restart interruption handler, kick starter for additional CPUs
827  */
828 #ifdef CONFIG_SMP
829         __CPUINIT
830         .globl restart_int_handler
831 restart_int_handler:
832         basr    %r1,0
833 restart_base:
834         spt     restart_vtime-restart_base(%r1)
835         stck    __LC_LAST_UPDATE_CLOCK
836         mvc     __LC_LAST_UPDATE_TIMER(8),restart_vtime-restart_base(%r1)
837         mvc     __LC_EXIT_TIMER(8),restart_vtime-restart_base(%r1)
838         l       %r15,__LC_SAVE_AREA+60  # load ksp
839         lctl    %c0,%c15,__LC_CREGS_SAVE_AREA # get new ctl regs
840         lam     %a0,%a15,__LC_AREGS_SAVE_AREA
841         lm      %r6,%r15,__SF_GPRS(%r15) # load registers from clone
842         l       %r1,__LC_THREAD_INFO
843         mvc     __LC_USER_TIMER(8),__TI_user_timer(%r1)
844         mvc     __LC_SYSTEM_TIMER(8),__TI_system_timer(%r1)
845         xc      __LC_STEAL_TIMER(8),__LC_STEAL_TIMER
846         stosm   __SF_EMPTY(%r15),0x04   # now we can turn dat on
847         basr    %r14,0
848         l       %r14,restart_addr-.(%r14)
849         br      %r14                    # branch to start_secondary
850 restart_addr:
851         .long   start_secondary
852         .align  8
853 restart_vtime:
854         .long   0x7fffffff,0xffffffff
855         .previous
856 #else
857 /*
858  * If we do not run with SMP enabled, let the new CPU crash ...
859  */
860         .globl restart_int_handler
861 restart_int_handler:
862         basr    %r1,0
863 restart_base:
864         lpsw    restart_crash-restart_base(%r1)
865         .align  8
866 restart_crash:
867         .long   0x000a0000,0x00000000
868 restart_go:
869 #endif
870
871 #ifdef CONFIG_CHECK_STACK
872 /*
873  * The synchronous or the asynchronous stack overflowed. We are dead.
874  * No need to properly save the registers, we are going to panic anyway.
875  * Setup a pt_regs so that show_trace can provide a good call trace.
876  */
877 stack_overflow:
878         l       %r15,__LC_PANIC_STACK   # change to panic stack
879         sl      %r15,BASED(.Lc_spsize)
880         mvc     SP_PSW(8,%r15),0(%r12)  # move user PSW to stack
881         stm     %r0,%r11,SP_R0(%r15)    # store gprs %r0-%r11 to kernel stack
882         la      %r1,__LC_SAVE_AREA
883         ch      %r12,BASED(.L0x020)     # old psw addr == __LC_SVC_OLD_PSW ?
884         be      BASED(0f)
885         ch      %r12,BASED(.L0x028)     # old psw addr == __LC_PGM_OLD_PSW ?
886         be      BASED(0f)
887         la      %r1,__LC_SAVE_AREA+16
888 0:      mvc     SP_R12(16,%r15),0(%r1)  # move %r12-%r15 to stack
889         xc      __SF_BACKCHAIN(4,%r15),__SF_BACKCHAIN(%r15) # clear back chain
890         l       %r1,BASED(1f)           # branch to kernel_stack_overflow
891         la      %r2,SP_PTREGS(%r15)     # load pt_regs
892         br      %r1
893 1:      .long   kernel_stack_overflow
894 #endif
895
896 cleanup_table_system_call:
897         .long   system_call + 0x80000000, sysc_do_svc + 0x80000000
898 cleanup_table_sysc_tif:
899         .long   sysc_tif + 0x80000000, sysc_restore + 0x80000000
900 cleanup_table_sysc_restore:
901         .long   sysc_restore + 0x80000000, sysc_done + 0x80000000
902 cleanup_table_io_tif:
903         .long   io_tif + 0x80000000, io_restore + 0x80000000
904 cleanup_table_io_restore:
905         .long   io_restore + 0x80000000, io_done + 0x80000000
906
907 cleanup_critical:
908         clc     4(4,%r12),BASED(cleanup_table_system_call)
909         bl      BASED(0f)
910         clc     4(4,%r12),BASED(cleanup_table_system_call+4)
911         bl      BASED(cleanup_system_call)
912 0:
913         clc     4(4,%r12),BASED(cleanup_table_sysc_tif)
914         bl      BASED(0f)
915         clc     4(4,%r12),BASED(cleanup_table_sysc_tif+4)
916         bl      BASED(cleanup_sysc_tif)
917 0:
918         clc     4(4,%r12),BASED(cleanup_table_sysc_restore)
919         bl      BASED(0f)
920         clc     4(4,%r12),BASED(cleanup_table_sysc_restore+4)
921         bl      BASED(cleanup_sysc_restore)
922 0:
923         clc     4(4,%r12),BASED(cleanup_table_io_tif)
924         bl      BASED(0f)
925         clc     4(4,%r12),BASED(cleanup_table_io_tif+4)
926         bl      BASED(cleanup_io_tif)
927 0:
928         clc     4(4,%r12),BASED(cleanup_table_io_restore)
929         bl      BASED(0f)
930         clc     4(4,%r12),BASED(cleanup_table_io_restore+4)
931         bl      BASED(cleanup_io_restore)
932 0:
933         br      %r14
934
935 cleanup_system_call:
936         mvc     __LC_RETURN_PSW(8),0(%r12)
937         c       %r12,BASED(.Lmck_old_psw)
938         be      BASED(0f)
939         la      %r12,__LC_SAVE_AREA+16
940         b       BASED(1f)
941 0:      la      %r12,__LC_SAVE_AREA+32
942 1:
943         clc     __LC_RETURN_PSW+4(4),BASED(cleanup_system_call_insn+4)
944         bh      BASED(0f)
945         mvc     __LC_SYNC_ENTER_TIMER(8),__LC_ASYNC_ENTER_TIMER
946 0:      clc     __LC_RETURN_PSW+4(4),BASED(cleanup_system_call_insn+8)
947         bhe     BASED(cleanup_vtime)
948         clc     __LC_RETURN_PSW+4(4),BASED(cleanup_system_call_insn)
949         bh      BASED(0f)
950         mvc     __LC_SAVE_AREA(16),0(%r12)
951 0:      st      %r13,4(%r12)
952         st      %r12,__LC_SAVE_AREA+48  # argh
953         SAVE_ALL_SYNC __LC_SVC_OLD_PSW,__LC_SAVE_AREA
954         CREATE_STACK_FRAME __LC_SVC_OLD_PSW,__LC_SAVE_AREA
955         l       %r12,__LC_SAVE_AREA+48  # argh
956         st      %r15,12(%r12)
957         lh      %r7,0x8a
958 cleanup_vtime:
959         clc     __LC_RETURN_PSW+4(4),BASED(cleanup_system_call_insn+12)
960         bhe     BASED(cleanup_stime)
961         UPDATE_VTIME __LC_EXIT_TIMER,__LC_SYNC_ENTER_TIMER,__LC_USER_TIMER
962 cleanup_stime:
963         clc     __LC_RETURN_PSW+4(4),BASED(cleanup_system_call_insn+16)
964         bh      BASED(cleanup_update)
965         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
966 cleanup_update:
967         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
968         mvc     __LC_RETURN_PSW+4(4),BASED(cleanup_table_system_call+4)
969         la      %r12,__LC_RETURN_PSW
970         br      %r14
971 cleanup_system_call_insn:
972         .long   sysc_saveall + 0x80000000
973         .long   system_call + 0x80000000
974         .long   sysc_vtime + 0x80000000
975         .long   sysc_stime + 0x80000000
976         .long   sysc_update + 0x80000000
977
978 cleanup_sysc_tif:
979         mvc     __LC_RETURN_PSW(4),0(%r12)
980         mvc     __LC_RETURN_PSW+4(4),BASED(cleanup_table_sysc_tif)
981         la      %r12,__LC_RETURN_PSW
982         br      %r14
983
984 cleanup_sysc_restore:
985         clc     4(4,%r12),BASED(cleanup_sysc_restore_insn)
986         be      BASED(2f)
987         mvc     __LC_EXIT_TIMER(8),__LC_ASYNC_ENTER_TIMER
988         clc     4(4,%r12),BASED(cleanup_sysc_restore_insn+4)
989         be      BASED(2f)
990         mvc     __LC_RETURN_PSW(8),SP_PSW(%r15)
991         c       %r12,BASED(.Lmck_old_psw)
992         bne     BASED(0f)
993         mvc     __LC_SAVE_AREA+32(16),SP_R12(%r15)
994         b       BASED(1f)
995 0:      mvc     __LC_SAVE_AREA+16(16),SP_R12(%r15)
996 1:      lm      %r0,%r11,SP_R0(%r15)
997         l       %r15,SP_R15(%r15)
998 2:      la      %r12,__LC_RETURN_PSW
999         br      %r14
1000 cleanup_sysc_restore_insn:
1001         .long   sysc_done - 4 + 0x80000000
1002         .long   sysc_done - 8 + 0x80000000
1003
1004 cleanup_io_tif:
1005         mvc     __LC_RETURN_PSW(4),0(%r12)
1006         mvc     __LC_RETURN_PSW+4(4),BASED(cleanup_table_io_tif)
1007         la      %r12,__LC_RETURN_PSW
1008         br      %r14
1009
1010 cleanup_io_restore:
1011         clc     4(4,%r12),BASED(cleanup_io_restore_insn)
1012         be      BASED(2f)
1013         mvc     __LC_EXIT_TIMER(8),__LC_ASYNC_ENTER_TIMER
1014         clc     4(4,%r12),BASED(cleanup_io_restore_insn+4)
1015         be      BASED(2f)
1016         mvc     __LC_RETURN_PSW(8),SP_PSW(%r15)
1017         c       %r12,BASED(.Lmck_old_psw)
1018         bne     BASED(0f)
1019         mvc     __LC_SAVE_AREA+32(16),SP_R12(%r15)
1020         b       BASED(1f)
1021 0:      mvc     __LC_SAVE_AREA+16(16),SP_R12(%r15)
1022 1:      lm      %r0,%r11,SP_R0(%r15)
1023         l       %r15,SP_R15(%r15)
1024 2:      la      %r12,__LC_RETURN_PSW
1025         br      %r14
1026 cleanup_io_restore_insn:
1027         .long   io_done - 4 + 0x80000000
1028         .long   io_done - 8 + 0x80000000
1029
1030 /*
1031  * Integer constants
1032  */
1033                 .align  4
1034 .Lc_spsize:     .long   SP_SIZE
1035 .Lc_overhead:   .long   STACK_FRAME_OVERHEAD
1036 .Lnr_syscalls:  .long   NR_syscalls
1037 .L0x018:        .short  0x018
1038 .L0x020:        .short  0x020
1039 .L0x028:        .short  0x028
1040 .L0x030:        .short  0x030
1041 .L0x038:        .short  0x038
1042 .Lc_1:          .long   1
1043
1044 /*
1045  * Symbol constants
1046  */
1047 .Ls390_mcck:    .long   s390_do_machine_check
1048 .Ls390_handle_mcck:
1049                 .long   s390_handle_mcck
1050 .Lmck_old_psw:  .long   __LC_MCK_OLD_PSW
1051 .Ldo_IRQ:       .long   do_IRQ
1052 .Ldo_extint:    .long   do_extint
1053 .Ldo_signal:    .long   do_signal
1054 .Ldo_notify_resume:
1055                 .long   do_notify_resume
1056 .Lhandle_per:   .long   do_single_step
1057 .Ldo_execve:    .long   do_execve
1058 .Lexecve_tail:  .long   execve_tail
1059 .Ljump_table:   .long   pgm_check_table
1060 .Lschedule:     .long   schedule
1061 #ifdef CONFIG_PREEMPT
1062 .Lpreempt_schedule_irq:
1063                 .long   preempt_schedule_irq
1064 #endif
1065 .Ltrace_entry:  .long   do_syscall_trace_enter
1066 .Ltrace_exit:   .long   do_syscall_trace_exit
1067 .Lschedtail:    .long   schedule_tail
1068 .Lsysc_table:   .long   sys_call_table
1069 #ifdef CONFIG_TRACE_IRQFLAGS
1070 .Ltrace_irq_on_caller:
1071                 .long   trace_hardirqs_on_caller
1072 .Ltrace_irq_off_caller:
1073                 .long   trace_hardirqs_off_caller
1074 #endif
1075 #ifdef CONFIG_LOCKDEP
1076 .Llockdep_sys_exit:
1077                 .long   lockdep_sys_exit
1078 #endif
1079 .Lcritical_start:
1080                 .long   __critical_start + 0x80000000
1081 .Lcritical_end:
1082                 .long   __critical_end + 0x80000000
1083 .Lcleanup_critical:
1084                 .long   cleanup_critical
1085
1086                 .section .rodata, "a"
1087 #define SYSCALL(esa,esame,emu)  .long esa
1088         .globl  sys_call_table
1089 sys_call_table:
1090 #include "syscalls.S"
1091 #undef SYSCALL