[PATCH] m68k: convert generic irq code to irq controller
[linux-2.6.git] / arch / m68k / kernel / entry.S
1 /* -*- mode: asm -*-
2  *
3  *  linux/arch/m68k/kernel/entry.S
4  *
5  *  Copyright (C) 1991, 1992  Linus Torvalds
6  *
7  * This file is subject to the terms and conditions of the GNU General Public
8  * License.  See the file README.legal in the main directory of this archive
9  * for more details.
10  *
11  * Linux/m68k support by Hamish Macdonald
12  *
13  * 68060 fixes by Jesper Skov
14  *
15  */
16
17 /*
18  * entry.S  contains the system-call and fault low-level handling routines.
19  * This also contains the timer-interrupt handler, as well as all interrupts
20  * and faults that can result in a task-switch.
21  *
22  * NOTE: This code handles signal-recognition, which happens every time
23  * after a timer-interrupt and after each system call.
24  *
25  */
26
27 /*
28  * 12/03/96 Jes: Currently we only support m68k single-cpu systems, so
29  *               all pointers that used to be 'current' are now entry
30  *               number 0 in the 'current_set' list.
31  *
32  *  6/05/00 RZ:  addedd writeback completion after return from sighandler
33  *               for 68040
34  */
35
36 #include <linux/config.h>
37 #include <linux/linkage.h>
38 #include <asm/entry.h>
39 #include <asm/errno.h>
40 #include <asm/setup.h>
41 #include <asm/segment.h>
42 #include <asm/traps.h>
43 #include <asm/unistd.h>
44
45 #include <asm/asm-offsets.h>
46
47 .globl system_call, buserr, trap, resume
48 .globl sys_call_table
49 .globl sys_fork, sys_clone, sys_vfork
50 .globl ret_from_interrupt, bad_interrupt
51 .globl auto_irqhandler_fixup
52 .globl user_irqvec_fixup, user_irqhandler_fixup
53
54 .text
55 ENTRY(buserr)
56         SAVE_ALL_INT
57         GET_CURRENT(%d0)
58         movel   %sp,%sp@-               | stack frame pointer argument
59         bsrl    buserr_c
60         addql   #4,%sp
61         jra     .Lret_from_exception
62
63 ENTRY(trap)
64         SAVE_ALL_INT
65         GET_CURRENT(%d0)
66         movel   %sp,%sp@-               | stack frame pointer argument
67         bsrl    trap_c
68         addql   #4,%sp
69         jra     .Lret_from_exception
70
71         | After a fork we jump here directly from resume,
72         | so that %d1 contains the previous task
73         | schedule_tail now used regardless of CONFIG_SMP
74 ENTRY(ret_from_fork)
75         movel   %d1,%sp@-
76         jsr     schedule_tail
77         addql   #4,%sp
78         jra     .Lret_from_exception
79
80 do_trace_entry:
81         movel   #-ENOSYS,%sp@(PT_D0)    | needed for strace
82         subql   #4,%sp
83         SAVE_SWITCH_STACK
84         jbsr    syscall_trace
85         RESTORE_SWITCH_STACK
86         addql   #4,%sp
87         movel   %sp@(PT_ORIG_D0),%d0
88         cmpl    #NR_syscalls,%d0
89         jcs     syscall
90 badsys:
91         movel   #-ENOSYS,%sp@(PT_D0)
92         jra     ret_from_syscall
93
94 do_trace_exit:
95         subql   #4,%sp
96         SAVE_SWITCH_STACK
97         jbsr    syscall_trace
98         RESTORE_SWITCH_STACK
99         addql   #4,%sp
100         jra     .Lret_from_exception
101
102 ENTRY(ret_from_signal)
103         RESTORE_SWITCH_STACK
104         addql   #4,%sp
105 /* on 68040 complete pending writebacks if any */
106 #ifdef CONFIG_M68040
107         bfextu  %sp@(PT_VECTOR){#0,#4},%d0
108         subql   #7,%d0                          | bus error frame ?
109         jbne    1f
110         movel   %sp,%sp@-
111         jbsr    berr_040cleanup
112         addql   #4,%sp
113 1:
114 #endif
115         jra     .Lret_from_exception
116
117 ENTRY(system_call)
118         SAVE_ALL_SYS
119
120         GET_CURRENT(%d1)
121         | save top of frame
122         movel   %sp,%curptr@(TASK_THREAD+THREAD_ESP0)
123
124         | syscall trace?
125         tstb    %curptr@(TASK_INFO+TINFO_FLAGS+2)
126         jmi     do_trace_entry
127         cmpl    #NR_syscalls,%d0
128         jcc     badsys
129 syscall:
130         jbsr    @(sys_call_table,%d0:l:4)@(0)
131         movel   %d0,%sp@(PT_D0)         | save the return value
132 ret_from_syscall:
133         |oriw   #0x0700,%sr
134         movew   %curptr@(TASK_INFO+TINFO_FLAGS+2),%d0
135         jne     syscall_exit_work
136 1:      RESTORE_ALL
137
138 syscall_exit_work:
139         btst    #5,%sp@(PT_SR)          | check if returning to kernel
140         bnes    1b                      | if so, skip resched, signals
141         lslw    #1,%d0
142         jcs     do_trace_exit
143         jmi     do_delayed_trace
144         lslw    #8,%d0
145         jmi     do_signal_return
146         pea     resume_userspace
147         jra     schedule
148
149
150 ENTRY(ret_from_exception)
151 .Lret_from_exception:
152         btst    #5,%sp@(PT_SR)          | check if returning to kernel
153         bnes    1f                      | if so, skip resched, signals
154         | only allow interrupts when we are really the last one on the
155         | kernel stack, otherwise stack overflow can occur during
156         | heavy interrupt load
157         andw    #ALLOWINT,%sr
158
159 resume_userspace:
160         moveb   %curptr@(TASK_INFO+TINFO_FLAGS+3),%d0
161         jne     exit_work
162 1:      RESTORE_ALL
163
164 exit_work:
165         | save top of frame
166         movel   %sp,%curptr@(TASK_THREAD+THREAD_ESP0)
167         lslb    #1,%d0
168         jmi     do_signal_return
169         pea     resume_userspace
170         jra     schedule
171
172
173 do_signal_return:
174         |andw   #ALLOWINT,%sr
175         subql   #4,%sp                  | dummy return address
176         SAVE_SWITCH_STACK
177         pea     %sp@(SWITCH_STACK_SIZE)
178         clrl    %sp@-
179         bsrl    do_signal
180         addql   #8,%sp
181         RESTORE_SWITCH_STACK
182         addql   #4,%sp
183         jbra    resume_userspace
184
185 do_delayed_trace:
186         bclr    #7,%sp@(PT_SR)          | clear trace bit in SR
187         pea     1                       | send SIGTRAP
188         movel   %curptr,%sp@-
189         pea     LSIGTRAP
190         jbsr    send_sig
191         addql   #8,%sp
192         addql   #4,%sp
193         jbra    resume_userspace
194
195
196 /* This is the main interrupt handler for autovector interrupts */
197
198 ENTRY(auto_inthandler)
199         SAVE_ALL_INT
200         GET_CURRENT(%d0)
201         addqb   #1,%curptr@(TASK_INFO+TINFO_PREEMPT+1)
202                                         |  put exception # in d0
203         bfextu  %sp@(PT_VECTOR){#4,#10},%d0
204         subw    #VEC_SPUR,%d0
205
206         movel   %sp,%sp@-
207         movel   %d0,%sp@-               |  put vector # on stack
208 #if defined(MACH_Q40_ONLY) && defined(CONFIG_BLK_DEV_FD)
209         btstb   #4,0xff000000           | Q40 floppy needs very special treatment ...
210         jbeq    1f
211         btstb   #3,0xff000004
212         jbeq    1f
213         jbsr    floppy_hardint
214         jbra    3f
215 1:
216 #endif
217 auto_irqhandler_fixup = . + 2
218         jsr     m68k_handle_int         |  process the IRQ
219 3:      addql   #8,%sp                  |  pop parameters off stack
220
221 ret_from_interrupt:
222         subqb   #1,%curptr@(TASK_INFO+TINFO_PREEMPT+1)
223         jeq     ret_from_last_interrupt
224 2:      RESTORE_ALL
225
226         ALIGN
227 ret_from_last_interrupt:
228         moveq   #(~ALLOWINT>>8)&0xff,%d0
229         andb    %sp@(PT_SR),%d0
230         jne     2b
231
232         /* check if we need to do software interrupts */
233         tstl    irq_stat+CPUSTAT_SOFTIRQ_PENDING
234         jeq     .Lret_from_exception
235         pea     ret_from_exception
236         jra     do_softirq
237
238 /* Handler for user defined interrupt vectors */
239
240 ENTRY(user_inthandler)
241         SAVE_ALL_INT
242         GET_CURRENT(%d0)
243         addqb   #1,%curptr@(TASK_INFO+TINFO_PREEMPT+1)
244                                         |  put exception # in d0
245         bfextu  %sp@(PT_VECTOR){#4,#10},%d0
246 user_irqvec_fixup = . + 2
247         subw    #VEC_USER,%d0
248
249         movel   %sp,%sp@-
250         movel   %d0,%sp@-               |  put vector # on stack
251 user_irqhandler_fixup = . + 2
252         jsr     m68k_handle_int         |  process the IRQ
253         addql   #8,%sp                  |  pop parameters off stack
254
255         subqb   #1,%curptr@(TASK_INFO+TINFO_PREEMPT+1)
256         jeq     ret_from_last_interrupt
257         RESTORE_ALL
258
259 /* Handler for uninitialized and spurious interrupts */
260
261 ENTRY(bad_inthandler)
262         SAVE_ALL_INT
263         GET_CURRENT(%d0)
264         addqb   #1,%curptr@(TASK_INFO+TINFO_PREEMPT+1)
265
266         movel   %sp,%sp@-
267         jsr     handle_badint
268         addql   #4,%sp
269
270         subqb   #1,%curptr@(TASK_INFO+TINFO_PREEMPT+1)
271         jeq     ret_from_last_interrupt
272         RESTORE_ALL
273
274
275 ENTRY(sys_fork)
276         SAVE_SWITCH_STACK
277         pea     %sp@(SWITCH_STACK_SIZE)
278         jbsr    m68k_fork
279         addql   #4,%sp
280         RESTORE_SWITCH_STACK
281         rts
282
283 ENTRY(sys_clone)
284         SAVE_SWITCH_STACK
285         pea     %sp@(SWITCH_STACK_SIZE)
286         jbsr    m68k_clone
287         addql   #4,%sp
288         RESTORE_SWITCH_STACK
289         rts
290
291 ENTRY(sys_vfork)
292         SAVE_SWITCH_STACK
293         pea     %sp@(SWITCH_STACK_SIZE)
294         jbsr    m68k_vfork
295         addql   #4,%sp
296         RESTORE_SWITCH_STACK
297         rts
298
299 ENTRY(sys_sigsuspend)
300         SAVE_SWITCH_STACK
301         pea     %sp@(SWITCH_STACK_SIZE)
302         jbsr    do_sigsuspend
303         addql   #4,%sp
304         RESTORE_SWITCH_STACK
305         rts
306
307 ENTRY(sys_rt_sigsuspend)
308         SAVE_SWITCH_STACK
309         pea     %sp@(SWITCH_STACK_SIZE)
310         jbsr    do_rt_sigsuspend
311         addql   #4,%sp
312         RESTORE_SWITCH_STACK
313         rts
314
315 ENTRY(sys_sigreturn)
316         SAVE_SWITCH_STACK
317         jbsr    do_sigreturn
318         RESTORE_SWITCH_STACK
319         rts
320
321 ENTRY(sys_rt_sigreturn)
322         SAVE_SWITCH_STACK
323         jbsr    do_rt_sigreturn
324         RESTORE_SWITCH_STACK
325         rts
326
327 resume:
328         /*
329          * Beware - when entering resume, prev (the current task) is
330          * in a0, next (the new task) is in a1,so don't change these
331          * registers until their contents are no longer needed.
332          */
333
334         /* save sr */
335         movew   %sr,%a0@(TASK_THREAD+THREAD_SR)
336
337         /* save fs (sfc,%dfc) (may be pointing to kernel memory) */
338         movec   %sfc,%d0
339         movew   %d0,%a0@(TASK_THREAD+THREAD_FS)
340
341         /* save usp */
342         /* it is better to use a movel here instead of a movew 8*) */
343         movec   %usp,%d0
344         movel   %d0,%a0@(TASK_THREAD+THREAD_USP)
345
346         /* save non-scratch registers on stack */
347         SAVE_SWITCH_STACK
348
349         /* save current kernel stack pointer */
350         movel   %sp,%a0@(TASK_THREAD+THREAD_KSP)
351
352         /* save floating point context */
353 #ifndef CONFIG_M68KFPU_EMU_ONLY
354 #ifdef CONFIG_M68KFPU_EMU
355         tstl    m68k_fputype
356         jeq     3f
357 #endif
358         fsave   %a0@(TASK_THREAD+THREAD_FPSTATE)
359
360 #if defined(CONFIG_M68060)
361 #if !defined(CPU_M68060_ONLY)
362         btst    #3,m68k_cputype+3
363         beqs    1f
364 #endif
365         /* The 060 FPU keeps status in bits 15-8 of the first longword */
366         tstb    %a0@(TASK_THREAD+THREAD_FPSTATE+2)
367         jeq     3f
368 #if !defined(CPU_M68060_ONLY)
369         jra     2f
370 #endif
371 #endif /* CONFIG_M68060 */
372 #if !defined(CPU_M68060_ONLY)
373 1:      tstb    %a0@(TASK_THREAD+THREAD_FPSTATE)
374         jeq     3f
375 #endif
376 2:      fmovemx %fp0-%fp7,%a0@(TASK_THREAD+THREAD_FPREG)
377         fmoveml %fpcr/%fpsr/%fpiar,%a0@(TASK_THREAD+THREAD_FPCNTL)
378 3:
379 #endif  /* CONFIG_M68KFPU_EMU_ONLY */
380         /* Return previous task in %d1 */
381         movel   %curptr,%d1
382
383         /* switch to new task (a1 contains new task) */
384         movel   %a1,%curptr
385
386         /* restore floating point context */
387 #ifndef CONFIG_M68KFPU_EMU_ONLY
388 #ifdef CONFIG_M68KFPU_EMU
389         tstl    m68k_fputype
390         jeq     4f
391 #endif
392 #if defined(CONFIG_M68060)
393 #if !defined(CPU_M68060_ONLY)
394         btst    #3,m68k_cputype+3
395         beqs    1f
396 #endif
397         /* The 060 FPU keeps status in bits 15-8 of the first longword */
398         tstb    %a1@(TASK_THREAD+THREAD_FPSTATE+2)
399         jeq     3f
400 #if !defined(CPU_M68060_ONLY)
401         jra     2f
402 #endif
403 #endif /* CONFIG_M68060 */
404 #if !defined(CPU_M68060_ONLY)
405 1:      tstb    %a1@(TASK_THREAD+THREAD_FPSTATE)
406         jeq     3f
407 #endif
408 2:      fmovemx %a1@(TASK_THREAD+THREAD_FPREG),%fp0-%fp7
409         fmoveml %a1@(TASK_THREAD+THREAD_FPCNTL),%fpcr/%fpsr/%fpiar
410 3:      frestore %a1@(TASK_THREAD+THREAD_FPSTATE)
411 4:
412 #endif  /* CONFIG_M68KFPU_EMU_ONLY */
413
414         /* restore the kernel stack pointer */
415         movel   %a1@(TASK_THREAD+THREAD_KSP),%sp
416
417         /* restore non-scratch registers */
418         RESTORE_SWITCH_STACK
419
420         /* restore user stack pointer */
421         movel   %a1@(TASK_THREAD+THREAD_USP),%a0
422         movel   %a0,%usp
423
424         /* restore fs (sfc,%dfc) */
425         movew   %a1@(TASK_THREAD+THREAD_FS),%a0
426         movec   %a0,%sfc
427         movec   %a0,%dfc
428
429         /* restore status register */
430         movew   %a1@(TASK_THREAD+THREAD_SR),%sr
431
432         rts
433
434 .data
435 ALIGN
436 sys_call_table:
437         .long sys_ni_syscall    /* 0  -  old "setup()" system call*/
438         .long sys_exit
439         .long sys_fork
440         .long sys_read
441         .long sys_write
442         .long sys_open          /* 5 */
443         .long sys_close
444         .long sys_waitpid
445         .long sys_creat
446         .long sys_link
447         .long sys_unlink        /* 10 */
448         .long sys_execve
449         .long sys_chdir
450         .long sys_time
451         .long sys_mknod
452         .long sys_chmod         /* 15 */
453         .long sys_chown16
454         .long sys_ni_syscall                            /* old break syscall holder */
455         .long sys_stat
456         .long sys_lseek
457         .long sys_getpid        /* 20 */
458         .long sys_mount
459         .long sys_oldumount
460         .long sys_setuid16
461         .long sys_getuid16
462         .long sys_stime         /* 25 */
463         .long sys_ptrace
464         .long sys_alarm
465         .long sys_fstat
466         .long sys_pause
467         .long sys_utime         /* 30 */
468         .long sys_ni_syscall                            /* old stty syscall holder */
469         .long sys_ni_syscall                            /* old gtty syscall holder */
470         .long sys_access
471         .long sys_nice
472         .long sys_ni_syscall    /* 35 */        /* old ftime syscall holder */
473         .long sys_sync
474         .long sys_kill
475         .long sys_rename
476         .long sys_mkdir
477         .long sys_rmdir         /* 40 */
478         .long sys_dup
479         .long sys_pipe
480         .long sys_times
481         .long sys_ni_syscall                            /* old prof syscall holder */
482         .long sys_brk           /* 45 */
483         .long sys_setgid16
484         .long sys_getgid16
485         .long sys_signal
486         .long sys_geteuid16
487         .long sys_getegid16     /* 50 */
488         .long sys_acct
489         .long sys_umount                                /* recycled never used phys() */
490         .long sys_ni_syscall                            /* old lock syscall holder */
491         .long sys_ioctl
492         .long sys_fcntl         /* 55 */
493         .long sys_ni_syscall                            /* old mpx syscall holder */
494         .long sys_setpgid
495         .long sys_ni_syscall                            /* old ulimit syscall holder */
496         .long sys_ni_syscall
497         .long sys_umask         /* 60 */
498         .long sys_chroot
499         .long sys_ustat
500         .long sys_dup2
501         .long sys_getppid
502         .long sys_getpgrp       /* 65 */
503         .long sys_setsid
504         .long sys_sigaction
505         .long sys_sgetmask
506         .long sys_ssetmask
507         .long sys_setreuid16    /* 70 */
508         .long sys_setregid16
509         .long sys_sigsuspend
510         .long sys_sigpending
511         .long sys_sethostname
512         .long sys_setrlimit     /* 75 */
513         .long sys_old_getrlimit
514         .long sys_getrusage
515         .long sys_gettimeofday
516         .long sys_settimeofday
517         .long sys_getgroups16   /* 80 */
518         .long sys_setgroups16
519         .long old_select
520         .long sys_symlink
521         .long sys_lstat
522         .long sys_readlink      /* 85 */
523         .long sys_uselib
524         .long sys_swapon
525         .long sys_reboot
526         .long old_readdir
527         .long old_mmap          /* 90 */
528         .long sys_munmap
529         .long sys_truncate
530         .long sys_ftruncate
531         .long sys_fchmod
532         .long sys_fchown16      /* 95 */
533         .long sys_getpriority
534         .long sys_setpriority
535         .long sys_ni_syscall                            /* old profil syscall holder */
536         .long sys_statfs
537         .long sys_fstatfs       /* 100 */
538         .long sys_ni_syscall                            /* ioperm for i386 */
539         .long sys_socketcall
540         .long sys_syslog
541         .long sys_setitimer
542         .long sys_getitimer     /* 105 */
543         .long sys_newstat
544         .long sys_newlstat
545         .long sys_newfstat
546         .long sys_ni_syscall
547         .long sys_ni_syscall    /* 110 */       /* iopl for i386 */
548         .long sys_vhangup
549         .long sys_ni_syscall                            /* obsolete idle() syscall */
550         .long sys_ni_syscall                            /* vm86old for i386 */
551         .long sys_wait4
552         .long sys_swapoff       /* 115 */
553         .long sys_sysinfo
554         .long sys_ipc
555         .long sys_fsync
556         .long sys_sigreturn
557         .long sys_clone         /* 120 */
558         .long sys_setdomainname
559         .long sys_newuname
560         .long sys_cacheflush                            /* modify_ldt for i386 */
561         .long sys_adjtimex
562         .long sys_mprotect      /* 125 */
563         .long sys_sigprocmask
564         .long sys_ni_syscall            /* old "create_module" */
565         .long sys_init_module
566         .long sys_delete_module
567         .long sys_ni_syscall    /* 130 - old "get_kernel_syms" */
568         .long sys_quotactl
569         .long sys_getpgid
570         .long sys_fchdir
571         .long sys_bdflush
572         .long sys_sysfs         /* 135 */
573         .long sys_personality
574         .long sys_ni_syscall                            /* for afs_syscall */
575         .long sys_setfsuid16
576         .long sys_setfsgid16
577         .long sys_llseek        /* 140 */
578         .long sys_getdents
579         .long sys_select
580         .long sys_flock
581         .long sys_msync
582         .long sys_readv         /* 145 */
583         .long sys_writev
584         .long sys_getsid
585         .long sys_fdatasync
586         .long sys_sysctl
587         .long sys_mlock         /* 150 */
588         .long sys_munlock
589         .long sys_mlockall
590         .long sys_munlockall
591         .long sys_sched_setparam
592         .long sys_sched_getparam        /* 155 */
593         .long sys_sched_setscheduler
594         .long sys_sched_getscheduler
595         .long sys_sched_yield
596         .long sys_sched_get_priority_max
597         .long sys_sched_get_priority_min  /* 160 */
598         .long sys_sched_rr_get_interval
599         .long sys_nanosleep
600         .long sys_mremap
601         .long sys_setresuid16
602         .long sys_getresuid16   /* 165 */
603         .long sys_getpagesize
604         .long sys_ni_syscall            /* old sys_query_module */
605         .long sys_poll
606         .long sys_nfsservctl
607         .long sys_setresgid16   /* 170 */
608         .long sys_getresgid16
609         .long sys_prctl
610         .long sys_rt_sigreturn
611         .long sys_rt_sigaction
612         .long sys_rt_sigprocmask        /* 175 */
613         .long sys_rt_sigpending
614         .long sys_rt_sigtimedwait
615         .long sys_rt_sigqueueinfo
616         .long sys_rt_sigsuspend
617         .long sys_pread64       /* 180 */
618         .long sys_pwrite64
619         .long sys_lchown16;
620         .long sys_getcwd
621         .long sys_capget
622         .long sys_capset        /* 185 */
623         .long sys_sigaltstack
624         .long sys_sendfile
625         .long sys_ni_syscall                            /* streams1 */
626         .long sys_ni_syscall                            /* streams2 */
627         .long sys_vfork         /* 190 */
628         .long sys_getrlimit
629         .long sys_mmap2
630         .long sys_truncate64
631         .long sys_ftruncate64
632         .long sys_stat64        /* 195 */
633         .long sys_lstat64
634         .long sys_fstat64
635         .long sys_chown
636         .long sys_getuid
637         .long sys_getgid        /* 200 */
638         .long sys_geteuid
639         .long sys_getegid
640         .long sys_setreuid
641         .long sys_setregid
642         .long sys_getgroups     /* 205 */
643         .long sys_setgroups
644         .long sys_fchown
645         .long sys_setresuid
646         .long sys_getresuid
647         .long sys_setresgid     /* 210 */
648         .long sys_getresgid
649         .long sys_lchown
650         .long sys_setuid
651         .long sys_setgid
652         .long sys_setfsuid      /* 215 */
653         .long sys_setfsgid
654         .long sys_pivot_root
655         .long sys_ni_syscall
656         .long sys_ni_syscall
657         .long sys_getdents64    /* 220 */
658         .long sys_gettid
659         .long sys_tkill
660         .long sys_setxattr
661         .long sys_lsetxattr
662         .long sys_fsetxattr     /* 225 */
663         .long sys_getxattr
664         .long sys_lgetxattr
665         .long sys_fgetxattr
666         .long sys_listxattr
667         .long sys_llistxattr    /* 230 */
668         .long sys_flistxattr
669         .long sys_removexattr
670         .long sys_lremovexattr
671         .long sys_fremovexattr
672         .long sys_futex         /* 235 */
673         .long sys_sendfile64
674         .long sys_mincore
675         .long sys_madvise
676         .long sys_fcntl64
677         .long sys_readahead     /* 240 */
678         .long sys_io_setup
679         .long sys_io_destroy
680         .long sys_io_getevents
681         .long sys_io_submit
682         .long sys_io_cancel     /* 245 */
683         .long sys_fadvise64
684         .long sys_exit_group
685         .long sys_lookup_dcookie
686         .long sys_epoll_create
687         .long sys_epoll_ctl     /* 250 */
688         .long sys_epoll_wait
689         .long sys_remap_file_pages
690         .long sys_set_tid_address
691         .long sys_timer_create
692         .long sys_timer_settime /* 255 */
693         .long sys_timer_gettime
694         .long sys_timer_getoverrun
695         .long sys_timer_delete
696         .long sys_clock_settime
697         .long sys_clock_gettime /* 260 */
698         .long sys_clock_getres
699         .long sys_clock_nanosleep
700         .long sys_statfs64
701         .long sys_fstatfs64
702         .long sys_tgkill        /* 265 */
703         .long sys_utimes
704         .long sys_fadvise64_64
705         .long sys_mbind 
706         .long sys_get_mempolicy
707         .long sys_set_mempolicy /* 270 */
708         .long sys_mq_open
709         .long sys_mq_unlink
710         .long sys_mq_timedsend
711         .long sys_mq_timedreceive
712         .long sys_mq_notify     /* 275 */
713         .long sys_mq_getsetattr
714         .long sys_waitid
715         .long sys_ni_syscall    /* for sys_vserver */
716         .long sys_add_key
717         .long sys_request_key   /* 280 */
718         .long sys_keyctl
719