x86, smep, smap: Make the switching functions one-way
[linux-3.10.git] / arch / x86 / kernel / entry_64.S
1 /*
2  *  linux/arch/x86_64/entry.S
3  *
4  *  Copyright (C) 1991, 1992  Linus Torvalds
5  *  Copyright (C) 2000, 2001, 2002  Andi Kleen SuSE Labs
6  *  Copyright (C) 2000  Pavel Machek <pavel@suse.cz>
7  */
8
9 /*
10  * entry.S contains the system-call and fault low-level handling routines.
11  *
12  * Some of this is documented in Documentation/x86/entry_64.txt
13  *
14  * NOTE: This code handles signal-recognition, which happens every time
15  * after an interrupt and after each system call.
16  *
17  * Normal syscalls and interrupts don't save a full stack frame, this is
18  * only done for syscall tracing, signals or fork/exec et.al.
19  *
20  * A note on terminology:
21  * - top of stack: Architecture defined interrupt frame from SS to RIP
22  * at the top of the kernel process stack.
23  * - partial stack frame: partially saved registers up to R11.
24  * - full stack frame: Like partial stack frame, but all register saved.
25  *
26  * Some macro usage:
27  * - CFI macros are used to generate dwarf2 unwind information for better
28  * backtraces. They don't change any code.
29  * - SAVE_ALL/RESTORE_ALL - Save/restore all registers
30  * - SAVE_ARGS/RESTORE_ARGS - Save/restore registers that C functions modify.
31  * There are unfortunately lots of special cases where some registers
32  * not touched. The macro is a big mess that should be cleaned up.
33  * - SAVE_REST/RESTORE_REST - Handle the registers not saved by SAVE_ARGS.
34  * Gives a full stack frame.
35  * - ENTRY/END Define functions in the symbol table.
36  * - FIXUP_TOP_OF_STACK/RESTORE_TOP_OF_STACK - Fix up the hardware stack
37  * frame that is otherwise undefined after a SYSCALL
38  * - TRACE_IRQ_* - Trace hard interrupt state for lock debugging.
39  * - errorentry/paranoidentry/zeroentry - Define exception entry points.
40  */
41
42 #include <linux/linkage.h>
43 #include <asm/segment.h>
44 #include <asm/cache.h>
45 #include <asm/errno.h>
46 #include <asm/dwarf2.h>
47 #include <asm/calling.h>
48 #include <asm/asm-offsets.h>
49 #include <asm/msr.h>
50 #include <asm/unistd.h>
51 #include <asm/thread_info.h>
52 #include <asm/hw_irq.h>
53 #include <asm/page_types.h>
54 #include <asm/irqflags.h>
55 #include <asm/paravirt.h>
56 #include <asm/ftrace.h>
57 #include <asm/percpu.h>
58 #include <asm/asm.h>
59 #include <asm/smap.h>
60 #include <linux/err.h>
61
62 /* Avoid __ASSEMBLER__'ifying <linux/audit.h> just for this.  */
63 #include <linux/elf-em.h>
64 #define AUDIT_ARCH_X86_64       (EM_X86_64|__AUDIT_ARCH_64BIT|__AUDIT_ARCH_LE)
65 #define __AUDIT_ARCH_64BIT 0x80000000
66 #define __AUDIT_ARCH_LE    0x40000000
67
68         .code64
69         .section .entry.text, "ax"
70
71 #ifdef CONFIG_FUNCTION_TRACER
72 #ifdef CONFIG_DYNAMIC_FTRACE
73 ENTRY(mcount)
74         retq
75 END(mcount)
76
77 ENTRY(ftrace_caller)
78         cmpl $0, function_trace_stop
79         jne  ftrace_stub
80
81         MCOUNT_SAVE_FRAME
82
83         movq 0x38(%rsp), %rdi
84         movq 8(%rbp), %rsi
85         subq $MCOUNT_INSN_SIZE, %rdi
86
87 GLOBAL(ftrace_call)
88         call ftrace_stub
89
90         MCOUNT_RESTORE_FRAME
91
92 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
93 GLOBAL(ftrace_graph_call)
94         jmp ftrace_stub
95 #endif
96
97 GLOBAL(ftrace_stub)
98         retq
99 END(ftrace_caller)
100
101 #else /* ! CONFIG_DYNAMIC_FTRACE */
102 ENTRY(mcount)
103         cmpl $0, function_trace_stop
104         jne  ftrace_stub
105
106         cmpq $ftrace_stub, ftrace_trace_function
107         jnz trace
108
109 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
110         cmpq $ftrace_stub, ftrace_graph_return
111         jnz ftrace_graph_caller
112
113         cmpq $ftrace_graph_entry_stub, ftrace_graph_entry
114         jnz ftrace_graph_caller
115 #endif
116
117 GLOBAL(ftrace_stub)
118         retq
119
120 trace:
121         MCOUNT_SAVE_FRAME
122
123         movq 0x38(%rsp), %rdi
124         movq 8(%rbp), %rsi
125         subq $MCOUNT_INSN_SIZE, %rdi
126
127         call   *ftrace_trace_function
128
129         MCOUNT_RESTORE_FRAME
130
131         jmp ftrace_stub
132 END(mcount)
133 #endif /* CONFIG_DYNAMIC_FTRACE */
134 #endif /* CONFIG_FUNCTION_TRACER */
135
136 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
137 ENTRY(ftrace_graph_caller)
138         cmpl $0, function_trace_stop
139         jne ftrace_stub
140
141         MCOUNT_SAVE_FRAME
142
143         leaq 8(%rbp), %rdi
144         movq 0x38(%rsp), %rsi
145         movq (%rbp), %rdx
146         subq $MCOUNT_INSN_SIZE, %rsi
147
148         call    prepare_ftrace_return
149
150         MCOUNT_RESTORE_FRAME
151
152         retq
153 END(ftrace_graph_caller)
154
155 GLOBAL(return_to_handler)
156         subq  $24, %rsp
157
158         /* Save the return values */
159         movq %rax, (%rsp)
160         movq %rdx, 8(%rsp)
161         movq %rbp, %rdi
162
163         call ftrace_return_to_handler
164
165         movq %rax, %rdi
166         movq 8(%rsp), %rdx
167         movq (%rsp), %rax
168         addq $24, %rsp
169         jmp *%rdi
170 #endif
171
172
173 #ifndef CONFIG_PREEMPT
174 #define retint_kernel retint_restore_args
175 #endif
176
177 #ifdef CONFIG_PARAVIRT
178 ENTRY(native_usergs_sysret64)
179         swapgs
180         sysretq
181 ENDPROC(native_usergs_sysret64)
182 #endif /* CONFIG_PARAVIRT */
183
184
185 .macro TRACE_IRQS_IRETQ offset=ARGOFFSET
186 #ifdef CONFIG_TRACE_IRQFLAGS
187         bt   $9,EFLAGS-\offset(%rsp)    /* interrupts off? */
188         jnc  1f
189         TRACE_IRQS_ON
190 1:
191 #endif
192 .endm
193
194 /*
195  * When dynamic function tracer is enabled it will add a breakpoint
196  * to all locations that it is about to modify, sync CPUs, update
197  * all the code, sync CPUs, then remove the breakpoints. In this time
198  * if lockdep is enabled, it might jump back into the debug handler
199  * outside the updating of the IST protection. (TRACE_IRQS_ON/OFF).
200  *
201  * We need to change the IDT table before calling TRACE_IRQS_ON/OFF to
202  * make sure the stack pointer does not get reset back to the top
203  * of the debug stack, and instead just reuses the current stack.
204  */
205 #if defined(CONFIG_DYNAMIC_FTRACE) && defined(CONFIG_TRACE_IRQFLAGS)
206
207 .macro TRACE_IRQS_OFF_DEBUG
208         call debug_stack_set_zero
209         TRACE_IRQS_OFF
210         call debug_stack_reset
211 .endm
212
213 .macro TRACE_IRQS_ON_DEBUG
214         call debug_stack_set_zero
215         TRACE_IRQS_ON
216         call debug_stack_reset
217 .endm
218
219 .macro TRACE_IRQS_IRETQ_DEBUG offset=ARGOFFSET
220         bt   $9,EFLAGS-\offset(%rsp)    /* interrupts off? */
221         jnc  1f
222         TRACE_IRQS_ON_DEBUG
223 1:
224 .endm
225
226 #else
227 # define TRACE_IRQS_OFF_DEBUG           TRACE_IRQS_OFF
228 # define TRACE_IRQS_ON_DEBUG            TRACE_IRQS_ON
229 # define TRACE_IRQS_IRETQ_DEBUG         TRACE_IRQS_IRETQ
230 #endif
231
232 /*
233  * C code is not supposed to know about undefined top of stack. Every time
234  * a C function with an pt_regs argument is called from the SYSCALL based
235  * fast path FIXUP_TOP_OF_STACK is needed.
236  * RESTORE_TOP_OF_STACK syncs the syscall state after any possible ptregs
237  * manipulation.
238  */
239
240         /* %rsp:at FRAMEEND */
241         .macro FIXUP_TOP_OF_STACK tmp offset=0
242         movq PER_CPU_VAR(old_rsp),\tmp
243         movq \tmp,RSP+\offset(%rsp)
244         movq $__USER_DS,SS+\offset(%rsp)
245         movq $__USER_CS,CS+\offset(%rsp)
246         movq $-1,RCX+\offset(%rsp)
247         movq R11+\offset(%rsp),\tmp  /* get eflags */
248         movq \tmp,EFLAGS+\offset(%rsp)
249         .endm
250
251         .macro RESTORE_TOP_OF_STACK tmp offset=0
252         movq RSP+\offset(%rsp),\tmp
253         movq \tmp,PER_CPU_VAR(old_rsp)
254         movq EFLAGS+\offset(%rsp),\tmp
255         movq \tmp,R11+\offset(%rsp)
256         .endm
257
258         .macro FAKE_STACK_FRAME child_rip
259         /* push in order ss, rsp, eflags, cs, rip */
260         xorl %eax, %eax
261         pushq_cfi $__KERNEL_DS /* ss */
262         /*CFI_REL_OFFSET        ss,0*/
263         pushq_cfi %rax /* rsp */
264         CFI_REL_OFFSET  rsp,0
265         pushq_cfi $(X86_EFLAGS_IF|X86_EFLAGS_BIT1) /* eflags - interrupts on */
266         /*CFI_REL_OFFSET        rflags,0*/
267         pushq_cfi $__KERNEL_CS /* cs */
268         /*CFI_REL_OFFSET        cs,0*/
269         pushq_cfi \child_rip /* rip */
270         CFI_REL_OFFSET  rip,0
271         pushq_cfi %rax /* orig rax */
272         .endm
273
274         .macro UNFAKE_STACK_FRAME
275         addq $8*6, %rsp
276         CFI_ADJUST_CFA_OFFSET   -(6*8)
277         .endm
278
279 /*
280  * initial frame state for interrupts (and exceptions without error code)
281  */
282         .macro EMPTY_FRAME start=1 offset=0
283         .if \start
284         CFI_STARTPROC simple
285         CFI_SIGNAL_FRAME
286         CFI_DEF_CFA rsp,8+\offset
287         .else
288         CFI_DEF_CFA_OFFSET 8+\offset
289         .endif
290         .endm
291
292 /*
293  * initial frame state for interrupts (and exceptions without error code)
294  */
295         .macro INTR_FRAME start=1 offset=0
296         EMPTY_FRAME \start, SS+8+\offset-RIP
297         /*CFI_REL_OFFSET ss, SS+\offset-RIP*/
298         CFI_REL_OFFSET rsp, RSP+\offset-RIP
299         /*CFI_REL_OFFSET rflags, EFLAGS+\offset-RIP*/
300         /*CFI_REL_OFFSET cs, CS+\offset-RIP*/
301         CFI_REL_OFFSET rip, RIP+\offset-RIP
302         .endm
303
304 /*
305  * initial frame state for exceptions with error code (and interrupts
306  * with vector already pushed)
307  */
308         .macro XCPT_FRAME start=1 offset=0
309         INTR_FRAME \start, RIP+\offset-ORIG_RAX
310         /*CFI_REL_OFFSET orig_rax, ORIG_RAX-ORIG_RAX*/
311         .endm
312
313 /*
314  * frame that enables calling into C.
315  */
316         .macro PARTIAL_FRAME start=1 offset=0
317         XCPT_FRAME \start, ORIG_RAX+\offset-ARGOFFSET
318         CFI_REL_OFFSET rdi, RDI+\offset-ARGOFFSET
319         CFI_REL_OFFSET rsi, RSI+\offset-ARGOFFSET
320         CFI_REL_OFFSET rdx, RDX+\offset-ARGOFFSET
321         CFI_REL_OFFSET rcx, RCX+\offset-ARGOFFSET
322         CFI_REL_OFFSET rax, RAX+\offset-ARGOFFSET
323         CFI_REL_OFFSET r8, R8+\offset-ARGOFFSET
324         CFI_REL_OFFSET r9, R9+\offset-ARGOFFSET
325         CFI_REL_OFFSET r10, R10+\offset-ARGOFFSET
326         CFI_REL_OFFSET r11, R11+\offset-ARGOFFSET
327         .endm
328
329 /*
330  * frame that enables passing a complete pt_regs to a C function.
331  */
332         .macro DEFAULT_FRAME start=1 offset=0
333         PARTIAL_FRAME \start, R11+\offset-R15
334         CFI_REL_OFFSET rbx, RBX+\offset
335         CFI_REL_OFFSET rbp, RBP+\offset
336         CFI_REL_OFFSET r12, R12+\offset
337         CFI_REL_OFFSET r13, R13+\offset
338         CFI_REL_OFFSET r14, R14+\offset
339         CFI_REL_OFFSET r15, R15+\offset
340         .endm
341
342 /* save partial stack frame */
343         .macro SAVE_ARGS_IRQ
344         cld
345         /* start from rbp in pt_regs and jump over */
346         movq_cfi rdi, RDI-RBP
347         movq_cfi rsi, RSI-RBP
348         movq_cfi rdx, RDX-RBP
349         movq_cfi rcx, RCX-RBP
350         movq_cfi rax, RAX-RBP
351         movq_cfi  r8,  R8-RBP
352         movq_cfi  r9,  R9-RBP
353         movq_cfi r10, R10-RBP
354         movq_cfi r11, R11-RBP
355
356         /* Save rbp so that we can unwind from get_irq_regs() */
357         movq_cfi rbp, 0
358
359         /* Save previous stack value */
360         movq %rsp, %rsi
361
362         leaq -RBP(%rsp),%rdi    /* arg1 for handler */
363         testl $3, CS-RBP(%rsi)
364         je 1f
365         SWAPGS
366         /*
367          * irq_count is used to check if a CPU is already on an interrupt stack
368          * or not. While this is essentially redundant with preempt_count it is
369          * a little cheaper to use a separate counter in the PDA (short of
370          * moving irq_enter into assembly, which would be too much work)
371          */
372 1:      incl PER_CPU_VAR(irq_count)
373         cmovzq PER_CPU_VAR(irq_stack_ptr),%rsp
374         CFI_DEF_CFA_REGISTER    rsi
375
376         /* Store previous stack value */
377         pushq %rsi
378         CFI_ESCAPE      0x0f /* DW_CFA_def_cfa_expression */, 6, \
379                         0x77 /* DW_OP_breg7 */, 0, \
380                         0x06 /* DW_OP_deref */, \
381                         0x08 /* DW_OP_const1u */, SS+8-RBP, \
382                         0x22 /* DW_OP_plus */
383         /* We entered an interrupt context - irqs are off: */
384         TRACE_IRQS_OFF
385         .endm
386
387 ENTRY(save_rest)
388         PARTIAL_FRAME 1 REST_SKIP+8
389         movq 5*8+16(%rsp), %r11 /* save return address */
390         movq_cfi rbx, RBX+16
391         movq_cfi rbp, RBP+16
392         movq_cfi r12, R12+16
393         movq_cfi r13, R13+16
394         movq_cfi r14, R14+16
395         movq_cfi r15, R15+16
396         movq %r11, 8(%rsp)      /* return address */
397         FIXUP_TOP_OF_STACK %r11, 16
398         ret
399         CFI_ENDPROC
400 END(save_rest)
401
402 /* save complete stack frame */
403         .pushsection .kprobes.text, "ax"
404 ENTRY(save_paranoid)
405         XCPT_FRAME 1 RDI+8
406         cld
407         movq_cfi rdi, RDI+8
408         movq_cfi rsi, RSI+8
409         movq_cfi rdx, RDX+8
410         movq_cfi rcx, RCX+8
411         movq_cfi rax, RAX+8
412         movq_cfi r8, R8+8
413         movq_cfi r9, R9+8
414         movq_cfi r10, R10+8
415         movq_cfi r11, R11+8
416         movq_cfi rbx, RBX+8
417         movq_cfi rbp, RBP+8
418         movq_cfi r12, R12+8
419         movq_cfi r13, R13+8
420         movq_cfi r14, R14+8
421         movq_cfi r15, R15+8
422         movl $1,%ebx
423         movl $MSR_GS_BASE,%ecx
424         rdmsr
425         testl %edx,%edx
426         js 1f   /* negative -> in kernel */
427         SWAPGS
428         xorl %ebx,%ebx
429 1:      ret
430         CFI_ENDPROC
431 END(save_paranoid)
432         .popsection
433
434 /*
435  * A newly forked process directly context switches into this address.
436  *
437  * rdi: prev task we switched from
438  */
439 ENTRY(ret_from_fork)
440         DEFAULT_FRAME
441
442         LOCK ; btr $TIF_FORK,TI_flags(%r8)
443
444         pushq_cfi kernel_eflags(%rip)
445         popfq_cfi                               # reset kernel eflags
446
447         call schedule_tail                      # rdi: 'prev' task parameter
448
449         GET_THREAD_INFO(%rcx)
450
451         RESTORE_REST
452
453         testl $3, CS-ARGOFFSET(%rsp)            # from kernel_thread?
454         jz   retint_restore_args
455
456         testl $_TIF_IA32, TI_flags(%rcx)        # 32-bit compat task needs IRET
457         jnz  int_ret_from_sys_call
458
459         RESTORE_TOP_OF_STACK %rdi, -ARGOFFSET
460         jmp ret_from_sys_call                   # go to the SYSRET fastpath
461
462         CFI_ENDPROC
463 END(ret_from_fork)
464
465 /*
466  * System call entry. Up to 6 arguments in registers are supported.
467  *
468  * SYSCALL does not save anything on the stack and does not change the
469  * stack pointer.  However, it does mask the flags register for us, so
470  * CLD and CLAC are not needed.
471  */
472
473 /*
474  * Register setup:
475  * rax  system call number
476  * rdi  arg0
477  * rcx  return address for syscall/sysret, C arg3
478  * rsi  arg1
479  * rdx  arg2
480  * r10  arg3    (--> moved to rcx for C)
481  * r8   arg4
482  * r9   arg5
483  * r11  eflags for syscall/sysret, temporary for C
484  * r12-r15,rbp,rbx saved by C code, not touched.
485  *
486  * Interrupts are off on entry.
487  * Only called from user space.
488  *
489  * XXX  if we had a free scratch register we could save the RSP into the stack frame
490  *      and report it properly in ps. Unfortunately we haven't.
491  *
492  * When user can change the frames always force IRET. That is because
493  * it deals with uncanonical addresses better. SYSRET has trouble
494  * with them due to bugs in both AMD and Intel CPUs.
495  */
496
497 ENTRY(system_call)
498         CFI_STARTPROC   simple
499         CFI_SIGNAL_FRAME
500         CFI_DEF_CFA     rsp,KERNEL_STACK_OFFSET
501         CFI_REGISTER    rip,rcx
502         /*CFI_REGISTER  rflags,r11*/
503         SWAPGS_UNSAFE_STACK
504         /*
505          * A hypervisor implementation might want to use a label
506          * after the swapgs, so that it can do the swapgs
507          * for the guest and jump here on syscall.
508          */
509 GLOBAL(system_call_after_swapgs)
510
511         movq    %rsp,PER_CPU_VAR(old_rsp)
512         movq    PER_CPU_VAR(kernel_stack),%rsp
513         /*
514          * No need to follow this irqs off/on section - it's straight
515          * and short:
516          */
517         ENABLE_INTERRUPTS(CLBR_NONE)
518         SAVE_ARGS 8,0
519         movq  %rax,ORIG_RAX-ARGOFFSET(%rsp)
520         movq  %rcx,RIP-ARGOFFSET(%rsp)
521         CFI_REL_OFFSET rip,RIP-ARGOFFSET
522         testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags+THREAD_INFO(%rsp,RIP-ARGOFFSET)
523         jnz tracesys
524 system_call_fastpath:
525 #if __SYSCALL_MASK == ~0
526         cmpq $__NR_syscall_max,%rax
527 #else
528         andl $__SYSCALL_MASK,%eax
529         cmpl $__NR_syscall_max,%eax
530 #endif
531         ja badsys
532         movq %r10,%rcx
533         call *sys_call_table(,%rax,8)  # XXX:    rip relative
534         movq %rax,RAX-ARGOFFSET(%rsp)
535 /*
536  * Syscall return path ending with SYSRET (fast path)
537  * Has incomplete stack frame and undefined top of stack.
538  */
539 ret_from_sys_call:
540         movl $_TIF_ALLWORK_MASK,%edi
541         /* edi: flagmask */
542 sysret_check:
543         LOCKDEP_SYS_EXIT
544         DISABLE_INTERRUPTS(CLBR_NONE)
545         TRACE_IRQS_OFF
546         movl TI_flags+THREAD_INFO(%rsp,RIP-ARGOFFSET),%edx
547         andl %edi,%edx
548         jnz  sysret_careful
549         CFI_REMEMBER_STATE
550         /*
551          * sysretq will re-enable interrupts:
552          */
553         TRACE_IRQS_ON
554         movq RIP-ARGOFFSET(%rsp),%rcx
555         CFI_REGISTER    rip,rcx
556         RESTORE_ARGS 1,-ARG_SKIP,0
557         /*CFI_REGISTER  rflags,r11*/
558         movq    PER_CPU_VAR(old_rsp), %rsp
559         USERGS_SYSRET64
560
561         CFI_RESTORE_STATE
562         /* Handle reschedules */
563         /* edx: work, edi: workmask */
564 sysret_careful:
565         bt $TIF_NEED_RESCHED,%edx
566         jnc sysret_signal
567         TRACE_IRQS_ON
568         ENABLE_INTERRUPTS(CLBR_NONE)
569         pushq_cfi %rdi
570         call schedule
571         popq_cfi %rdi
572         jmp sysret_check
573
574         /* Handle a signal */
575 sysret_signal:
576         TRACE_IRQS_ON
577         ENABLE_INTERRUPTS(CLBR_NONE)
578 #ifdef CONFIG_AUDITSYSCALL
579         bt $TIF_SYSCALL_AUDIT,%edx
580         jc sysret_audit
581 #endif
582         /*
583          * We have a signal, or exit tracing or single-step.
584          * These all wind up with the iret return path anyway,
585          * so just join that path right now.
586          */
587         FIXUP_TOP_OF_STACK %r11, -ARGOFFSET
588         jmp int_check_syscall_exit_work
589
590 badsys:
591         movq $-ENOSYS,RAX-ARGOFFSET(%rsp)
592         jmp ret_from_sys_call
593
594 #ifdef CONFIG_AUDITSYSCALL
595         /*
596          * Fast path for syscall audit without full syscall trace.
597          * We just call __audit_syscall_entry() directly, and then
598          * jump back to the normal fast path.
599          */
600 auditsys:
601         movq %r10,%r9                   /* 6th arg: 4th syscall arg */
602         movq %rdx,%r8                   /* 5th arg: 3rd syscall arg */
603         movq %rsi,%rcx                  /* 4th arg: 2nd syscall arg */
604         movq %rdi,%rdx                  /* 3rd arg: 1st syscall arg */
605         movq %rax,%rsi                  /* 2nd arg: syscall number */
606         movl $AUDIT_ARCH_X86_64,%edi    /* 1st arg: audit arch */
607         call __audit_syscall_entry
608         LOAD_ARGS 0             /* reload call-clobbered registers */
609         jmp system_call_fastpath
610
611         /*
612          * Return fast path for syscall audit.  Call __audit_syscall_exit()
613          * directly and then jump back to the fast path with TIF_SYSCALL_AUDIT
614          * masked off.
615          */
616 sysret_audit:
617         movq RAX-ARGOFFSET(%rsp),%rsi   /* second arg, syscall return value */
618         cmpq $-MAX_ERRNO,%rsi   /* is it < -MAX_ERRNO? */
619         setbe %al               /* 1 if so, 0 if not */
620         movzbl %al,%edi         /* zero-extend that into %edi */
621         call __audit_syscall_exit
622         movl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT),%edi
623         jmp sysret_check
624 #endif  /* CONFIG_AUDITSYSCALL */
625
626         /* Do syscall tracing */
627 tracesys:
628 #ifdef CONFIG_AUDITSYSCALL
629         testl $(_TIF_WORK_SYSCALL_ENTRY & ~_TIF_SYSCALL_AUDIT),TI_flags+THREAD_INFO(%rsp,RIP-ARGOFFSET)
630         jz auditsys
631 #endif
632         SAVE_REST
633         movq $-ENOSYS,RAX(%rsp) /* ptrace can change this for a bad syscall */
634         FIXUP_TOP_OF_STACK %rdi
635         movq %rsp,%rdi
636         call syscall_trace_enter
637         /*
638          * Reload arg registers from stack in case ptrace changed them.
639          * We don't reload %rax because syscall_trace_enter() returned
640          * the value it wants us to use in the table lookup.
641          */
642         LOAD_ARGS ARGOFFSET, 1
643         RESTORE_REST
644 #if __SYSCALL_MASK == ~0
645         cmpq $__NR_syscall_max,%rax
646 #else
647         andl $__SYSCALL_MASK,%eax
648         cmpl $__NR_syscall_max,%eax
649 #endif
650         ja   int_ret_from_sys_call      /* RAX(%rsp) set to -ENOSYS above */
651         movq %r10,%rcx  /* fixup for C */
652         call *sys_call_table(,%rax,8)
653         movq %rax,RAX-ARGOFFSET(%rsp)
654         /* Use IRET because user could have changed frame */
655
656 /*
657  * Syscall return path ending with IRET.
658  * Has correct top of stack, but partial stack frame.
659  */
660 GLOBAL(int_ret_from_sys_call)
661         DISABLE_INTERRUPTS(CLBR_NONE)
662         TRACE_IRQS_OFF
663         movl $_TIF_ALLWORK_MASK,%edi
664         /* edi: mask to check */
665 GLOBAL(int_with_check)
666         LOCKDEP_SYS_EXIT_IRQ
667         GET_THREAD_INFO(%rcx)
668         movl TI_flags(%rcx),%edx
669         andl %edi,%edx
670         jnz   int_careful
671         andl    $~TS_COMPAT,TI_status(%rcx)
672         jmp   retint_swapgs
673
674         /* Either reschedule or signal or syscall exit tracking needed. */
675         /* First do a reschedule test. */
676         /* edx: work, edi: workmask */
677 int_careful:
678         bt $TIF_NEED_RESCHED,%edx
679         jnc  int_very_careful
680         TRACE_IRQS_ON
681         ENABLE_INTERRUPTS(CLBR_NONE)
682         pushq_cfi %rdi
683         call schedule
684         popq_cfi %rdi
685         DISABLE_INTERRUPTS(CLBR_NONE)
686         TRACE_IRQS_OFF
687         jmp int_with_check
688
689         /* handle signals and tracing -- both require a full stack frame */
690 int_very_careful:
691         TRACE_IRQS_ON
692         ENABLE_INTERRUPTS(CLBR_NONE)
693 int_check_syscall_exit_work:
694         SAVE_REST
695         /* Check for syscall exit trace */
696         testl $_TIF_WORK_SYSCALL_EXIT,%edx
697         jz int_signal
698         pushq_cfi %rdi
699         leaq 8(%rsp),%rdi       # &ptregs -> arg1
700         call syscall_trace_leave
701         popq_cfi %rdi
702         andl $~(_TIF_WORK_SYSCALL_EXIT|_TIF_SYSCALL_EMU),%edi
703         jmp int_restore_rest
704
705 int_signal:
706         testl $_TIF_DO_NOTIFY_MASK,%edx
707         jz 1f
708         movq %rsp,%rdi          # &ptregs -> arg1
709         xorl %esi,%esi          # oldset -> arg2
710         call do_notify_resume
711 1:      movl $_TIF_WORK_MASK,%edi
712 int_restore_rest:
713         RESTORE_REST
714         DISABLE_INTERRUPTS(CLBR_NONE)
715         TRACE_IRQS_OFF
716         jmp int_with_check
717         CFI_ENDPROC
718 END(system_call)
719
720 /*
721  * Certain special system calls that need to save a complete full stack frame.
722  */
723         .macro PTREGSCALL label,func,arg
724 ENTRY(\label)
725         PARTIAL_FRAME 1 8               /* offset 8: return address */
726         subq $REST_SKIP, %rsp
727         CFI_ADJUST_CFA_OFFSET REST_SKIP
728         call save_rest
729         DEFAULT_FRAME 0 8               /* offset 8: return address */
730         leaq 8(%rsp), \arg      /* pt_regs pointer */
731         call \func
732         jmp ptregscall_common
733         CFI_ENDPROC
734 END(\label)
735         .endm
736
737         PTREGSCALL stub_clone, sys_clone, %r8
738         PTREGSCALL stub_fork, sys_fork, %rdi
739         PTREGSCALL stub_vfork, sys_vfork, %rdi
740         PTREGSCALL stub_sigaltstack, sys_sigaltstack, %rdx
741         PTREGSCALL stub_iopl, sys_iopl, %rsi
742
743 ENTRY(ptregscall_common)
744         DEFAULT_FRAME 1 8       /* offset 8: return address */
745         RESTORE_TOP_OF_STACK %r11, 8
746         movq_cfi_restore R15+8, r15
747         movq_cfi_restore R14+8, r14
748         movq_cfi_restore R13+8, r13
749         movq_cfi_restore R12+8, r12
750         movq_cfi_restore RBP+8, rbp
751         movq_cfi_restore RBX+8, rbx
752         ret $REST_SKIP          /* pop extended registers */
753         CFI_ENDPROC
754 END(ptregscall_common)
755
756 ENTRY(stub_execve)
757         CFI_STARTPROC
758         addq $8, %rsp
759         PARTIAL_FRAME 0
760         SAVE_REST
761         FIXUP_TOP_OF_STACK %r11
762         movq %rsp, %rcx
763         call sys_execve
764         RESTORE_TOP_OF_STACK %r11
765         movq %rax,RAX(%rsp)
766         RESTORE_REST
767         jmp int_ret_from_sys_call
768         CFI_ENDPROC
769 END(stub_execve)
770
771 /*
772  * sigreturn is special because it needs to restore all registers on return.
773  * This cannot be done with SYSRET, so use the IRET return path instead.
774  */
775 ENTRY(stub_rt_sigreturn)
776         CFI_STARTPROC
777         addq $8, %rsp
778         PARTIAL_FRAME 0
779         SAVE_REST
780         movq %rsp,%rdi
781         FIXUP_TOP_OF_STACK %r11
782         call sys_rt_sigreturn
783         movq %rax,RAX(%rsp) # fixme, this could be done at the higher layer
784         RESTORE_REST
785         jmp int_ret_from_sys_call
786         CFI_ENDPROC
787 END(stub_rt_sigreturn)
788
789 #ifdef CONFIG_X86_X32_ABI
790         PTREGSCALL stub_x32_sigaltstack, sys32_sigaltstack, %rdx
791
792 ENTRY(stub_x32_rt_sigreturn)
793         CFI_STARTPROC
794         addq $8, %rsp
795         PARTIAL_FRAME 0
796         SAVE_REST
797         movq %rsp,%rdi
798         FIXUP_TOP_OF_STACK %r11
799         call sys32_x32_rt_sigreturn
800         movq %rax,RAX(%rsp) # fixme, this could be done at the higher layer
801         RESTORE_REST
802         jmp int_ret_from_sys_call
803         CFI_ENDPROC
804 END(stub_x32_rt_sigreturn)
805
806 ENTRY(stub_x32_execve)
807         CFI_STARTPROC
808         addq $8, %rsp
809         PARTIAL_FRAME 0
810         SAVE_REST
811         FIXUP_TOP_OF_STACK %r11
812         movq %rsp, %rcx
813         call sys32_execve
814         RESTORE_TOP_OF_STACK %r11
815         movq %rax,RAX(%rsp)
816         RESTORE_REST
817         jmp int_ret_from_sys_call
818         CFI_ENDPROC
819 END(stub_x32_execve)
820
821 #endif
822
823 /*
824  * Build the entry stubs and pointer table with some assembler magic.
825  * We pack 7 stubs into a single 32-byte chunk, which will fit in a
826  * single cache line on all modern x86 implementations.
827  */
828         .section .init.rodata,"a"
829 ENTRY(interrupt)
830         .section .entry.text
831         .p2align 5
832         .p2align CONFIG_X86_L1_CACHE_SHIFT
833 ENTRY(irq_entries_start)
834         INTR_FRAME
835 vector=FIRST_EXTERNAL_VECTOR
836 .rept (NR_VECTORS-FIRST_EXTERNAL_VECTOR+6)/7
837         .balign 32
838   .rept 7
839     .if vector < NR_VECTORS
840       .if vector <> FIRST_EXTERNAL_VECTOR
841         CFI_ADJUST_CFA_OFFSET -8
842       .endif
843 1:      pushq_cfi $(~vector+0x80)       /* Note: always in signed byte range */
844       .if ((vector-FIRST_EXTERNAL_VECTOR)%7) <> 6
845         jmp 2f
846       .endif
847       .previous
848         .quad 1b
849       .section .entry.text
850 vector=vector+1
851     .endif
852   .endr
853 2:      jmp common_interrupt
854 .endr
855         CFI_ENDPROC
856 END(irq_entries_start)
857
858 .previous
859 END(interrupt)
860 .previous
861
862 /*
863  * Interrupt entry/exit.
864  *
865  * Interrupt entry points save only callee clobbered registers in fast path.
866  *
867  * Entry runs with interrupts off.
868  */
869
870 /* 0(%rsp): ~(interrupt number) */
871         .macro interrupt func
872         /* reserve pt_regs for scratch regs and rbp */
873         subq $ORIG_RAX-RBP, %rsp
874         CFI_ADJUST_CFA_OFFSET ORIG_RAX-RBP
875         SAVE_ARGS_IRQ
876         call \func
877         .endm
878
879 /*
880  * Interrupt entry/exit should be protected against kprobes
881  */
882         .pushsection .kprobes.text, "ax"
883         /*
884          * The interrupt stubs push (~vector+0x80) onto the stack and
885          * then jump to common_interrupt.
886          */
887         .p2align CONFIG_X86_L1_CACHE_SHIFT
888 common_interrupt:
889         ASM_CLAC
890         XCPT_FRAME
891         addq $-0x80,(%rsp)              /* Adjust vector to [-256,-1] range */
892         interrupt do_IRQ
893         /* 0(%rsp): old_rsp-ARGOFFSET */
894 ret_from_intr:
895         DISABLE_INTERRUPTS(CLBR_NONE)
896         TRACE_IRQS_OFF
897         decl PER_CPU_VAR(irq_count)
898
899         /* Restore saved previous stack */
900         popq %rsi
901         CFI_DEF_CFA rsi,SS+8-RBP        /* reg/off reset after def_cfa_expr */
902         leaq ARGOFFSET-RBP(%rsi), %rsp
903         CFI_DEF_CFA_REGISTER    rsp
904         CFI_ADJUST_CFA_OFFSET   RBP-ARGOFFSET
905
906 exit_intr:
907         GET_THREAD_INFO(%rcx)
908         testl $3,CS-ARGOFFSET(%rsp)
909         je retint_kernel
910
911         /* Interrupt came from user space */
912         /*
913          * Has a correct top of stack, but a partial stack frame
914          * %rcx: thread info. Interrupts off.
915          */
916 retint_with_reschedule:
917         movl $_TIF_WORK_MASK,%edi
918 retint_check:
919         LOCKDEP_SYS_EXIT_IRQ
920         movl TI_flags(%rcx),%edx
921         andl %edi,%edx
922         CFI_REMEMBER_STATE
923         jnz  retint_careful
924
925 retint_swapgs:          /* return to user-space */
926         /*
927          * The iretq could re-enable interrupts:
928          */
929         DISABLE_INTERRUPTS(CLBR_ANY)
930         TRACE_IRQS_IRETQ
931         SWAPGS
932         jmp restore_args
933
934 retint_restore_args:    /* return to kernel space */
935         DISABLE_INTERRUPTS(CLBR_ANY)
936         /*
937          * The iretq could re-enable interrupts:
938          */
939         TRACE_IRQS_IRETQ
940 restore_args:
941         RESTORE_ARGS 1,8,1
942
943 irq_return:
944         INTERRUPT_RETURN
945         _ASM_EXTABLE(irq_return, bad_iret)
946
947 #ifdef CONFIG_PARAVIRT
948 ENTRY(native_iret)
949         iretq
950         _ASM_EXTABLE(native_iret, bad_iret)
951 #endif
952
953         .section .fixup,"ax"
954 bad_iret:
955         /*
956          * The iret traps when the %cs or %ss being restored is bogus.
957          * We've lost the original trap vector and error code.
958          * #GPF is the most likely one to get for an invalid selector.
959          * So pretend we completed the iret and took the #GPF in user mode.
960          *
961          * We are now running with the kernel GS after exception recovery.
962          * But error_entry expects us to have user GS to match the user %cs,
963          * so swap back.
964          */
965         pushq $0
966
967         SWAPGS
968         jmp general_protection
969
970         .previous
971
972         /* edi: workmask, edx: work */
973 retint_careful:
974         CFI_RESTORE_STATE
975         bt    $TIF_NEED_RESCHED,%edx
976         jnc   retint_signal
977         TRACE_IRQS_ON
978         ENABLE_INTERRUPTS(CLBR_NONE)
979         pushq_cfi %rdi
980         call  schedule
981         popq_cfi %rdi
982         GET_THREAD_INFO(%rcx)
983         DISABLE_INTERRUPTS(CLBR_NONE)
984         TRACE_IRQS_OFF
985         jmp retint_check
986
987 retint_signal:
988         testl $_TIF_DO_NOTIFY_MASK,%edx
989         jz    retint_swapgs
990         TRACE_IRQS_ON
991         ENABLE_INTERRUPTS(CLBR_NONE)
992         SAVE_REST
993         movq $-1,ORIG_RAX(%rsp)
994         xorl %esi,%esi          # oldset
995         movq %rsp,%rdi          # &pt_regs
996         call do_notify_resume
997         RESTORE_REST
998         DISABLE_INTERRUPTS(CLBR_NONE)
999         TRACE_IRQS_OFF
1000         GET_THREAD_INFO(%rcx)
1001         jmp retint_with_reschedule
1002
1003 #ifdef CONFIG_PREEMPT
1004         /* Returning to kernel space. Check if we need preemption */
1005         /* rcx:  threadinfo. interrupts off. */
1006 ENTRY(retint_kernel)
1007         cmpl $0,TI_preempt_count(%rcx)
1008         jnz  retint_restore_args
1009         bt  $TIF_NEED_RESCHED,TI_flags(%rcx)
1010         jnc  retint_restore_args
1011         bt   $9,EFLAGS-ARGOFFSET(%rsp)  /* interrupts off? */
1012         jnc  retint_restore_args
1013         call preempt_schedule_irq
1014         jmp exit_intr
1015 #endif
1016
1017         CFI_ENDPROC
1018 END(common_interrupt)
1019 /*
1020  * End of kprobes section
1021  */
1022        .popsection
1023
1024 /*
1025  * APIC interrupts.
1026  */
1027 .macro apicinterrupt num sym do_sym
1028 ENTRY(\sym)
1029         ASM_CLAC
1030         INTR_FRAME
1031         pushq_cfi $~(\num)
1032 .Lcommon_\sym:
1033         interrupt \do_sym
1034         jmp ret_from_intr
1035         CFI_ENDPROC
1036 END(\sym)
1037 .endm
1038
1039 #ifdef CONFIG_SMP
1040 apicinterrupt IRQ_MOVE_CLEANUP_VECTOR \
1041         irq_move_cleanup_interrupt smp_irq_move_cleanup_interrupt
1042 apicinterrupt REBOOT_VECTOR \
1043         reboot_interrupt smp_reboot_interrupt
1044 #endif
1045
1046 #ifdef CONFIG_X86_UV
1047 apicinterrupt UV_BAU_MESSAGE \
1048         uv_bau_message_intr1 uv_bau_message_interrupt
1049 #endif
1050 apicinterrupt LOCAL_TIMER_VECTOR \
1051         apic_timer_interrupt smp_apic_timer_interrupt
1052 apicinterrupt X86_PLATFORM_IPI_VECTOR \
1053         x86_platform_ipi smp_x86_platform_ipi
1054
1055 apicinterrupt THRESHOLD_APIC_VECTOR \
1056         threshold_interrupt smp_threshold_interrupt
1057 apicinterrupt THERMAL_APIC_VECTOR \
1058         thermal_interrupt smp_thermal_interrupt
1059
1060 #ifdef CONFIG_SMP
1061 apicinterrupt CALL_FUNCTION_SINGLE_VECTOR \
1062         call_function_single_interrupt smp_call_function_single_interrupt
1063 apicinterrupt CALL_FUNCTION_VECTOR \
1064         call_function_interrupt smp_call_function_interrupt
1065 apicinterrupt RESCHEDULE_VECTOR \
1066         reschedule_interrupt smp_reschedule_interrupt
1067 #endif
1068
1069 apicinterrupt ERROR_APIC_VECTOR \
1070         error_interrupt smp_error_interrupt
1071 apicinterrupt SPURIOUS_APIC_VECTOR \
1072         spurious_interrupt smp_spurious_interrupt
1073
1074 #ifdef CONFIG_IRQ_WORK
1075 apicinterrupt IRQ_WORK_VECTOR \
1076         irq_work_interrupt smp_irq_work_interrupt
1077 #endif
1078
1079 /*
1080  * Exception entry points.
1081  */
1082 .macro zeroentry sym do_sym
1083 ENTRY(\sym)
1084         ASM_CLAC
1085         INTR_FRAME
1086         PARAVIRT_ADJUST_EXCEPTION_FRAME
1087         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1088         subq $ORIG_RAX-R15, %rsp
1089         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1090         call error_entry
1091         DEFAULT_FRAME 0
1092         movq %rsp,%rdi          /* pt_regs pointer */
1093         xorl %esi,%esi          /* no error code */
1094         call \do_sym
1095         jmp error_exit          /* %ebx: no swapgs flag */
1096         CFI_ENDPROC
1097 END(\sym)
1098 .endm
1099
1100 .macro paranoidzeroentry sym do_sym
1101 ENTRY(\sym)
1102         ASM_CLAC
1103         INTR_FRAME
1104         PARAVIRT_ADJUST_EXCEPTION_FRAME
1105         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1106         subq $ORIG_RAX-R15, %rsp
1107         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1108         call save_paranoid
1109         TRACE_IRQS_OFF
1110         movq %rsp,%rdi          /* pt_regs pointer */
1111         xorl %esi,%esi          /* no error code */
1112         call \do_sym
1113         jmp paranoid_exit       /* %ebx: no swapgs flag */
1114         CFI_ENDPROC
1115 END(\sym)
1116 .endm
1117
1118 #define INIT_TSS_IST(x) PER_CPU_VAR(init_tss) + (TSS_ist + ((x) - 1) * 8)
1119 .macro paranoidzeroentry_ist sym do_sym ist
1120 ENTRY(\sym)
1121         ASM_CLAC
1122         INTR_FRAME
1123         PARAVIRT_ADJUST_EXCEPTION_FRAME
1124         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1125         subq $ORIG_RAX-R15, %rsp
1126         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1127         call save_paranoid
1128         TRACE_IRQS_OFF_DEBUG
1129         movq %rsp,%rdi          /* pt_regs pointer */
1130         xorl %esi,%esi          /* no error code */
1131         subq $EXCEPTION_STKSZ, INIT_TSS_IST(\ist)
1132         call \do_sym
1133         addq $EXCEPTION_STKSZ, INIT_TSS_IST(\ist)
1134         jmp paranoid_exit       /* %ebx: no swapgs flag */
1135         CFI_ENDPROC
1136 END(\sym)
1137 .endm
1138
1139 .macro errorentry sym do_sym
1140 ENTRY(\sym)
1141         ASM_CLAC
1142         XCPT_FRAME
1143         PARAVIRT_ADJUST_EXCEPTION_FRAME
1144         subq $ORIG_RAX-R15, %rsp
1145         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1146         call error_entry
1147         DEFAULT_FRAME 0
1148         movq %rsp,%rdi                  /* pt_regs pointer */
1149         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1150         movq $-1,ORIG_RAX(%rsp)         /* no syscall to restart */
1151         call \do_sym
1152         jmp error_exit                  /* %ebx: no swapgs flag */
1153         CFI_ENDPROC
1154 END(\sym)
1155 .endm
1156
1157         /* error code is on the stack already */
1158 .macro paranoiderrorentry sym do_sym
1159 ENTRY(\sym)
1160         ASM_CLAC
1161         XCPT_FRAME
1162         PARAVIRT_ADJUST_EXCEPTION_FRAME
1163         subq $ORIG_RAX-R15, %rsp
1164         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1165         call save_paranoid
1166         DEFAULT_FRAME 0
1167         TRACE_IRQS_OFF
1168         movq %rsp,%rdi                  /* pt_regs pointer */
1169         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1170         movq $-1,ORIG_RAX(%rsp)         /* no syscall to restart */
1171         call \do_sym
1172         jmp paranoid_exit               /* %ebx: no swapgs flag */
1173         CFI_ENDPROC
1174 END(\sym)
1175 .endm
1176
1177 zeroentry divide_error do_divide_error
1178 zeroentry overflow do_overflow
1179 zeroentry bounds do_bounds
1180 zeroentry invalid_op do_invalid_op
1181 zeroentry device_not_available do_device_not_available
1182 paranoiderrorentry double_fault do_double_fault
1183 zeroentry coprocessor_segment_overrun do_coprocessor_segment_overrun
1184 errorentry invalid_TSS do_invalid_TSS
1185 errorentry segment_not_present do_segment_not_present
1186 zeroentry spurious_interrupt_bug do_spurious_interrupt_bug
1187 zeroentry coprocessor_error do_coprocessor_error
1188 errorentry alignment_check do_alignment_check
1189 zeroentry simd_coprocessor_error do_simd_coprocessor_error
1190
1191
1192         /* Reload gs selector with exception handling */
1193         /* edi:  new selector */
1194 ENTRY(native_load_gs_index)
1195         CFI_STARTPROC
1196         pushfq_cfi
1197         DISABLE_INTERRUPTS(CLBR_ANY & ~CLBR_RDI)
1198         SWAPGS
1199 gs_change:
1200         movl %edi,%gs
1201 2:      mfence          /* workaround */
1202         SWAPGS
1203         popfq_cfi
1204         ret
1205         CFI_ENDPROC
1206 END(native_load_gs_index)
1207
1208         _ASM_EXTABLE(gs_change,bad_gs)
1209         .section .fixup,"ax"
1210         /* running with kernelgs */
1211 bad_gs:
1212         SWAPGS                  /* switch back to user gs */
1213         xorl %eax,%eax
1214         movl %eax,%gs
1215         jmp  2b
1216         .previous
1217
1218 ENTRY(kernel_thread_helper)
1219         pushq $0                # fake return address
1220         CFI_STARTPROC
1221         /*
1222          * Here we are in the child and the registers are set as they were
1223          * at kernel_thread() invocation in the parent.
1224          */
1225         call *%rsi
1226         # exit
1227         mov %eax, %edi
1228         call do_exit
1229         ud2                     # padding for call trace
1230         CFI_ENDPROC
1231 END(kernel_thread_helper)
1232
1233 /*
1234  * execve(). This function needs to use IRET, not SYSRET, to set up all state properly.
1235  *
1236  * C extern interface:
1237  *       extern long execve(const char *name, char **argv, char **envp)
1238  *
1239  * asm input arguments:
1240  *      rdi: name, rsi: argv, rdx: envp
1241  *
1242  * We want to fallback into:
1243  *      extern long sys_execve(const char *name, char **argv,char **envp, struct pt_regs *regs)
1244  *
1245  * do_sys_execve asm fallback arguments:
1246  *      rdi: name, rsi: argv, rdx: envp, rcx: fake frame on the stack
1247  */
1248 ENTRY(kernel_execve)
1249         CFI_STARTPROC
1250         FAKE_STACK_FRAME $0
1251         SAVE_ALL
1252         movq %rsp,%rcx
1253         call sys_execve
1254         movq %rax, RAX(%rsp)
1255         RESTORE_REST
1256         testq %rax,%rax
1257         je int_ret_from_sys_call
1258         RESTORE_ARGS
1259         UNFAKE_STACK_FRAME
1260         ret
1261         CFI_ENDPROC
1262 END(kernel_execve)
1263
1264 /* Call softirq on interrupt stack. Interrupts are off. */
1265 ENTRY(call_softirq)
1266         CFI_STARTPROC
1267         pushq_cfi %rbp
1268         CFI_REL_OFFSET rbp,0
1269         mov  %rsp,%rbp
1270         CFI_DEF_CFA_REGISTER rbp
1271         incl PER_CPU_VAR(irq_count)
1272         cmove PER_CPU_VAR(irq_stack_ptr),%rsp
1273         push  %rbp                      # backlink for old unwinder
1274         call __do_softirq
1275         leaveq
1276         CFI_RESTORE             rbp
1277         CFI_DEF_CFA_REGISTER    rsp
1278         CFI_ADJUST_CFA_OFFSET   -8
1279         decl PER_CPU_VAR(irq_count)
1280         ret
1281         CFI_ENDPROC
1282 END(call_softirq)
1283
1284 #ifdef CONFIG_XEN
1285 zeroentry xen_hypervisor_callback xen_do_hypervisor_callback
1286
1287 /*
1288  * A note on the "critical region" in our callback handler.
1289  * We want to avoid stacking callback handlers due to events occurring
1290  * during handling of the last event. To do this, we keep events disabled
1291  * until we've done all processing. HOWEVER, we must enable events before
1292  * popping the stack frame (can't be done atomically) and so it would still
1293  * be possible to get enough handler activations to overflow the stack.
1294  * Although unlikely, bugs of that kind are hard to track down, so we'd
1295  * like to avoid the possibility.
1296  * So, on entry to the handler we detect whether we interrupted an
1297  * existing activation in its critical region -- if so, we pop the current
1298  * activation and restart the handler using the previous one.
1299  */
1300 ENTRY(xen_do_hypervisor_callback)   # do_hypervisor_callback(struct *pt_regs)
1301         CFI_STARTPROC
1302 /*
1303  * Since we don't modify %rdi, evtchn_do_upall(struct *pt_regs) will
1304  * see the correct pointer to the pt_regs
1305  */
1306         movq %rdi, %rsp            # we don't return, adjust the stack frame
1307         CFI_ENDPROC
1308         DEFAULT_FRAME
1309 11:     incl PER_CPU_VAR(irq_count)
1310         movq %rsp,%rbp
1311         CFI_DEF_CFA_REGISTER rbp
1312         cmovzq PER_CPU_VAR(irq_stack_ptr),%rsp
1313         pushq %rbp                      # backlink for old unwinder
1314         call xen_evtchn_do_upcall
1315         popq %rsp
1316         CFI_DEF_CFA_REGISTER rsp
1317         decl PER_CPU_VAR(irq_count)
1318         jmp  error_exit
1319         CFI_ENDPROC
1320 END(xen_do_hypervisor_callback)
1321
1322 /*
1323  * Hypervisor uses this for application faults while it executes.
1324  * We get here for two reasons:
1325  *  1. Fault while reloading DS, ES, FS or GS
1326  *  2. Fault while executing IRET
1327  * Category 1 we do not need to fix up as Xen has already reloaded all segment
1328  * registers that could be reloaded and zeroed the others.
1329  * Category 2 we fix up by killing the current process. We cannot use the
1330  * normal Linux return path in this case because if we use the IRET hypercall
1331  * to pop the stack frame we end up in an infinite loop of failsafe callbacks.
1332  * We distinguish between categories by comparing each saved segment register
1333  * with its current contents: any discrepancy means we in category 1.
1334  */
1335 ENTRY(xen_failsafe_callback)
1336         INTR_FRAME 1 (6*8)
1337         /*CFI_REL_OFFSET gs,GS*/
1338         /*CFI_REL_OFFSET fs,FS*/
1339         /*CFI_REL_OFFSET es,ES*/
1340         /*CFI_REL_OFFSET ds,DS*/
1341         CFI_REL_OFFSET r11,8
1342         CFI_REL_OFFSET rcx,0
1343         movw %ds,%cx
1344         cmpw %cx,0x10(%rsp)
1345         CFI_REMEMBER_STATE
1346         jne 1f
1347         movw %es,%cx
1348         cmpw %cx,0x18(%rsp)
1349         jne 1f
1350         movw %fs,%cx
1351         cmpw %cx,0x20(%rsp)
1352         jne 1f
1353         movw %gs,%cx
1354         cmpw %cx,0x28(%rsp)
1355         jne 1f
1356         /* All segments match their saved values => Category 2 (Bad IRET). */
1357         movq (%rsp),%rcx
1358         CFI_RESTORE rcx
1359         movq 8(%rsp),%r11
1360         CFI_RESTORE r11
1361         addq $0x30,%rsp
1362         CFI_ADJUST_CFA_OFFSET -0x30
1363         pushq_cfi $0    /* RIP */
1364         pushq_cfi %r11
1365         pushq_cfi %rcx
1366         jmp general_protection
1367         CFI_RESTORE_STATE
1368 1:      /* Segment mismatch => Category 1 (Bad segment). Retry the IRET. */
1369         movq (%rsp),%rcx
1370         CFI_RESTORE rcx
1371         movq 8(%rsp),%r11
1372         CFI_RESTORE r11
1373         addq $0x30,%rsp
1374         CFI_ADJUST_CFA_OFFSET -0x30
1375         pushq_cfi $0
1376         SAVE_ALL
1377         jmp error_exit
1378         CFI_ENDPROC
1379 END(xen_failsafe_callback)
1380
1381 apicinterrupt XEN_HVM_EVTCHN_CALLBACK \
1382         xen_hvm_callback_vector xen_evtchn_do_upcall
1383
1384 #endif /* CONFIG_XEN */
1385
1386 /*
1387  * Some functions should be protected against kprobes
1388  */
1389         .pushsection .kprobes.text, "ax"
1390
1391 paranoidzeroentry_ist debug do_debug DEBUG_STACK
1392 paranoidzeroentry_ist int3 do_int3 DEBUG_STACK
1393 paranoiderrorentry stack_segment do_stack_segment
1394 #ifdef CONFIG_XEN
1395 zeroentry xen_debug do_debug
1396 zeroentry xen_int3 do_int3
1397 errorentry xen_stack_segment do_stack_segment
1398 #endif
1399 errorentry general_protection do_general_protection
1400 errorentry page_fault do_page_fault
1401 #ifdef CONFIG_KVM_GUEST
1402 errorentry async_page_fault do_async_page_fault
1403 #endif
1404 #ifdef CONFIG_X86_MCE
1405 paranoidzeroentry machine_check *machine_check_vector(%rip)
1406 #endif
1407
1408         /*
1409          * "Paranoid" exit path from exception stack.
1410          * Paranoid because this is used by NMIs and cannot take
1411          * any kernel state for granted.
1412          * We don't do kernel preemption checks here, because only
1413          * NMI should be common and it does not enable IRQs and
1414          * cannot get reschedule ticks.
1415          *
1416          * "trace" is 0 for the NMI handler only, because irq-tracing
1417          * is fundamentally NMI-unsafe. (we cannot change the soft and
1418          * hard flags at once, atomically)
1419          */
1420
1421         /* ebx: no swapgs flag */
1422 ENTRY(paranoid_exit)
1423         DEFAULT_FRAME
1424         DISABLE_INTERRUPTS(CLBR_NONE)
1425         TRACE_IRQS_OFF_DEBUG
1426         testl %ebx,%ebx                         /* swapgs needed? */
1427         jnz paranoid_restore
1428         testl $3,CS(%rsp)
1429         jnz   paranoid_userspace
1430 paranoid_swapgs:
1431         TRACE_IRQS_IRETQ 0
1432         SWAPGS_UNSAFE_STACK
1433         RESTORE_ALL 8
1434         jmp irq_return
1435 paranoid_restore:
1436         TRACE_IRQS_IRETQ_DEBUG 0
1437         RESTORE_ALL 8
1438         jmp irq_return
1439 paranoid_userspace:
1440         GET_THREAD_INFO(%rcx)
1441         movl TI_flags(%rcx),%ebx
1442         andl $_TIF_WORK_MASK,%ebx
1443         jz paranoid_swapgs
1444         movq %rsp,%rdi                  /* &pt_regs */
1445         call sync_regs
1446         movq %rax,%rsp                  /* switch stack for scheduling */
1447         testl $_TIF_NEED_RESCHED,%ebx
1448         jnz paranoid_schedule
1449         movl %ebx,%edx                  /* arg3: thread flags */
1450         TRACE_IRQS_ON
1451         ENABLE_INTERRUPTS(CLBR_NONE)
1452         xorl %esi,%esi                  /* arg2: oldset */
1453         movq %rsp,%rdi                  /* arg1: &pt_regs */
1454         call do_notify_resume
1455         DISABLE_INTERRUPTS(CLBR_NONE)
1456         TRACE_IRQS_OFF
1457         jmp paranoid_userspace
1458 paranoid_schedule:
1459         TRACE_IRQS_ON
1460         ENABLE_INTERRUPTS(CLBR_ANY)
1461         call schedule
1462         DISABLE_INTERRUPTS(CLBR_ANY)
1463         TRACE_IRQS_OFF
1464         jmp paranoid_userspace
1465         CFI_ENDPROC
1466 END(paranoid_exit)
1467
1468 /*
1469  * Exception entry point. This expects an error code/orig_rax on the stack.
1470  * returns in "no swapgs flag" in %ebx.
1471  */
1472 ENTRY(error_entry)
1473         XCPT_FRAME
1474         CFI_ADJUST_CFA_OFFSET 15*8
1475         /* oldrax contains error code */
1476         cld
1477         movq_cfi rdi, RDI+8
1478         movq_cfi rsi, RSI+8
1479         movq_cfi rdx, RDX+8
1480         movq_cfi rcx, RCX+8
1481         movq_cfi rax, RAX+8
1482         movq_cfi  r8,  R8+8
1483         movq_cfi  r9,  R9+8
1484         movq_cfi r10, R10+8
1485         movq_cfi r11, R11+8
1486         movq_cfi rbx, RBX+8
1487         movq_cfi rbp, RBP+8
1488         movq_cfi r12, R12+8
1489         movq_cfi r13, R13+8
1490         movq_cfi r14, R14+8
1491         movq_cfi r15, R15+8
1492         xorl %ebx,%ebx
1493         testl $3,CS+8(%rsp)
1494         je error_kernelspace
1495 error_swapgs:
1496         SWAPGS
1497 error_sti:
1498         TRACE_IRQS_OFF
1499         ret
1500
1501 /*
1502  * There are two places in the kernel that can potentially fault with
1503  * usergs. Handle them here. The exception handlers after iret run with
1504  * kernel gs again, so don't set the user space flag. B stepping K8s
1505  * sometimes report an truncated RIP for IRET exceptions returning to
1506  * compat mode. Check for these here too.
1507  */
1508 error_kernelspace:
1509         incl %ebx
1510         leaq irq_return(%rip),%rcx
1511         cmpq %rcx,RIP+8(%rsp)
1512         je error_swapgs
1513         movl %ecx,%eax  /* zero extend */
1514         cmpq %rax,RIP+8(%rsp)
1515         je bstep_iret
1516         cmpq $gs_change,RIP+8(%rsp)
1517         je error_swapgs
1518         jmp error_sti
1519
1520 bstep_iret:
1521         /* Fix truncated RIP */
1522         movq %rcx,RIP+8(%rsp)
1523         jmp error_swapgs
1524         CFI_ENDPROC
1525 END(error_entry)
1526
1527
1528 /* ebx: no swapgs flag (1: don't need swapgs, 0: need it) */
1529 ENTRY(error_exit)
1530         DEFAULT_FRAME
1531         movl %ebx,%eax
1532         RESTORE_REST
1533         DISABLE_INTERRUPTS(CLBR_NONE)
1534         TRACE_IRQS_OFF
1535         GET_THREAD_INFO(%rcx)
1536         testl %eax,%eax
1537         jne retint_kernel
1538         LOCKDEP_SYS_EXIT_IRQ
1539         movl TI_flags(%rcx),%edx
1540         movl $_TIF_WORK_MASK,%edi
1541         andl %edi,%edx
1542         jnz retint_careful
1543         jmp retint_swapgs
1544         CFI_ENDPROC
1545 END(error_exit)
1546
1547 /*
1548  * Test if a given stack is an NMI stack or not.
1549  */
1550         .macro test_in_nmi reg stack nmi_ret normal_ret
1551         cmpq %\reg, \stack
1552         ja \normal_ret
1553         subq $EXCEPTION_STKSZ, %\reg
1554         cmpq %\reg, \stack
1555         jb \normal_ret
1556         jmp \nmi_ret
1557         .endm
1558
1559         /* runs on exception stack */
1560 ENTRY(nmi)
1561         INTR_FRAME
1562         PARAVIRT_ADJUST_EXCEPTION_FRAME
1563         /*
1564          * We allow breakpoints in NMIs. If a breakpoint occurs, then
1565          * the iretq it performs will take us out of NMI context.
1566          * This means that we can have nested NMIs where the next
1567          * NMI is using the top of the stack of the previous NMI. We
1568          * can't let it execute because the nested NMI will corrupt the
1569          * stack of the previous NMI. NMI handlers are not re-entrant
1570          * anyway.
1571          *
1572          * To handle this case we do the following:
1573          *  Check the a special location on the stack that contains
1574          *  a variable that is set when NMIs are executing.
1575          *  The interrupted task's stack is also checked to see if it
1576          *  is an NMI stack.
1577          *  If the variable is not set and the stack is not the NMI
1578          *  stack then:
1579          *    o Set the special variable on the stack
1580          *    o Copy the interrupt frame into a "saved" location on the stack
1581          *    o Copy the interrupt frame into a "copy" location on the stack
1582          *    o Continue processing the NMI
1583          *  If the variable is set or the previous stack is the NMI stack:
1584          *    o Modify the "copy" location to jump to the repeate_nmi
1585          *    o return back to the first NMI
1586          *
1587          * Now on exit of the first NMI, we first clear the stack variable
1588          * The NMI stack will tell any nested NMIs at that point that it is
1589          * nested. Then we pop the stack normally with iret, and if there was
1590          * a nested NMI that updated the copy interrupt stack frame, a
1591          * jump will be made to the repeat_nmi code that will handle the second
1592          * NMI.
1593          */
1594
1595         /* Use %rdx as out temp variable throughout */
1596         pushq_cfi %rdx
1597         CFI_REL_OFFSET rdx, 0
1598
1599         /*
1600          * If %cs was not the kernel segment, then the NMI triggered in user
1601          * space, which means it is definitely not nested.
1602          */
1603         cmpl $__KERNEL_CS, 16(%rsp)
1604         jne first_nmi
1605
1606         /*
1607          * Check the special variable on the stack to see if NMIs are
1608          * executing.
1609          */
1610         cmpl $1, -8(%rsp)
1611         je nested_nmi
1612
1613         /*
1614          * Now test if the previous stack was an NMI stack.
1615          * We need the double check. We check the NMI stack to satisfy the
1616          * race when the first NMI clears the variable before returning.
1617          * We check the variable because the first NMI could be in a
1618          * breakpoint routine using a breakpoint stack.
1619          */
1620         lea 6*8(%rsp), %rdx
1621         test_in_nmi rdx, 4*8(%rsp), nested_nmi, first_nmi
1622         CFI_REMEMBER_STATE
1623
1624 nested_nmi:
1625         /*
1626          * Do nothing if we interrupted the fixup in repeat_nmi.
1627          * It's about to repeat the NMI handler, so we are fine
1628          * with ignoring this one.
1629          */
1630         movq $repeat_nmi, %rdx
1631         cmpq 8(%rsp), %rdx
1632         ja 1f
1633         movq $end_repeat_nmi, %rdx
1634         cmpq 8(%rsp), %rdx
1635         ja nested_nmi_out
1636
1637 1:
1638         /* Set up the interrupted NMIs stack to jump to repeat_nmi */
1639         leaq -6*8(%rsp), %rdx
1640         movq %rdx, %rsp
1641         CFI_ADJUST_CFA_OFFSET 6*8
1642         pushq_cfi $__KERNEL_DS
1643         pushq_cfi %rdx
1644         pushfq_cfi
1645         pushq_cfi $__KERNEL_CS
1646         pushq_cfi $repeat_nmi
1647
1648         /* Put stack back */
1649         addq $(11*8), %rsp
1650         CFI_ADJUST_CFA_OFFSET -11*8
1651
1652 nested_nmi_out:
1653         popq_cfi %rdx
1654         CFI_RESTORE rdx
1655
1656         /* No need to check faults here */
1657         INTERRUPT_RETURN
1658
1659         CFI_RESTORE_STATE
1660 first_nmi:
1661         /*
1662          * Because nested NMIs will use the pushed location that we
1663          * stored in rdx, we must keep that space available.
1664          * Here's what our stack frame will look like:
1665          * +-------------------------+
1666          * | original SS             |
1667          * | original Return RSP     |
1668          * | original RFLAGS         |
1669          * | original CS             |
1670          * | original RIP            |
1671          * +-------------------------+
1672          * | temp storage for rdx    |
1673          * +-------------------------+
1674          * | NMI executing variable  |
1675          * +-------------------------+
1676          * | Saved SS                |
1677          * | Saved Return RSP        |
1678          * | Saved RFLAGS            |
1679          * | Saved CS                |
1680          * | Saved RIP               |
1681          * +-------------------------+
1682          * | copied SS               |
1683          * | copied Return RSP       |
1684          * | copied RFLAGS           |
1685          * | copied CS               |
1686          * | copied RIP              |
1687          * +-------------------------+
1688          * | pt_regs                 |
1689          * +-------------------------+
1690          *
1691          * The saved stack frame is used to fix up the copied stack frame
1692          * that a nested NMI may change to make the interrupted NMI iret jump
1693          * to the repeat_nmi. The original stack frame and the temp storage
1694          * is also used by nested NMIs and can not be trusted on exit.
1695          */
1696         /* Do not pop rdx, nested NMIs will corrupt that part of the stack */
1697         movq (%rsp), %rdx
1698         CFI_RESTORE rdx
1699
1700         /* Set the NMI executing variable on the stack. */
1701         pushq_cfi $1
1702
1703         /* Copy the stack frame to the Saved frame */
1704         .rept 5
1705         pushq_cfi 6*8(%rsp)
1706         .endr
1707         CFI_DEF_CFA_OFFSET SS+8-RIP
1708
1709         /* Everything up to here is safe from nested NMIs */
1710
1711         /*
1712          * If there was a nested NMI, the first NMI's iret will return
1713          * here. But NMIs are still enabled and we can take another
1714          * nested NMI. The nested NMI checks the interrupted RIP to see
1715          * if it is between repeat_nmi and end_repeat_nmi, and if so
1716          * it will just return, as we are about to repeat an NMI anyway.
1717          * This makes it safe to copy to the stack frame that a nested
1718          * NMI will update.
1719          */
1720 repeat_nmi:
1721         /*
1722          * Update the stack variable to say we are still in NMI (the update
1723          * is benign for the non-repeat case, where 1 was pushed just above
1724          * to this very stack slot).
1725          */
1726         movq $1, 5*8(%rsp)
1727
1728         /* Make another copy, this one may be modified by nested NMIs */
1729         .rept 5
1730         pushq_cfi 4*8(%rsp)
1731         .endr
1732         CFI_DEF_CFA_OFFSET SS+8-RIP
1733 end_repeat_nmi:
1734
1735         /*
1736          * Everything below this point can be preempted by a nested
1737          * NMI if the first NMI took an exception and reset our iret stack
1738          * so that we repeat another NMI.
1739          */
1740         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1741         subq $ORIG_RAX-R15, %rsp
1742         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1743         /*
1744          * Use save_paranoid to handle SWAPGS, but no need to use paranoid_exit
1745          * as we should not be calling schedule in NMI context.
1746          * Even with normal interrupts enabled. An NMI should not be
1747          * setting NEED_RESCHED or anything that normal interrupts and
1748          * exceptions might do.
1749          */
1750         call save_paranoid
1751         DEFAULT_FRAME 0
1752
1753         /*
1754          * Save off the CR2 register. If we take a page fault in the NMI then
1755          * it could corrupt the CR2 value. If the NMI preempts a page fault
1756          * handler before it was able to read the CR2 register, and then the
1757          * NMI itself takes a page fault, the page fault that was preempted
1758          * will read the information from the NMI page fault and not the
1759          * origin fault. Save it off and restore it if it changes.
1760          * Use the r12 callee-saved register.
1761          */
1762         movq %cr2, %r12
1763
1764         /* paranoidentry do_nmi, 0; without TRACE_IRQS_OFF */
1765         movq %rsp,%rdi
1766         movq $-1,%rsi
1767         call do_nmi
1768
1769         /* Did the NMI take a page fault? Restore cr2 if it did */
1770         movq %cr2, %rcx
1771         cmpq %rcx, %r12
1772         je 1f
1773         movq %r12, %cr2
1774 1:
1775         
1776         testl %ebx,%ebx                         /* swapgs needed? */
1777         jnz nmi_restore
1778 nmi_swapgs:
1779         SWAPGS_UNSAFE_STACK
1780 nmi_restore:
1781         RESTORE_ALL 8
1782         /* Clear the NMI executing stack variable */
1783         movq $0, 10*8(%rsp)
1784         jmp irq_return
1785         CFI_ENDPROC
1786 END(nmi)
1787
1788 ENTRY(ignore_sysret)
1789         CFI_STARTPROC
1790         mov $-ENOSYS,%eax
1791         sysret
1792         CFI_ENDPROC
1793 END(ignore_sysret)
1794
1795 /*
1796  * End of kprobes section
1797  */
1798         .popsection