Merge branch 'x86-smap-for-linus' of git://git.kernel.org/pub/scm/linux/kernel/git...
[linux-3.10.git] / arch / x86 / kernel / entry_64.S
1 /*
2  *  linux/arch/x86_64/entry.S
3  *
4  *  Copyright (C) 1991, 1992  Linus Torvalds
5  *  Copyright (C) 2000, 2001, 2002  Andi Kleen SuSE Labs
6  *  Copyright (C) 2000  Pavel Machek <pavel@suse.cz>
7  */
8
9 /*
10  * entry.S contains the system-call and fault low-level handling routines.
11  *
12  * Some of this is documented in Documentation/x86/entry_64.txt
13  *
14  * NOTE: This code handles signal-recognition, which happens every time
15  * after an interrupt and after each system call.
16  *
17  * Normal syscalls and interrupts don't save a full stack frame, this is
18  * only done for syscall tracing, signals or fork/exec et.al.
19  *
20  * A note on terminology:
21  * - top of stack: Architecture defined interrupt frame from SS to RIP
22  * at the top of the kernel process stack.
23  * - partial stack frame: partially saved registers up to R11.
24  * - full stack frame: Like partial stack frame, but all register saved.
25  *
26  * Some macro usage:
27  * - CFI macros are used to generate dwarf2 unwind information for better
28  * backtraces. They don't change any code.
29  * - SAVE_ALL/RESTORE_ALL - Save/restore all registers
30  * - SAVE_ARGS/RESTORE_ARGS - Save/restore registers that C functions modify.
31  * There are unfortunately lots of special cases where some registers
32  * not touched. The macro is a big mess that should be cleaned up.
33  * - SAVE_REST/RESTORE_REST - Handle the registers not saved by SAVE_ARGS.
34  * Gives a full stack frame.
35  * - ENTRY/END Define functions in the symbol table.
36  * - FIXUP_TOP_OF_STACK/RESTORE_TOP_OF_STACK - Fix up the hardware stack
37  * frame that is otherwise undefined after a SYSCALL
38  * - TRACE_IRQ_* - Trace hard interrupt state for lock debugging.
39  * - errorentry/paranoidentry/zeroentry - Define exception entry points.
40  */
41
42 #include <linux/linkage.h>
43 #include <asm/segment.h>
44 #include <asm/cache.h>
45 #include <asm/errno.h>
46 #include <asm/dwarf2.h>
47 #include <asm/calling.h>
48 #include <asm/asm-offsets.h>
49 #include <asm/msr.h>
50 #include <asm/unistd.h>
51 #include <asm/thread_info.h>
52 #include <asm/hw_irq.h>
53 #include <asm/page_types.h>
54 #include <asm/irqflags.h>
55 #include <asm/paravirt.h>
56 #include <asm/ftrace.h>
57 #include <asm/percpu.h>
58 #include <asm/asm.h>
59 #include <asm/rcu.h>
60 #include <asm/smap.h>
61 #include <linux/err.h>
62
63 /* Avoid __ASSEMBLER__'ifying <linux/audit.h> just for this.  */
64 #include <linux/elf-em.h>
65 #define AUDIT_ARCH_X86_64       (EM_X86_64|__AUDIT_ARCH_64BIT|__AUDIT_ARCH_LE)
66 #define __AUDIT_ARCH_64BIT 0x80000000
67 #define __AUDIT_ARCH_LE    0x40000000
68
69         .code64
70         .section .entry.text, "ax"
71
72 #ifdef CONFIG_FUNCTION_TRACER
73
74 #ifdef CC_USING_FENTRY
75 # define function_hook  __fentry__
76 #else
77 # define function_hook  mcount
78 #endif
79
80 #ifdef CONFIG_DYNAMIC_FTRACE
81
82 ENTRY(function_hook)
83         retq
84 END(function_hook)
85
86 /* skip is set if stack has been adjusted */
87 .macro ftrace_caller_setup skip=0
88         MCOUNT_SAVE_FRAME \skip
89
90         /* Load the ftrace_ops into the 3rd parameter */
91         leaq function_trace_op, %rdx
92
93         /* Load ip into the first parameter */
94         movq RIP(%rsp), %rdi
95         subq $MCOUNT_INSN_SIZE, %rdi
96         /* Load the parent_ip into the second parameter */
97 #ifdef CC_USING_FENTRY
98         movq SS+16(%rsp), %rsi
99 #else
100         movq 8(%rbp), %rsi
101 #endif
102 .endm
103
104 ENTRY(ftrace_caller)
105         /* Check if tracing was disabled (quick check) */
106         cmpl $0, function_trace_stop
107         jne  ftrace_stub
108
109         ftrace_caller_setup
110         /* regs go into 4th parameter (but make it NULL) */
111         movq $0, %rcx
112
113 GLOBAL(ftrace_call)
114         call ftrace_stub
115
116         MCOUNT_RESTORE_FRAME
117 ftrace_return:
118
119 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
120 GLOBAL(ftrace_graph_call)
121         jmp ftrace_stub
122 #endif
123
124 GLOBAL(ftrace_stub)
125         retq
126 END(ftrace_caller)
127
128 ENTRY(ftrace_regs_caller)
129         /* Save the current flags before compare (in SS location)*/
130         pushfq
131
132         /* Check if tracing was disabled (quick check) */
133         cmpl $0, function_trace_stop
134         jne  ftrace_restore_flags
135
136         /* skip=8 to skip flags saved in SS */
137         ftrace_caller_setup 8
138
139         /* Save the rest of pt_regs */
140         movq %r15, R15(%rsp)
141         movq %r14, R14(%rsp)
142         movq %r13, R13(%rsp)
143         movq %r12, R12(%rsp)
144         movq %r11, R11(%rsp)
145         movq %r10, R10(%rsp)
146         movq %rbp, RBP(%rsp)
147         movq %rbx, RBX(%rsp)
148         /* Copy saved flags */
149         movq SS(%rsp), %rcx
150         movq %rcx, EFLAGS(%rsp)
151         /* Kernel segments */
152         movq $__KERNEL_DS, %rcx
153         movq %rcx, SS(%rsp)
154         movq $__KERNEL_CS, %rcx
155         movq %rcx, CS(%rsp)
156         /* Stack - skipping return address */
157         leaq SS+16(%rsp), %rcx
158         movq %rcx, RSP(%rsp)
159
160         /* regs go into 4th parameter */
161         leaq (%rsp), %rcx
162
163 GLOBAL(ftrace_regs_call)
164         call ftrace_stub
165
166         /* Copy flags back to SS, to restore them */
167         movq EFLAGS(%rsp), %rax
168         movq %rax, SS(%rsp)
169
170         /* Handlers can change the RIP */
171         movq RIP(%rsp), %rax
172         movq %rax, SS+8(%rsp)
173
174         /* restore the rest of pt_regs */
175         movq R15(%rsp), %r15
176         movq R14(%rsp), %r14
177         movq R13(%rsp), %r13
178         movq R12(%rsp), %r12
179         movq R10(%rsp), %r10
180         movq RBP(%rsp), %rbp
181         movq RBX(%rsp), %rbx
182
183         /* skip=8 to skip flags saved in SS */
184         MCOUNT_RESTORE_FRAME 8
185
186         /* Restore flags */
187         popfq
188
189         jmp ftrace_return
190 ftrace_restore_flags:
191         popfq
192         jmp  ftrace_stub
193
194 END(ftrace_regs_caller)
195
196
197 #else /* ! CONFIG_DYNAMIC_FTRACE */
198
199 ENTRY(function_hook)
200         cmpl $0, function_trace_stop
201         jne  ftrace_stub
202
203         cmpq $ftrace_stub, ftrace_trace_function
204         jnz trace
205
206 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
207         cmpq $ftrace_stub, ftrace_graph_return
208         jnz ftrace_graph_caller
209
210         cmpq $ftrace_graph_entry_stub, ftrace_graph_entry
211         jnz ftrace_graph_caller
212 #endif
213
214 GLOBAL(ftrace_stub)
215         retq
216
217 trace:
218         MCOUNT_SAVE_FRAME
219
220         movq RIP(%rsp), %rdi
221 #ifdef CC_USING_FENTRY
222         movq SS+16(%rsp), %rsi
223 #else
224         movq 8(%rbp), %rsi
225 #endif
226         subq $MCOUNT_INSN_SIZE, %rdi
227
228         call   *ftrace_trace_function
229
230         MCOUNT_RESTORE_FRAME
231
232         jmp ftrace_stub
233 END(function_hook)
234 #endif /* CONFIG_DYNAMIC_FTRACE */
235 #endif /* CONFIG_FUNCTION_TRACER */
236
237 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
238 ENTRY(ftrace_graph_caller)
239         MCOUNT_SAVE_FRAME
240
241 #ifdef CC_USING_FENTRY
242         leaq SS+16(%rsp), %rdi
243         movq $0, %rdx   /* No framepointers needed */
244 #else
245         leaq 8(%rbp), %rdi
246         movq (%rbp), %rdx
247 #endif
248         movq RIP(%rsp), %rsi
249         subq $MCOUNT_INSN_SIZE, %rsi
250
251         call    prepare_ftrace_return
252
253         MCOUNT_RESTORE_FRAME
254
255         retq
256 END(ftrace_graph_caller)
257
258 GLOBAL(return_to_handler)
259         subq  $24, %rsp
260
261         /* Save the return values */
262         movq %rax, (%rsp)
263         movq %rdx, 8(%rsp)
264         movq %rbp, %rdi
265
266         call ftrace_return_to_handler
267
268         movq %rax, %rdi
269         movq 8(%rsp), %rdx
270         movq (%rsp), %rax
271         addq $24, %rsp
272         jmp *%rdi
273 #endif
274
275
276 #ifndef CONFIG_PREEMPT
277 #define retint_kernel retint_restore_args
278 #endif
279
280 #ifdef CONFIG_PARAVIRT
281 ENTRY(native_usergs_sysret64)
282         swapgs
283         sysretq
284 ENDPROC(native_usergs_sysret64)
285 #endif /* CONFIG_PARAVIRT */
286
287
288 .macro TRACE_IRQS_IRETQ offset=ARGOFFSET
289 #ifdef CONFIG_TRACE_IRQFLAGS
290         bt   $9,EFLAGS-\offset(%rsp)    /* interrupts off? */
291         jnc  1f
292         TRACE_IRQS_ON
293 1:
294 #endif
295 .endm
296
297 /*
298  * When dynamic function tracer is enabled it will add a breakpoint
299  * to all locations that it is about to modify, sync CPUs, update
300  * all the code, sync CPUs, then remove the breakpoints. In this time
301  * if lockdep is enabled, it might jump back into the debug handler
302  * outside the updating of the IST protection. (TRACE_IRQS_ON/OFF).
303  *
304  * We need to change the IDT table before calling TRACE_IRQS_ON/OFF to
305  * make sure the stack pointer does not get reset back to the top
306  * of the debug stack, and instead just reuses the current stack.
307  */
308 #if defined(CONFIG_DYNAMIC_FTRACE) && defined(CONFIG_TRACE_IRQFLAGS)
309
310 .macro TRACE_IRQS_OFF_DEBUG
311         call debug_stack_set_zero
312         TRACE_IRQS_OFF
313         call debug_stack_reset
314 .endm
315
316 .macro TRACE_IRQS_ON_DEBUG
317         call debug_stack_set_zero
318         TRACE_IRQS_ON
319         call debug_stack_reset
320 .endm
321
322 .macro TRACE_IRQS_IRETQ_DEBUG offset=ARGOFFSET
323         bt   $9,EFLAGS-\offset(%rsp)    /* interrupts off? */
324         jnc  1f
325         TRACE_IRQS_ON_DEBUG
326 1:
327 .endm
328
329 #else
330 # define TRACE_IRQS_OFF_DEBUG           TRACE_IRQS_OFF
331 # define TRACE_IRQS_ON_DEBUG            TRACE_IRQS_ON
332 # define TRACE_IRQS_IRETQ_DEBUG         TRACE_IRQS_IRETQ
333 #endif
334
335 /*
336  * C code is not supposed to know about undefined top of stack. Every time
337  * a C function with an pt_regs argument is called from the SYSCALL based
338  * fast path FIXUP_TOP_OF_STACK is needed.
339  * RESTORE_TOP_OF_STACK syncs the syscall state after any possible ptregs
340  * manipulation.
341  */
342
343         /* %rsp:at FRAMEEND */
344         .macro FIXUP_TOP_OF_STACK tmp offset=0
345         movq PER_CPU_VAR(old_rsp),\tmp
346         movq \tmp,RSP+\offset(%rsp)
347         movq $__USER_DS,SS+\offset(%rsp)
348         movq $__USER_CS,CS+\offset(%rsp)
349         movq $-1,RCX+\offset(%rsp)
350         movq R11+\offset(%rsp),\tmp  /* get eflags */
351         movq \tmp,EFLAGS+\offset(%rsp)
352         .endm
353
354         .macro RESTORE_TOP_OF_STACK tmp offset=0
355         movq RSP+\offset(%rsp),\tmp
356         movq \tmp,PER_CPU_VAR(old_rsp)
357         movq EFLAGS+\offset(%rsp),\tmp
358         movq \tmp,R11+\offset(%rsp)
359         .endm
360
361         .macro FAKE_STACK_FRAME child_rip
362         /* push in order ss, rsp, eflags, cs, rip */
363         xorl %eax, %eax
364         pushq_cfi $__KERNEL_DS /* ss */
365         /*CFI_REL_OFFSET        ss,0*/
366         pushq_cfi %rax /* rsp */
367         CFI_REL_OFFSET  rsp,0
368         pushq_cfi $(X86_EFLAGS_IF|X86_EFLAGS_BIT1) /* eflags - interrupts on */
369         /*CFI_REL_OFFSET        rflags,0*/
370         pushq_cfi $__KERNEL_CS /* cs */
371         /*CFI_REL_OFFSET        cs,0*/
372         pushq_cfi \child_rip /* rip */
373         CFI_REL_OFFSET  rip,0
374         pushq_cfi %rax /* orig rax */
375         .endm
376
377         .macro UNFAKE_STACK_FRAME
378         addq $8*6, %rsp
379         CFI_ADJUST_CFA_OFFSET   -(6*8)
380         .endm
381
382 /*
383  * initial frame state for interrupts (and exceptions without error code)
384  */
385         .macro EMPTY_FRAME start=1 offset=0
386         .if \start
387         CFI_STARTPROC simple
388         CFI_SIGNAL_FRAME
389         CFI_DEF_CFA rsp,8+\offset
390         .else
391         CFI_DEF_CFA_OFFSET 8+\offset
392         .endif
393         .endm
394
395 /*
396  * initial frame state for interrupts (and exceptions without error code)
397  */
398         .macro INTR_FRAME start=1 offset=0
399         EMPTY_FRAME \start, SS+8+\offset-RIP
400         /*CFI_REL_OFFSET ss, SS+\offset-RIP*/
401         CFI_REL_OFFSET rsp, RSP+\offset-RIP
402         /*CFI_REL_OFFSET rflags, EFLAGS+\offset-RIP*/
403         /*CFI_REL_OFFSET cs, CS+\offset-RIP*/
404         CFI_REL_OFFSET rip, RIP+\offset-RIP
405         .endm
406
407 /*
408  * initial frame state for exceptions with error code (and interrupts
409  * with vector already pushed)
410  */
411         .macro XCPT_FRAME start=1 offset=0
412         INTR_FRAME \start, RIP+\offset-ORIG_RAX
413         /*CFI_REL_OFFSET orig_rax, ORIG_RAX-ORIG_RAX*/
414         .endm
415
416 /*
417  * frame that enables calling into C.
418  */
419         .macro PARTIAL_FRAME start=1 offset=0
420         XCPT_FRAME \start, ORIG_RAX+\offset-ARGOFFSET
421         CFI_REL_OFFSET rdi, RDI+\offset-ARGOFFSET
422         CFI_REL_OFFSET rsi, RSI+\offset-ARGOFFSET
423         CFI_REL_OFFSET rdx, RDX+\offset-ARGOFFSET
424         CFI_REL_OFFSET rcx, RCX+\offset-ARGOFFSET
425         CFI_REL_OFFSET rax, RAX+\offset-ARGOFFSET
426         CFI_REL_OFFSET r8, R8+\offset-ARGOFFSET
427         CFI_REL_OFFSET r9, R9+\offset-ARGOFFSET
428         CFI_REL_OFFSET r10, R10+\offset-ARGOFFSET
429         CFI_REL_OFFSET r11, R11+\offset-ARGOFFSET
430         .endm
431
432 /*
433  * frame that enables passing a complete pt_regs to a C function.
434  */
435         .macro DEFAULT_FRAME start=1 offset=0
436         PARTIAL_FRAME \start, R11+\offset-R15
437         CFI_REL_OFFSET rbx, RBX+\offset
438         CFI_REL_OFFSET rbp, RBP+\offset
439         CFI_REL_OFFSET r12, R12+\offset
440         CFI_REL_OFFSET r13, R13+\offset
441         CFI_REL_OFFSET r14, R14+\offset
442         CFI_REL_OFFSET r15, R15+\offset
443         .endm
444
445 /* save partial stack frame */
446         .macro SAVE_ARGS_IRQ
447         cld
448         /* start from rbp in pt_regs and jump over */
449         movq_cfi rdi, (RDI-RBP)
450         movq_cfi rsi, (RSI-RBP)
451         movq_cfi rdx, (RDX-RBP)
452         movq_cfi rcx, (RCX-RBP)
453         movq_cfi rax, (RAX-RBP)
454         movq_cfi  r8,  (R8-RBP)
455         movq_cfi  r9,  (R9-RBP)
456         movq_cfi r10, (R10-RBP)
457         movq_cfi r11, (R11-RBP)
458
459         /* Save rbp so that we can unwind from get_irq_regs() */
460         movq_cfi rbp, 0
461
462         /* Save previous stack value */
463         movq %rsp, %rsi
464
465         leaq -RBP(%rsp),%rdi    /* arg1 for handler */
466         testl $3, CS-RBP(%rsi)
467         je 1f
468         SWAPGS
469         /*
470          * irq_count is used to check if a CPU is already on an interrupt stack
471          * or not. While this is essentially redundant with preempt_count it is
472          * a little cheaper to use a separate counter in the PDA (short of
473          * moving irq_enter into assembly, which would be too much work)
474          */
475 1:      incl PER_CPU_VAR(irq_count)
476         cmovzq PER_CPU_VAR(irq_stack_ptr),%rsp
477         CFI_DEF_CFA_REGISTER    rsi
478
479         /* Store previous stack value */
480         pushq %rsi
481         CFI_ESCAPE      0x0f /* DW_CFA_def_cfa_expression */, 6, \
482                         0x77 /* DW_OP_breg7 */, 0, \
483                         0x06 /* DW_OP_deref */, \
484                         0x08 /* DW_OP_const1u */, SS+8-RBP, \
485                         0x22 /* DW_OP_plus */
486         /* We entered an interrupt context - irqs are off: */
487         TRACE_IRQS_OFF
488         .endm
489
490 ENTRY(save_rest)
491         PARTIAL_FRAME 1 (REST_SKIP+8)
492         movq 5*8+16(%rsp), %r11 /* save return address */
493         movq_cfi rbx, RBX+16
494         movq_cfi rbp, RBP+16
495         movq_cfi r12, R12+16
496         movq_cfi r13, R13+16
497         movq_cfi r14, R14+16
498         movq_cfi r15, R15+16
499         movq %r11, 8(%rsp)      /* return address */
500         FIXUP_TOP_OF_STACK %r11, 16
501         ret
502         CFI_ENDPROC
503 END(save_rest)
504
505 /* save complete stack frame */
506         .pushsection .kprobes.text, "ax"
507 ENTRY(save_paranoid)
508         XCPT_FRAME 1 RDI+8
509         cld
510         movq_cfi rdi, RDI+8
511         movq_cfi rsi, RSI+8
512         movq_cfi rdx, RDX+8
513         movq_cfi rcx, RCX+8
514         movq_cfi rax, RAX+8
515         movq_cfi r8, R8+8
516         movq_cfi r9, R9+8
517         movq_cfi r10, R10+8
518         movq_cfi r11, R11+8
519         movq_cfi rbx, RBX+8
520         movq_cfi rbp, RBP+8
521         movq_cfi r12, R12+8
522         movq_cfi r13, R13+8
523         movq_cfi r14, R14+8
524         movq_cfi r15, R15+8
525         movl $1,%ebx
526         movl $MSR_GS_BASE,%ecx
527         rdmsr
528         testl %edx,%edx
529         js 1f   /* negative -> in kernel */
530         SWAPGS
531         xorl %ebx,%ebx
532 1:      ret
533         CFI_ENDPROC
534 END(save_paranoid)
535         .popsection
536
537 /*
538  * A newly forked process directly context switches into this address.
539  *
540  * rdi: prev task we switched from
541  */
542 ENTRY(ret_from_fork)
543         DEFAULT_FRAME
544
545         LOCK ; btr $TIF_FORK,TI_flags(%r8)
546
547         pushq_cfi $0x0002
548         popfq_cfi                               # reset kernel eflags
549
550         call schedule_tail                      # rdi: 'prev' task parameter
551
552         GET_THREAD_INFO(%rcx)
553
554         RESTORE_REST
555
556         testl $3, CS-ARGOFFSET(%rsp)            # from kernel_thread?
557         jz   retint_restore_args
558
559         testl $_TIF_IA32, TI_flags(%rcx)        # 32-bit compat task needs IRET
560         jnz  int_ret_from_sys_call
561
562         RESTORE_TOP_OF_STACK %rdi, -ARGOFFSET
563         jmp ret_from_sys_call                   # go to the SYSRET fastpath
564
565         CFI_ENDPROC
566 END(ret_from_fork)
567
568 /*
569  * System call entry. Up to 6 arguments in registers are supported.
570  *
571  * SYSCALL does not save anything on the stack and does not change the
572  * stack pointer.  However, it does mask the flags register for us, so
573  * CLD and CLAC are not needed.
574  */
575
576 /*
577  * Register setup:
578  * rax  system call number
579  * rdi  arg0
580  * rcx  return address for syscall/sysret, C arg3
581  * rsi  arg1
582  * rdx  arg2
583  * r10  arg3    (--> moved to rcx for C)
584  * r8   arg4
585  * r9   arg5
586  * r11  eflags for syscall/sysret, temporary for C
587  * r12-r15,rbp,rbx saved by C code, not touched.
588  *
589  * Interrupts are off on entry.
590  * Only called from user space.
591  *
592  * XXX  if we had a free scratch register we could save the RSP into the stack frame
593  *      and report it properly in ps. Unfortunately we haven't.
594  *
595  * When user can change the frames always force IRET. That is because
596  * it deals with uncanonical addresses better. SYSRET has trouble
597  * with them due to bugs in both AMD and Intel CPUs.
598  */
599
600 ENTRY(system_call)
601         CFI_STARTPROC   simple
602         CFI_SIGNAL_FRAME
603         CFI_DEF_CFA     rsp,KERNEL_STACK_OFFSET
604         CFI_REGISTER    rip,rcx
605         /*CFI_REGISTER  rflags,r11*/
606         SWAPGS_UNSAFE_STACK
607         /*
608          * A hypervisor implementation might want to use a label
609          * after the swapgs, so that it can do the swapgs
610          * for the guest and jump here on syscall.
611          */
612 GLOBAL(system_call_after_swapgs)
613
614         movq    %rsp,PER_CPU_VAR(old_rsp)
615         movq    PER_CPU_VAR(kernel_stack),%rsp
616         /*
617          * No need to follow this irqs off/on section - it's straight
618          * and short:
619          */
620         ENABLE_INTERRUPTS(CLBR_NONE)
621         SAVE_ARGS 8,0
622         movq  %rax,ORIG_RAX-ARGOFFSET(%rsp)
623         movq  %rcx,RIP-ARGOFFSET(%rsp)
624         CFI_REL_OFFSET rip,RIP-ARGOFFSET
625         testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags+THREAD_INFO(%rsp,RIP-ARGOFFSET)
626         jnz tracesys
627 system_call_fastpath:
628 #if __SYSCALL_MASK == ~0
629         cmpq $__NR_syscall_max,%rax
630 #else
631         andl $__SYSCALL_MASK,%eax
632         cmpl $__NR_syscall_max,%eax
633 #endif
634         ja badsys
635         movq %r10,%rcx
636         call *sys_call_table(,%rax,8)  # XXX:    rip relative
637         movq %rax,RAX-ARGOFFSET(%rsp)
638 /*
639  * Syscall return path ending with SYSRET (fast path)
640  * Has incomplete stack frame and undefined top of stack.
641  */
642 ret_from_sys_call:
643         movl $_TIF_ALLWORK_MASK,%edi
644         /* edi: flagmask */
645 sysret_check:
646         LOCKDEP_SYS_EXIT
647         DISABLE_INTERRUPTS(CLBR_NONE)
648         TRACE_IRQS_OFF
649         movl TI_flags+THREAD_INFO(%rsp,RIP-ARGOFFSET),%edx
650         andl %edi,%edx
651         jnz  sysret_careful
652         CFI_REMEMBER_STATE
653         /*
654          * sysretq will re-enable interrupts:
655          */
656         TRACE_IRQS_ON
657         movq RIP-ARGOFFSET(%rsp),%rcx
658         CFI_REGISTER    rip,rcx
659         RESTORE_ARGS 1,-ARG_SKIP,0
660         /*CFI_REGISTER  rflags,r11*/
661         movq    PER_CPU_VAR(old_rsp), %rsp
662         USERGS_SYSRET64
663
664         CFI_RESTORE_STATE
665         /* Handle reschedules */
666         /* edx: work, edi: workmask */
667 sysret_careful:
668         bt $TIF_NEED_RESCHED,%edx
669         jnc sysret_signal
670         TRACE_IRQS_ON
671         ENABLE_INTERRUPTS(CLBR_NONE)
672         pushq_cfi %rdi
673         SCHEDULE_USER
674         popq_cfi %rdi
675         jmp sysret_check
676
677         /* Handle a signal */
678 sysret_signal:
679         TRACE_IRQS_ON
680         ENABLE_INTERRUPTS(CLBR_NONE)
681 #ifdef CONFIG_AUDITSYSCALL
682         bt $TIF_SYSCALL_AUDIT,%edx
683         jc sysret_audit
684 #endif
685         /*
686          * We have a signal, or exit tracing or single-step.
687          * These all wind up with the iret return path anyway,
688          * so just join that path right now.
689          */
690         FIXUP_TOP_OF_STACK %r11, -ARGOFFSET
691         jmp int_check_syscall_exit_work
692
693 badsys:
694         movq $-ENOSYS,RAX-ARGOFFSET(%rsp)
695         jmp ret_from_sys_call
696
697 #ifdef CONFIG_AUDITSYSCALL
698         /*
699          * Fast path for syscall audit without full syscall trace.
700          * We just call __audit_syscall_entry() directly, and then
701          * jump back to the normal fast path.
702          */
703 auditsys:
704         movq %r10,%r9                   /* 6th arg: 4th syscall arg */
705         movq %rdx,%r8                   /* 5th arg: 3rd syscall arg */
706         movq %rsi,%rcx                  /* 4th arg: 2nd syscall arg */
707         movq %rdi,%rdx                  /* 3rd arg: 1st syscall arg */
708         movq %rax,%rsi                  /* 2nd arg: syscall number */
709         movl $AUDIT_ARCH_X86_64,%edi    /* 1st arg: audit arch */
710         call __audit_syscall_entry
711         LOAD_ARGS 0             /* reload call-clobbered registers */
712         jmp system_call_fastpath
713
714         /*
715          * Return fast path for syscall audit.  Call __audit_syscall_exit()
716          * directly and then jump back to the fast path with TIF_SYSCALL_AUDIT
717          * masked off.
718          */
719 sysret_audit:
720         movq RAX-ARGOFFSET(%rsp),%rsi   /* second arg, syscall return value */
721         cmpq $-MAX_ERRNO,%rsi   /* is it < -MAX_ERRNO? */
722         setbe %al               /* 1 if so, 0 if not */
723         movzbl %al,%edi         /* zero-extend that into %edi */
724         call __audit_syscall_exit
725         movl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT),%edi
726         jmp sysret_check
727 #endif  /* CONFIG_AUDITSYSCALL */
728
729         /* Do syscall tracing */
730 tracesys:
731 #ifdef CONFIG_AUDITSYSCALL
732         testl $(_TIF_WORK_SYSCALL_ENTRY & ~_TIF_SYSCALL_AUDIT),TI_flags+THREAD_INFO(%rsp,RIP-ARGOFFSET)
733         jz auditsys
734 #endif
735         SAVE_REST
736         movq $-ENOSYS,RAX(%rsp) /* ptrace can change this for a bad syscall */
737         FIXUP_TOP_OF_STACK %rdi
738         movq %rsp,%rdi
739         call syscall_trace_enter
740         /*
741          * Reload arg registers from stack in case ptrace changed them.
742          * We don't reload %rax because syscall_trace_enter() returned
743          * the value it wants us to use in the table lookup.
744          */
745         LOAD_ARGS ARGOFFSET, 1
746         RESTORE_REST
747 #if __SYSCALL_MASK == ~0
748         cmpq $__NR_syscall_max,%rax
749 #else
750         andl $__SYSCALL_MASK,%eax
751         cmpl $__NR_syscall_max,%eax
752 #endif
753         ja   int_ret_from_sys_call      /* RAX(%rsp) set to -ENOSYS above */
754         movq %r10,%rcx  /* fixup for C */
755         call *sys_call_table(,%rax,8)
756         movq %rax,RAX-ARGOFFSET(%rsp)
757         /* Use IRET because user could have changed frame */
758
759 /*
760  * Syscall return path ending with IRET.
761  * Has correct top of stack, but partial stack frame.
762  */
763 GLOBAL(int_ret_from_sys_call)
764         DISABLE_INTERRUPTS(CLBR_NONE)
765         TRACE_IRQS_OFF
766         movl $_TIF_ALLWORK_MASK,%edi
767         /* edi: mask to check */
768 GLOBAL(int_with_check)
769         LOCKDEP_SYS_EXIT_IRQ
770         GET_THREAD_INFO(%rcx)
771         movl TI_flags(%rcx),%edx
772         andl %edi,%edx
773         jnz   int_careful
774         andl    $~TS_COMPAT,TI_status(%rcx)
775         jmp   retint_swapgs
776
777         /* Either reschedule or signal or syscall exit tracking needed. */
778         /* First do a reschedule test. */
779         /* edx: work, edi: workmask */
780 int_careful:
781         bt $TIF_NEED_RESCHED,%edx
782         jnc  int_very_careful
783         TRACE_IRQS_ON
784         ENABLE_INTERRUPTS(CLBR_NONE)
785         pushq_cfi %rdi
786         SCHEDULE_USER
787         popq_cfi %rdi
788         DISABLE_INTERRUPTS(CLBR_NONE)
789         TRACE_IRQS_OFF
790         jmp int_with_check
791
792         /* handle signals and tracing -- both require a full stack frame */
793 int_very_careful:
794         TRACE_IRQS_ON
795         ENABLE_INTERRUPTS(CLBR_NONE)
796 int_check_syscall_exit_work:
797         SAVE_REST
798         /* Check for syscall exit trace */
799         testl $_TIF_WORK_SYSCALL_EXIT,%edx
800         jz int_signal
801         pushq_cfi %rdi
802         leaq 8(%rsp),%rdi       # &ptregs -> arg1
803         call syscall_trace_leave
804         popq_cfi %rdi
805         andl $~(_TIF_WORK_SYSCALL_EXIT|_TIF_SYSCALL_EMU),%edi
806         jmp int_restore_rest
807
808 int_signal:
809         testl $_TIF_DO_NOTIFY_MASK,%edx
810         jz 1f
811         movq %rsp,%rdi          # &ptregs -> arg1
812         xorl %esi,%esi          # oldset -> arg2
813         call do_notify_resume
814 1:      movl $_TIF_WORK_MASK,%edi
815 int_restore_rest:
816         RESTORE_REST
817         DISABLE_INTERRUPTS(CLBR_NONE)
818         TRACE_IRQS_OFF
819         jmp int_with_check
820         CFI_ENDPROC
821 END(system_call)
822
823 /*
824  * Certain special system calls that need to save a complete full stack frame.
825  */
826         .macro PTREGSCALL label,func,arg
827 ENTRY(\label)
828         PARTIAL_FRAME 1 8               /* offset 8: return address */
829         subq $REST_SKIP, %rsp
830         CFI_ADJUST_CFA_OFFSET REST_SKIP
831         call save_rest
832         DEFAULT_FRAME 0 8               /* offset 8: return address */
833         leaq 8(%rsp), \arg      /* pt_regs pointer */
834         call \func
835         jmp ptregscall_common
836         CFI_ENDPROC
837 END(\label)
838         .endm
839
840         PTREGSCALL stub_clone, sys_clone, %r8
841         PTREGSCALL stub_fork, sys_fork, %rdi
842         PTREGSCALL stub_vfork, sys_vfork, %rdi
843         PTREGSCALL stub_sigaltstack, sys_sigaltstack, %rdx
844         PTREGSCALL stub_iopl, sys_iopl, %rsi
845
846 ENTRY(ptregscall_common)
847         DEFAULT_FRAME 1 8       /* offset 8: return address */
848         RESTORE_TOP_OF_STACK %r11, 8
849         movq_cfi_restore R15+8, r15
850         movq_cfi_restore R14+8, r14
851         movq_cfi_restore R13+8, r13
852         movq_cfi_restore R12+8, r12
853         movq_cfi_restore RBP+8, rbp
854         movq_cfi_restore RBX+8, rbx
855         ret $REST_SKIP          /* pop extended registers */
856         CFI_ENDPROC
857 END(ptregscall_common)
858
859 ENTRY(stub_execve)
860         CFI_STARTPROC
861         addq $8, %rsp
862         PARTIAL_FRAME 0
863         SAVE_REST
864         FIXUP_TOP_OF_STACK %r11
865         movq %rsp, %rcx
866         call sys_execve
867         RESTORE_TOP_OF_STACK %r11
868         movq %rax,RAX(%rsp)
869         RESTORE_REST
870         jmp int_ret_from_sys_call
871         CFI_ENDPROC
872 END(stub_execve)
873
874 /*
875  * sigreturn is special because it needs to restore all registers on return.
876  * This cannot be done with SYSRET, so use the IRET return path instead.
877  */
878 ENTRY(stub_rt_sigreturn)
879         CFI_STARTPROC
880         addq $8, %rsp
881         PARTIAL_FRAME 0
882         SAVE_REST
883         movq %rsp,%rdi
884         FIXUP_TOP_OF_STACK %r11
885         call sys_rt_sigreturn
886         movq %rax,RAX(%rsp) # fixme, this could be done at the higher layer
887         RESTORE_REST
888         jmp int_ret_from_sys_call
889         CFI_ENDPROC
890 END(stub_rt_sigreturn)
891
892 #ifdef CONFIG_X86_X32_ABI
893         PTREGSCALL stub_x32_sigaltstack, sys32_sigaltstack, %rdx
894
895 ENTRY(stub_x32_rt_sigreturn)
896         CFI_STARTPROC
897         addq $8, %rsp
898         PARTIAL_FRAME 0
899         SAVE_REST
900         movq %rsp,%rdi
901         FIXUP_TOP_OF_STACK %r11
902         call sys32_x32_rt_sigreturn
903         movq %rax,RAX(%rsp) # fixme, this could be done at the higher layer
904         RESTORE_REST
905         jmp int_ret_from_sys_call
906         CFI_ENDPROC
907 END(stub_x32_rt_sigreturn)
908
909 ENTRY(stub_x32_execve)
910         CFI_STARTPROC
911         addq $8, %rsp
912         PARTIAL_FRAME 0
913         SAVE_REST
914         FIXUP_TOP_OF_STACK %r11
915         movq %rsp, %rcx
916         call sys32_execve
917         RESTORE_TOP_OF_STACK %r11
918         movq %rax,RAX(%rsp)
919         RESTORE_REST
920         jmp int_ret_from_sys_call
921         CFI_ENDPROC
922 END(stub_x32_execve)
923
924 #endif
925
926 /*
927  * Build the entry stubs and pointer table with some assembler magic.
928  * We pack 7 stubs into a single 32-byte chunk, which will fit in a
929  * single cache line on all modern x86 implementations.
930  */
931         .section .init.rodata,"a"
932 ENTRY(interrupt)
933         .section .entry.text
934         .p2align 5
935         .p2align CONFIG_X86_L1_CACHE_SHIFT
936 ENTRY(irq_entries_start)
937         INTR_FRAME
938 vector=FIRST_EXTERNAL_VECTOR
939 .rept (NR_VECTORS-FIRST_EXTERNAL_VECTOR+6)/7
940         .balign 32
941   .rept 7
942     .if vector < NR_VECTORS
943       .if vector <> FIRST_EXTERNAL_VECTOR
944         CFI_ADJUST_CFA_OFFSET -8
945       .endif
946 1:      pushq_cfi $(~vector+0x80)       /* Note: always in signed byte range */
947       .if ((vector-FIRST_EXTERNAL_VECTOR)%7) <> 6
948         jmp 2f
949       .endif
950       .previous
951         .quad 1b
952       .section .entry.text
953 vector=vector+1
954     .endif
955   .endr
956 2:      jmp common_interrupt
957 .endr
958         CFI_ENDPROC
959 END(irq_entries_start)
960
961 .previous
962 END(interrupt)
963 .previous
964
965 /*
966  * Interrupt entry/exit.
967  *
968  * Interrupt entry points save only callee clobbered registers in fast path.
969  *
970  * Entry runs with interrupts off.
971  */
972
973 /* 0(%rsp): ~(interrupt number) */
974         .macro interrupt func
975         /* reserve pt_regs for scratch regs and rbp */
976         subq $ORIG_RAX-RBP, %rsp
977         CFI_ADJUST_CFA_OFFSET ORIG_RAX-RBP
978         SAVE_ARGS_IRQ
979         call \func
980         .endm
981
982 /*
983  * Interrupt entry/exit should be protected against kprobes
984  */
985         .pushsection .kprobes.text, "ax"
986         /*
987          * The interrupt stubs push (~vector+0x80) onto the stack and
988          * then jump to common_interrupt.
989          */
990         .p2align CONFIG_X86_L1_CACHE_SHIFT
991 common_interrupt:
992         ASM_CLAC
993         XCPT_FRAME
994         addq $-0x80,(%rsp)              /* Adjust vector to [-256,-1] range */
995         interrupt do_IRQ
996         /* 0(%rsp): old_rsp-ARGOFFSET */
997 ret_from_intr:
998         DISABLE_INTERRUPTS(CLBR_NONE)
999         TRACE_IRQS_OFF
1000         decl PER_CPU_VAR(irq_count)
1001
1002         /* Restore saved previous stack */
1003         popq %rsi
1004         CFI_DEF_CFA rsi,SS+8-RBP        /* reg/off reset after def_cfa_expr */
1005         leaq ARGOFFSET-RBP(%rsi), %rsp
1006         CFI_DEF_CFA_REGISTER    rsp
1007         CFI_ADJUST_CFA_OFFSET   RBP-ARGOFFSET
1008
1009 exit_intr:
1010         GET_THREAD_INFO(%rcx)
1011         testl $3,CS-ARGOFFSET(%rsp)
1012         je retint_kernel
1013
1014         /* Interrupt came from user space */
1015         /*
1016          * Has a correct top of stack, but a partial stack frame
1017          * %rcx: thread info. Interrupts off.
1018          */
1019 retint_with_reschedule:
1020         movl $_TIF_WORK_MASK,%edi
1021 retint_check:
1022         LOCKDEP_SYS_EXIT_IRQ
1023         movl TI_flags(%rcx),%edx
1024         andl %edi,%edx
1025         CFI_REMEMBER_STATE
1026         jnz  retint_careful
1027
1028 retint_swapgs:          /* return to user-space */
1029         /*
1030          * The iretq could re-enable interrupts:
1031          */
1032         DISABLE_INTERRUPTS(CLBR_ANY)
1033         TRACE_IRQS_IRETQ
1034         SWAPGS
1035         jmp restore_args
1036
1037 retint_restore_args:    /* return to kernel space */
1038         DISABLE_INTERRUPTS(CLBR_ANY)
1039         /*
1040          * The iretq could re-enable interrupts:
1041          */
1042         TRACE_IRQS_IRETQ
1043 restore_args:
1044         RESTORE_ARGS 1,8,1
1045
1046 irq_return:
1047         INTERRUPT_RETURN
1048         _ASM_EXTABLE(irq_return, bad_iret)
1049
1050 #ifdef CONFIG_PARAVIRT
1051 ENTRY(native_iret)
1052         iretq
1053         _ASM_EXTABLE(native_iret, bad_iret)
1054 #endif
1055
1056         .section .fixup,"ax"
1057 bad_iret:
1058         /*
1059          * The iret traps when the %cs or %ss being restored is bogus.
1060          * We've lost the original trap vector and error code.
1061          * #GPF is the most likely one to get for an invalid selector.
1062          * So pretend we completed the iret and took the #GPF in user mode.
1063          *
1064          * We are now running with the kernel GS after exception recovery.
1065          * But error_entry expects us to have user GS to match the user %cs,
1066          * so swap back.
1067          */
1068         pushq $0
1069
1070         SWAPGS
1071         jmp general_protection
1072
1073         .previous
1074
1075         /* edi: workmask, edx: work */
1076 retint_careful:
1077         CFI_RESTORE_STATE
1078         bt    $TIF_NEED_RESCHED,%edx
1079         jnc   retint_signal
1080         TRACE_IRQS_ON
1081         ENABLE_INTERRUPTS(CLBR_NONE)
1082         pushq_cfi %rdi
1083         SCHEDULE_USER
1084         popq_cfi %rdi
1085         GET_THREAD_INFO(%rcx)
1086         DISABLE_INTERRUPTS(CLBR_NONE)
1087         TRACE_IRQS_OFF
1088         jmp retint_check
1089
1090 retint_signal:
1091         testl $_TIF_DO_NOTIFY_MASK,%edx
1092         jz    retint_swapgs
1093         TRACE_IRQS_ON
1094         ENABLE_INTERRUPTS(CLBR_NONE)
1095         SAVE_REST
1096         movq $-1,ORIG_RAX(%rsp)
1097         xorl %esi,%esi          # oldset
1098         movq %rsp,%rdi          # &pt_regs
1099         call do_notify_resume
1100         RESTORE_REST
1101         DISABLE_INTERRUPTS(CLBR_NONE)
1102         TRACE_IRQS_OFF
1103         GET_THREAD_INFO(%rcx)
1104         jmp retint_with_reschedule
1105
1106 #ifdef CONFIG_PREEMPT
1107         /* Returning to kernel space. Check if we need preemption */
1108         /* rcx:  threadinfo. interrupts off. */
1109 ENTRY(retint_kernel)
1110         cmpl $0,TI_preempt_count(%rcx)
1111         jnz  retint_restore_args
1112         bt  $TIF_NEED_RESCHED,TI_flags(%rcx)
1113         jnc  retint_restore_args
1114         bt   $9,EFLAGS-ARGOFFSET(%rsp)  /* interrupts off? */
1115         jnc  retint_restore_args
1116         call preempt_schedule_irq
1117         jmp exit_intr
1118 #endif
1119
1120         CFI_ENDPROC
1121 END(common_interrupt)
1122 /*
1123  * End of kprobes section
1124  */
1125        .popsection
1126
1127 /*
1128  * APIC interrupts.
1129  */
1130 .macro apicinterrupt num sym do_sym
1131 ENTRY(\sym)
1132         ASM_CLAC
1133         INTR_FRAME
1134         pushq_cfi $~(\num)
1135 .Lcommon_\sym:
1136         interrupt \do_sym
1137         jmp ret_from_intr
1138         CFI_ENDPROC
1139 END(\sym)
1140 .endm
1141
1142 #ifdef CONFIG_SMP
1143 apicinterrupt IRQ_MOVE_CLEANUP_VECTOR \
1144         irq_move_cleanup_interrupt smp_irq_move_cleanup_interrupt
1145 apicinterrupt REBOOT_VECTOR \
1146         reboot_interrupt smp_reboot_interrupt
1147 #endif
1148
1149 #ifdef CONFIG_X86_UV
1150 apicinterrupt UV_BAU_MESSAGE \
1151         uv_bau_message_intr1 uv_bau_message_interrupt
1152 #endif
1153 apicinterrupt LOCAL_TIMER_VECTOR \
1154         apic_timer_interrupt smp_apic_timer_interrupt
1155 apicinterrupt X86_PLATFORM_IPI_VECTOR \
1156         x86_platform_ipi smp_x86_platform_ipi
1157
1158 apicinterrupt THRESHOLD_APIC_VECTOR \
1159         threshold_interrupt smp_threshold_interrupt
1160 apicinterrupt THERMAL_APIC_VECTOR \
1161         thermal_interrupt smp_thermal_interrupt
1162
1163 #ifdef CONFIG_SMP
1164 apicinterrupt CALL_FUNCTION_SINGLE_VECTOR \
1165         call_function_single_interrupt smp_call_function_single_interrupt
1166 apicinterrupt CALL_FUNCTION_VECTOR \
1167         call_function_interrupt smp_call_function_interrupt
1168 apicinterrupt RESCHEDULE_VECTOR \
1169         reschedule_interrupt smp_reschedule_interrupt
1170 #endif
1171
1172 apicinterrupt ERROR_APIC_VECTOR \
1173         error_interrupt smp_error_interrupt
1174 apicinterrupt SPURIOUS_APIC_VECTOR \
1175         spurious_interrupt smp_spurious_interrupt
1176
1177 #ifdef CONFIG_IRQ_WORK
1178 apicinterrupt IRQ_WORK_VECTOR \
1179         irq_work_interrupt smp_irq_work_interrupt
1180 #endif
1181
1182 /*
1183  * Exception entry points.
1184  */
1185 .macro zeroentry sym do_sym
1186 ENTRY(\sym)
1187         ASM_CLAC
1188         INTR_FRAME
1189         PARAVIRT_ADJUST_EXCEPTION_FRAME
1190         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1191         subq $ORIG_RAX-R15, %rsp
1192         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1193         call error_entry
1194         DEFAULT_FRAME 0
1195         movq %rsp,%rdi          /* pt_regs pointer */
1196         xorl %esi,%esi          /* no error code */
1197         call \do_sym
1198         jmp error_exit          /* %ebx: no swapgs flag */
1199         CFI_ENDPROC
1200 END(\sym)
1201 .endm
1202
1203 .macro paranoidzeroentry sym do_sym
1204 ENTRY(\sym)
1205         ASM_CLAC
1206         INTR_FRAME
1207         PARAVIRT_ADJUST_EXCEPTION_FRAME
1208         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1209         subq $ORIG_RAX-R15, %rsp
1210         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1211         call save_paranoid
1212         TRACE_IRQS_OFF
1213         movq %rsp,%rdi          /* pt_regs pointer */
1214         xorl %esi,%esi          /* no error code */
1215         call \do_sym
1216         jmp paranoid_exit       /* %ebx: no swapgs flag */
1217         CFI_ENDPROC
1218 END(\sym)
1219 .endm
1220
1221 #define INIT_TSS_IST(x) PER_CPU_VAR(init_tss) + (TSS_ist + ((x) - 1) * 8)
1222 .macro paranoidzeroentry_ist sym do_sym ist
1223 ENTRY(\sym)
1224         ASM_CLAC
1225         INTR_FRAME
1226         PARAVIRT_ADJUST_EXCEPTION_FRAME
1227         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1228         subq $ORIG_RAX-R15, %rsp
1229         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1230         call save_paranoid
1231         TRACE_IRQS_OFF_DEBUG
1232         movq %rsp,%rdi          /* pt_regs pointer */
1233         xorl %esi,%esi          /* no error code */
1234         subq $EXCEPTION_STKSZ, INIT_TSS_IST(\ist)
1235         call \do_sym
1236         addq $EXCEPTION_STKSZ, INIT_TSS_IST(\ist)
1237         jmp paranoid_exit       /* %ebx: no swapgs flag */
1238         CFI_ENDPROC
1239 END(\sym)
1240 .endm
1241
1242 .macro errorentry sym do_sym
1243 ENTRY(\sym)
1244         ASM_CLAC
1245         XCPT_FRAME
1246         PARAVIRT_ADJUST_EXCEPTION_FRAME
1247         subq $ORIG_RAX-R15, %rsp
1248         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1249         call error_entry
1250         DEFAULT_FRAME 0
1251         movq %rsp,%rdi                  /* pt_regs pointer */
1252         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1253         movq $-1,ORIG_RAX(%rsp)         /* no syscall to restart */
1254         call \do_sym
1255         jmp error_exit                  /* %ebx: no swapgs flag */
1256         CFI_ENDPROC
1257 END(\sym)
1258 .endm
1259
1260         /* error code is on the stack already */
1261 .macro paranoiderrorentry sym do_sym
1262 ENTRY(\sym)
1263         ASM_CLAC
1264         XCPT_FRAME
1265         PARAVIRT_ADJUST_EXCEPTION_FRAME
1266         subq $ORIG_RAX-R15, %rsp
1267         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1268         call save_paranoid
1269         DEFAULT_FRAME 0
1270         TRACE_IRQS_OFF
1271         movq %rsp,%rdi                  /* pt_regs pointer */
1272         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1273         movq $-1,ORIG_RAX(%rsp)         /* no syscall to restart */
1274         call \do_sym
1275         jmp paranoid_exit               /* %ebx: no swapgs flag */
1276         CFI_ENDPROC
1277 END(\sym)
1278 .endm
1279
1280 zeroentry divide_error do_divide_error
1281 zeroentry overflow do_overflow
1282 zeroentry bounds do_bounds
1283 zeroentry invalid_op do_invalid_op
1284 zeroentry device_not_available do_device_not_available
1285 paranoiderrorentry double_fault do_double_fault
1286 zeroentry coprocessor_segment_overrun do_coprocessor_segment_overrun
1287 errorentry invalid_TSS do_invalid_TSS
1288 errorentry segment_not_present do_segment_not_present
1289 zeroentry spurious_interrupt_bug do_spurious_interrupt_bug
1290 zeroentry coprocessor_error do_coprocessor_error
1291 errorentry alignment_check do_alignment_check
1292 zeroentry simd_coprocessor_error do_simd_coprocessor_error
1293
1294
1295         /* Reload gs selector with exception handling */
1296         /* edi:  new selector */
1297 ENTRY(native_load_gs_index)
1298         CFI_STARTPROC
1299         pushfq_cfi
1300         DISABLE_INTERRUPTS(CLBR_ANY & ~CLBR_RDI)
1301         SWAPGS
1302 gs_change:
1303         movl %edi,%gs
1304 2:      mfence          /* workaround */
1305         SWAPGS
1306         popfq_cfi
1307         ret
1308         CFI_ENDPROC
1309 END(native_load_gs_index)
1310
1311         _ASM_EXTABLE(gs_change,bad_gs)
1312         .section .fixup,"ax"
1313         /* running with kernelgs */
1314 bad_gs:
1315         SWAPGS                  /* switch back to user gs */
1316         xorl %eax,%eax
1317         movl %eax,%gs
1318         jmp  2b
1319         .previous
1320
1321 ENTRY(kernel_thread_helper)
1322         pushq $0                # fake return address
1323         CFI_STARTPROC
1324         /*
1325          * Here we are in the child and the registers are set as they were
1326          * at kernel_thread() invocation in the parent.
1327          */
1328         call *%rsi
1329         # exit
1330         mov %eax, %edi
1331         call do_exit
1332         ud2                     # padding for call trace
1333         CFI_ENDPROC
1334 END(kernel_thread_helper)
1335
1336 /*
1337  * execve(). This function needs to use IRET, not SYSRET, to set up all state properly.
1338  *
1339  * C extern interface:
1340  *       extern long execve(const char *name, char **argv, char **envp)
1341  *
1342  * asm input arguments:
1343  *      rdi: name, rsi: argv, rdx: envp
1344  *
1345  * We want to fallback into:
1346  *      extern long sys_execve(const char *name, char **argv,char **envp, struct pt_regs *regs)
1347  *
1348  * do_sys_execve asm fallback arguments:
1349  *      rdi: name, rsi: argv, rdx: envp, rcx: fake frame on the stack
1350  */
1351 ENTRY(kernel_execve)
1352         CFI_STARTPROC
1353         FAKE_STACK_FRAME $0
1354         SAVE_ALL
1355         movq %rsp,%rcx
1356         call sys_execve
1357         movq %rax, RAX(%rsp)
1358         RESTORE_REST
1359         testq %rax,%rax
1360         je int_ret_from_sys_call
1361         RESTORE_ARGS
1362         UNFAKE_STACK_FRAME
1363         ret
1364         CFI_ENDPROC
1365 END(kernel_execve)
1366
1367 /* Call softirq on interrupt stack. Interrupts are off. */
1368 ENTRY(call_softirq)
1369         CFI_STARTPROC
1370         pushq_cfi %rbp
1371         CFI_REL_OFFSET rbp,0
1372         mov  %rsp,%rbp
1373         CFI_DEF_CFA_REGISTER rbp
1374         incl PER_CPU_VAR(irq_count)
1375         cmove PER_CPU_VAR(irq_stack_ptr),%rsp
1376         push  %rbp                      # backlink for old unwinder
1377         call __do_softirq
1378         leaveq
1379         CFI_RESTORE             rbp
1380         CFI_DEF_CFA_REGISTER    rsp
1381         CFI_ADJUST_CFA_OFFSET   -8
1382         decl PER_CPU_VAR(irq_count)
1383         ret
1384         CFI_ENDPROC
1385 END(call_softirq)
1386
1387 #ifdef CONFIG_XEN
1388 zeroentry xen_hypervisor_callback xen_do_hypervisor_callback
1389
1390 /*
1391  * A note on the "critical region" in our callback handler.
1392  * We want to avoid stacking callback handlers due to events occurring
1393  * during handling of the last event. To do this, we keep events disabled
1394  * until we've done all processing. HOWEVER, we must enable events before
1395  * popping the stack frame (can't be done atomically) and so it would still
1396  * be possible to get enough handler activations to overflow the stack.
1397  * Although unlikely, bugs of that kind are hard to track down, so we'd
1398  * like to avoid the possibility.
1399  * So, on entry to the handler we detect whether we interrupted an
1400  * existing activation in its critical region -- if so, we pop the current
1401  * activation and restart the handler using the previous one.
1402  */
1403 ENTRY(xen_do_hypervisor_callback)   # do_hypervisor_callback(struct *pt_regs)
1404         CFI_STARTPROC
1405 /*
1406  * Since we don't modify %rdi, evtchn_do_upall(struct *pt_regs) will
1407  * see the correct pointer to the pt_regs
1408  */
1409         movq %rdi, %rsp            # we don't return, adjust the stack frame
1410         CFI_ENDPROC
1411         DEFAULT_FRAME
1412 11:     incl PER_CPU_VAR(irq_count)
1413         movq %rsp,%rbp
1414         CFI_DEF_CFA_REGISTER rbp
1415         cmovzq PER_CPU_VAR(irq_stack_ptr),%rsp
1416         pushq %rbp                      # backlink for old unwinder
1417         call xen_evtchn_do_upcall
1418         popq %rsp
1419         CFI_DEF_CFA_REGISTER rsp
1420         decl PER_CPU_VAR(irq_count)
1421         jmp  error_exit
1422         CFI_ENDPROC
1423 END(xen_do_hypervisor_callback)
1424
1425 /*
1426  * Hypervisor uses this for application faults while it executes.
1427  * We get here for two reasons:
1428  *  1. Fault while reloading DS, ES, FS or GS
1429  *  2. Fault while executing IRET
1430  * Category 1 we do not need to fix up as Xen has already reloaded all segment
1431  * registers that could be reloaded and zeroed the others.
1432  * Category 2 we fix up by killing the current process. We cannot use the
1433  * normal Linux return path in this case because if we use the IRET hypercall
1434  * to pop the stack frame we end up in an infinite loop of failsafe callbacks.
1435  * We distinguish between categories by comparing each saved segment register
1436  * with its current contents: any discrepancy means we in category 1.
1437  */
1438 ENTRY(xen_failsafe_callback)
1439         INTR_FRAME 1 (6*8)
1440         /*CFI_REL_OFFSET gs,GS*/
1441         /*CFI_REL_OFFSET fs,FS*/
1442         /*CFI_REL_OFFSET es,ES*/
1443         /*CFI_REL_OFFSET ds,DS*/
1444         CFI_REL_OFFSET r11,8
1445         CFI_REL_OFFSET rcx,0
1446         movw %ds,%cx
1447         cmpw %cx,0x10(%rsp)
1448         CFI_REMEMBER_STATE
1449         jne 1f
1450         movw %es,%cx
1451         cmpw %cx,0x18(%rsp)
1452         jne 1f
1453         movw %fs,%cx
1454         cmpw %cx,0x20(%rsp)
1455         jne 1f
1456         movw %gs,%cx
1457         cmpw %cx,0x28(%rsp)
1458         jne 1f
1459         /* All segments match their saved values => Category 2 (Bad IRET). */
1460         movq (%rsp),%rcx
1461         CFI_RESTORE rcx
1462         movq 8(%rsp),%r11
1463         CFI_RESTORE r11
1464         addq $0x30,%rsp
1465         CFI_ADJUST_CFA_OFFSET -0x30
1466         pushq_cfi $0    /* RIP */
1467         pushq_cfi %r11
1468         pushq_cfi %rcx
1469         jmp general_protection
1470         CFI_RESTORE_STATE
1471 1:      /* Segment mismatch => Category 1 (Bad segment). Retry the IRET. */
1472         movq (%rsp),%rcx
1473         CFI_RESTORE rcx
1474         movq 8(%rsp),%r11
1475         CFI_RESTORE r11
1476         addq $0x30,%rsp
1477         CFI_ADJUST_CFA_OFFSET -0x30
1478         pushq_cfi $0
1479         SAVE_ALL
1480         jmp error_exit
1481         CFI_ENDPROC
1482 END(xen_failsafe_callback)
1483
1484 apicinterrupt XEN_HVM_EVTCHN_CALLBACK \
1485         xen_hvm_callback_vector xen_evtchn_do_upcall
1486
1487 #endif /* CONFIG_XEN */
1488
1489 /*
1490  * Some functions should be protected against kprobes
1491  */
1492         .pushsection .kprobes.text, "ax"
1493
1494 paranoidzeroentry_ist debug do_debug DEBUG_STACK
1495 paranoidzeroentry_ist int3 do_int3 DEBUG_STACK
1496 paranoiderrorentry stack_segment do_stack_segment
1497 #ifdef CONFIG_XEN
1498 zeroentry xen_debug do_debug
1499 zeroentry xen_int3 do_int3
1500 errorentry xen_stack_segment do_stack_segment
1501 #endif
1502 errorentry general_protection do_general_protection
1503 errorentry page_fault do_page_fault
1504 #ifdef CONFIG_KVM_GUEST
1505 errorentry async_page_fault do_async_page_fault
1506 #endif
1507 #ifdef CONFIG_X86_MCE
1508 paranoidzeroentry machine_check *machine_check_vector(%rip)
1509 #endif
1510
1511         /*
1512          * "Paranoid" exit path from exception stack.
1513          * Paranoid because this is used by NMIs and cannot take
1514          * any kernel state for granted.
1515          * We don't do kernel preemption checks here, because only
1516          * NMI should be common and it does not enable IRQs and
1517          * cannot get reschedule ticks.
1518          *
1519          * "trace" is 0 for the NMI handler only, because irq-tracing
1520          * is fundamentally NMI-unsafe. (we cannot change the soft and
1521          * hard flags at once, atomically)
1522          */
1523
1524         /* ebx: no swapgs flag */
1525 ENTRY(paranoid_exit)
1526         DEFAULT_FRAME
1527         DISABLE_INTERRUPTS(CLBR_NONE)
1528         TRACE_IRQS_OFF_DEBUG
1529         testl %ebx,%ebx                         /* swapgs needed? */
1530         jnz paranoid_restore
1531         testl $3,CS(%rsp)
1532         jnz   paranoid_userspace
1533 paranoid_swapgs:
1534         TRACE_IRQS_IRETQ 0
1535         SWAPGS_UNSAFE_STACK
1536         RESTORE_ALL 8
1537         jmp irq_return
1538 paranoid_restore:
1539         TRACE_IRQS_IRETQ_DEBUG 0
1540         RESTORE_ALL 8
1541         jmp irq_return
1542 paranoid_userspace:
1543         GET_THREAD_INFO(%rcx)
1544         movl TI_flags(%rcx),%ebx
1545         andl $_TIF_WORK_MASK,%ebx
1546         jz paranoid_swapgs
1547         movq %rsp,%rdi                  /* &pt_regs */
1548         call sync_regs
1549         movq %rax,%rsp                  /* switch stack for scheduling */
1550         testl $_TIF_NEED_RESCHED,%ebx
1551         jnz paranoid_schedule
1552         movl %ebx,%edx                  /* arg3: thread flags */
1553         TRACE_IRQS_ON
1554         ENABLE_INTERRUPTS(CLBR_NONE)
1555         xorl %esi,%esi                  /* arg2: oldset */
1556         movq %rsp,%rdi                  /* arg1: &pt_regs */
1557         call do_notify_resume
1558         DISABLE_INTERRUPTS(CLBR_NONE)
1559         TRACE_IRQS_OFF
1560         jmp paranoid_userspace
1561 paranoid_schedule:
1562         TRACE_IRQS_ON
1563         ENABLE_INTERRUPTS(CLBR_ANY)
1564         SCHEDULE_USER
1565         DISABLE_INTERRUPTS(CLBR_ANY)
1566         TRACE_IRQS_OFF
1567         jmp paranoid_userspace
1568         CFI_ENDPROC
1569 END(paranoid_exit)
1570
1571 /*
1572  * Exception entry point. This expects an error code/orig_rax on the stack.
1573  * returns in "no swapgs flag" in %ebx.
1574  */
1575 ENTRY(error_entry)
1576         XCPT_FRAME
1577         CFI_ADJUST_CFA_OFFSET 15*8
1578         /* oldrax contains error code */
1579         cld
1580         movq_cfi rdi, RDI+8
1581         movq_cfi rsi, RSI+8
1582         movq_cfi rdx, RDX+8
1583         movq_cfi rcx, RCX+8
1584         movq_cfi rax, RAX+8
1585         movq_cfi  r8,  R8+8
1586         movq_cfi  r9,  R9+8
1587         movq_cfi r10, R10+8
1588         movq_cfi r11, R11+8
1589         movq_cfi rbx, RBX+8
1590         movq_cfi rbp, RBP+8
1591         movq_cfi r12, R12+8
1592         movq_cfi r13, R13+8
1593         movq_cfi r14, R14+8
1594         movq_cfi r15, R15+8
1595         xorl %ebx,%ebx
1596         testl $3,CS+8(%rsp)
1597         je error_kernelspace
1598 error_swapgs:
1599         SWAPGS
1600 error_sti:
1601         TRACE_IRQS_OFF
1602         ret
1603
1604 /*
1605  * There are two places in the kernel that can potentially fault with
1606  * usergs. Handle them here. The exception handlers after iret run with
1607  * kernel gs again, so don't set the user space flag. B stepping K8s
1608  * sometimes report an truncated RIP for IRET exceptions returning to
1609  * compat mode. Check for these here too.
1610  */
1611 error_kernelspace:
1612         incl %ebx
1613         leaq irq_return(%rip),%rcx
1614         cmpq %rcx,RIP+8(%rsp)
1615         je error_swapgs
1616         movl %ecx,%eax  /* zero extend */
1617         cmpq %rax,RIP+8(%rsp)
1618         je bstep_iret
1619         cmpq $gs_change,RIP+8(%rsp)
1620         je error_swapgs
1621         jmp error_sti
1622
1623 bstep_iret:
1624         /* Fix truncated RIP */
1625         movq %rcx,RIP+8(%rsp)
1626         jmp error_swapgs
1627         CFI_ENDPROC
1628 END(error_entry)
1629
1630
1631 /* ebx: no swapgs flag (1: don't need swapgs, 0: need it) */
1632 ENTRY(error_exit)
1633         DEFAULT_FRAME
1634         movl %ebx,%eax
1635         RESTORE_REST
1636         DISABLE_INTERRUPTS(CLBR_NONE)
1637         TRACE_IRQS_OFF
1638         GET_THREAD_INFO(%rcx)
1639         testl %eax,%eax
1640         jne retint_kernel
1641         LOCKDEP_SYS_EXIT_IRQ
1642         movl TI_flags(%rcx),%edx
1643         movl $_TIF_WORK_MASK,%edi
1644         andl %edi,%edx
1645         jnz retint_careful
1646         jmp retint_swapgs
1647         CFI_ENDPROC
1648 END(error_exit)
1649
1650 /*
1651  * Test if a given stack is an NMI stack or not.
1652  */
1653         .macro test_in_nmi reg stack nmi_ret normal_ret
1654         cmpq %\reg, \stack
1655         ja \normal_ret
1656         subq $EXCEPTION_STKSZ, %\reg
1657         cmpq %\reg, \stack
1658         jb \normal_ret
1659         jmp \nmi_ret
1660         .endm
1661
1662         /* runs on exception stack */
1663 ENTRY(nmi)
1664         INTR_FRAME
1665         PARAVIRT_ADJUST_EXCEPTION_FRAME
1666         /*
1667          * We allow breakpoints in NMIs. If a breakpoint occurs, then
1668          * the iretq it performs will take us out of NMI context.
1669          * This means that we can have nested NMIs where the next
1670          * NMI is using the top of the stack of the previous NMI. We
1671          * can't let it execute because the nested NMI will corrupt the
1672          * stack of the previous NMI. NMI handlers are not re-entrant
1673          * anyway.
1674          *
1675          * To handle this case we do the following:
1676          *  Check the a special location on the stack that contains
1677          *  a variable that is set when NMIs are executing.
1678          *  The interrupted task's stack is also checked to see if it
1679          *  is an NMI stack.
1680          *  If the variable is not set and the stack is not the NMI
1681          *  stack then:
1682          *    o Set the special variable on the stack
1683          *    o Copy the interrupt frame into a "saved" location on the stack
1684          *    o Copy the interrupt frame into a "copy" location on the stack
1685          *    o Continue processing the NMI
1686          *  If the variable is set or the previous stack is the NMI stack:
1687          *    o Modify the "copy" location to jump to the repeate_nmi
1688          *    o return back to the first NMI
1689          *
1690          * Now on exit of the first NMI, we first clear the stack variable
1691          * The NMI stack will tell any nested NMIs at that point that it is
1692          * nested. Then we pop the stack normally with iret, and if there was
1693          * a nested NMI that updated the copy interrupt stack frame, a
1694          * jump will be made to the repeat_nmi code that will handle the second
1695          * NMI.
1696          */
1697
1698         /* Use %rdx as out temp variable throughout */
1699         pushq_cfi %rdx
1700         CFI_REL_OFFSET rdx, 0
1701
1702         /*
1703          * If %cs was not the kernel segment, then the NMI triggered in user
1704          * space, which means it is definitely not nested.
1705          */
1706         cmpl $__KERNEL_CS, 16(%rsp)
1707         jne first_nmi
1708
1709         /*
1710          * Check the special variable on the stack to see if NMIs are
1711          * executing.
1712          */
1713         cmpl $1, -8(%rsp)
1714         je nested_nmi
1715
1716         /*
1717          * Now test if the previous stack was an NMI stack.
1718          * We need the double check. We check the NMI stack to satisfy the
1719          * race when the first NMI clears the variable before returning.
1720          * We check the variable because the first NMI could be in a
1721          * breakpoint routine using a breakpoint stack.
1722          */
1723         lea 6*8(%rsp), %rdx
1724         test_in_nmi rdx, 4*8(%rsp), nested_nmi, first_nmi
1725         CFI_REMEMBER_STATE
1726
1727 nested_nmi:
1728         /*
1729          * Do nothing if we interrupted the fixup in repeat_nmi.
1730          * It's about to repeat the NMI handler, so we are fine
1731          * with ignoring this one.
1732          */
1733         movq $repeat_nmi, %rdx
1734         cmpq 8(%rsp), %rdx
1735         ja 1f
1736         movq $end_repeat_nmi, %rdx
1737         cmpq 8(%rsp), %rdx
1738         ja nested_nmi_out
1739
1740 1:
1741         /* Set up the interrupted NMIs stack to jump to repeat_nmi */
1742         leaq -6*8(%rsp), %rdx
1743         movq %rdx, %rsp
1744         CFI_ADJUST_CFA_OFFSET 6*8
1745         pushq_cfi $__KERNEL_DS
1746         pushq_cfi %rdx
1747         pushfq_cfi
1748         pushq_cfi $__KERNEL_CS
1749         pushq_cfi $repeat_nmi
1750
1751         /* Put stack back */
1752         addq $(11*8), %rsp
1753         CFI_ADJUST_CFA_OFFSET -11*8
1754
1755 nested_nmi_out:
1756         popq_cfi %rdx
1757         CFI_RESTORE rdx
1758
1759         /* No need to check faults here */
1760         INTERRUPT_RETURN
1761
1762         CFI_RESTORE_STATE
1763 first_nmi:
1764         /*
1765          * Because nested NMIs will use the pushed location that we
1766          * stored in rdx, we must keep that space available.
1767          * Here's what our stack frame will look like:
1768          * +-------------------------+
1769          * | original SS             |
1770          * | original Return RSP     |
1771          * | original RFLAGS         |
1772          * | original CS             |
1773          * | original RIP            |
1774          * +-------------------------+
1775          * | temp storage for rdx    |
1776          * +-------------------------+
1777          * | NMI executing variable  |
1778          * +-------------------------+
1779          * | Saved SS                |
1780          * | Saved Return RSP        |
1781          * | Saved RFLAGS            |
1782          * | Saved CS                |
1783          * | Saved RIP               |
1784          * +-------------------------+
1785          * | copied SS               |
1786          * | copied Return RSP       |
1787          * | copied RFLAGS           |
1788          * | copied CS               |
1789          * | copied RIP              |
1790          * +-------------------------+
1791          * | pt_regs                 |
1792          * +-------------------------+
1793          *
1794          * The saved stack frame is used to fix up the copied stack frame
1795          * that a nested NMI may change to make the interrupted NMI iret jump
1796          * to the repeat_nmi. The original stack frame and the temp storage
1797          * is also used by nested NMIs and can not be trusted on exit.
1798          */
1799         /* Do not pop rdx, nested NMIs will corrupt that part of the stack */
1800         movq (%rsp), %rdx
1801         CFI_RESTORE rdx
1802
1803         /* Set the NMI executing variable on the stack. */
1804         pushq_cfi $1
1805
1806         /* Copy the stack frame to the Saved frame */
1807         .rept 5
1808         pushq_cfi 6*8(%rsp)
1809         .endr
1810         CFI_DEF_CFA_OFFSET SS+8-RIP
1811
1812         /* Everything up to here is safe from nested NMIs */
1813
1814         /*
1815          * If there was a nested NMI, the first NMI's iret will return
1816          * here. But NMIs are still enabled and we can take another
1817          * nested NMI. The nested NMI checks the interrupted RIP to see
1818          * if it is between repeat_nmi and end_repeat_nmi, and if so
1819          * it will just return, as we are about to repeat an NMI anyway.
1820          * This makes it safe to copy to the stack frame that a nested
1821          * NMI will update.
1822          */
1823 repeat_nmi:
1824         /*
1825          * Update the stack variable to say we are still in NMI (the update
1826          * is benign for the non-repeat case, where 1 was pushed just above
1827          * to this very stack slot).
1828          */
1829         movq $1, 5*8(%rsp)
1830
1831         /* Make another copy, this one may be modified by nested NMIs */
1832         .rept 5
1833         pushq_cfi 4*8(%rsp)
1834         .endr
1835         CFI_DEF_CFA_OFFSET SS+8-RIP
1836 end_repeat_nmi:
1837
1838         /*
1839          * Everything below this point can be preempted by a nested
1840          * NMI if the first NMI took an exception and reset our iret stack
1841          * so that we repeat another NMI.
1842          */
1843         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1844         subq $ORIG_RAX-R15, %rsp
1845         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1846         /*
1847          * Use save_paranoid to handle SWAPGS, but no need to use paranoid_exit
1848          * as we should not be calling schedule in NMI context.
1849          * Even with normal interrupts enabled. An NMI should not be
1850          * setting NEED_RESCHED or anything that normal interrupts and
1851          * exceptions might do.
1852          */
1853         call save_paranoid
1854         DEFAULT_FRAME 0
1855
1856         /*
1857          * Save off the CR2 register. If we take a page fault in the NMI then
1858          * it could corrupt the CR2 value. If the NMI preempts a page fault
1859          * handler before it was able to read the CR2 register, and then the
1860          * NMI itself takes a page fault, the page fault that was preempted
1861          * will read the information from the NMI page fault and not the
1862          * origin fault. Save it off and restore it if it changes.
1863          * Use the r12 callee-saved register.
1864          */
1865         movq %cr2, %r12
1866
1867         /* paranoidentry do_nmi, 0; without TRACE_IRQS_OFF */
1868         movq %rsp,%rdi
1869         movq $-1,%rsi
1870         call do_nmi
1871
1872         /* Did the NMI take a page fault? Restore cr2 if it did */
1873         movq %cr2, %rcx
1874         cmpq %rcx, %r12
1875         je 1f
1876         movq %r12, %cr2
1877 1:
1878         
1879         testl %ebx,%ebx                         /* swapgs needed? */
1880         jnz nmi_restore
1881 nmi_swapgs:
1882         SWAPGS_UNSAFE_STACK
1883 nmi_restore:
1884         RESTORE_ALL 8
1885         /* Clear the NMI executing stack variable */
1886         movq $0, 10*8(%rsp)
1887         jmp irq_return
1888         CFI_ENDPROC
1889 END(nmi)
1890
1891 ENTRY(ignore_sysret)
1892         CFI_STARTPROC
1893         mov $-ENOSYS,%eax
1894         sysret
1895         CFI_ENDPROC
1896 END(ignore_sysret)
1897
1898 /*
1899  * End of kprobes section
1900  */
1901         .popsection