[PATCH] x86: Allow percpu variables to be page-aligned
[linux-3.10.git] / arch / xtensa / kernel / vmlinux.lds.S
1 /*
2  * arch/xtensa/kernel/vmlinux.lds.S
3  *
4  * Xtensa linker script
5  *
6  * This file is subject to the terms and conditions of the GNU General Public
7  * License.  See the file "COPYING" in the main directory of this archive
8  * for more details.
9  *
10  * Copyright (C) 2001 - 2005 Tensilica Inc.
11  *
12  * Chris Zankel <chris@zankel.net>
13  * Marc Gauthier <marc@tensilica.com, marc@alumni.uwaterloo.ca>
14  * Joe Taylor <joe@tensilica.com, joetylr@yahoo.com>
15  */
16
17 #include <asm-generic/vmlinux.lds.h>
18
19 #include <asm/variant/core.h>
20 OUTPUT_ARCH(xtensa)
21 ENTRY(_start)
22
23 #ifdef __XTENSA_EB__
24 jiffies = jiffies_64 + 4;
25 #else
26 jiffies = jiffies_64;
27 #endif
28
29 #define KERNELOFFSET 0xd0001000
30
31 /* Note: In the following macros, it would be nice to specify only the
32    vector name and section kind and construct "sym" and "section" using
33    CPP concatenation, but that does not work reliably.  Concatenating a
34    string with "." produces an invalid token.  CPP will not print a
35    warning because it thinks this is an assembly file, but it leaves
36    them as multiple tokens and there may or may not be whitespace
37    between them.  */
38
39 /* Macro for a relocation entry */
40
41 #define RELOCATE_ENTRY(sym, section)            \
42         LONG(sym ## _start);                    \
43         LONG(sym ## _end);                      \
44         LONG(LOADADDR(section))
45
46 /* Macro to define a section for a vector.
47  *
48  * Use of the MIN function catches the types of errors illustrated in
49  * the following example:
50  *
51  * Assume the section .DoubleExceptionVector.literal is completely
52  * full.  Then a programmer adds code to .DoubleExceptionVector.text
53  * that produces another literal.  The final literal position will
54  * overlay onto the first word of the adjacent code section
55  * .DoubleExceptionVector.text.  (In practice, the literals will
56  * overwrite the code, and the first few instructions will be
57  * garbage.)
58  */
59
60 #define SECTION_VECTOR(sym, section, addr, max_prevsec_size, prevsec)       \
61   section addr : AT((MIN(LOADADDR(prevsec) + max_prevsec_size,              \
62                          LOADADDR(prevsec) + SIZEOF(prevsec)) + 3) & ~ 3)   \
63   {                                                                         \
64     . = ALIGN(4);                                                           \
65     sym ## _start = ABSOLUTE(.);                                            \
66     *(section)                                                              \
67     sym ## _end = ABSOLUTE(.);                                              \
68   }
69
70 /*
71  *  Mapping of input sections to output sections when linking.
72  */
73
74 SECTIONS
75 {
76   . = KERNELOFFSET;
77   /* .text section */
78
79   _text = .;
80   _stext = .;
81   _ftext = .;
82
83   .text :
84   {
85     /* The .head.text section must be the first section! */
86     *(.head.text)
87     *(.literal .text)
88     *(.srom.text)
89     VMLINUX_SYMBOL(__sched_text_start) = .;
90     *(.sched.literal .sched.text)
91     VMLINUX_SYMBOL(__sched_text_end) = .;
92     VMLINUX_SYMBOL(__lock_text_start) = .;
93     *(.spinlock.literal .spinlock.text)
94     VMLINUX_SYMBOL(__lock_text_end) = .;
95
96   }
97   _etext = .;
98
99   . = ALIGN(16);
100
101   RODATA
102
103   /*  Relocation table */
104
105   . = ALIGN(16);
106   __boot_reloc_table_start = ABSOLUTE(.);
107
108   __relocate : {
109
110     RELOCATE_ENTRY(_WindowVectors_text,
111                    .WindowVectors.text);
112 #if 0
113     RELOCATE_ENTRY(_KernelExceptionVector_literal,
114                    .KernelExceptionVector.literal);
115 #endif
116     RELOCATE_ENTRY(_KernelExceptionVector_text,
117                    .KernelExceptionVector.text);
118 #if 0
119     RELOCATE_ENTRY(_UserExceptionVector_literal,
120                    .UserExceptionVector.literal);
121 #endif
122     RELOCATE_ENTRY(_UserExceptionVector_text,
123                    .UserExceptionVector.text);
124     RELOCATE_ENTRY(_DoubleExceptionVector_literal,
125                    .DoubleExceptionVector.literal);
126     RELOCATE_ENTRY(_DoubleExceptionVector_text,
127                    .DoubleExceptionVector.text);
128   }
129   __boot_reloc_table_end = ABSOLUTE(.) ;
130
131   .fixup   : { *(.fixup) }
132
133   . = ALIGN(16);
134
135   __ex_table : {
136     __start___ex_table = .;
137     *(__ex_table)
138     __stop___ex_table = .;
139   }
140
141   /* Data section */
142
143   . = ALIGN(XCHAL_ICACHE_LINESIZE);
144   _fdata = .;
145   .data :
146   {
147     *(.data) CONSTRUCTORS
148     . = ALIGN(XCHAL_ICACHE_LINESIZE);
149     *(.data.cacheline_aligned)
150   }
151
152   _edata = .;
153
154   /* The initial task */
155   . = ALIGN(8192);
156   .data.init_task : { *(.data.init_task) }
157
158   /* Initialization code and data: */
159
160   . = ALIGN(1 << 12);
161   __init_begin = .;
162   .init.text : {
163         _sinittext = .;
164         *(.init.literal) *(.init.text)
165         _einittext = .;
166   }
167
168   .init.data :
169   {
170     *(.init.data)
171     . = ALIGN(0x4);
172     __tagtable_begin = .;
173     *(.taglist)
174     __tagtable_end = .;
175   }
176
177   . = ALIGN(XCHAL_ICACHE_LINESIZE);
178
179   __setup_start = .;
180   .init.setup : { *(.init.setup) }
181   __setup_end = .;
182
183   __initcall_start = .;
184   .initcall.init : {
185         INITCALLS
186   }
187   __initcall_end = .;
188
189   __con_initcall_start = .;
190   .con_initcall.init : { *(.con_initcall.init) }
191   __con_initcall_end = .;
192
193   SECURITY_INIT
194
195   . = ALIGN(4);
196
197   __start___ftr_fixup = .;
198   __ftr_fixup : { *(__ftr_fixup) }
199   __stop___ftr_fixup = .;
200
201   . = ALIGN(4096);
202   __per_cpu_start = .;
203   .data.percpu  : { *(.data.percpu) }
204   __per_cpu_end = .;
205
206 #ifdef CONFIG_BLK_DEV_INITRD
207   . = ALIGN(4096);
208   __initramfs_start =.;
209   .init.ramfs : { *(.init.ramfs) }
210   __initramfs_end = .;
211 #endif
212
213   /* We need this dummy segment here */
214
215   . = ALIGN(4);
216   .dummy : { LONG(0) }
217
218   /* The vectors are relocated to the real position at startup time */
219
220   SECTION_VECTOR (_WindowVectors_text,
221                   .WindowVectors.text,
222                   XCHAL_WINDOW_VECTORS_VADDR, 4,
223                   .dummy)
224   SECTION_VECTOR (_DebugInterruptVector_literal,
225                   .DebugInterruptVector.literal,
226                   XCHAL_DEBUG_VECTOR_VADDR - 4,
227                   SIZEOF(.WindowVectors.text),
228                   .WindowVectors.text)
229   SECTION_VECTOR (_DebugInterruptVector_text,
230                   .DebugInterruptVector.text,
231                   XCHAL_DEBUG_VECTOR_VADDR,
232                   4,
233                   .DebugInterruptVector.literal)
234   SECTION_VECTOR (_KernelExceptionVector_literal,
235                   .KernelExceptionVector.literal,
236                   XCHAL_KERNEL_VECTOR_VADDR - 4,
237                   SIZEOF(.DebugInterruptVector.text),
238                   .DebugInterruptVector.text)
239   SECTION_VECTOR (_KernelExceptionVector_text,
240                   .KernelExceptionVector.text,
241                   XCHAL_KERNEL_VECTOR_VADDR,
242                   4,
243                   .KernelExceptionVector.literal)
244   SECTION_VECTOR (_UserExceptionVector_literal,
245                   .UserExceptionVector.literal,
246                   XCHAL_USER_VECTOR_VADDR - 4,
247                   SIZEOF(.KernelExceptionVector.text),
248                   .KernelExceptionVector.text)
249   SECTION_VECTOR (_UserExceptionVector_text,
250                   .UserExceptionVector.text,
251                   XCHAL_USER_VECTOR_VADDR,
252                   4,
253                   .UserExceptionVector.literal)
254   SECTION_VECTOR (_DoubleExceptionVector_literal,
255                   .DoubleExceptionVector.literal,
256                   XCHAL_DOUBLEEXC_VECTOR_VADDR - 16,
257                   SIZEOF(.UserExceptionVector.text),
258                   .UserExceptionVector.text)
259   SECTION_VECTOR (_DoubleExceptionVector_text,
260                   .DoubleExceptionVector.text,
261                   XCHAL_DOUBLEEXC_VECTOR_VADDR,
262                   32,
263                   .DoubleExceptionVector.literal)
264
265   . = (LOADADDR( .DoubleExceptionVector.text ) + SIZEOF( .DoubleExceptionVector.text ) + 3) & ~ 3;
266   . = ALIGN(1 << 12);
267
268   __init_end = .;
269
270   . = ALIGN(8192);
271
272   /* BSS section */
273   _bss_start = .;
274   .sbss : { *(.sbss) *(.scommon) }
275   .bss : { *(COMMON) *(.bss) }
276   _bss_end = .;
277   _end = .;
278
279   /* only used by the boot loader  */
280
281   . = ALIGN(0x10);
282   .bootstrap : { *(.bootstrap.literal .bootstrap.text .bootstrap.data) }
283
284   . = ALIGN(0x1000);
285   __initrd_start = .;
286   .initrd : { *(.initrd) }
287   __initrd_end = .;
288
289   .ResetVector.text XCHAL_RESET_VECTOR_VADDR :
290   {
291     *(.ResetVector.text)
292   }
293
294
295   /* Sections to be discarded */
296   /DISCARD/ :
297   {
298         *(.text.exit)
299         *(.text.exit.literal)
300         *(.data.exit)
301         *(.exitcall.exit)
302   }
303
304
305   .debug  0 :  { *(.debug) }
306   .line  0 :  { *(.line) }
307   .debug_srcinfo  0 :  { *(.debug_srcinfo) }
308   .debug_sfnames  0 :  { *(.debug_sfnames) }
309   .debug_aranges  0 :  { *(.debug_aranges) }
310   .debug_pubnames  0 :  { *(.debug_pubnames) }
311   .debug_info  0 :  { *(.debug_info) }
312   .debug_abbrev  0 :  { *(.debug_abbrev) }
313   .debug_line  0 :  { *(.debug_line) }
314   .debug_frame  0 :  { *(.debug_frame) }
315   .debug_str  0 :  { *(.debug_str) }
316   .debug_loc  0 :  { *(.debug_loc) }
317   .debug_macinfo  0 :  { *(.debug_macinfo) }
318   .debug_weaknames  0 :  { *(.debug_weaknames) }
319   .debug_funcnames  0 :  { *(.debug_funcnames) }
320   .debug_typenames  0 :  { *(.debug_typenames) }
321   .debug_varnames  0 :  { *(.debug_varnames) }
322
323   .xt.insn 0 :
324   {
325     *(.xt.insn)
326     *(.gnu.linkonce.x*)
327   }
328
329   .xt.lit 0 :
330   {
331     *(.xt.lit)
332     *(.gnu.linkonce.p*)
333   }
334 }