sh: romImage support V2
[linux-2.6.git] / arch / powerpc / lib / copypage_64.S
1 /*
2  * Copyright (C) 2008 Mark Nelson, IBM Corp.
3  *
4  * This program is free software; you can redistribute it and/or
5  * modify it under the terms of the GNU General Public License
6  * as published by the Free Software Foundation; either version
7  * 2 of the License, or (at your option) any later version.
8  */
9 #include <asm/processor.h>
10 #include <asm/ppc_asm.h>
11 #include <asm/asm-offsets.h>
12
13         .section        ".toc","aw"
14 PPC64_CACHES:
15         .tc             ppc64_caches[TC],ppc64_caches
16         .section        ".text"
17
18
19 _GLOBAL(copy_4K_page)
20         li      r5,4096         /* 4K page size */
21 BEGIN_FTR_SECTION
22         ld      r10,PPC64_CACHES@toc(r2)
23         lwz     r11,DCACHEL1LOGLINESIZE(r10)    /* log2 of cache line size */
24         lwz     r12,DCACHEL1LINESIZE(r10)       /* get cache line size */
25         li      r9,0
26         srd     r8,r5,r11
27
28         mtctr   r8
29 setup:
30         dcbt    r9,r4
31         dcbz    r9,r3
32         add     r9,r9,r12
33         bdnz    setup
34 END_FTR_SECTION_IFSET(CPU_FTR_CP_USE_DCBTZ)
35         addi    r3,r3,-8
36         srdi    r8,r5,7         /* page is copied in 128 byte strides */
37         addi    r8,r8,-1        /* one stride copied outside loop */
38
39         mtctr   r8
40
41         ld      r5,0(r4)
42         ld      r6,8(r4)
43         ld      r7,16(r4)
44         ldu     r8,24(r4)
45 1:      std     r5,8(r3)
46         ld      r9,8(r4)
47         std     r6,16(r3)
48         ld      r10,16(r4)
49         std     r7,24(r3)
50         ld      r11,24(r4)
51         std     r8,32(r3)
52         ld      r12,32(r4)
53         std     r9,40(r3)
54         ld      r5,40(r4)
55         std     r10,48(r3)
56         ld      r6,48(r4)
57         std     r11,56(r3)
58         ld      r7,56(r4)
59         std     r12,64(r3)
60         ld      r8,64(r4)
61         std     r5,72(r3)
62         ld      r9,72(r4)
63         std     r6,80(r3)
64         ld      r10,80(r4)
65         std     r7,88(r3)
66         ld      r11,88(r4)
67         std     r8,96(r3)
68         ld      r12,96(r4)
69         std     r9,104(r3)
70         ld      r5,104(r4)
71         std     r10,112(r3)
72         ld      r6,112(r4)
73         std     r11,120(r3)
74         ld      r7,120(r4)
75         stdu    r12,128(r3)
76         ldu     r8,128(r4)
77         bdnz    1b
78
79         std     r5,8(r3)
80         ld      r9,8(r4)
81         std     r6,16(r3)
82         ld      r10,16(r4)
83         std     r7,24(r3)
84         ld      r11,24(r4)
85         std     r8,32(r3)
86         ld      r12,32(r4)
87         std     r9,40(r3)
88         ld      r5,40(r4)
89         std     r10,48(r3)
90         ld      r6,48(r4)
91         std     r11,56(r3)
92         ld      r7,56(r4)
93         std     r12,64(r3)
94         ld      r8,64(r4)
95         std     r5,72(r3)
96         ld      r9,72(r4)
97         std     r6,80(r3)
98         ld      r10,80(r4)
99         std     r7,88(r3)
100         ld      r11,88(r4)
101         std     r8,96(r3)
102         ld      r12,96(r4)
103         std     r9,104(r3)
104         std     r10,112(r3)
105         std     r11,120(r3)
106         std     r12,128(r3)
107         blr