Merge branch 'for-2.6.39' of git://git.kernel.org/pub/scm/linux/kernel/git/tj/wq
[linux-3.10.git] / arch / x86 / kernel / vmlinux.lds.S
1 /*
2  * ld script for the x86 kernel
3  *
4  * Historic 32-bit version written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>
5  *
6  * Modernisation, unification and other changes and fixes:
7  *   Copyright (C) 2007-2009  Sam Ravnborg <sam@ravnborg.org>
8  *
9  *
10  * Don't define absolute symbols until and unless you know that symbol
11  * value is should remain constant even if kernel image is relocated
12  * at run time. Absolute symbols are not relocated. If symbol value should
13  * change if kernel is relocated, make the symbol section relative and
14  * put it inside the section definition.
15  */
16
17 #ifdef CONFIG_X86_32
18 #define LOAD_OFFSET __PAGE_OFFSET
19 #else
20 #define LOAD_OFFSET __START_KERNEL_map
21 #endif
22
23 #include <asm-generic/vmlinux.lds.h>
24 #include <asm/asm-offsets.h>
25 #include <asm/thread_info.h>
26 #include <asm/page_types.h>
27 #include <asm/cache.h>
28 #include <asm/boot.h>
29
30 #undef i386     /* in case the preprocessor is a 32bit one */
31
32 OUTPUT_FORMAT(CONFIG_OUTPUT_FORMAT, CONFIG_OUTPUT_FORMAT, CONFIG_OUTPUT_FORMAT)
33
34 #ifdef CONFIG_X86_32
35 OUTPUT_ARCH(i386)
36 ENTRY(phys_startup_32)
37 jiffies = jiffies_64;
38 #else
39 OUTPUT_ARCH(i386:x86-64)
40 ENTRY(phys_startup_64)
41 jiffies_64 = jiffies;
42 #endif
43
44 #if defined(CONFIG_X86_64) && defined(CONFIG_DEBUG_RODATA)
45 /*
46  * On 64-bit, align RODATA to 2MB so that even with CONFIG_DEBUG_RODATA
47  * we retain large page mappings for boundaries spanning kernel text, rodata
48  * and data sections.
49  *
50  * However, kernel identity mappings will have different RWX permissions
51  * to the pages mapping to text and to the pages padding (which are freed) the
52  * text section. Hence kernel identity mappings will be broken to smaller
53  * pages. For 64-bit, kernel text and kernel identity mappings are different,
54  * so we can enable protection checks that come with CONFIG_DEBUG_RODATA,
55  * as well as retain 2MB large page mappings for kernel text.
56  */
57 #define X64_ALIGN_DEBUG_RODATA_BEGIN    . = ALIGN(HPAGE_SIZE);
58
59 #define X64_ALIGN_DEBUG_RODATA_END                              \
60                 . = ALIGN(HPAGE_SIZE);                          \
61                 __end_rodata_hpage_align = .;
62
63 #else
64
65 #define X64_ALIGN_DEBUG_RODATA_BEGIN
66 #define X64_ALIGN_DEBUG_RODATA_END
67
68 #endif
69
70 PHDRS {
71         text PT_LOAD FLAGS(5);          /* R_E */
72         data PT_LOAD FLAGS(6);          /* RW_ */
73 #ifdef CONFIG_X86_64
74         user PT_LOAD FLAGS(5);          /* R_E */
75 #ifdef CONFIG_SMP
76         percpu PT_LOAD FLAGS(6);        /* RW_ */
77 #endif
78         init PT_LOAD FLAGS(7);          /* RWE */
79 #endif
80         note PT_NOTE FLAGS(0);          /* ___ */
81 }
82
83 SECTIONS
84 {
85 #ifdef CONFIG_X86_32
86         . = LOAD_OFFSET + LOAD_PHYSICAL_ADDR;
87         phys_startup_32 = startup_32 - LOAD_OFFSET;
88 #else
89         . = __START_KERNEL;
90         phys_startup_64 = startup_64 - LOAD_OFFSET;
91 #endif
92
93         /* Text and read-only data */
94         .text :  AT(ADDR(.text) - LOAD_OFFSET) {
95                 _text = .;
96                 /* bootstrapping code */
97                 HEAD_TEXT
98 #ifdef CONFIG_X86_32
99                 . = ALIGN(PAGE_SIZE);
100                 *(.text..page_aligned)
101 #endif
102                 . = ALIGN(8);
103                 _stext = .;
104                 TEXT_TEXT
105                 SCHED_TEXT
106                 LOCK_TEXT
107                 KPROBES_TEXT
108                 ENTRY_TEXT
109                 IRQENTRY_TEXT
110                 *(.fixup)
111                 *(.gnu.warning)
112                 /* End of text section */
113                 _etext = .;
114         } :text = 0x9090
115
116         NOTES :text :note
117
118         EXCEPTION_TABLE(16) :text = 0x9090
119
120 #if defined(CONFIG_DEBUG_RODATA)
121         /* .text should occupy whole number of pages */
122         . = ALIGN(PAGE_SIZE);
123 #endif
124         X64_ALIGN_DEBUG_RODATA_BEGIN
125         RO_DATA(PAGE_SIZE)
126         X64_ALIGN_DEBUG_RODATA_END
127
128         /* Data */
129         .data : AT(ADDR(.data) - LOAD_OFFSET) {
130                 /* Start of data section */
131                 _sdata = .;
132
133                 /* init_task */
134                 INIT_TASK_DATA(THREAD_SIZE)
135
136 #ifdef CONFIG_X86_32
137                 /* 32 bit has nosave before _edata */
138                 NOSAVE_DATA
139 #endif
140
141                 PAGE_ALIGNED_DATA(PAGE_SIZE)
142
143                 CACHELINE_ALIGNED_DATA(L1_CACHE_BYTES)
144
145                 DATA_DATA
146                 CONSTRUCTORS
147
148                 /* rarely changed data like cpu maps */
149                 READ_MOSTLY_DATA(INTERNODE_CACHE_BYTES)
150
151                 /* End of data section */
152                 _edata = .;
153         } :data
154
155 #ifdef CONFIG_X86_64
156
157 #define VSYSCALL_ADDR (-10*1024*1024)
158
159 #define VLOAD_OFFSET (VSYSCALL_ADDR - __vsyscall_0 + LOAD_OFFSET)
160 #define VLOAD(x) (ADDR(x) - VLOAD_OFFSET)
161
162 #define VVIRT_OFFSET (VSYSCALL_ADDR - __vsyscall_0)
163 #define VVIRT(x) (ADDR(x) - VVIRT_OFFSET)
164
165         . = ALIGN(4096);
166         __vsyscall_0 = .;
167
168         . = VSYSCALL_ADDR;
169         .vsyscall_0 : AT(VLOAD(.vsyscall_0)) {
170                 *(.vsyscall_0)
171         } :user
172
173         . = ALIGN(L1_CACHE_BYTES);
174         .vsyscall_fn : AT(VLOAD(.vsyscall_fn)) {
175                 *(.vsyscall_fn)
176         }
177
178         . = ALIGN(L1_CACHE_BYTES);
179         .vsyscall_gtod_data : AT(VLOAD(.vsyscall_gtod_data)) {
180                 *(.vsyscall_gtod_data)
181         }
182
183         vsyscall_gtod_data = VVIRT(.vsyscall_gtod_data);
184         .vsyscall_clock : AT(VLOAD(.vsyscall_clock)) {
185                 *(.vsyscall_clock)
186         }
187         vsyscall_clock = VVIRT(.vsyscall_clock);
188
189
190         .vsyscall_1 ADDR(.vsyscall_0) + 1024: AT(VLOAD(.vsyscall_1)) {
191                 *(.vsyscall_1)
192         }
193         .vsyscall_2 ADDR(.vsyscall_0) + 2048: AT(VLOAD(.vsyscall_2)) {
194                 *(.vsyscall_2)
195         }
196
197         .vgetcpu_mode : AT(VLOAD(.vgetcpu_mode)) {
198                 *(.vgetcpu_mode)
199         }
200         vgetcpu_mode = VVIRT(.vgetcpu_mode);
201
202         . = ALIGN(L1_CACHE_BYTES);
203         .jiffies : AT(VLOAD(.jiffies)) {
204                 *(.jiffies)
205         }
206         jiffies = VVIRT(.jiffies);
207
208         .vsyscall_3 ADDR(.vsyscall_0) + 3072: AT(VLOAD(.vsyscall_3)) {
209                 *(.vsyscall_3)
210         }
211
212         . = __vsyscall_0 + PAGE_SIZE;
213
214 #undef VSYSCALL_ADDR
215 #undef VLOAD_OFFSET
216 #undef VLOAD
217 #undef VVIRT_OFFSET
218 #undef VVIRT
219
220 #endif /* CONFIG_X86_64 */
221
222         /* Init code and data - will be freed after init */
223         . = ALIGN(PAGE_SIZE);
224         .init.begin : AT(ADDR(.init.begin) - LOAD_OFFSET) {
225                 __init_begin = .; /* paired with __init_end */
226         }
227
228 #if defined(CONFIG_X86_64) && defined(CONFIG_SMP)
229         /*
230          * percpu offsets are zero-based on SMP.  PERCPU_VADDR() changes the
231          * output PHDR, so the next output section - .init.text - should
232          * start another segment - init.
233          */
234         PERCPU_VADDR(0, :percpu)
235 #endif
236
237         INIT_TEXT_SECTION(PAGE_SIZE)
238 #ifdef CONFIG_X86_64
239         :init
240 #endif
241
242         INIT_DATA_SECTION(16)
243
244         .x86_cpu_dev.init : AT(ADDR(.x86_cpu_dev.init) - LOAD_OFFSET) {
245                 __x86_cpu_dev_start = .;
246                 *(.x86_cpu_dev.init)
247                 __x86_cpu_dev_end = .;
248         }
249
250         /*
251          * start address and size of operations which during runtime
252          * can be patched with virtualization friendly instructions or
253          * baremetal native ones. Think page table operations.
254          * Details in paravirt_types.h
255          */
256         . = ALIGN(8);
257         .parainstructions : AT(ADDR(.parainstructions) - LOAD_OFFSET) {
258                 __parainstructions = .;
259                 *(.parainstructions)
260                 __parainstructions_end = .;
261         }
262
263         /*
264          * struct alt_inst entries. From the header (alternative.h):
265          * "Alternative instructions for different CPU types or capabilities"
266          * Think locking instructions on spinlocks.
267          */
268         . = ALIGN(8);
269         .altinstructions : AT(ADDR(.altinstructions) - LOAD_OFFSET) {
270                 __alt_instructions = .;
271                 *(.altinstructions)
272                 __alt_instructions_end = .;
273         }
274
275         /*
276          * And here are the replacement instructions. The linker sticks
277          * them as binary blobs. The .altinstructions has enough data to
278          * get the address and the length of them to patch the kernel safely.
279          */
280         .altinstr_replacement : AT(ADDR(.altinstr_replacement) - LOAD_OFFSET) {
281                 *(.altinstr_replacement)
282         }
283
284         /*
285          * struct iommu_table_entry entries are injected in this section.
286          * It is an array of IOMMUs which during run time gets sorted depending
287          * on its dependency order. After rootfs_initcall is complete
288          * this section can be safely removed.
289          */
290         .iommu_table : AT(ADDR(.iommu_table) - LOAD_OFFSET) {
291                 __iommu_table = .;
292                 *(.iommu_table)
293                 __iommu_table_end = .;
294         }
295         . = ALIGN(8);
296         /*
297          * .exit.text is discard at runtime, not link time, to deal with
298          *  references from .altinstructions and .eh_frame
299          */
300         .exit.text : AT(ADDR(.exit.text) - LOAD_OFFSET) {
301                 EXIT_TEXT
302         }
303
304         .exit.data : AT(ADDR(.exit.data) - LOAD_OFFSET) {
305                 EXIT_DATA
306         }
307
308 #if !defined(CONFIG_X86_64) || !defined(CONFIG_SMP)
309         PERCPU(PAGE_SIZE)
310 #endif
311
312         . = ALIGN(PAGE_SIZE);
313
314         /* freed after init ends here */
315         .init.end : AT(ADDR(.init.end) - LOAD_OFFSET) {
316                 __init_end = .;
317         }
318
319         /*
320          * smp_locks might be freed after init
321          * start/end must be page aligned
322          */
323         . = ALIGN(PAGE_SIZE);
324         .smp_locks : AT(ADDR(.smp_locks) - LOAD_OFFSET) {
325                 __smp_locks = .;
326                 *(.smp_locks)
327                 . = ALIGN(PAGE_SIZE);
328                 __smp_locks_end = .;
329         }
330
331 #ifdef CONFIG_X86_64
332         .data_nosave : AT(ADDR(.data_nosave) - LOAD_OFFSET) {
333                 NOSAVE_DATA
334         }
335 #endif
336
337         /* BSS */
338         . = ALIGN(PAGE_SIZE);
339         .bss : AT(ADDR(.bss) - LOAD_OFFSET) {
340                 __bss_start = .;
341                 *(.bss..page_aligned)
342                 *(.bss)
343                 . = ALIGN(PAGE_SIZE);
344                 __bss_stop = .;
345         }
346
347         . = ALIGN(PAGE_SIZE);
348         .brk : AT(ADDR(.brk) - LOAD_OFFSET) {
349                 __brk_base = .;
350                 . += 64 * 1024;         /* 64k alignment slop space */
351                 *(.brk_reservation)     /* areas brk users have reserved */
352                 __brk_limit = .;
353         }
354
355         _end = .;
356
357         STABS_DEBUG
358         DWARF_DEBUG
359
360         /* Sections to be discarded */
361         DISCARDS
362         /DISCARD/ : { *(.eh_frame) }
363 }
364
365
366 #ifdef CONFIG_X86_32
367 /*
368  * The ASSERT() sink to . is intentional, for binutils 2.14 compatibility:
369  */
370 . = ASSERT((_end - LOAD_OFFSET <= KERNEL_IMAGE_SIZE),
371            "kernel image bigger than KERNEL_IMAGE_SIZE");
372 #else
373 /*
374  * Per-cpu symbols which need to be offset from __per_cpu_load
375  * for the boot processor.
376  */
377 #define INIT_PER_CPU(x) init_per_cpu__##x = x + __per_cpu_load
378 INIT_PER_CPU(gdt_page);
379 INIT_PER_CPU(irq_stack_union);
380
381 /*
382  * Build-time check on the image size:
383  */
384 . = ASSERT((_end - _text <= KERNEL_IMAGE_SIZE),
385            "kernel image bigger than KERNEL_IMAGE_SIZE");
386
387 #ifdef CONFIG_SMP
388 . = ASSERT((irq_stack_union == 0),
389            "irq_stack_union is not at start of per-cpu area");
390 #endif
391
392 #endif /* CONFIG_X86_32 */
393
394 #ifdef CONFIG_KEXEC
395 #include <asm/kexec.h>
396
397 . = ASSERT(kexec_control_code_size <= KEXEC_CONTROL_CODE_MAX_SIZE,
398            "kexec control code size is too big");
399 #endif
400