[PATCH] mm: update comments to pte lock
[linux-2.6.git] / arch / cris / arch-v32 / vmlinux.lds.S
1 /* ld script to make the Linux/CRIS kernel
2  * Authors: Bjorn Wesen (bjornw@axis.com)
3  *
4  * It is VERY DANGEROUS to fiddle around with the symbols in this
5  * script. It is for example quite vital that all generated sections
6  * that are used are actually named here, otherwise the linker will
7  * put them at the end, where the init stuff is which is FREED after
8  * the kernel has booted.
9  */
10
11 #include <linux/config.h>
12 #include <asm-generic/vmlinux.lds.h>
13
14 jiffies = jiffies_64;
15 SECTIONS
16 {
17         . = DRAM_VIRTUAL_BASE;
18         dram_start = .;
19         ebp_start = .;
20
21         /* The boot section is only necessary until the VCS top level testbench */
22         /* includes both flash and DRAM. */
23         .boot : { *(.boot) }
24
25         . = DRAM_VIRTUAL_BASE + 0x4000;         /* See head.S and pages reserved at the start. */
26
27         _text = .;              /* Text and read-only data. */
28         text_start = .;         /* Lots of aliases. */
29         _stext = .;
30         __stext = .;
31         .text : {
32                 *(.text)
33                 SCHED_TEXT
34                 LOCK_TEXT
35                 *(.fixup)
36                 *(.text.__*)
37         }
38
39         _etext = . ;            /* End of text section. */
40         __etext = .;
41
42         . = ALIGN(4);           /* Exception table. */
43         __start___ex_table = .;
44         __ex_table : { *(__ex_table) }
45         __stop___ex_table = .;
46
47         RODATA
48
49         . = ALIGN (4);
50         ___data_start = . ;
51         __Sdata = . ;
52         .data : {                     /* Data */
53                 *(.data)
54         }
55         __edata = . ;           /* End of data section. */
56         _edata = . ;
57
58         . = ALIGN(8192);        /* init_task and stack, must be aligned. */
59         .data.init_task : { *(.data.init_task) }
60
61         . = ALIGN(8192);        /* Init code and data. */
62         __init_begin = .;
63         .init.text : {
64                    _sinittext = .;
65                    *(.init.text)
66                    _einittext = .;
67         }
68         .init.data : { *(.init.data) }
69         . = ALIGN(16);
70         __setup_start = .;
71         .init.setup : { *(.init.setup) }
72         __setup_end = .;
73         __start___param = .;
74         __param : { *(__param) }
75         __stop___param = .;
76         .initcall.init : {
77                 __initcall_start = .;
78                 *(.initcall1.init);
79                 *(.initcall2.init);
80                 *(.initcall3.init);
81                 *(.initcall4.init);
82                 *(.initcall5.init);
83                 *(.initcall6.init);
84                 *(.initcall7.init);
85                 __initcall_end = .;
86         }
87
88         .con_initcall.init : {
89                 __con_initcall_start = .;
90                 *(.con_initcall.init)
91                 __con_initcall_end = .;
92         }
93         SECURITY_INIT
94
95         __per_cpu_start = .;
96         .data.percpu  : { *(.data.percpu) }
97         __per_cpu_end = .;
98
99         .init.ramfs : {
100                 __initramfs_start = .;
101                 *(.init.ramfs)
102                 __initramfs_end = .;
103                 /*
104                  * We fill to the next page, so we can discard all init
105                  * pages without needing to consider what payload might be
106                  * appended to the kernel image.
107                  */
108                 FILL (0);
109                 . = ALIGN (8192);
110         }
111
112         __vmlinux_end = .;      /* Last address of the physical file. */
113         __init_end = .;
114
115         __data_end = . ;        /* Move to _edata? */
116         __bss_start = .;        /* BSS. */
117         .bss : {
118                 *(COMMON)
119                 *(.bss)
120         }
121
122         . =  ALIGN (0x20);
123         _end = .;
124         __end = .;
125
126         /* Sections to be discarded */
127         /DISCARD/ : {
128                 *(.text.exit)
129                 *(.data.exit)
130                 *(.exitcall.exit)
131         }
132
133         dram_end = dram_start + CONFIG_ETRAX_DRAM_SIZE*1024*1024;
134 }