Revert setting GDB_TARGET for i[3456]86-*-linux-android and x86_64-*-linux-android
[android/toolchain/build.git] / configure.ac
1 #   Copyright (C) 2008, 2010, 2011 Google Inc.
2 #
3 # This file is free software; you can redistribute it and/or modify it
4 # under the terms of the GNU General Public License as published by
5 # the Free Software Foundation; either version 2 of the License, or
6 # (at your option) any later version.
7 #
8 # This program is distributed in the hope that it will be useful, but
9 # WITHOUT ANY WARRANTY; without even the implied warranty of
10 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
11 # General Public License for more details.
12 #
13
14 AC_INIT(android-tools,2.0)
15 AC_PREREQ(2.59)
16
17 AC_CONFIG_FILES([Makefile])
18
19 AC_CANONICAL_SYSTEM
20
21 # Get 'install' or 'install-sh' and its variants.
22 AC_PROG_INSTALL
23
24 # We only allow the following 3 targets:
25 # 1. arm-linux-androideabi (primary target)
26 # 2. arm-eabi (for Android kernel)
27 # 3. arm-newlib-eabi (for gcc testing)
28 # 4. i[3456]86-*-linux-gnu, x86-*-linux-gnu, i[3456]86-*-linux-android, x86-*-linux-android (for x86 targets)
29 # 5. mips*-*-linux* (for mips targets)
30
31 GDB_TARGET=$target
32 case $target in
33   arm-unknown-linux-androideabi | arm-unknown-eabi)
34     BUILD_ANDROID_GCC=yes
35     GDB_TARGET=arm-elf-linux
36     ;;
37   arm-newlib-elf)
38     BUILD_ANDROID_GCC=no
39     ;;
40   i[[3456]]86-*-linux-gnu | x86_64-*-linux-gnu | i[[3456]]86-*-linux-android | x86_64-*-linux-android)
41     BUILD_ANDROID_GCC=yes
42     ;;
43   mips*-*-linux*)
44     BUILD_ANDROID_GCC=yes
45     ;;
46   *)
47     AC_MSG_ERROR(Unsupported target $target.);
48 esac
49 AC_SUBST(BUILD_ANDROID_GCC)
50 AC_SUBST(GDB_TARGET)
51 AC_ARG_PROGRAM
52
53 # TOPLEVEL_CONFIGURE_ARGUMENTS lifted from top-level configure.ac in gcc.
54
55 # Export original configure arguments for use by sub-configures.
56 # Quote arguments with shell meta charatcers.
57 TOPLEVEL_CONFIGURE_ARGUMENTS=
58 TOPLEVEL_NO_GOLD_CONFIGURE_ARGUMENTS=
59
60 set -- "$progname" "$@"
61 for ac_arg
62 do
63   case "$ac_arg" in
64   *" "*|*"      "*|*[[\[\]\~\#\$\^\&\*\(\)\{\}\\\|\;\<\>\?\']]*)
65     ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"`
66     # if the argument is of the form -foo=baz, quote the baz part only
67     ac_arg=`echo "'$ac_arg'" | sed "s/^'\([[-a-zA-Z0-9]]*=\)/\\1'/"` ;;
68   *) ;;
69   esac
70   # Add the quoted argument to the list.
71   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS $ac_arg"
72 done
73 if test "$silent" = yes; then
74   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS --silent"
75 fi
76 # Remove the initial space we just introduced and, as these will be
77 # expanded by make, quote '$'.
78 TOPLEVEL_CONFIGURE_ARGUMENTS=`echo "x$TOPLEVEL_CONFIGURE_ARGUMENTS" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
79 AC_SUBST(TOPLEVEL_CONFIGURE_ARGUMENTS)
80
81 # Base args.  Strip norecursion, cache-file, srcdir, host, build,
82 # target, nonopt, and variable assignments.  These are the ones we
83 # might not want to pass down to subconfigures.  Also strip
84 # program-prefix, program-suffix, and program-transform-name, so that
85 # we can pass down a consistent program-transform-name.
86 baseargs=
87 keep_next=no
88 skip_next=no
89 enable_gold=
90 eval "set -- $ac_configure_args"
91 for ac_arg
92 do
93   if test X"$skip_next" = X"yes"; then
94     skip_next=no
95     continue
96   fi
97   if test X"$keep_next" = X"yes"; then
98     case $ac_arg in
99       *\'*)
100         ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
101     esac
102     baseargs="$baseargs '$ac_arg'"
103     keep_next=no
104     continue
105   fi
106
107   # Handle separated arguments.  Based on the logic generated by
108   # autoconf 2.59.
109   case $ac_arg in
110     *=* | --config-cache | -C | -disable-* | --disable-* \
111       | -enable-* | --enable-* | -gas | --g* | -nfp | --nf* \
112       | -q | -quiet | --q* | -silent | --sil* | -v | -verb* \
113       | -with-* | --with-* | -without-* | --without-* | --x)
114       separate_arg=no
115       ;;
116     -*)
117       separate_arg=yes
118       ;;
119     *)
120       separate_arg=no
121       ;;
122   esac
123
124   case "$ac_arg" in
125     --no*)
126       continue
127       ;;
128     --c* | \
129     --sr* | \
130     --ho* | \
131     --bu* | \
132     --t* | \
133     --program-* | \
134     -cache_file* | \
135     -srcdir* | \
136     -host* | \
137     -build* | \
138     -target* | \
139     -program-prefix* | \
140     -program-suffix* | \
141     -program-transform-name* )
142       skip_next=$separate_arg
143       continue
144       ;;
145     -*)
146       # Strip argument from --enable-gold=*, since our binutils and
147       # gcc-4.6 take different arguments for dual linker support. We will
148       # pass --enable-gold=both/gold to binutils and --enable-gold=default
149       # gcc-4.6 if dual linker is needed.
150       case "$ac_arg" in
151         --enable-gold | --enable-gold=* )
152           enable_gold="$ac_arg"
153           ac_arg="--enable-gold"
154           ;;
155         --disable-gold )
156           enable_gold=
157           ;;
158       esac
159
160       # An option.  Add it.
161       case $ac_arg in
162         *\'*)
163           ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
164       esac
165       baseargs="$baseargs '$ac_arg'"
166       keep_next=$separate_arg
167       ;;
168     *)
169       # Either a variable assignment, or a nonopt (triplet).  Don't
170       # pass it down; let the Makefile handle this.
171       continue
172       ;;
173   esac
174 done
175 # Remove the initial space we just introduced and, as these will be
176 # expanded by make, quote '$'.
177 baseargs=`echo "x$baseargs" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
178
179 # Add in --program-transform-name, after --program-prefix and
180 # --program-suffix have been applied to it.  Autoconf has already
181 # doubled dollar signs and backslashes in program_transform_name; we want
182 # the backslashes un-doubled, and then the entire thing wrapped in single
183 # quotes, because this will be expanded first by make and then by the shell.
184 # Also, because we want to override the logic in subdir configure scripts to
185 # choose program_transform_name, replace any s,x,x, with s,y,y,.
186 sed -e "s,\\\\\\\\,\\\\,g; s,','\\\\'',g; s/s,x,x,/s,y,y,/" <<EOF_SED > conftestsed.out
187 ${program_transform_name}
188 EOF_SED
189 gcc_transform_name=`cat conftestsed.out`
190 rm -f conftestsed.out
191 baseargs="$baseargs --program-transform-name='${gcc_transform_name}'"
192 if test "$silent" = yes; then
193   baseargs="$baseargs --silent"
194 fi
195
196 AC_SUBST(baseargs)
197 AC_SUBST(enable_gold)
198
199 # Strip --{enable|disable}-{gold|ld}* from baseargs.  These are used for the
200 # gold binutils.  Note that baseargs are quoted.
201 gold_baseargs=
202 for ac_arg in $baseargs
203 do
204   case $ac_arg in
205   \'--enable-gold\' | \'--enable-gold=*\' | \'--disable-gold\' | \
206    \'--enable-ld\' | \'--enable-ld=*\' | \'--disable-ld\' )
207     ;;
208   *)
209     gold_baseargs="$gold_baseargs $ac_arg"
210     ;;
211   esac
212 done
213
214 AC_SUBST(gold_baseargs)
215
216 ENABLE_GRAPHITE=no
217 AC_ARG_ENABLE([graphite],
218               AC_HELP_STRING([--enable-graphite],
219                              [Enable Graphite optimization @<:@default=no@:>@]))
220 if test x${enableval} != xyes; then
221   graphite=no
222 fi
223 if test "$GCC_MIN_VERSION_4_5_0" == "no"; then
224   graphite=no
225 fi
226 ENABLE_GRAPHITE=$graphite
227 AC_SUBST(ENABLE_GRAPHITE)
228
229 # package to source path
230 case $srcdir in
231  /* | [A-Za-z]:*) package_to_srcdir=$srcdir ;;
232  *) package_to_srcdir=../$srcdir ;;
233 esac
234 AC_SUBST(package_to_srcdir)
235 #
236 # Specify tool component versions
237 #
238
239 # macro to check that we have a package. A package x exists if any one
240 # of the following exists (x is in the format of "tool-version"):
241 # 1. tool/x
242 # 2. tool/x.tar.gz
243 # 3. tool/x.tgz
244 # 4. tool/x.tar.bz2
245 m4_pattern_allow([^AC_MSG_ERROR$])
246 AC_DEFUN([ANDROID_CHECK_PACKAGE],
247 [x=$1; tool=$(echo "$x" | sed -e 's/-.*//'); version=$(echo "$x" | sed -e 's/[[^-]]*-//'); \
248 if test \( ! -d $srcdir/../$tool/$1 \) -a \( x"$version" != x"none"  \) ; then
249   if test -f $srcdir/../$tool/$1.tar ; then
250     mkdir -p temp-src && tar -C temp-src -xf $srcdir/../$tool/$1.tar
251   elif test -f $srcdir/../$tool/$1.tar.gz ; then
252     mkdir -p temp-src && tar -C temp-src -xzf $srcdir/../$tool/$1.tar.gz
253   elif test -f $srcdir/../$tool/$1.tgz ; then
254     mkdir -p temp-src && tar -C temp-src -xzf $srcdir/../$tool/$1.tgz
255   elif test -f $srcdir/../$tool/$1.tar.bz2 ; then
256     mkdir -p temp-src && tar -C temp-src -xjf $srcdir/../$tool/$1.tar.bz2
257   elif test -f $srcdir/../tarballs/$1.tar ; then
258     mkdir -p temp-src && tar -C temp-src -xf $srcdir/../tarballs/$1.tar
259   elif test -f $srcdir/../tarballs/$1.tar.gz ; then
260     mkdir -p temp-src && tar -C temp-src -xzf $srcdir/../tarballs/$1.tar.gz
261   elif test -f $srcdir/../tarballs/$1.tgz ; then
262     mkdir -p temp-src && tar -C temp-src -xzf $srcdir/../tarballs/$1.tgz
263   elif test -f $srcdir/../tarballs/$1.tar.bz2 ; then
264     mkdir -p temp-src && tar -C temp-src -xjf $srcdir/../tarballs/$1.tar.bz2
265   else
266     AC_MSG_ERROR('package $1 does not exist.')
267   fi
268 fi ])
269
270 # binutils version (default is 2.17)
271 AC_MSG_CHECKING([target binutils version to build])
272 AC_ARG_WITH([binutils-version],
273   [  --with-binutils-version=VERSION
274                           use binutils-VERSION (default is 2.17)],
275   [if test x"$withval" != x ; then
276      BINUTILS_VERSION="$withval"
277    fi],
278 [BINUTILS_VERSION="2.17"])
279 AC_MSG_RESULT($BINUTILS_VERSION)
280 AC_SUBST(BINUTILS_VERSION)
281 ANDROID_CHECK_PACKAGE(binutils-${BINUTILS_VERSION})
282
283 m4_pattern_allow(AM_INIT_AUTOMAKE)
284 # macro to find binutils version for dual linker support.
285 # For binutils-2.21 and up, add --enable-gold=default,
286 # else add --enable-gold=both/gold.
287 AC_DEFUN([FIND_BINUTILS_VERSION],
288 [binutils_version_file="${srcdir}/../binutils/$1/bfd/configure.in"
289 if test -f "${binutils_version_file}"; then
290   binutils_version_num=`grep AM_INIT_AUTOMAKE ${binutils_version_file} | \
291                         sed -n "s/[AM_INIT_AUTOMAKE][[^,]]*,*\([[^)]]*\))/\1/p"`
292   BINUTILS_MAJOR=`echo $binutils_version_num | sed -e "s/[[^0-9]].*//"`
293   BINUTILS_MINOR=`echo $binutils_version_num | \
294                   sed  -e "s/^[[0-9]]*\.//" -e "s/[[^0-9]].*//"`
295   if test "$BINUTILS_MAJOR" -gt 2 -o \
296           \( "$BINUTILS_MAJOR" -eq 2 -a "$BINUTILS_MINOR" -ge 21 \); then
297     $2_MIN_VERSION_2_21="yes"
298   else
299     $2_MIN_VERSION_2_21="no"
300   fi
301 else
302   # No configure file found. assume yes.
303   $2_MIN_VERSION_2_21="yes"
304 fi ])
305
306 FIND_BINUTILS_VERSION(binutils-${BINUTILS_VERSION},[BINUTILS])
307 AC_SUBST(BINUTILS_MIN_VERSION_2_21)
308
309 # gold binutils version (default is the same version as the main
310 # binutils package).
311 GOLD_VERSION="$BINUTILS_VERSION"
312 AC_MSG_CHECKING([target gold binutils version to build])
313 AC_ARG_WITH([gold-version],
314   [  --with-gold-version=VERSION
315                           use binutils-VERSION for gold (default is the main binutils version)],
316   [if test x"$withval" != x ; then
317      GOLD_VERSION="$withval"
318    fi])
319 AC_MSG_RESULT($GOLD_VERSION)
320 AC_SUBST(GOLD_VERSION)
321
322 # Skip check if we are using the main binutils for gold.
323 GOLD_MIN_VERSION_2_21="$BINUTILS_MIN_VERSION_2_21"
324 if test x"$GOLD_VERSION" != x"$BINUTILS_VERSION" ; then
325   ANDROID_CHECK_PACKAGE(binutils-${GOLD_VERSION})
326   FIND_BINUTILS_VERSION(binutils-${GOLD_VERSION},[GOLD])
327 fi
328 AC_SUBST(GOLD_MIN_VERSION_2_21)
329
330 # gcc version (default is 4.2.1)
331 AC_MSG_CHECKING([target gcc version to build])
332 AC_ARG_WITH([gcc-version],
333   [  --with-gcc-version=VERSION
334                           use gcc-VERSION (default is 4.2.1)],
335   [if test x"$withval" != x ; then
336      GCC_VERSION="$withval"
337    fi],
338 [GCC_VERSION="4.2.1"])
339 AC_MSG_RESULT($GCC_VERSION)
340 AC_SUBST(GCC_VERSION)
341 ANDROID_CHECK_PACKAGE(gcc-${GCC_VERSION})
342
343 # figure out if we need to build gmp and mpfr for gcc 4.3.0+ 
344 gcc_version_file="${srcdir}/../gcc/gcc-${GCC_VERSION}/gcc/BASE-VER"
345 if test -f "${gcc_version_file}"; then
346   GCC_MAJOR=`head -n 1 $gcc_version_file | sed  -e "s/[[^0-9]].*//"`
347   GCC_MINOR=`head -n 1 $gcc_version_file | \
348             sed  -e "s/^[[0-9]]*\.//" -e "s/[[^0-9]].*//"`
349   if test "$GCC_MAJOR" -gt 4 -o \
350           \( "$GCC_MAJOR" -eq 4 -a "$GCC_MINOR" -ge 3 \) ; then
351     GCC_MIN_VERSION_4_3_0="yes"
352   else
353     GCC_MIN_VERSION_4_3_0="no"
354   fi
355   if test "$GCC_MAJOR" -gt 4 -o \
356               \( "$GCC_MAJOR" -eq 4 -a "$GCC_MINOR" -ge 5 \) ; then
357     GCC_MIN_VERSION_4_5_0="yes"
358   else
359     GCC_MIN_VERSION_4_5_0="no"
360   fi
361 else
362   # No version file, assume it is trunk
363   GCC_MIN_VERSION_4_3_0="yes"
364   GCC_MIN_VERSION_4_5_0="yes"
365 fi
366 AC_SUBST(GCC_MIN_VERSION_4_3_0)
367 AC_SUBST(GCC_MIN_VERSION_4_5_0)
368
369 # newlib version (default is 1.16.0)
370 # newlib is only used for arm-newlib-eabi for testing
371 if test x$target == xarm-newlib-elf ; then 
372 AC_MSG_CHECKING([target newlib version to build])
373 AC_ARG_WITH([newlib-version],
374   [  --with-newlib-version=VERSION
375                           use newlib-VERSION (default is 1.16.0)],
376   [if test x"$withval" != x ; then
377      NEWLIB_VERSION="$withval"
378    fi],
379 [NEWLIB_VERSION="1.16.0"])
380 AC_MSG_RESULT($NEWLIB_VERSION)
381 AC_SUBST(NEWLIB_VERSION)
382 ANDROID_CHECK_PACKAGE(newlib-${NEWLIB_VERSION})
383 fi
384
385 if test "$GCC_MIN_VERSION_4_3_0" == "yes"; then
386 # gmp version (default is 4.2.2)
387 # gmp is only used for gcc version higher than 4.3.0
388 AC_MSG_CHECKING([gmp version])
389 AC_ARG_WITH([gmp-version],
390   [  --with-gmp-version=VERSION
391                           use gmp-VERSION (default is 4.2.2)],
392   [if test x"$withval" != x ; then
393      GMP_VERSION="$withval"
394    fi],
395 [GMP_VERSION="4.2.2"])
396 AC_MSG_RESULT($GMP_VERSION)
397 ANDROID_CHECK_PACKAGE(gmp-${GMP_VERSION})
398
399 # mpfr version (default is 2.3.0)
400 # mpfr is only used for gcc version higher than 4.3.0
401 AC_MSG_CHECKING([mpfr version])
402 AC_ARG_WITH([mpfr-version],
403   [  --with-mpfr-version=VERSION
404                           use mpfr-VERSION (default is 2.3.0)],
405   [if test x"$withval" != x ; then
406      MPFR_VERSION="$withval"
407    fi],
408 [MPFR_VERSION="2.3.0"])
409 AC_MSG_RESULT($MPFR_VERSION)
410 ANDROID_CHECK_PACKAGE(mpfr-${MPFR_VERSION})
411
412 fi
413 AC_SUBST(GMP_VERSION)
414 AC_SUBST(MPFR_VERSION)
415
416 if test "$GCC_MIN_VERSION_4_5_0" == "yes"; then
417 # mpc version (default is 0.8.1)
418 # mpc is only used for gcc version higher than 4.5.0
419 AC_MSG_CHECKING([mpc version])
420 AC_ARG_WITH([mpc-version],
421   [  --with-mpc-version=VERSION
422                           use mpc-VERSION (default is 0.8.1)],
423   [if test x"$withval" != x; then
424      MPC_VERSION="$withval"
425    fi],
426 [MPC_VERSION="0.8.1"])
427 AC_MSG_RESULT($MPC_VERSION)
428 ANDROID_CHECK_PACKAGE(mpc-${MPC_VERSION})
429 fi
430 AC_SUBST(MPC_VERSION)
431
432 if test "$ENABLE_GRAPHITE" == "yes"; then
433 # ppl version (default is 0.11.2)
434 # ppl is only used for gcc 4.5+ with graphite optimization.
435 AC_MSG_CHECKING([ppl version])
436 AC_ARG_WITH([ppl-version],
437   [  --with-ppl-version=VERSION
438                          use ppl-VERSION (default is 0.11.2)],
439   [if test x"$withval" != x ; then
440      PPL_VERSION="$withval"
441    fi],
442 [PPL_VERSION="0.11.2"])
443 AC_MSG_RESULT($PPL_VERSION)
444 ANDROID_CHECK_PACKAGE(ppl-${PPL_VERSION})
445 fi
446 AC_SUBST(PPL_VERSION)
447
448 if test "$ENABLE_GRAPHITE" == "yes"; then
449 # cloog-ppl or cloog version (default is 0.15.9)
450 # cloog is only used for gcc 4.5+ with graphite optimization.
451 AC_MSG_CHECKING([cloog version])
452 AC_ARG_WITH([cloog-version],
453   [  --with-cloog-version=VERSION
454                            use cloog-VERSION (default is 0.15.9)],
455   [if test x"$withval" != x ; then
456      CLOOG_VERSION="$withval"
457    fi],
458 [CLOOG_VERSION="0.15.9"])
459 AC_MSG_RESULT($CLOOG_VERSION)
460 case $CLOOG_VERSION in
461   0.15*)
462     # CLooG/PPL relies on the PPL for version 0.15.x
463     CLOOG_VERSION="ppl-$CLOOG_VERSION"
464     ;;
465   0.16*)
466     # CLooG 0.16.x has its own embedded polyhedral library
467     ;;
468   *)
469     AC_MSG_ERROR(Unsupported cloog version);
470 esac
471 ANDROID_CHECK_PACKAGE(cloog-${CLOOG_VERSION})
472 fi
473 AC_SUBST(CLOOG_VERSION)
474
475 # gdb version (default is 6.6)
476 AC_MSG_CHECKING([target gdb version to build])
477 AC_ARG_WITH([gdb-version],
478   [  --with-gdb-version=VERSION
479                           use gdb-VERSION (default is 6.6)],
480   [if test x"$withval" != x ; then
481      GDB_VERSION="$withval"
482    fi],
483 [GDB_VERSION="6.6"])
484 AC_MSG_RESULT($GDB_VERSION)
485 AC_SUBST(GDB_VERSION)
486 ANDROID_CHECK_PACKAGE(gdb-${GDB_VERSION})
487
488 # figure out if we need to build expat for gdb 7.2+
489 gdb_version_file="${srcdir}/../gdb/gdb-${GDB_VERSION}/gdb/version.in"
490 if test -f "${gdb_version_file}"; then
491   GDB_MAJOR=`head -n 1 $gdb_version_file | sed  -e "s/[[^0-9]].*//"`
492   GDB_MINOR=`head -n 1 $gdb_version_file | \
493             sed  -e "s/^[[0-9]]*\.//" -e "s/[[^0-9]].*//"`
494   if test "$GDB_MAJOR" -gt 7 -o \
495           \( "$GDB_MAJOR" -eq 7 -a "$GDB_MINOR" -ge 2 \) ; then
496     GDB_MIN_VERSION_7_2="yes"
497   else
498     GDB_MIN_VERSION_7_2="no"
499   fi
500 else
501   # No version file, assume it is trunk
502   GDB_MIN_VERSION_7_2="yes"
503 fi
504 AC_SUBST(GDB_MIN_VERSION_7_2)
505
506 if test "$GDB_MIN_VERSION_7_2" == "yes"; then
507 # expat version (default is 2.0.1)
508 # expat is only used for gdb version higher than 7.2
509 AC_MSG_CHECKING([expat version])
510 AC_ARG_WITH([expat-version],
511   [  --with-expat-version=VERSION
512                           use expat-VERSION (default is 2.0.1)],
513   [if test x"$withval" != x ; then
514      EXPAT_VERSION="$withval"
515    fi],
516 [EXPAT_VERSION="2.0.1"])
517 AC_MSG_RESULT($EXPAT_VERSION)
518 ANDROID_CHECK_PACKAGE(expat-${EXPAT_VERSION})
519 fi
520 AC_SUBST(EXPAT_VERSION)
521
522 # For certain targets, with gdb 7.2+, the proper gdb target is 
523 # arm-linux-android.
524 if test "$GDB_MIN_VERSION_7_2" == "yes"; then
525 case $target in
526   arm-unknown-linux-androideabi | arm-unknown-eabi)
527     GDB_TARGET=arm-linux-android
528     ;;
529     *)
530     ;;
531 esac
532 fi
533
534 # Sysroot location
535 AC_ARG_WITH([sysroot],
536   [  --with-sysroot=DIR
537                           use target sysroot in DIR],
538   [if test x"$withval" != x ; then
539      if test $build != $host ; then
540        case "$withval" in
541          "$prefix"|"${prefix%/}/"*)
542            ;;
543          *)
544            AC_MSG_ERROR('Target sysroot must be a subdirectory of <prefix> for canadian cross build $prefix ; $withval')
545            ;;
546        esac
547      fi
548
549      sysroot="$withval"
550    fi],
551 [if test $build != $host ; then
552    AC_MSG_ERROR('Target sysroot is not set for canadian cross build')
553  fi])
554 AC_SUBST(sysroot)
555
556 # Specify a location for mpc
557 AC_ARG_WITH(mpc, [  --with-mpc=PATH
558                           specify prefix directory for installed MPC package.],
559   [if test -d "$withval" ; then
560      have_mpc="$withval"
561      have_mpfr="$withval"
562      have_gmp="$withval"
563    elif test x"$withval" != x"no"; then
564      AC_MSG_ERROR(invalid value for --with-mpc)
565    else
566      have_mpc=no
567    fi],
568   [have_mpc=no])
569 AC_SUBST(have_mpc)
570
571 # Specify a location for mpfr
572 AC_ARG_WITH(mpfr, [  --with-mpfr=PATH
573                           specify prefix directory for installed MPFR package.],
574   [if test -d "$withval" ; then
575      have_mpfr="$withval"
576      have_gmp="$withval"
577    elif test x"$withval" != x"no"; then
578      AC_MSG_ERROR(invalid value for --with-mpfr)
579    else
580      have_mpfr=no
581    fi],
582   [have_mpfr=no])
583 AC_SUBST(have_mpfr)
584
585 # Specify a location for gmp
586 AC_ARG_WITH(gmp, [  --with-gmp=PATH
587                           specify prefix directory for the installed GMP package.],
588   [if test -d "$withval" ; then
589      have_gmp="$withval"
590    elif test x"$withval" != x"no"; then
591      AC_MSG_ERROR(invalid value for --with-gmp)
592    else
593      have_gmp=no
594    fi],
595   [have_gmp=no])
596 AC_SUBST(have_gmp)
597
598 # Specify a location for ppl
599 AC_ARG_WITH(ppl, [  --with-ppl=PATH
600                           specify prefix directory for the installed PPL package.],
601   [if test -d "$withval" ; then
602      have_ppl="$withval"
603    elif test x"$withval" != x"no"; then
604      AC_MSG_ERROR(invalid value for --with-ppl)
605    else
606      have_ppl=no
607    fi],
608   [have_ppl=no])
609 AC_SUBST(have_ppl)
610
611 # Specify a location for cloog
612 AC_ARG_WITH(cloog, [  --with-cloog=PATH
613                           specify prefix directory for the installed CLooG package.],
614   [if test -d "$withval" ; then
615      have_cloog="$withval"
616    elif test x"$withval" != x"no"; then
617      AC_MSG_ERROR(invalid value for --with-cloog)
618    else
619      have_cloog=no
620    fi],
621   [have_cloog=no])
622 AC_SUBST(have_cloog)
623
624 # Specify a location for expat
625 AC_ARG_WITH(expat, [  --with-expat=PATH
626                           specify prefix directory for the installed EXPAT package.],
627   [if test -d "$withval" ; then
628      have_expat="$withval"
629    elif test x"$withval" != x"no"; then
630      AC_MSG_ERROR(invalid value for --with-expat)
631    else
632      have_expat=no
633    fi],
634   [have_expat=no])
635 AC_SUBST(have_expat)
636
637 AC_OUTPUT