[PATCH] vDSO hash-style fix
[linux-2.6.git] / arch / i386 / kernel / vsyscall.lds.S
1 /*
2  * Linker script for vsyscall DSO.  The vsyscall page is an ELF shared
3  * object prelinked to its virtual address, and with only one read-only
4  * segment (that fits in one page).  This script controls its layout.
5  */
6 #include <asm/asm-offsets.h>
7
8 SECTIONS
9 {
10   . = VDSO_PRELINK + SIZEOF_HEADERS;
11
12   .hash           : { *(.hash) }                :text
13   .gnu.hash       : { *(.gnu.hash) }
14   .dynsym         : { *(.dynsym) }
15   .dynstr         : { *(.dynstr) }
16   .gnu.version    : { *(.gnu.version) }
17   .gnu.version_d  : { *(.gnu.version_d) }
18   .gnu.version_r  : { *(.gnu.version_r) }
19
20   /* This linker script is used both with -r and with -shared.
21      For the layouts to match, we need to skip more than enough
22      space for the dynamic symbol table et al.  If this amount
23      is insufficient, ld -shared will barf.  Just increase it here.  */
24   . = VDSO_PRELINK + 0x400;
25
26   .text           : { *(.text) }                :text =0x90909090
27   .note           : { *(.note.*) }              :text :note
28   .eh_frame_hdr   : { *(.eh_frame_hdr) }        :text :eh_frame_hdr
29   .eh_frame       : { KEEP (*(.eh_frame)) }     :text
30   .dynamic        : { *(.dynamic) }             :text :dynamic
31   .useless        : {
32         *(.got.plt) *(.got)
33         *(.data .data.* .gnu.linkonce.d.*)
34         *(.dynbss)
35         *(.bss .bss.* .gnu.linkonce.b.*)
36   }                                             :text
37 }
38
39 /*
40  * We must supply the ELF program headers explicitly to get just one
41  * PT_LOAD segment, and set the flags explicitly to make segments read-only.
42  */
43 PHDRS
44 {
45   text PT_LOAD FILEHDR PHDRS FLAGS(5); /* PF_R|PF_X */
46   dynamic PT_DYNAMIC FLAGS(4); /* PF_R */
47   note PT_NOTE FLAGS(4); /* PF_R */
48   eh_frame_hdr 0x6474e550; /* PT_GNU_EH_FRAME, but ld doesn't match the name */
49 }
50
51 /*
52  * This controls what symbols we export from the DSO.
53  */
54 VERSION
55 {
56   LINUX_2.5 {
57     global:
58         __kernel_vsyscall;
59         __kernel_sigreturn;
60         __kernel_rt_sigreturn;
61
62     local: *;
63   };
64 }
65
66 /* The ELF entry point can be used to set the AT_SYSINFO value.  */
67 ENTRY(__kernel_vsyscall);