percpu: use __weak only in the definition of weak percpu variables
[linux-2.6.git] / arch / arm / kernel / vmlinux.lds.S
1 /* ld script to make ARM Linux kernel
2  * taken from the i386 version by Russell King
3  * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>
4  */
5
6 #include <asm-generic/vmlinux.lds.h>
7 #include <asm/thread_info.h>
8 #include <asm/memory.h>
9         
10 OUTPUT_ARCH(arm)
11 ENTRY(stext)
12
13 #ifndef __ARMEB__
14 jiffies = jiffies_64;
15 #else
16 jiffies = jiffies_64 + 4;
17 #endif
18
19 SECTIONS
20 {
21 #ifdef CONFIG_XIP_KERNEL
22         . = XIP_VIRT_ADDR(CONFIG_XIP_PHYS_ADDR);
23 #else
24         . = PAGE_OFFSET + TEXT_OFFSET;
25 #endif
26         .text.head : {
27                 _stext = .;
28                 _sinittext = .;
29                 *(.text.head)
30         }
31
32         .init : {                       /* Init code and data           */
33                         INIT_TEXT
34                 _einittext = .;
35                 __proc_info_begin = .;
36                         *(.proc.info.init)
37                 __proc_info_end = .;
38                 __arch_info_begin = .;
39                         *(.arch.info.init)
40                 __arch_info_end = .;
41                 __tagtable_begin = .;
42                         *(.taglist.init)
43                 __tagtable_end = .;
44                 . = ALIGN(16);
45                 __setup_start = .;
46                         *(.init.setup)
47                 __setup_end = .;
48                 __early_begin = .;
49                         *(.early_param.init)
50                 __early_end = .;
51                 __initcall_start = .;
52                         INITCALLS
53                 __initcall_end = .;
54                 __con_initcall_start = .;
55                         *(.con_initcall.init)
56                 __con_initcall_end = .;
57                 __security_initcall_start = .;
58                         *(.security_initcall.init)
59                 __security_initcall_end = .;
60 #ifdef CONFIG_BLK_DEV_INITRD
61                 . = ALIGN(32);
62                 __initramfs_start = .;
63                         usr/built-in.o(.init.ramfs)
64                 __initramfs_end = .;
65 #endif
66                 . = ALIGN(4096);
67                 __per_cpu_load = .;
68                 __per_cpu_start = .;
69                         *(.data.percpu.page_aligned)
70                         *(.data.percpu)
71                         *(.data.percpu.shared_aligned)
72                 __per_cpu_end = .;
73 #ifndef CONFIG_XIP_KERNEL
74                 __init_begin = _stext;
75                 INIT_DATA
76                 . = ALIGN(4096);
77                 __init_end = .;
78 #endif
79         }
80
81         /DISCARD/ : {                   /* Exit code and data           */
82                 EXIT_TEXT
83                 EXIT_DATA
84                 *(.exitcall.exit)
85                 *(.discard)
86                 *(.ARM.exidx.exit.text)
87                 *(.ARM.extab.exit.text)
88 #ifndef CONFIG_MMU
89                 *(.fixup)
90                 *(__ex_table)
91 #endif
92         }
93
94         .text : {                       /* Real text segment            */
95                 _text = .;              /* Text and read-only data      */
96                         __exception_text_start = .;
97                         *(.exception.text)
98                         __exception_text_end = .;
99                         TEXT_TEXT
100                         SCHED_TEXT
101                         LOCK_TEXT
102                         KPROBES_TEXT
103 #ifdef CONFIG_MMU
104                         *(.fixup)
105 #endif
106                         *(.gnu.warning)
107                         *(.rodata)
108                         *(.rodata.*)
109                         *(.glue_7)
110                         *(.glue_7t)
111                 *(.got)                 /* Global offset table          */
112         }
113
114         RODATA
115
116         _etext = .;                     /* End of text and rodata section */
117
118 #ifdef CONFIG_ARM_UNWIND
119         /*
120          * Stack unwinding tables
121          */
122         . = ALIGN(8);
123         .ARM.unwind_idx : {
124                 __start_unwind_idx = .;
125                 *(.ARM.exidx*)
126                 __stop_unwind_idx = .;
127         }
128         .ARM.unwind_tab : {
129                 __start_unwind_tab = .;
130                 *(.ARM.extab*)
131                 __stop_unwind_tab = .;
132         }
133 #endif
134
135 #ifdef CONFIG_XIP_KERNEL
136         __data_loc = ALIGN(4);          /* location in binary */
137         . = PAGE_OFFSET + TEXT_OFFSET;
138 #else
139         . = ALIGN(THREAD_SIZE);
140         __data_loc = .;
141 #endif
142
143         .data : AT(__data_loc) {
144                 _data = .;              /* address in memory */
145                 _sdata = .;
146
147                 /*
148                  * first, the init task union, aligned
149                  * to an 8192 byte boundary.
150                  */
151                 *(.data.init_task)
152
153 #ifdef CONFIG_XIP_KERNEL
154                 . = ALIGN(4096);
155                 __init_begin = .;
156                 INIT_DATA
157                 . = ALIGN(4096);
158                 __init_end = .;
159 #endif
160
161                 . = ALIGN(4096);
162                 __nosave_begin = .;
163                 *(.data.nosave)
164                 . = ALIGN(4096);
165                 __nosave_end = .;
166
167                 /*
168                  * then the cacheline aligned data
169                  */
170                 . = ALIGN(32);
171                 *(.data.cacheline_aligned)
172
173                 /*
174                  * The exception fixup table (might need resorting at runtime)
175                  */
176                 . = ALIGN(32);
177                 __start___ex_table = .;
178 #ifdef CONFIG_MMU
179                 *(__ex_table)
180 #endif
181                 __stop___ex_table = .;
182
183                 /*
184                  * and the usual data section
185                  */
186                 DATA_DATA
187                 CONSTRUCTORS
188
189                 _edata = .;
190         }
191         _edata_loc = __data_loc + SIZEOF(.data);
192
193         .bss : {
194                 __bss_start = .;        /* BSS                          */
195                 *(.bss)
196                 *(COMMON)
197                 __bss_stop = .;
198                 _end = .;
199         }
200                                         /* Stabs debugging sections.    */
201         .stab 0 : { *(.stab) }
202         .stabstr 0 : { *(.stabstr) }
203         .stab.excl 0 : { *(.stab.excl) }
204         .stab.exclstr 0 : { *(.stab.exclstr) }
205         .stab.index 0 : { *(.stab.index) }
206         .stab.indexstr 0 : { *(.stab.indexstr) }
207         .comment 0 : { *(.comment) }
208 }
209
210 /*
211  * These must never be empty
212  * If you have to comment these two assert statements out, your
213  * binutils is too old (for other reasons as well)
214  */
215 ASSERT((__proc_info_end - __proc_info_begin), "missing CPU support")
216 ASSERT((__arch_info_end - __arch_info_begin), "no machine record defined")