um: take arch/um/sys-x86 to arch/x86/um
[linux-3.10.git] / arch / x86 / um / vdso / vdso-layout.lds.S
1 /*
2  * Linker script for vDSO.  This is an ELF shared object prelinked to
3  * its virtual address, and with only one read-only segment.
4  * This script controls its layout.
5  */
6
7 SECTIONS
8 {
9         . = VDSO_PRELINK + SIZEOF_HEADERS;
10
11         .hash           : { *(.hash) }                  :text
12         .gnu.hash       : { *(.gnu.hash) }
13         .dynsym         : { *(.dynsym) }
14         .dynstr         : { *(.dynstr) }
15         .gnu.version    : { *(.gnu.version) }
16         .gnu.version_d  : { *(.gnu.version_d) }
17         .gnu.version_r  : { *(.gnu.version_r) }
18
19         .note           : { *(.note.*) }                :text   :note
20
21         .eh_frame_hdr   : { *(.eh_frame_hdr) }          :text   :eh_frame_hdr
22         .eh_frame       : { KEEP (*(.eh_frame)) }       :text
23
24         .dynamic        : { *(.dynamic) }               :text   :dynamic
25
26         .rodata         : { *(.rodata*) }               :text
27         .data           : {
28               *(.data*)
29               *(.sdata*)
30               *(.got.plt) *(.got)
31               *(.gnu.linkonce.d.*)
32               *(.bss*)
33               *(.dynbss*)
34               *(.gnu.linkonce.b.*)
35         }
36
37         .altinstructions        : { *(.altinstructions) }
38         .altinstr_replacement   : { *(.altinstr_replacement) }
39
40         /*
41          * Align the actual code well away from the non-instruction data.
42          * This is the best thing for the I-cache.
43          */
44         . = ALIGN(0x100);
45
46         .text           : { *(.text*) }                 :text   =0x90909090
47 }
48
49 /*
50  * Very old versions of ld do not recognize this name token; use the constant.
51  */
52 #define PT_GNU_EH_FRAME 0x6474e550
53
54 /*
55  * We must supply the ELF program headers explicitly to get just one
56  * PT_LOAD segment, and set the flags explicitly to make segments read-only.
57  */
58 PHDRS
59 {
60         text            PT_LOAD         FLAGS(5) FILEHDR PHDRS; /* PF_R|PF_X */
61         dynamic         PT_DYNAMIC      FLAGS(4);               /* PF_R */
62         note            PT_NOTE         FLAGS(4);               /* PF_R */
63         eh_frame_hdr    PT_GNU_EH_FRAME;
64 }