frv: remove unused .altinstructions code
[linux-2.6.git] / arch / frv / kernel / vmlinux.lds.S
1 /* ld script to make FRV Linux kernel
2  * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>;
3  */
4 OUTPUT_FORMAT("elf32-frv", "elf32-frv", "elf32-frv")
5 OUTPUT_ARCH(frv)
6 ENTRY(_start)
7
8 #include <asm-generic/vmlinux.lds.h>
9 #include <asm/processor.h>
10 #include <asm/page.h>
11 #include <asm/cache.h>
12 #include <asm/thread_info.h>
13
14 jiffies = jiffies_64 + 4;
15
16 __page_offset = CONFIG_PAGE_OFFSET;     /* start of area covered by struct pages */
17 __kernel_image_start = __page_offset;   /* address at which kernel image resides */
18
19 SECTIONS
20 {
21   . = __kernel_image_start;
22
23   /* discardable initialisation code and data */
24   . = ALIGN(PAGE_SIZE);                 /* Init code and data */
25   __init_begin = .;
26
27   _sinittext = .;
28   .init.text : {
29         HEAD_TEXT
30 #ifndef CONFIG_DEBUG_INFO
31         INIT_TEXT
32         EXIT_TEXT
33         EXIT_DATA
34         *(.exitcall.exit)
35 #endif
36   }
37   _einittext = .;
38   .init.data : { INIT_DATA }
39
40   . = ALIGN(8);
41   __setup_start = .;
42   .setup.init : { KEEP(*(.init.setup)) }
43   __setup_end = .;
44
45   __initcall_start = .;
46   .initcall.init : {
47         INITCALLS
48   }
49   __initcall_end = .;
50   __con_initcall_start = .;
51   .con_initcall.init : { *(.con_initcall.init) }
52   __con_initcall_end = .;
53   SECURITY_INIT
54
55   PERCPU(4096)
56
57 #ifdef CONFIG_BLK_DEV_INITRD
58   . = ALIGN(4096);
59   __initramfs_start = .;
60   .init.ramfs : { *(.init.ramfs) }
61   __initramfs_end = .;
62 #endif
63
64   . = ALIGN(THREAD_SIZE);
65   __init_end = .;
66
67   /* put sections together that have massive alignment issues */
68   . = ALIGN(THREAD_SIZE);
69   .data.init_task : {
70           /* init task record & stack */
71           *(.data.init_task)
72   }
73
74   . = ALIGN(L1_CACHE_BYTES);
75   .data.cacheline_aligned : { *(.data.cacheline_aligned) }
76
77   .trap : {
78         /* trap table management - read entry-table.S before modifying */
79         . = ALIGN(8192);
80         __trap_tables = .;
81         *(.trap.user)
82         *(.trap.kernel)
83         . = ALIGN(4096);
84         *(.trap.break)
85   }
86
87   /* Text and read-only data */
88   . = ALIGN(4);
89   _text = .;
90   _stext = .;
91   .text : {
92         *(.text.start)
93         *(.text.entry)
94         *(.text.break)
95         *(.text.tlbmiss)
96         TEXT_TEXT
97         SCHED_TEXT
98         LOCK_TEXT
99 #ifdef CONFIG_DEBUG_INFO
100         INIT_TEXT
101         EXIT_TEXT
102         *(.exitcall.exit)
103 #endif
104         *(.fixup)
105         *(.gnu.warning)
106         *(.exitcall.exit)
107         } = 0x9090
108
109   _etext = .;                   /* End of text section */
110
111   RODATA
112
113   .rodata : {
114         *(.trap.vector)
115
116         /* this clause must not be modified - the ordering and adjacency are imperative */
117         __trap_fixup_tables = .;
118         *(.trap.fixup.user .trap.fixup.kernel)
119
120         }
121
122   . = ALIGN(8);         /* Exception table */
123   __start___ex_table = .;
124   __ex_table : { KEEP(*(__ex_table)) }
125   __stop___ex_table = .;
126
127   _sdata = .;
128   .data : {                     /* Data */
129         DATA_DATA
130         *(.data.*)
131         EXIT_DATA
132         CONSTRUCTORS
133         }
134
135   _edata = .;                   /* End of data section */
136
137   /* GP section */
138   . = ALIGN(L1_CACHE_BYTES);
139   _gp = . + 2048;
140   PROVIDE (gp = _gp);
141
142   .sdata : { *(.sdata .sdata.*) }
143
144   /* BSS */
145   . = ALIGN(L1_CACHE_BYTES);
146   __bss_start = .;
147
148   .sbss         : { *(.sbss .sbss.*) }
149   .bss          : { *(.bss .bss.*) }
150   .bss.stack    : { *(.bss) }
151
152   __bss_stop = .;
153   _end = . ;
154   . = ALIGN(PAGE_SIZE);
155   __kernel_image_end = .;
156
157   /* Stabs debugging sections.  */
158   .stab 0 : { *(.stab) }
159   .stabstr 0 : { *(.stabstr) }
160   .stab.excl 0 : { *(.stab.excl) }
161   .stab.exclstr 0 : { *(.stab.exclstr) }
162   .stab.index 0 : { *(.stab.index) }
163   .stab.indexstr 0 : { *(.stab.indexstr) }
164
165   .debug_line           0 : { *(.debug_line) }
166   .debug_info           0 : { *(.debug_info) }
167   .debug_abbrev         0 : { *(.debug_abbrev) }
168   .debug_aranges        0 : { *(.debug_aranges) }
169   .debug_frame          0 : { *(.debug_frame) }
170   .debug_pubnames       0 : { *(.debug_pubnames) }
171   .debug_str            0 : { *(.debug_str) }
172   .debug_ranges         0 : { *(.debug_ranges) }
173
174   .comment 0 : { *(.comment) }
175
176   DISCARDS
177 }
178
179 __kernel_image_size_no_bss = __bss_start - __kernel_image_start;