m32r: Move the spi_stack_top and spu_stack_top into .init.data section.
[linux-2.6.git] / arch / m32r / kernel / vmlinux.lds.S
1 /* ld script to make M32R Linux kernel
2  */
3
4 #include <asm-generic/vmlinux.lds.h>
5 #include <asm/addrspace.h>
6 #include <asm/page.h>
7
8 OUTPUT_ARCH(m32r)
9 #if defined(__LITTLE_ENDIAN__)
10        jiffies = jiffies_64;
11 #else
12        jiffies = jiffies_64 + 4;
13 #endif
14
15 kernel_entry = boot - 0x80000000;
16 ENTRY(kernel_entry)
17
18 SECTIONS
19 {
20   . = CONFIG_MEMORY_START + __PAGE_OFFSET;
21   eit_vector = .;
22
23   . = . + 0x1000;
24   .empty_zero_page : { *(.empty_zero_page) } = 0
25
26   /* read-only */
27   _text = .;                    /* Text and read-only data */
28   .boot : { *(.boot) } = 0
29   .text : {
30         HEAD_TEXT
31         TEXT_TEXT
32         SCHED_TEXT
33         LOCK_TEXT
34         *(.fixup)
35         *(.gnu.warning)
36         } = 0x9090
37 #ifdef CONFIG_SMP
38   . = ALIGN(65536);
39   .eit_vector4 : { *(.eit_vector4) }
40 #endif
41   _etext = .;                   /* End of text section */
42
43   . = ALIGN(16);                /* Exception table */
44   __start___ex_table = .;
45   __ex_table : { *(__ex_table) }
46   __stop___ex_table = .;
47
48   RODATA
49
50   /* writeable */
51   .data : {                     /* Data */
52         DATA_DATA
53         CONSTRUCTORS
54         }
55
56   . = ALIGN(4096);
57   __nosave_begin = .;
58   .data_nosave : { *(.data.nosave) }
59   . = ALIGN(4096);
60   __nosave_end = .;
61
62   . = ALIGN(32);
63   .data.cacheline_aligned : { *(.data.cacheline_aligned) }
64
65   _edata = .;                   /* End of data section */
66
67   . = ALIGN(8192);              /* init_task */
68   .data.init_task : { *(.data.init_task) }
69
70   /* will be freed after init */
71   . = ALIGN(4096);              /* Init code and data */
72   __init_begin = .;
73   .init.text : {
74         _sinittext = .;
75         INIT_TEXT
76         _einittext = .;
77   }
78   .init.data : { INIT_DATA }
79   . = ALIGN(16);
80   __setup_start = .;
81   .init.setup : { *(.init.setup) }
82   __setup_end = .;
83   __initcall_start = .;
84   .initcall.init : {
85         INITCALLS
86   }
87   __initcall_end = .;
88   __con_initcall_start = .;
89   .con_initcall.init : { *(.con_initcall.init) }
90   __con_initcall_end = .;
91   SECURITY_INIT
92
93 #ifdef CONFIG_BLK_DEV_INITRD
94   . = ALIGN(4096);
95   __initramfs_start = .;
96   .init.ramfs : { *(.init.ramfs) }
97   __initramfs_end = .;
98 #endif
99
100   PERCPU(4096)
101   . = ALIGN(4096);
102   __init_end = .;
103   /* freed after init ends here */
104
105   __bss_start = .;              /* BSS */
106   .bss : { *(.bss) }
107   . = ALIGN(4);
108   __bss_stop = .;
109
110   _end = . ;
111
112   /* Stabs debugging sections.  */
113   .stab 0 : { *(.stab) }
114   .stabstr 0 : { *(.stabstr) }
115   .stab.excl 0 : { *(.stab.excl) }
116   .stab.exclstr 0 : { *(.stab.exclstr) }
117   .stab.index 0 : { *(.stab.index) }
118   .stab.indexstr 0 : { *(.stab.indexstr) }
119   .comment 0 : { *(.comment) }
120
121   /* Sections to be discarded */
122   DISCARDS
123 }