m68knommu: generic irq handling
[linux-2.6.git] / arch / m68knommu / platform / 5307 / entry.S
1 /*
2  *  linux/arch/m68knommu/platform/5307/entry.S
3  *
4  *  Copyright (C) 1999-2007, Greg Ungerer (gerg@snapgear.com)
5  *  Copyright (C) 1998  D. Jeff Dionne <jeff@lineo.ca>,
6  *                      Kenneth Albanowski <kjahds@kjahds.com>,
7  *  Copyright (C) 2000  Lineo Inc. (www.lineo.com)
8  *  Copyright (C) 2004-2006  Macq Electronique SA. (www.macqel.com)
9  *
10  * Based on:
11  *
12  *  linux/arch/m68k/kernel/entry.S
13  *
14  *  Copyright (C) 1991, 1992  Linus Torvalds
15  *
16  * This file is subject to the terms and conditions of the GNU General Public
17  * License.  See the file README.legal in the main directory of this archive
18  * for more details.
19  *
20  * Linux/m68k support by Hamish Macdonald
21  *
22  * 68060 fixes by Jesper Skov
23  * ColdFire support by Greg Ungerer (gerg@snapgear.com)
24  * 5307 fixes by David W. Miller
25  * linux 2.4 support David McCullough <davidm@snapgear.com>
26  * Bug, speed and maintainability fixes by Philippe De Muyter <phdm@macqel.be>
27  */
28
29 #include <linux/sys.h>
30 #include <linux/linkage.h>
31 #include <asm/unistd.h>
32 #include <asm/thread_info.h>
33 #include <asm/errno.h>
34 #include <asm/setup.h>
35 #include <asm/segment.h>
36 #include <asm/asm-offsets.h>
37 #include <asm/entry.h>
38
39 .bss
40
41 sw_ksp:
42 .long   0
43
44 sw_usp:
45 .long   0
46
47 .text
48
49 .globl system_call
50 .globl resume
51 .globl ret_from_exception
52 .globl ret_from_signal
53 .globl sys_call_table
54 .globl ret_from_interrupt
55 .globl inthandler
56 .globl fasthandler
57
58 enosys:
59         mov.l   #sys_ni_syscall,%d3
60         bra     1f
61
62 ENTRY(system_call)
63         SAVE_ALL
64         move    #0x2000,%sr             /* enable intrs again */
65
66         cmpl    #NR_syscalls,%d0
67         jcc     enosys
68         lea     sys_call_table,%a0
69         lsll    #2,%d0                  /* movel %a0@(%d0:l:4),%d3 */
70         movel   %a0@(%d0),%d3
71         jeq     enosys
72
73 1:
74         movel   %sp,%d2                 /* get thread_info pointer */
75         andl    #-THREAD_SIZE,%d2       /* at start of kernel stack */
76         movel   %d2,%a0
77         movel   %sp,%a0@(THREAD_ESP0)   /* save top of frame */
78         btst    #(TIF_SYSCALL_TRACE%8),%a0@(TI_FLAGS+(31-TIF_SYSCALL_TRACE)/8)
79         bnes    1f
80
81         movel   %d3,%a0
82         jbsr    %a0@
83         movel   %d0,%sp@(PT_D0)         /* save the return value */
84         jra     ret_from_exception
85 1:
86         subql   #4,%sp
87         SAVE_SWITCH_STACK
88         jbsr    syscall_trace
89         RESTORE_SWITCH_STACK
90         addql   #4,%sp
91         movel   %d3,%a0
92         jbsr    %a0@
93         movel   %d0,%sp@(PT_D0)         /* save the return value */
94         subql   #4,%sp                  /* dummy return address */
95         SAVE_SWITCH_STACK
96         jbsr    syscall_trace
97
98 ret_from_signal:
99         RESTORE_SWITCH_STACK
100         addql   #4,%sp
101
102 ret_from_exception:
103         btst    #5,%sp@(PT_SR)          /* check if returning to kernel */
104         jeq     Luser_return            /* if so, skip resched, signals */
105
106 Lkernel_return:
107         moveml  %sp@,%d1-%d5/%a0-%a2
108         lea     %sp@(32),%sp            /* space for 8 regs */
109         movel   %sp@+,%d0
110         addql   #4,%sp                  /* orig d0 */
111         addl    %sp@+,%sp               /* stk adj */
112         rte
113
114 Luser_return:
115         movel   %sp,%d1                 /* get thread_info pointer */
116         andl    #-THREAD_SIZE,%d1       /* at base of kernel stack */
117         movel   %d1,%a0
118         movel   %a0@(TI_FLAGS),%d1      /* get thread_info->flags */
119         andl    #_TIF_WORK_MASK,%d1
120         jne     Lwork_to_do             /* still work to do */
121
122 Lreturn:
123         move    #0x2700,%sr             /* disable intrs */
124         movel   sw_usp,%a0              /* get usp */
125         movel   %sp@(PT_PC),%a0@-       /* copy exception program counter */
126         movel   %sp@(PT_FORMATVEC),%a0@-/* copy exception format/vector/sr */
127         moveml  %sp@,%d1-%d5/%a0-%a2
128         lea     %sp@(32),%sp            /* space for 8 regs */
129         movel   %sp@+,%d0
130         addql   #4,%sp                  /* orig d0 */
131         addl    %sp@+,%sp               /* stk adj */
132         addql   #8,%sp                  /* remove exception */
133         movel   %sp,sw_ksp              /* save ksp */
134         subql   #8,sw_usp               /* set exception */
135         movel   sw_usp,%sp              /* restore usp */
136         rte
137
138 Lwork_to_do:
139         movel   %a0@(TI_FLAGS),%d1      /* get thread_info->flags */
140         btst    #TIF_NEED_RESCHED,%d1
141         jne     reschedule
142
143         /* GERG: do we need something here for TRACEing?? */
144
145 Lsignal_return:
146         subql   #4,%sp                  /* dummy return address */
147         SAVE_SWITCH_STACK
148         pea     %sp@(SWITCH_STACK_SIZE)
149         clrl    %sp@-
150         jsr     do_signal
151         addql   #8,%sp
152         RESTORE_SWITCH_STACK
153         addql   #4,%sp
154         jmp     Lreturn
155
156 /*
157  * This is the generic interrupt handler (for all hardware interrupt
158  * sources). Calls upto high level code to do all the work.
159  */
160 ENTRY(inthandler)
161         SAVE_ALL
162         moveq   #-1,%d0
163         movel   %d0,%sp@(PT_ORIG_D0)
164
165         movew   %sp@(PT_FORMATVEC),%d0  /* put exception # in d0 */
166         andl    #0x03fc,%d0             /* mask out vector only */
167
168         movel   %sp,%sp@-               /* push regs arg */
169         lsrl    #2,%d0                  /* calculate real vector # */
170         movel   %d0,%sp@-               /* push vector number */
171         jbsr    do_IRQ                  /* call high level irq handler */
172         lea     %sp@(8),%sp             /* pop args off stack */
173
174         bra     ret_from_interrupt      /* this was fallthrough */
175
176 /*
177  * This is the fast interrupt handler (for certain hardware interrupt
178  * sources). Unlike the normal interrupt handler it just uses the
179  * current stack (doesn't care if it is user or kernel). It also
180  * doesn't bother doing the bottom half handlers.
181  */
182 ENTRY(fasthandler)
183         SAVE_LOCAL
184
185         movew   %sp@(PT_FORMATVEC),%d0
186         andl    #0x03fc,%d0             /* mask out vector only */
187
188         movel   %sp,%sp@-               /* push regs arg */
189         lsrl    #2,%d0                  /* calculate real vector # */
190         movel   %d0,%sp@-               /* push vector number */
191         jbsr    do_IRQ                  /* call high level irq handler */
192         lea     %sp@(8),%sp             /* pop args off stack */
193
194         RESTORE_LOCAL
195
196 ENTRY(ret_from_interrupt)
197         jeq     2f
198 1:
199         RESTORE_ALL
200 2:
201         moveb   %sp@(PT_SR),%d0
202         andl    #0x7,%d0
203         jhi     1b
204
205         /* check if we need to do software interrupts */
206         movel   irq_stat+CPUSTAT_SOFTIRQ_PENDING,%d0
207         jeq     ret_from_exception
208
209         pea     ret_from_exception
210         jmp     do_softirq
211
212 /*
213  * Beware - when entering resume, prev (the current task) is
214  * in a0, next (the new task) is in a1,so don't change these
215  * registers until their contents are no longer needed.
216  */
217 ENTRY(resume)
218         movel   %a0, %d1                        /* get prev thread in d1 */
219
220         movew   %sr,%d0                         /* save thread status reg */
221         movew   %d0,%a0@(TASK_THREAD+THREAD_SR)
222
223         oril    #0x700,%d0                      /* disable interrupts */
224         move    %d0,%sr
225
226         movel   sw_usp,%d0                      /* save usp */
227         movel   %d0,%a0@(TASK_THREAD+THREAD_USP)
228
229         SAVE_SWITCH_STACK
230         movel   %sp,%a0@(TASK_THREAD+THREAD_KSP) /* save kernel stack pointer */
231         movel   %a1@(TASK_THREAD+THREAD_KSP),%sp /* restore new thread stack */
232         RESTORE_SWITCH_STACK
233
234         movel   %a1@(TASK_THREAD+THREAD_USP),%a0 /* restore thread user stack */
235         movel   %a0, sw_usp
236
237         movew   %a1@(TASK_THREAD+THREAD_SR),%d0 /* restore thread status reg */
238         movew   %d0, %sr
239         rts