Merge tag 'please-pull-ia64-for-3.7' of git://git.kernel.org/pub/scm/linux/kernel...
[linux-3.10.git] / arch / x86 / kernel / entry_64.S
1 /*
2  *  linux/arch/x86_64/entry.S
3  *
4  *  Copyright (C) 1991, 1992  Linus Torvalds
5  *  Copyright (C) 2000, 2001, 2002  Andi Kleen SuSE Labs
6  *  Copyright (C) 2000  Pavel Machek <pavel@suse.cz>
7  */
8
9 /*
10  * entry.S contains the system-call and fault low-level handling routines.
11  *
12  * Some of this is documented in Documentation/x86/entry_64.txt
13  *
14  * NOTE: This code handles signal-recognition, which happens every time
15  * after an interrupt and after each system call.
16  *
17  * Normal syscalls and interrupts don't save a full stack frame, this is
18  * only done for syscall tracing, signals or fork/exec et.al.
19  *
20  * A note on terminology:
21  * - top of stack: Architecture defined interrupt frame from SS to RIP
22  * at the top of the kernel process stack.
23  * - partial stack frame: partially saved registers up to R11.
24  * - full stack frame: Like partial stack frame, but all register saved.
25  *
26  * Some macro usage:
27  * - CFI macros are used to generate dwarf2 unwind information for better
28  * backtraces. They don't change any code.
29  * - SAVE_ALL/RESTORE_ALL - Save/restore all registers
30  * - SAVE_ARGS/RESTORE_ARGS - Save/restore registers that C functions modify.
31  * There are unfortunately lots of special cases where some registers
32  * not touched. The macro is a big mess that should be cleaned up.
33  * - SAVE_REST/RESTORE_REST - Handle the registers not saved by SAVE_ARGS.
34  * Gives a full stack frame.
35  * - ENTRY/END Define functions in the symbol table.
36  * - FIXUP_TOP_OF_STACK/RESTORE_TOP_OF_STACK - Fix up the hardware stack
37  * frame that is otherwise undefined after a SYSCALL
38  * - TRACE_IRQ_* - Trace hard interrupt state for lock debugging.
39  * - errorentry/paranoidentry/zeroentry - Define exception entry points.
40  */
41
42 #include <linux/linkage.h>
43 #include <asm/segment.h>
44 #include <asm/cache.h>
45 #include <asm/errno.h>
46 #include <asm/dwarf2.h>
47 #include <asm/calling.h>
48 #include <asm/asm-offsets.h>
49 #include <asm/msr.h>
50 #include <asm/unistd.h>
51 #include <asm/thread_info.h>
52 #include <asm/hw_irq.h>
53 #include <asm/page_types.h>
54 #include <asm/irqflags.h>
55 #include <asm/paravirt.h>
56 #include <asm/ftrace.h>
57 #include <asm/percpu.h>
58 #include <asm/asm.h>
59 #include <asm/rcu.h>
60 #include <linux/err.h>
61
62 /* Avoid __ASSEMBLER__'ifying <linux/audit.h> just for this.  */
63 #include <linux/elf-em.h>
64 #define AUDIT_ARCH_X86_64       (EM_X86_64|__AUDIT_ARCH_64BIT|__AUDIT_ARCH_LE)
65 #define __AUDIT_ARCH_64BIT 0x80000000
66 #define __AUDIT_ARCH_LE    0x40000000
67
68         .code64
69         .section .entry.text, "ax"
70
71 #ifdef CONFIG_FUNCTION_TRACER
72
73 #ifdef CC_USING_FENTRY
74 # define function_hook  __fentry__
75 #else
76 # define function_hook  mcount
77 #endif
78
79 #ifdef CONFIG_DYNAMIC_FTRACE
80
81 ENTRY(function_hook)
82         retq
83 END(function_hook)
84
85 /* skip is set if stack has been adjusted */
86 .macro ftrace_caller_setup skip=0
87         MCOUNT_SAVE_FRAME \skip
88
89         /* Load the ftrace_ops into the 3rd parameter */
90         leaq function_trace_op, %rdx
91
92         /* Load ip into the first parameter */
93         movq RIP(%rsp), %rdi
94         subq $MCOUNT_INSN_SIZE, %rdi
95         /* Load the parent_ip into the second parameter */
96 #ifdef CC_USING_FENTRY
97         movq SS+16(%rsp), %rsi
98 #else
99         movq 8(%rbp), %rsi
100 #endif
101 .endm
102
103 ENTRY(ftrace_caller)
104         /* Check if tracing was disabled (quick check) */
105         cmpl $0, function_trace_stop
106         jne  ftrace_stub
107
108         ftrace_caller_setup
109         /* regs go into 4th parameter (but make it NULL) */
110         movq $0, %rcx
111
112 GLOBAL(ftrace_call)
113         call ftrace_stub
114
115         MCOUNT_RESTORE_FRAME
116 ftrace_return:
117
118 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
119 GLOBAL(ftrace_graph_call)
120         jmp ftrace_stub
121 #endif
122
123 GLOBAL(ftrace_stub)
124         retq
125 END(ftrace_caller)
126
127 ENTRY(ftrace_regs_caller)
128         /* Save the current flags before compare (in SS location)*/
129         pushfq
130
131         /* Check if tracing was disabled (quick check) */
132         cmpl $0, function_trace_stop
133         jne  ftrace_restore_flags
134
135         /* skip=8 to skip flags saved in SS */
136         ftrace_caller_setup 8
137
138         /* Save the rest of pt_regs */
139         movq %r15, R15(%rsp)
140         movq %r14, R14(%rsp)
141         movq %r13, R13(%rsp)
142         movq %r12, R12(%rsp)
143         movq %r11, R11(%rsp)
144         movq %r10, R10(%rsp)
145         movq %rbp, RBP(%rsp)
146         movq %rbx, RBX(%rsp)
147         /* Copy saved flags */
148         movq SS(%rsp), %rcx
149         movq %rcx, EFLAGS(%rsp)
150         /* Kernel segments */
151         movq $__KERNEL_DS, %rcx
152         movq %rcx, SS(%rsp)
153         movq $__KERNEL_CS, %rcx
154         movq %rcx, CS(%rsp)
155         /* Stack - skipping return address */
156         leaq SS+16(%rsp), %rcx
157         movq %rcx, RSP(%rsp)
158
159         /* regs go into 4th parameter */
160         leaq (%rsp), %rcx
161
162 GLOBAL(ftrace_regs_call)
163         call ftrace_stub
164
165         /* Copy flags back to SS, to restore them */
166         movq EFLAGS(%rsp), %rax
167         movq %rax, SS(%rsp)
168
169         /* Handlers can change the RIP */
170         movq RIP(%rsp), %rax
171         movq %rax, SS+8(%rsp)
172
173         /* restore the rest of pt_regs */
174         movq R15(%rsp), %r15
175         movq R14(%rsp), %r14
176         movq R13(%rsp), %r13
177         movq R12(%rsp), %r12
178         movq R10(%rsp), %r10
179         movq RBP(%rsp), %rbp
180         movq RBX(%rsp), %rbx
181
182         /* skip=8 to skip flags saved in SS */
183         MCOUNT_RESTORE_FRAME 8
184
185         /* Restore flags */
186         popfq
187
188         jmp ftrace_return
189 ftrace_restore_flags:
190         popfq
191         jmp  ftrace_stub
192
193 END(ftrace_regs_caller)
194
195
196 #else /* ! CONFIG_DYNAMIC_FTRACE */
197
198 ENTRY(function_hook)
199         cmpl $0, function_trace_stop
200         jne  ftrace_stub
201
202         cmpq $ftrace_stub, ftrace_trace_function
203         jnz trace
204
205 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
206         cmpq $ftrace_stub, ftrace_graph_return
207         jnz ftrace_graph_caller
208
209         cmpq $ftrace_graph_entry_stub, ftrace_graph_entry
210         jnz ftrace_graph_caller
211 #endif
212
213 GLOBAL(ftrace_stub)
214         retq
215
216 trace:
217         MCOUNT_SAVE_FRAME
218
219         movq RIP(%rsp), %rdi
220 #ifdef CC_USING_FENTRY
221         movq SS+16(%rsp), %rsi
222 #else
223         movq 8(%rbp), %rsi
224 #endif
225         subq $MCOUNT_INSN_SIZE, %rdi
226
227         call   *ftrace_trace_function
228
229         MCOUNT_RESTORE_FRAME
230
231         jmp ftrace_stub
232 END(function_hook)
233 #endif /* CONFIG_DYNAMIC_FTRACE */
234 #endif /* CONFIG_FUNCTION_TRACER */
235
236 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
237 ENTRY(ftrace_graph_caller)
238         MCOUNT_SAVE_FRAME
239
240 #ifdef CC_USING_FENTRY
241         leaq SS+16(%rsp), %rdi
242         movq $0, %rdx   /* No framepointers needed */
243 #else
244         leaq 8(%rbp), %rdi
245         movq (%rbp), %rdx
246 #endif
247         movq RIP(%rsp), %rsi
248         subq $MCOUNT_INSN_SIZE, %rsi
249
250         call    prepare_ftrace_return
251
252         MCOUNT_RESTORE_FRAME
253
254         retq
255 END(ftrace_graph_caller)
256
257 GLOBAL(return_to_handler)
258         subq  $24, %rsp
259
260         /* Save the return values */
261         movq %rax, (%rsp)
262         movq %rdx, 8(%rsp)
263         movq %rbp, %rdi
264
265         call ftrace_return_to_handler
266
267         movq %rax, %rdi
268         movq 8(%rsp), %rdx
269         movq (%rsp), %rax
270         addq $24, %rsp
271         jmp *%rdi
272 #endif
273
274
275 #ifndef CONFIG_PREEMPT
276 #define retint_kernel retint_restore_args
277 #endif
278
279 #ifdef CONFIG_PARAVIRT
280 ENTRY(native_usergs_sysret64)
281         swapgs
282         sysretq
283 ENDPROC(native_usergs_sysret64)
284 #endif /* CONFIG_PARAVIRT */
285
286
287 .macro TRACE_IRQS_IRETQ offset=ARGOFFSET
288 #ifdef CONFIG_TRACE_IRQFLAGS
289         bt   $9,EFLAGS-\offset(%rsp)    /* interrupts off? */
290         jnc  1f
291         TRACE_IRQS_ON
292 1:
293 #endif
294 .endm
295
296 /*
297  * When dynamic function tracer is enabled it will add a breakpoint
298  * to all locations that it is about to modify, sync CPUs, update
299  * all the code, sync CPUs, then remove the breakpoints. In this time
300  * if lockdep is enabled, it might jump back into the debug handler
301  * outside the updating of the IST protection. (TRACE_IRQS_ON/OFF).
302  *
303  * We need to change the IDT table before calling TRACE_IRQS_ON/OFF to
304  * make sure the stack pointer does not get reset back to the top
305  * of the debug stack, and instead just reuses the current stack.
306  */
307 #if defined(CONFIG_DYNAMIC_FTRACE) && defined(CONFIG_TRACE_IRQFLAGS)
308
309 .macro TRACE_IRQS_OFF_DEBUG
310         call debug_stack_set_zero
311         TRACE_IRQS_OFF
312         call debug_stack_reset
313 .endm
314
315 .macro TRACE_IRQS_ON_DEBUG
316         call debug_stack_set_zero
317         TRACE_IRQS_ON
318         call debug_stack_reset
319 .endm
320
321 .macro TRACE_IRQS_IRETQ_DEBUG offset=ARGOFFSET
322         bt   $9,EFLAGS-\offset(%rsp)    /* interrupts off? */
323         jnc  1f
324         TRACE_IRQS_ON_DEBUG
325 1:
326 .endm
327
328 #else
329 # define TRACE_IRQS_OFF_DEBUG           TRACE_IRQS_OFF
330 # define TRACE_IRQS_ON_DEBUG            TRACE_IRQS_ON
331 # define TRACE_IRQS_IRETQ_DEBUG         TRACE_IRQS_IRETQ
332 #endif
333
334 /*
335  * C code is not supposed to know about undefined top of stack. Every time
336  * a C function with an pt_regs argument is called from the SYSCALL based
337  * fast path FIXUP_TOP_OF_STACK is needed.
338  * RESTORE_TOP_OF_STACK syncs the syscall state after any possible ptregs
339  * manipulation.
340  */
341
342         /* %rsp:at FRAMEEND */
343         .macro FIXUP_TOP_OF_STACK tmp offset=0
344         movq PER_CPU_VAR(old_rsp),\tmp
345         movq \tmp,RSP+\offset(%rsp)
346         movq $__USER_DS,SS+\offset(%rsp)
347         movq $__USER_CS,CS+\offset(%rsp)
348         movq $-1,RCX+\offset(%rsp)
349         movq R11+\offset(%rsp),\tmp  /* get eflags */
350         movq \tmp,EFLAGS+\offset(%rsp)
351         .endm
352
353         .macro RESTORE_TOP_OF_STACK tmp offset=0
354         movq RSP+\offset(%rsp),\tmp
355         movq \tmp,PER_CPU_VAR(old_rsp)
356         movq EFLAGS+\offset(%rsp),\tmp
357         movq \tmp,R11+\offset(%rsp)
358         .endm
359
360         .macro FAKE_STACK_FRAME child_rip
361         /* push in order ss, rsp, eflags, cs, rip */
362         xorl %eax, %eax
363         pushq_cfi $__KERNEL_DS /* ss */
364         /*CFI_REL_OFFSET        ss,0*/
365         pushq_cfi %rax /* rsp */
366         CFI_REL_OFFSET  rsp,0
367         pushq_cfi $(X86_EFLAGS_IF|X86_EFLAGS_BIT1) /* eflags - interrupts on */
368         /*CFI_REL_OFFSET        rflags,0*/
369         pushq_cfi $__KERNEL_CS /* cs */
370         /*CFI_REL_OFFSET        cs,0*/
371         pushq_cfi \child_rip /* rip */
372         CFI_REL_OFFSET  rip,0
373         pushq_cfi %rax /* orig rax */
374         .endm
375
376         .macro UNFAKE_STACK_FRAME
377         addq $8*6, %rsp
378         CFI_ADJUST_CFA_OFFSET   -(6*8)
379         .endm
380
381 /*
382  * initial frame state for interrupts (and exceptions without error code)
383  */
384         .macro EMPTY_FRAME start=1 offset=0
385         .if \start
386         CFI_STARTPROC simple
387         CFI_SIGNAL_FRAME
388         CFI_DEF_CFA rsp,8+\offset
389         .else
390         CFI_DEF_CFA_OFFSET 8+\offset
391         .endif
392         .endm
393
394 /*
395  * initial frame state for interrupts (and exceptions without error code)
396  */
397         .macro INTR_FRAME start=1 offset=0
398         EMPTY_FRAME \start, SS+8+\offset-RIP
399         /*CFI_REL_OFFSET ss, SS+\offset-RIP*/
400         CFI_REL_OFFSET rsp, RSP+\offset-RIP
401         /*CFI_REL_OFFSET rflags, EFLAGS+\offset-RIP*/
402         /*CFI_REL_OFFSET cs, CS+\offset-RIP*/
403         CFI_REL_OFFSET rip, RIP+\offset-RIP
404         .endm
405
406 /*
407  * initial frame state for exceptions with error code (and interrupts
408  * with vector already pushed)
409  */
410         .macro XCPT_FRAME start=1 offset=0
411         INTR_FRAME \start, RIP+\offset-ORIG_RAX
412         /*CFI_REL_OFFSET orig_rax, ORIG_RAX-ORIG_RAX*/
413         .endm
414
415 /*
416  * frame that enables calling into C.
417  */
418         .macro PARTIAL_FRAME start=1 offset=0
419         XCPT_FRAME \start, ORIG_RAX+\offset-ARGOFFSET
420         CFI_REL_OFFSET rdi, RDI+\offset-ARGOFFSET
421         CFI_REL_OFFSET rsi, RSI+\offset-ARGOFFSET
422         CFI_REL_OFFSET rdx, RDX+\offset-ARGOFFSET
423         CFI_REL_OFFSET rcx, RCX+\offset-ARGOFFSET
424         CFI_REL_OFFSET rax, RAX+\offset-ARGOFFSET
425         CFI_REL_OFFSET r8, R8+\offset-ARGOFFSET
426         CFI_REL_OFFSET r9, R9+\offset-ARGOFFSET
427         CFI_REL_OFFSET r10, R10+\offset-ARGOFFSET
428         CFI_REL_OFFSET r11, R11+\offset-ARGOFFSET
429         .endm
430
431 /*
432  * frame that enables passing a complete pt_regs to a C function.
433  */
434         .macro DEFAULT_FRAME start=1 offset=0
435         PARTIAL_FRAME \start, R11+\offset-R15
436         CFI_REL_OFFSET rbx, RBX+\offset
437         CFI_REL_OFFSET rbp, RBP+\offset
438         CFI_REL_OFFSET r12, R12+\offset
439         CFI_REL_OFFSET r13, R13+\offset
440         CFI_REL_OFFSET r14, R14+\offset
441         CFI_REL_OFFSET r15, R15+\offset
442         .endm
443
444 /* save partial stack frame */
445         .macro SAVE_ARGS_IRQ
446         cld
447         /* start from rbp in pt_regs and jump over */
448         movq_cfi rdi, (RDI-RBP)
449         movq_cfi rsi, (RSI-RBP)
450         movq_cfi rdx, (RDX-RBP)
451         movq_cfi rcx, (RCX-RBP)
452         movq_cfi rax, (RAX-RBP)
453         movq_cfi  r8,  (R8-RBP)
454         movq_cfi  r9,  (R9-RBP)
455         movq_cfi r10, (R10-RBP)
456         movq_cfi r11, (R11-RBP)
457
458         /* Save rbp so that we can unwind from get_irq_regs() */
459         movq_cfi rbp, 0
460
461         /* Save previous stack value */
462         movq %rsp, %rsi
463
464         leaq -RBP(%rsp),%rdi    /* arg1 for handler */
465         testl $3, CS-RBP(%rsi)
466         je 1f
467         SWAPGS
468         /*
469          * irq_count is used to check if a CPU is already on an interrupt stack
470          * or not. While this is essentially redundant with preempt_count it is
471          * a little cheaper to use a separate counter in the PDA (short of
472          * moving irq_enter into assembly, which would be too much work)
473          */
474 1:      incl PER_CPU_VAR(irq_count)
475         cmovzq PER_CPU_VAR(irq_stack_ptr),%rsp
476         CFI_DEF_CFA_REGISTER    rsi
477
478         /* Store previous stack value */
479         pushq %rsi
480         CFI_ESCAPE      0x0f /* DW_CFA_def_cfa_expression */, 6, \
481                         0x77 /* DW_OP_breg7 */, 0, \
482                         0x06 /* DW_OP_deref */, \
483                         0x08 /* DW_OP_const1u */, SS+8-RBP, \
484                         0x22 /* DW_OP_plus */
485         /* We entered an interrupt context - irqs are off: */
486         TRACE_IRQS_OFF
487         .endm
488
489 ENTRY(save_rest)
490         PARTIAL_FRAME 1 (REST_SKIP+8)
491         movq 5*8+16(%rsp), %r11 /* save return address */
492         movq_cfi rbx, RBX+16
493         movq_cfi rbp, RBP+16
494         movq_cfi r12, R12+16
495         movq_cfi r13, R13+16
496         movq_cfi r14, R14+16
497         movq_cfi r15, R15+16
498         movq %r11, 8(%rsp)      /* return address */
499         FIXUP_TOP_OF_STACK %r11, 16
500         ret
501         CFI_ENDPROC
502 END(save_rest)
503
504 /* save complete stack frame */
505         .pushsection .kprobes.text, "ax"
506 ENTRY(save_paranoid)
507         XCPT_FRAME 1 RDI+8
508         cld
509         movq_cfi rdi, RDI+8
510         movq_cfi rsi, RSI+8
511         movq_cfi rdx, RDX+8
512         movq_cfi rcx, RCX+8
513         movq_cfi rax, RAX+8
514         movq_cfi r8, R8+8
515         movq_cfi r9, R9+8
516         movq_cfi r10, R10+8
517         movq_cfi r11, R11+8
518         movq_cfi rbx, RBX+8
519         movq_cfi rbp, RBP+8
520         movq_cfi r12, R12+8
521         movq_cfi r13, R13+8
522         movq_cfi r14, R14+8
523         movq_cfi r15, R15+8
524         movl $1,%ebx
525         movl $MSR_GS_BASE,%ecx
526         rdmsr
527         testl %edx,%edx
528         js 1f   /* negative -> in kernel */
529         SWAPGS
530         xorl %ebx,%ebx
531 1:      ret
532         CFI_ENDPROC
533 END(save_paranoid)
534         .popsection
535
536 /*
537  * A newly forked process directly context switches into this address.
538  *
539  * rdi: prev task we switched from
540  */
541 ENTRY(ret_from_fork)
542         DEFAULT_FRAME
543
544         LOCK ; btr $TIF_FORK,TI_flags(%r8)
545
546         pushq_cfi $0x0002
547         popfq_cfi                               # reset kernel eflags
548
549         call schedule_tail                      # rdi: 'prev' task parameter
550
551         GET_THREAD_INFO(%rcx)
552
553         RESTORE_REST
554
555         testl $3, CS-ARGOFFSET(%rsp)            # from kernel_thread?
556         jz   retint_restore_args
557
558         testl $_TIF_IA32, TI_flags(%rcx)        # 32-bit compat task needs IRET
559         jnz  int_ret_from_sys_call
560
561         RESTORE_TOP_OF_STACK %rdi, -ARGOFFSET
562         jmp ret_from_sys_call                   # go to the SYSRET fastpath
563
564         CFI_ENDPROC
565 END(ret_from_fork)
566
567 /*
568  * System call entry. Up to 6 arguments in registers are supported.
569  *
570  * SYSCALL does not save anything on the stack and does not change the
571  * stack pointer.
572  */
573
574 /*
575  * Register setup:
576  * rax  system call number
577  * rdi  arg0
578  * rcx  return address for syscall/sysret, C arg3
579  * rsi  arg1
580  * rdx  arg2
581  * r10  arg3    (--> moved to rcx for C)
582  * r8   arg4
583  * r9   arg5
584  * r11  eflags for syscall/sysret, temporary for C
585  * r12-r15,rbp,rbx saved by C code, not touched.
586  *
587  * Interrupts are off on entry.
588  * Only called from user space.
589  *
590  * XXX  if we had a free scratch register we could save the RSP into the stack frame
591  *      and report it properly in ps. Unfortunately we haven't.
592  *
593  * When user can change the frames always force IRET. That is because
594  * it deals with uncanonical addresses better. SYSRET has trouble
595  * with them due to bugs in both AMD and Intel CPUs.
596  */
597
598 ENTRY(system_call)
599         CFI_STARTPROC   simple
600         CFI_SIGNAL_FRAME
601         CFI_DEF_CFA     rsp,KERNEL_STACK_OFFSET
602         CFI_REGISTER    rip,rcx
603         /*CFI_REGISTER  rflags,r11*/
604         SWAPGS_UNSAFE_STACK
605         /*
606          * A hypervisor implementation might want to use a label
607          * after the swapgs, so that it can do the swapgs
608          * for the guest and jump here on syscall.
609          */
610 GLOBAL(system_call_after_swapgs)
611
612         movq    %rsp,PER_CPU_VAR(old_rsp)
613         movq    PER_CPU_VAR(kernel_stack),%rsp
614         /*
615          * No need to follow this irqs off/on section - it's straight
616          * and short:
617          */
618         ENABLE_INTERRUPTS(CLBR_NONE)
619         SAVE_ARGS 8,0
620         movq  %rax,ORIG_RAX-ARGOFFSET(%rsp)
621         movq  %rcx,RIP-ARGOFFSET(%rsp)
622         CFI_REL_OFFSET rip,RIP-ARGOFFSET
623         testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags+THREAD_INFO(%rsp,RIP-ARGOFFSET)
624         jnz tracesys
625 system_call_fastpath:
626 #if __SYSCALL_MASK == ~0
627         cmpq $__NR_syscall_max,%rax
628 #else
629         andl $__SYSCALL_MASK,%eax
630         cmpl $__NR_syscall_max,%eax
631 #endif
632         ja badsys
633         movq %r10,%rcx
634         call *sys_call_table(,%rax,8)  # XXX:    rip relative
635         movq %rax,RAX-ARGOFFSET(%rsp)
636 /*
637  * Syscall return path ending with SYSRET (fast path)
638  * Has incomplete stack frame and undefined top of stack.
639  */
640 ret_from_sys_call:
641         movl $_TIF_ALLWORK_MASK,%edi
642         /* edi: flagmask */
643 sysret_check:
644         LOCKDEP_SYS_EXIT
645         DISABLE_INTERRUPTS(CLBR_NONE)
646         TRACE_IRQS_OFF
647         movl TI_flags+THREAD_INFO(%rsp,RIP-ARGOFFSET),%edx
648         andl %edi,%edx
649         jnz  sysret_careful
650         CFI_REMEMBER_STATE
651         /*
652          * sysretq will re-enable interrupts:
653          */
654         TRACE_IRQS_ON
655         movq RIP-ARGOFFSET(%rsp),%rcx
656         CFI_REGISTER    rip,rcx
657         RESTORE_ARGS 1,-ARG_SKIP,0
658         /*CFI_REGISTER  rflags,r11*/
659         movq    PER_CPU_VAR(old_rsp), %rsp
660         USERGS_SYSRET64
661
662         CFI_RESTORE_STATE
663         /* Handle reschedules */
664         /* edx: work, edi: workmask */
665 sysret_careful:
666         bt $TIF_NEED_RESCHED,%edx
667         jnc sysret_signal
668         TRACE_IRQS_ON
669         ENABLE_INTERRUPTS(CLBR_NONE)
670         pushq_cfi %rdi
671         SCHEDULE_USER
672         popq_cfi %rdi
673         jmp sysret_check
674
675         /* Handle a signal */
676 sysret_signal:
677         TRACE_IRQS_ON
678         ENABLE_INTERRUPTS(CLBR_NONE)
679 #ifdef CONFIG_AUDITSYSCALL
680         bt $TIF_SYSCALL_AUDIT,%edx
681         jc sysret_audit
682 #endif
683         /*
684          * We have a signal, or exit tracing or single-step.
685          * These all wind up with the iret return path anyway,
686          * so just join that path right now.
687          */
688         FIXUP_TOP_OF_STACK %r11, -ARGOFFSET
689         jmp int_check_syscall_exit_work
690
691 badsys:
692         movq $-ENOSYS,RAX-ARGOFFSET(%rsp)
693         jmp ret_from_sys_call
694
695 #ifdef CONFIG_AUDITSYSCALL
696         /*
697          * Fast path for syscall audit without full syscall trace.
698          * We just call __audit_syscall_entry() directly, and then
699          * jump back to the normal fast path.
700          */
701 auditsys:
702         movq %r10,%r9                   /* 6th arg: 4th syscall arg */
703         movq %rdx,%r8                   /* 5th arg: 3rd syscall arg */
704         movq %rsi,%rcx                  /* 4th arg: 2nd syscall arg */
705         movq %rdi,%rdx                  /* 3rd arg: 1st syscall arg */
706         movq %rax,%rsi                  /* 2nd arg: syscall number */
707         movl $AUDIT_ARCH_X86_64,%edi    /* 1st arg: audit arch */
708         call __audit_syscall_entry
709         LOAD_ARGS 0             /* reload call-clobbered registers */
710         jmp system_call_fastpath
711
712         /*
713          * Return fast path for syscall audit.  Call __audit_syscall_exit()
714          * directly and then jump back to the fast path with TIF_SYSCALL_AUDIT
715          * masked off.
716          */
717 sysret_audit:
718         movq RAX-ARGOFFSET(%rsp),%rsi   /* second arg, syscall return value */
719         cmpq $-MAX_ERRNO,%rsi   /* is it < -MAX_ERRNO? */
720         setbe %al               /* 1 if so, 0 if not */
721         movzbl %al,%edi         /* zero-extend that into %edi */
722         call __audit_syscall_exit
723         movl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT),%edi
724         jmp sysret_check
725 #endif  /* CONFIG_AUDITSYSCALL */
726
727         /* Do syscall tracing */
728 tracesys:
729 #ifdef CONFIG_AUDITSYSCALL
730         testl $(_TIF_WORK_SYSCALL_ENTRY & ~_TIF_SYSCALL_AUDIT),TI_flags+THREAD_INFO(%rsp,RIP-ARGOFFSET)
731         jz auditsys
732 #endif
733         SAVE_REST
734         movq $-ENOSYS,RAX(%rsp) /* ptrace can change this for a bad syscall */
735         FIXUP_TOP_OF_STACK %rdi
736         movq %rsp,%rdi
737         call syscall_trace_enter
738         /*
739          * Reload arg registers from stack in case ptrace changed them.
740          * We don't reload %rax because syscall_trace_enter() returned
741          * the value it wants us to use in the table lookup.
742          */
743         LOAD_ARGS ARGOFFSET, 1
744         RESTORE_REST
745 #if __SYSCALL_MASK == ~0
746         cmpq $__NR_syscall_max,%rax
747 #else
748         andl $__SYSCALL_MASK,%eax
749         cmpl $__NR_syscall_max,%eax
750 #endif
751         ja   int_ret_from_sys_call      /* RAX(%rsp) set to -ENOSYS above */
752         movq %r10,%rcx  /* fixup for C */
753         call *sys_call_table(,%rax,8)
754         movq %rax,RAX-ARGOFFSET(%rsp)
755         /* Use IRET because user could have changed frame */
756
757 /*
758  * Syscall return path ending with IRET.
759  * Has correct top of stack, but partial stack frame.
760  */
761 GLOBAL(int_ret_from_sys_call)
762         DISABLE_INTERRUPTS(CLBR_NONE)
763         TRACE_IRQS_OFF
764         movl $_TIF_ALLWORK_MASK,%edi
765         /* edi: mask to check */
766 GLOBAL(int_with_check)
767         LOCKDEP_SYS_EXIT_IRQ
768         GET_THREAD_INFO(%rcx)
769         movl TI_flags(%rcx),%edx
770         andl %edi,%edx
771         jnz   int_careful
772         andl    $~TS_COMPAT,TI_status(%rcx)
773         jmp   retint_swapgs
774
775         /* Either reschedule or signal or syscall exit tracking needed. */
776         /* First do a reschedule test. */
777         /* edx: work, edi: workmask */
778 int_careful:
779         bt $TIF_NEED_RESCHED,%edx
780         jnc  int_very_careful
781         TRACE_IRQS_ON
782         ENABLE_INTERRUPTS(CLBR_NONE)
783         pushq_cfi %rdi
784         SCHEDULE_USER
785         popq_cfi %rdi
786         DISABLE_INTERRUPTS(CLBR_NONE)
787         TRACE_IRQS_OFF
788         jmp int_with_check
789
790         /* handle signals and tracing -- both require a full stack frame */
791 int_very_careful:
792         TRACE_IRQS_ON
793         ENABLE_INTERRUPTS(CLBR_NONE)
794 int_check_syscall_exit_work:
795         SAVE_REST
796         /* Check for syscall exit trace */
797         testl $_TIF_WORK_SYSCALL_EXIT,%edx
798         jz int_signal
799         pushq_cfi %rdi
800         leaq 8(%rsp),%rdi       # &ptregs -> arg1
801         call syscall_trace_leave
802         popq_cfi %rdi
803         andl $~(_TIF_WORK_SYSCALL_EXIT|_TIF_SYSCALL_EMU),%edi
804         jmp int_restore_rest
805
806 int_signal:
807         testl $_TIF_DO_NOTIFY_MASK,%edx
808         jz 1f
809         movq %rsp,%rdi          # &ptregs -> arg1
810         xorl %esi,%esi          # oldset -> arg2
811         call do_notify_resume
812 1:      movl $_TIF_WORK_MASK,%edi
813 int_restore_rest:
814         RESTORE_REST
815         DISABLE_INTERRUPTS(CLBR_NONE)
816         TRACE_IRQS_OFF
817         jmp int_with_check
818         CFI_ENDPROC
819 END(system_call)
820
821 /*
822  * Certain special system calls that need to save a complete full stack frame.
823  */
824         .macro PTREGSCALL label,func,arg
825 ENTRY(\label)
826         PARTIAL_FRAME 1 8               /* offset 8: return address */
827         subq $REST_SKIP, %rsp
828         CFI_ADJUST_CFA_OFFSET REST_SKIP
829         call save_rest
830         DEFAULT_FRAME 0 8               /* offset 8: return address */
831         leaq 8(%rsp), \arg      /* pt_regs pointer */
832         call \func
833         jmp ptregscall_common
834         CFI_ENDPROC
835 END(\label)
836         .endm
837
838         PTREGSCALL stub_clone, sys_clone, %r8
839         PTREGSCALL stub_fork, sys_fork, %rdi
840         PTREGSCALL stub_vfork, sys_vfork, %rdi
841         PTREGSCALL stub_sigaltstack, sys_sigaltstack, %rdx
842         PTREGSCALL stub_iopl, sys_iopl, %rsi
843
844 ENTRY(ptregscall_common)
845         DEFAULT_FRAME 1 8       /* offset 8: return address */
846         RESTORE_TOP_OF_STACK %r11, 8
847         movq_cfi_restore R15+8, r15
848         movq_cfi_restore R14+8, r14
849         movq_cfi_restore R13+8, r13
850         movq_cfi_restore R12+8, r12
851         movq_cfi_restore RBP+8, rbp
852         movq_cfi_restore RBX+8, rbx
853         ret $REST_SKIP          /* pop extended registers */
854         CFI_ENDPROC
855 END(ptregscall_common)
856
857 ENTRY(stub_execve)
858         CFI_STARTPROC
859         addq $8, %rsp
860         PARTIAL_FRAME 0
861         SAVE_REST
862         FIXUP_TOP_OF_STACK %r11
863         movq %rsp, %rcx
864         call sys_execve
865         RESTORE_TOP_OF_STACK %r11
866         movq %rax,RAX(%rsp)
867         RESTORE_REST
868         jmp int_ret_from_sys_call
869         CFI_ENDPROC
870 END(stub_execve)
871
872 /*
873  * sigreturn is special because it needs to restore all registers on return.
874  * This cannot be done with SYSRET, so use the IRET return path instead.
875  */
876 ENTRY(stub_rt_sigreturn)
877         CFI_STARTPROC
878         addq $8, %rsp
879         PARTIAL_FRAME 0
880         SAVE_REST
881         movq %rsp,%rdi
882         FIXUP_TOP_OF_STACK %r11
883         call sys_rt_sigreturn
884         movq %rax,RAX(%rsp) # fixme, this could be done at the higher layer
885         RESTORE_REST
886         jmp int_ret_from_sys_call
887         CFI_ENDPROC
888 END(stub_rt_sigreturn)
889
890 #ifdef CONFIG_X86_X32_ABI
891         PTREGSCALL stub_x32_sigaltstack, sys32_sigaltstack, %rdx
892
893 ENTRY(stub_x32_rt_sigreturn)
894         CFI_STARTPROC
895         addq $8, %rsp
896         PARTIAL_FRAME 0
897         SAVE_REST
898         movq %rsp,%rdi
899         FIXUP_TOP_OF_STACK %r11
900         call sys32_x32_rt_sigreturn
901         movq %rax,RAX(%rsp) # fixme, this could be done at the higher layer
902         RESTORE_REST
903         jmp int_ret_from_sys_call
904         CFI_ENDPROC
905 END(stub_x32_rt_sigreturn)
906
907 ENTRY(stub_x32_execve)
908         CFI_STARTPROC
909         addq $8, %rsp
910         PARTIAL_FRAME 0
911         SAVE_REST
912         FIXUP_TOP_OF_STACK %r11
913         movq %rsp, %rcx
914         call sys32_execve
915         RESTORE_TOP_OF_STACK %r11
916         movq %rax,RAX(%rsp)
917         RESTORE_REST
918         jmp int_ret_from_sys_call
919         CFI_ENDPROC
920 END(stub_x32_execve)
921
922 #endif
923
924 /*
925  * Build the entry stubs and pointer table with some assembler magic.
926  * We pack 7 stubs into a single 32-byte chunk, which will fit in a
927  * single cache line on all modern x86 implementations.
928  */
929         .section .init.rodata,"a"
930 ENTRY(interrupt)
931         .section .entry.text
932         .p2align 5
933         .p2align CONFIG_X86_L1_CACHE_SHIFT
934 ENTRY(irq_entries_start)
935         INTR_FRAME
936 vector=FIRST_EXTERNAL_VECTOR
937 .rept (NR_VECTORS-FIRST_EXTERNAL_VECTOR+6)/7
938         .balign 32
939   .rept 7
940     .if vector < NR_VECTORS
941       .if vector <> FIRST_EXTERNAL_VECTOR
942         CFI_ADJUST_CFA_OFFSET -8
943       .endif
944 1:      pushq_cfi $(~vector+0x80)       /* Note: always in signed byte range */
945       .if ((vector-FIRST_EXTERNAL_VECTOR)%7) <> 6
946         jmp 2f
947       .endif
948       .previous
949         .quad 1b
950       .section .entry.text
951 vector=vector+1
952     .endif
953   .endr
954 2:      jmp common_interrupt
955 .endr
956         CFI_ENDPROC
957 END(irq_entries_start)
958
959 .previous
960 END(interrupt)
961 .previous
962
963 /*
964  * Interrupt entry/exit.
965  *
966  * Interrupt entry points save only callee clobbered registers in fast path.
967  *
968  * Entry runs with interrupts off.
969  */
970
971 /* 0(%rsp): ~(interrupt number) */
972         .macro interrupt func
973         /* reserve pt_regs for scratch regs and rbp */
974         subq $ORIG_RAX-RBP, %rsp
975         CFI_ADJUST_CFA_OFFSET ORIG_RAX-RBP
976         SAVE_ARGS_IRQ
977         call \func
978         .endm
979
980 /*
981  * Interrupt entry/exit should be protected against kprobes
982  */
983         .pushsection .kprobes.text, "ax"
984         /*
985          * The interrupt stubs push (~vector+0x80) onto the stack and
986          * then jump to common_interrupt.
987          */
988         .p2align CONFIG_X86_L1_CACHE_SHIFT
989 common_interrupt:
990         XCPT_FRAME
991         addq $-0x80,(%rsp)              /* Adjust vector to [-256,-1] range */
992         interrupt do_IRQ
993         /* 0(%rsp): old_rsp-ARGOFFSET */
994 ret_from_intr:
995         DISABLE_INTERRUPTS(CLBR_NONE)
996         TRACE_IRQS_OFF
997         decl PER_CPU_VAR(irq_count)
998
999         /* Restore saved previous stack */
1000         popq %rsi
1001         CFI_DEF_CFA rsi,SS+8-RBP        /* reg/off reset after def_cfa_expr */
1002         leaq ARGOFFSET-RBP(%rsi), %rsp
1003         CFI_DEF_CFA_REGISTER    rsp
1004         CFI_ADJUST_CFA_OFFSET   RBP-ARGOFFSET
1005
1006 exit_intr:
1007         GET_THREAD_INFO(%rcx)
1008         testl $3,CS-ARGOFFSET(%rsp)
1009         je retint_kernel
1010
1011         /* Interrupt came from user space */
1012         /*
1013          * Has a correct top of stack, but a partial stack frame
1014          * %rcx: thread info. Interrupts off.
1015          */
1016 retint_with_reschedule:
1017         movl $_TIF_WORK_MASK,%edi
1018 retint_check:
1019         LOCKDEP_SYS_EXIT_IRQ
1020         movl TI_flags(%rcx),%edx
1021         andl %edi,%edx
1022         CFI_REMEMBER_STATE
1023         jnz  retint_careful
1024
1025 retint_swapgs:          /* return to user-space */
1026         /*
1027          * The iretq could re-enable interrupts:
1028          */
1029         DISABLE_INTERRUPTS(CLBR_ANY)
1030         TRACE_IRQS_IRETQ
1031         SWAPGS
1032         jmp restore_args
1033
1034 retint_restore_args:    /* return to kernel space */
1035         DISABLE_INTERRUPTS(CLBR_ANY)
1036         /*
1037          * The iretq could re-enable interrupts:
1038          */
1039         TRACE_IRQS_IRETQ
1040 restore_args:
1041         RESTORE_ARGS 1,8,1
1042
1043 irq_return:
1044         INTERRUPT_RETURN
1045         _ASM_EXTABLE(irq_return, bad_iret)
1046
1047 #ifdef CONFIG_PARAVIRT
1048 ENTRY(native_iret)
1049         iretq
1050         _ASM_EXTABLE(native_iret, bad_iret)
1051 #endif
1052
1053         .section .fixup,"ax"
1054 bad_iret:
1055         /*
1056          * The iret traps when the %cs or %ss being restored is bogus.
1057          * We've lost the original trap vector and error code.
1058          * #GPF is the most likely one to get for an invalid selector.
1059          * So pretend we completed the iret and took the #GPF in user mode.
1060          *
1061          * We are now running with the kernel GS after exception recovery.
1062          * But error_entry expects us to have user GS to match the user %cs,
1063          * so swap back.
1064          */
1065         pushq $0
1066
1067         SWAPGS
1068         jmp general_protection
1069
1070         .previous
1071
1072         /* edi: workmask, edx: work */
1073 retint_careful:
1074         CFI_RESTORE_STATE
1075         bt    $TIF_NEED_RESCHED,%edx
1076         jnc   retint_signal
1077         TRACE_IRQS_ON
1078         ENABLE_INTERRUPTS(CLBR_NONE)
1079         pushq_cfi %rdi
1080         SCHEDULE_USER
1081         popq_cfi %rdi
1082         GET_THREAD_INFO(%rcx)
1083         DISABLE_INTERRUPTS(CLBR_NONE)
1084         TRACE_IRQS_OFF
1085         jmp retint_check
1086
1087 retint_signal:
1088         testl $_TIF_DO_NOTIFY_MASK,%edx
1089         jz    retint_swapgs
1090         TRACE_IRQS_ON
1091         ENABLE_INTERRUPTS(CLBR_NONE)
1092         SAVE_REST
1093         movq $-1,ORIG_RAX(%rsp)
1094         xorl %esi,%esi          # oldset
1095         movq %rsp,%rdi          # &pt_regs
1096         call do_notify_resume
1097         RESTORE_REST
1098         DISABLE_INTERRUPTS(CLBR_NONE)
1099         TRACE_IRQS_OFF
1100         GET_THREAD_INFO(%rcx)
1101         jmp retint_with_reschedule
1102
1103 #ifdef CONFIG_PREEMPT
1104         /* Returning to kernel space. Check if we need preemption */
1105         /* rcx:  threadinfo. interrupts off. */
1106 ENTRY(retint_kernel)
1107         cmpl $0,TI_preempt_count(%rcx)
1108         jnz  retint_restore_args
1109         bt  $TIF_NEED_RESCHED,TI_flags(%rcx)
1110         jnc  retint_restore_args
1111         bt   $9,EFLAGS-ARGOFFSET(%rsp)  /* interrupts off? */
1112         jnc  retint_restore_args
1113         call preempt_schedule_irq
1114         jmp exit_intr
1115 #endif
1116
1117         CFI_ENDPROC
1118 END(common_interrupt)
1119 /*
1120  * End of kprobes section
1121  */
1122        .popsection
1123
1124 /*
1125  * APIC interrupts.
1126  */
1127 .macro apicinterrupt num sym do_sym
1128 ENTRY(\sym)
1129         INTR_FRAME
1130         pushq_cfi $~(\num)
1131 .Lcommon_\sym:
1132         interrupt \do_sym
1133         jmp ret_from_intr
1134         CFI_ENDPROC
1135 END(\sym)
1136 .endm
1137
1138 #ifdef CONFIG_SMP
1139 apicinterrupt IRQ_MOVE_CLEANUP_VECTOR \
1140         irq_move_cleanup_interrupt smp_irq_move_cleanup_interrupt
1141 apicinterrupt REBOOT_VECTOR \
1142         reboot_interrupt smp_reboot_interrupt
1143 #endif
1144
1145 #ifdef CONFIG_X86_UV
1146 apicinterrupt UV_BAU_MESSAGE \
1147         uv_bau_message_intr1 uv_bau_message_interrupt
1148 #endif
1149 apicinterrupt LOCAL_TIMER_VECTOR \
1150         apic_timer_interrupt smp_apic_timer_interrupt
1151 apicinterrupt X86_PLATFORM_IPI_VECTOR \
1152         x86_platform_ipi smp_x86_platform_ipi
1153
1154 apicinterrupt THRESHOLD_APIC_VECTOR \
1155         threshold_interrupt smp_threshold_interrupt
1156 apicinterrupt THERMAL_APIC_VECTOR \
1157         thermal_interrupt smp_thermal_interrupt
1158
1159 #ifdef CONFIG_SMP
1160 apicinterrupt CALL_FUNCTION_SINGLE_VECTOR \
1161         call_function_single_interrupt smp_call_function_single_interrupt
1162 apicinterrupt CALL_FUNCTION_VECTOR \
1163         call_function_interrupt smp_call_function_interrupt
1164 apicinterrupt RESCHEDULE_VECTOR \
1165         reschedule_interrupt smp_reschedule_interrupt
1166 #endif
1167
1168 apicinterrupt ERROR_APIC_VECTOR \
1169         error_interrupt smp_error_interrupt
1170 apicinterrupt SPURIOUS_APIC_VECTOR \
1171         spurious_interrupt smp_spurious_interrupt
1172
1173 #ifdef CONFIG_IRQ_WORK
1174 apicinterrupt IRQ_WORK_VECTOR \
1175         irq_work_interrupt smp_irq_work_interrupt
1176 #endif
1177
1178 /*
1179  * Exception entry points.
1180  */
1181 .macro zeroentry sym do_sym
1182 ENTRY(\sym)
1183         INTR_FRAME
1184         PARAVIRT_ADJUST_EXCEPTION_FRAME
1185         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1186         subq $ORIG_RAX-R15, %rsp
1187         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1188         call error_entry
1189         DEFAULT_FRAME 0
1190         movq %rsp,%rdi          /* pt_regs pointer */
1191         xorl %esi,%esi          /* no error code */
1192         call \do_sym
1193         jmp error_exit          /* %ebx: no swapgs flag */
1194         CFI_ENDPROC
1195 END(\sym)
1196 .endm
1197
1198 .macro paranoidzeroentry sym do_sym
1199 ENTRY(\sym)
1200         INTR_FRAME
1201         PARAVIRT_ADJUST_EXCEPTION_FRAME
1202         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1203         subq $ORIG_RAX-R15, %rsp
1204         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1205         call save_paranoid
1206         TRACE_IRQS_OFF
1207         movq %rsp,%rdi          /* pt_regs pointer */
1208         xorl %esi,%esi          /* no error code */
1209         call \do_sym
1210         jmp paranoid_exit       /* %ebx: no swapgs flag */
1211         CFI_ENDPROC
1212 END(\sym)
1213 .endm
1214
1215 #define INIT_TSS_IST(x) PER_CPU_VAR(init_tss) + (TSS_ist + ((x) - 1) * 8)
1216 .macro paranoidzeroentry_ist sym do_sym ist
1217 ENTRY(\sym)
1218         INTR_FRAME
1219         PARAVIRT_ADJUST_EXCEPTION_FRAME
1220         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1221         subq $ORIG_RAX-R15, %rsp
1222         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1223         call save_paranoid
1224         TRACE_IRQS_OFF_DEBUG
1225         movq %rsp,%rdi          /* pt_regs pointer */
1226         xorl %esi,%esi          /* no error code */
1227         subq $EXCEPTION_STKSZ, INIT_TSS_IST(\ist)
1228         call \do_sym
1229         addq $EXCEPTION_STKSZ, INIT_TSS_IST(\ist)
1230         jmp paranoid_exit       /* %ebx: no swapgs flag */
1231         CFI_ENDPROC
1232 END(\sym)
1233 .endm
1234
1235 .macro errorentry sym do_sym
1236 ENTRY(\sym)
1237         XCPT_FRAME
1238         PARAVIRT_ADJUST_EXCEPTION_FRAME
1239         subq $ORIG_RAX-R15, %rsp
1240         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1241         call error_entry
1242         DEFAULT_FRAME 0
1243         movq %rsp,%rdi                  /* pt_regs pointer */
1244         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1245         movq $-1,ORIG_RAX(%rsp)         /* no syscall to restart */
1246         call \do_sym
1247         jmp error_exit                  /* %ebx: no swapgs flag */
1248         CFI_ENDPROC
1249 END(\sym)
1250 .endm
1251
1252         /* error code is on the stack already */
1253 .macro paranoiderrorentry sym do_sym
1254 ENTRY(\sym)
1255         XCPT_FRAME
1256         PARAVIRT_ADJUST_EXCEPTION_FRAME
1257         subq $ORIG_RAX-R15, %rsp
1258         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1259         call save_paranoid
1260         DEFAULT_FRAME 0
1261         TRACE_IRQS_OFF
1262         movq %rsp,%rdi                  /* pt_regs pointer */
1263         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1264         movq $-1,ORIG_RAX(%rsp)         /* no syscall to restart */
1265         call \do_sym
1266         jmp paranoid_exit               /* %ebx: no swapgs flag */
1267         CFI_ENDPROC
1268 END(\sym)
1269 .endm
1270
1271 zeroentry divide_error do_divide_error
1272 zeroentry overflow do_overflow
1273 zeroentry bounds do_bounds
1274 zeroentry invalid_op do_invalid_op
1275 zeroentry device_not_available do_device_not_available
1276 paranoiderrorentry double_fault do_double_fault
1277 zeroentry coprocessor_segment_overrun do_coprocessor_segment_overrun
1278 errorentry invalid_TSS do_invalid_TSS
1279 errorentry segment_not_present do_segment_not_present
1280 zeroentry spurious_interrupt_bug do_spurious_interrupt_bug
1281 zeroentry coprocessor_error do_coprocessor_error
1282 errorentry alignment_check do_alignment_check
1283 zeroentry simd_coprocessor_error do_simd_coprocessor_error
1284
1285
1286         /* Reload gs selector with exception handling */
1287         /* edi:  new selector */
1288 ENTRY(native_load_gs_index)
1289         CFI_STARTPROC
1290         pushfq_cfi
1291         DISABLE_INTERRUPTS(CLBR_ANY & ~CLBR_RDI)
1292         SWAPGS
1293 gs_change:
1294         movl %edi,%gs
1295 2:      mfence          /* workaround */
1296         SWAPGS
1297         popfq_cfi
1298         ret
1299         CFI_ENDPROC
1300 END(native_load_gs_index)
1301
1302         _ASM_EXTABLE(gs_change,bad_gs)
1303         .section .fixup,"ax"
1304         /* running with kernelgs */
1305 bad_gs:
1306         SWAPGS                  /* switch back to user gs */
1307         xorl %eax,%eax
1308         movl %eax,%gs
1309         jmp  2b
1310         .previous
1311
1312 ENTRY(kernel_thread_helper)
1313         pushq $0                # fake return address
1314         CFI_STARTPROC
1315         /*
1316          * Here we are in the child and the registers are set as they were
1317          * at kernel_thread() invocation in the parent.
1318          */
1319         call *%rsi
1320         # exit
1321         mov %eax, %edi
1322         call do_exit
1323         ud2                     # padding for call trace
1324         CFI_ENDPROC
1325 END(kernel_thread_helper)
1326
1327 /*
1328  * execve(). This function needs to use IRET, not SYSRET, to set up all state properly.
1329  *
1330  * C extern interface:
1331  *       extern long execve(const char *name, char **argv, char **envp)
1332  *
1333  * asm input arguments:
1334  *      rdi: name, rsi: argv, rdx: envp
1335  *
1336  * We want to fallback into:
1337  *      extern long sys_execve(const char *name, char **argv,char **envp, struct pt_regs *regs)
1338  *
1339  * do_sys_execve asm fallback arguments:
1340  *      rdi: name, rsi: argv, rdx: envp, rcx: fake frame on the stack
1341  */
1342 ENTRY(kernel_execve)
1343         CFI_STARTPROC
1344         FAKE_STACK_FRAME $0
1345         SAVE_ALL
1346         movq %rsp,%rcx
1347         call sys_execve
1348         movq %rax, RAX(%rsp)
1349         RESTORE_REST
1350         testq %rax,%rax
1351         je int_ret_from_sys_call
1352         RESTORE_ARGS
1353         UNFAKE_STACK_FRAME
1354         ret
1355         CFI_ENDPROC
1356 END(kernel_execve)
1357
1358 /* Call softirq on interrupt stack. Interrupts are off. */
1359 ENTRY(call_softirq)
1360         CFI_STARTPROC
1361         pushq_cfi %rbp
1362         CFI_REL_OFFSET rbp,0
1363         mov  %rsp,%rbp
1364         CFI_DEF_CFA_REGISTER rbp
1365         incl PER_CPU_VAR(irq_count)
1366         cmove PER_CPU_VAR(irq_stack_ptr),%rsp
1367         push  %rbp                      # backlink for old unwinder
1368         call __do_softirq
1369         leaveq
1370         CFI_RESTORE             rbp
1371         CFI_DEF_CFA_REGISTER    rsp
1372         CFI_ADJUST_CFA_OFFSET   -8
1373         decl PER_CPU_VAR(irq_count)
1374         ret
1375         CFI_ENDPROC
1376 END(call_softirq)
1377
1378 #ifdef CONFIG_XEN
1379 zeroentry xen_hypervisor_callback xen_do_hypervisor_callback
1380
1381 /*
1382  * A note on the "critical region" in our callback handler.
1383  * We want to avoid stacking callback handlers due to events occurring
1384  * during handling of the last event. To do this, we keep events disabled
1385  * until we've done all processing. HOWEVER, we must enable events before
1386  * popping the stack frame (can't be done atomically) and so it would still
1387  * be possible to get enough handler activations to overflow the stack.
1388  * Although unlikely, bugs of that kind are hard to track down, so we'd
1389  * like to avoid the possibility.
1390  * So, on entry to the handler we detect whether we interrupted an
1391  * existing activation in its critical region -- if so, we pop the current
1392  * activation and restart the handler using the previous one.
1393  */
1394 ENTRY(xen_do_hypervisor_callback)   # do_hypervisor_callback(struct *pt_regs)
1395         CFI_STARTPROC
1396 /*
1397  * Since we don't modify %rdi, evtchn_do_upall(struct *pt_regs) will
1398  * see the correct pointer to the pt_regs
1399  */
1400         movq %rdi, %rsp            # we don't return, adjust the stack frame
1401         CFI_ENDPROC
1402         DEFAULT_FRAME
1403 11:     incl PER_CPU_VAR(irq_count)
1404         movq %rsp,%rbp
1405         CFI_DEF_CFA_REGISTER rbp
1406         cmovzq PER_CPU_VAR(irq_stack_ptr),%rsp
1407         pushq %rbp                      # backlink for old unwinder
1408         call xen_evtchn_do_upcall
1409         popq %rsp
1410         CFI_DEF_CFA_REGISTER rsp
1411         decl PER_CPU_VAR(irq_count)
1412         jmp  error_exit
1413         CFI_ENDPROC
1414 END(xen_do_hypervisor_callback)
1415
1416 /*
1417  * Hypervisor uses this for application faults while it executes.
1418  * We get here for two reasons:
1419  *  1. Fault while reloading DS, ES, FS or GS
1420  *  2. Fault while executing IRET
1421  * Category 1 we do not need to fix up as Xen has already reloaded all segment
1422  * registers that could be reloaded and zeroed the others.
1423  * Category 2 we fix up by killing the current process. We cannot use the
1424  * normal Linux return path in this case because if we use the IRET hypercall
1425  * to pop the stack frame we end up in an infinite loop of failsafe callbacks.
1426  * We distinguish between categories by comparing each saved segment register
1427  * with its current contents: any discrepancy means we in category 1.
1428  */
1429 ENTRY(xen_failsafe_callback)
1430         INTR_FRAME 1 (6*8)
1431         /*CFI_REL_OFFSET gs,GS*/
1432         /*CFI_REL_OFFSET fs,FS*/
1433         /*CFI_REL_OFFSET es,ES*/
1434         /*CFI_REL_OFFSET ds,DS*/
1435         CFI_REL_OFFSET r11,8
1436         CFI_REL_OFFSET rcx,0
1437         movw %ds,%cx
1438         cmpw %cx,0x10(%rsp)
1439         CFI_REMEMBER_STATE
1440         jne 1f
1441         movw %es,%cx
1442         cmpw %cx,0x18(%rsp)
1443         jne 1f
1444         movw %fs,%cx
1445         cmpw %cx,0x20(%rsp)
1446         jne 1f
1447         movw %gs,%cx
1448         cmpw %cx,0x28(%rsp)
1449         jne 1f
1450         /* All segments match their saved values => Category 2 (Bad IRET). */
1451         movq (%rsp),%rcx
1452         CFI_RESTORE rcx
1453         movq 8(%rsp),%r11
1454         CFI_RESTORE r11
1455         addq $0x30,%rsp
1456         CFI_ADJUST_CFA_OFFSET -0x30
1457         pushq_cfi $0    /* RIP */
1458         pushq_cfi %r11
1459         pushq_cfi %rcx
1460         jmp general_protection
1461         CFI_RESTORE_STATE
1462 1:      /* Segment mismatch => Category 1 (Bad segment). Retry the IRET. */
1463         movq (%rsp),%rcx
1464         CFI_RESTORE rcx
1465         movq 8(%rsp),%r11
1466         CFI_RESTORE r11
1467         addq $0x30,%rsp
1468         CFI_ADJUST_CFA_OFFSET -0x30
1469         pushq_cfi $0
1470         SAVE_ALL
1471         jmp error_exit
1472         CFI_ENDPROC
1473 END(xen_failsafe_callback)
1474
1475 apicinterrupt XEN_HVM_EVTCHN_CALLBACK \
1476         xen_hvm_callback_vector xen_evtchn_do_upcall
1477
1478 #endif /* CONFIG_XEN */
1479
1480 /*
1481  * Some functions should be protected against kprobes
1482  */
1483         .pushsection .kprobes.text, "ax"
1484
1485 paranoidzeroentry_ist debug do_debug DEBUG_STACK
1486 paranoidzeroentry_ist int3 do_int3 DEBUG_STACK
1487 paranoiderrorentry stack_segment do_stack_segment
1488 #ifdef CONFIG_XEN
1489 zeroentry xen_debug do_debug
1490 zeroentry xen_int3 do_int3
1491 errorentry xen_stack_segment do_stack_segment
1492 #endif
1493 errorentry general_protection do_general_protection
1494 errorentry page_fault do_page_fault
1495 #ifdef CONFIG_KVM_GUEST
1496 errorentry async_page_fault do_async_page_fault
1497 #endif
1498 #ifdef CONFIG_X86_MCE
1499 paranoidzeroentry machine_check *machine_check_vector(%rip)
1500 #endif
1501
1502         /*
1503          * "Paranoid" exit path from exception stack.
1504          * Paranoid because this is used by NMIs and cannot take
1505          * any kernel state for granted.
1506          * We don't do kernel preemption checks here, because only
1507          * NMI should be common and it does not enable IRQs and
1508          * cannot get reschedule ticks.
1509          *
1510          * "trace" is 0 for the NMI handler only, because irq-tracing
1511          * is fundamentally NMI-unsafe. (we cannot change the soft and
1512          * hard flags at once, atomically)
1513          */
1514
1515         /* ebx: no swapgs flag */
1516 ENTRY(paranoid_exit)
1517         DEFAULT_FRAME
1518         DISABLE_INTERRUPTS(CLBR_NONE)
1519         TRACE_IRQS_OFF_DEBUG
1520         testl %ebx,%ebx                         /* swapgs needed? */
1521         jnz paranoid_restore
1522         testl $3,CS(%rsp)
1523         jnz   paranoid_userspace
1524 paranoid_swapgs:
1525         TRACE_IRQS_IRETQ 0
1526         SWAPGS_UNSAFE_STACK
1527         RESTORE_ALL 8
1528         jmp irq_return
1529 paranoid_restore:
1530         TRACE_IRQS_IRETQ_DEBUG 0
1531         RESTORE_ALL 8
1532         jmp irq_return
1533 paranoid_userspace:
1534         GET_THREAD_INFO(%rcx)
1535         movl TI_flags(%rcx),%ebx
1536         andl $_TIF_WORK_MASK,%ebx
1537         jz paranoid_swapgs
1538         movq %rsp,%rdi                  /* &pt_regs */
1539         call sync_regs
1540         movq %rax,%rsp                  /* switch stack for scheduling */
1541         testl $_TIF_NEED_RESCHED,%ebx
1542         jnz paranoid_schedule
1543         movl %ebx,%edx                  /* arg3: thread flags */
1544         TRACE_IRQS_ON
1545         ENABLE_INTERRUPTS(CLBR_NONE)
1546         xorl %esi,%esi                  /* arg2: oldset */
1547         movq %rsp,%rdi                  /* arg1: &pt_regs */
1548         call do_notify_resume
1549         DISABLE_INTERRUPTS(CLBR_NONE)
1550         TRACE_IRQS_OFF
1551         jmp paranoid_userspace
1552 paranoid_schedule:
1553         TRACE_IRQS_ON
1554         ENABLE_INTERRUPTS(CLBR_ANY)
1555         SCHEDULE_USER
1556         DISABLE_INTERRUPTS(CLBR_ANY)
1557         TRACE_IRQS_OFF
1558         jmp paranoid_userspace
1559         CFI_ENDPROC
1560 END(paranoid_exit)
1561
1562 /*
1563  * Exception entry point. This expects an error code/orig_rax on the stack.
1564  * returns in "no swapgs flag" in %ebx.
1565  */
1566 ENTRY(error_entry)
1567         XCPT_FRAME
1568         CFI_ADJUST_CFA_OFFSET 15*8
1569         /* oldrax contains error code */
1570         cld
1571         movq_cfi rdi, RDI+8
1572         movq_cfi rsi, RSI+8
1573         movq_cfi rdx, RDX+8
1574         movq_cfi rcx, RCX+8
1575         movq_cfi rax, RAX+8
1576         movq_cfi  r8,  R8+8
1577         movq_cfi  r9,  R9+8
1578         movq_cfi r10, R10+8
1579         movq_cfi r11, R11+8
1580         movq_cfi rbx, RBX+8
1581         movq_cfi rbp, RBP+8
1582         movq_cfi r12, R12+8
1583         movq_cfi r13, R13+8
1584         movq_cfi r14, R14+8
1585         movq_cfi r15, R15+8
1586         xorl %ebx,%ebx
1587         testl $3,CS+8(%rsp)
1588         je error_kernelspace
1589 error_swapgs:
1590         SWAPGS
1591 error_sti:
1592         TRACE_IRQS_OFF
1593         ret
1594
1595 /*
1596  * There are two places in the kernel that can potentially fault with
1597  * usergs. Handle them here. The exception handlers after iret run with
1598  * kernel gs again, so don't set the user space flag. B stepping K8s
1599  * sometimes report an truncated RIP for IRET exceptions returning to
1600  * compat mode. Check for these here too.
1601  */
1602 error_kernelspace:
1603         incl %ebx
1604         leaq irq_return(%rip),%rcx
1605         cmpq %rcx,RIP+8(%rsp)
1606         je error_swapgs
1607         movl %ecx,%eax  /* zero extend */
1608         cmpq %rax,RIP+8(%rsp)
1609         je bstep_iret
1610         cmpq $gs_change,RIP+8(%rsp)
1611         je error_swapgs
1612         jmp error_sti
1613
1614 bstep_iret:
1615         /* Fix truncated RIP */
1616         movq %rcx,RIP+8(%rsp)
1617         jmp error_swapgs
1618         CFI_ENDPROC
1619 END(error_entry)
1620
1621
1622 /* ebx: no swapgs flag (1: don't need swapgs, 0: need it) */
1623 ENTRY(error_exit)
1624         DEFAULT_FRAME
1625         movl %ebx,%eax
1626         RESTORE_REST
1627         DISABLE_INTERRUPTS(CLBR_NONE)
1628         TRACE_IRQS_OFF
1629         GET_THREAD_INFO(%rcx)
1630         testl %eax,%eax
1631         jne retint_kernel
1632         LOCKDEP_SYS_EXIT_IRQ
1633         movl TI_flags(%rcx),%edx
1634         movl $_TIF_WORK_MASK,%edi
1635         andl %edi,%edx
1636         jnz retint_careful
1637         jmp retint_swapgs
1638         CFI_ENDPROC
1639 END(error_exit)
1640
1641 /*
1642  * Test if a given stack is an NMI stack or not.
1643  */
1644         .macro test_in_nmi reg stack nmi_ret normal_ret
1645         cmpq %\reg, \stack
1646         ja \normal_ret
1647         subq $EXCEPTION_STKSZ, %\reg
1648         cmpq %\reg, \stack
1649         jb \normal_ret
1650         jmp \nmi_ret
1651         .endm
1652
1653         /* runs on exception stack */
1654 ENTRY(nmi)
1655         INTR_FRAME
1656         PARAVIRT_ADJUST_EXCEPTION_FRAME
1657         /*
1658          * We allow breakpoints in NMIs. If a breakpoint occurs, then
1659          * the iretq it performs will take us out of NMI context.
1660          * This means that we can have nested NMIs where the next
1661          * NMI is using the top of the stack of the previous NMI. We
1662          * can't let it execute because the nested NMI will corrupt the
1663          * stack of the previous NMI. NMI handlers are not re-entrant
1664          * anyway.
1665          *
1666          * To handle this case we do the following:
1667          *  Check the a special location on the stack that contains
1668          *  a variable that is set when NMIs are executing.
1669          *  The interrupted task's stack is also checked to see if it
1670          *  is an NMI stack.
1671          *  If the variable is not set and the stack is not the NMI
1672          *  stack then:
1673          *    o Set the special variable on the stack
1674          *    o Copy the interrupt frame into a "saved" location on the stack
1675          *    o Copy the interrupt frame into a "copy" location on the stack
1676          *    o Continue processing the NMI
1677          *  If the variable is set or the previous stack is the NMI stack:
1678          *    o Modify the "copy" location to jump to the repeate_nmi
1679          *    o return back to the first NMI
1680          *
1681          * Now on exit of the first NMI, we first clear the stack variable
1682          * The NMI stack will tell any nested NMIs at that point that it is
1683          * nested. Then we pop the stack normally with iret, and if there was
1684          * a nested NMI that updated the copy interrupt stack frame, a
1685          * jump will be made to the repeat_nmi code that will handle the second
1686          * NMI.
1687          */
1688
1689         /* Use %rdx as out temp variable throughout */
1690         pushq_cfi %rdx
1691         CFI_REL_OFFSET rdx, 0
1692
1693         /*
1694          * If %cs was not the kernel segment, then the NMI triggered in user
1695          * space, which means it is definitely not nested.
1696          */
1697         cmpl $__KERNEL_CS, 16(%rsp)
1698         jne first_nmi
1699
1700         /*
1701          * Check the special variable on the stack to see if NMIs are
1702          * executing.
1703          */
1704         cmpl $1, -8(%rsp)
1705         je nested_nmi
1706
1707         /*
1708          * Now test if the previous stack was an NMI stack.
1709          * We need the double check. We check the NMI stack to satisfy the
1710          * race when the first NMI clears the variable before returning.
1711          * We check the variable because the first NMI could be in a
1712          * breakpoint routine using a breakpoint stack.
1713          */
1714         lea 6*8(%rsp), %rdx
1715         test_in_nmi rdx, 4*8(%rsp), nested_nmi, first_nmi
1716         CFI_REMEMBER_STATE
1717
1718 nested_nmi:
1719         /*
1720          * Do nothing if we interrupted the fixup in repeat_nmi.
1721          * It's about to repeat the NMI handler, so we are fine
1722          * with ignoring this one.
1723          */
1724         movq $repeat_nmi, %rdx
1725         cmpq 8(%rsp), %rdx
1726         ja 1f
1727         movq $end_repeat_nmi, %rdx
1728         cmpq 8(%rsp), %rdx
1729         ja nested_nmi_out
1730
1731 1:
1732         /* Set up the interrupted NMIs stack to jump to repeat_nmi */
1733         leaq -6*8(%rsp), %rdx
1734         movq %rdx, %rsp
1735         CFI_ADJUST_CFA_OFFSET 6*8
1736         pushq_cfi $__KERNEL_DS
1737         pushq_cfi %rdx
1738         pushfq_cfi
1739         pushq_cfi $__KERNEL_CS
1740         pushq_cfi $repeat_nmi
1741
1742         /* Put stack back */
1743         addq $(11*8), %rsp
1744         CFI_ADJUST_CFA_OFFSET -11*8
1745
1746 nested_nmi_out:
1747         popq_cfi %rdx
1748         CFI_RESTORE rdx
1749
1750         /* No need to check faults here */
1751         INTERRUPT_RETURN
1752
1753         CFI_RESTORE_STATE
1754 first_nmi:
1755         /*
1756          * Because nested NMIs will use the pushed location that we
1757          * stored in rdx, we must keep that space available.
1758          * Here's what our stack frame will look like:
1759          * +-------------------------+
1760          * | original SS             |
1761          * | original Return RSP     |
1762          * | original RFLAGS         |
1763          * | original CS             |
1764          * | original RIP            |
1765          * +-------------------------+
1766          * | temp storage for rdx    |
1767          * +-------------------------+
1768          * | NMI executing variable  |
1769          * +-------------------------+
1770          * | Saved SS                |
1771          * | Saved Return RSP        |
1772          * | Saved RFLAGS            |
1773          * | Saved CS                |
1774          * | Saved RIP               |
1775          * +-------------------------+
1776          * | copied SS               |
1777          * | copied Return RSP       |
1778          * | copied RFLAGS           |
1779          * | copied CS               |
1780          * | copied RIP              |
1781          * +-------------------------+
1782          * | pt_regs                 |
1783          * +-------------------------+
1784          *
1785          * The saved stack frame is used to fix up the copied stack frame
1786          * that a nested NMI may change to make the interrupted NMI iret jump
1787          * to the repeat_nmi. The original stack frame and the temp storage
1788          * is also used by nested NMIs and can not be trusted on exit.
1789          */
1790         /* Do not pop rdx, nested NMIs will corrupt that part of the stack */
1791         movq (%rsp), %rdx
1792         CFI_RESTORE rdx
1793
1794         /* Set the NMI executing variable on the stack. */
1795         pushq_cfi $1
1796
1797         /* Copy the stack frame to the Saved frame */
1798         .rept 5
1799         pushq_cfi 6*8(%rsp)
1800         .endr
1801         CFI_DEF_CFA_OFFSET SS+8-RIP
1802
1803         /* Everything up to here is safe from nested NMIs */
1804
1805         /*
1806          * If there was a nested NMI, the first NMI's iret will return
1807          * here. But NMIs are still enabled and we can take another
1808          * nested NMI. The nested NMI checks the interrupted RIP to see
1809          * if it is between repeat_nmi and end_repeat_nmi, and if so
1810          * it will just return, as we are about to repeat an NMI anyway.
1811          * This makes it safe to copy to the stack frame that a nested
1812          * NMI will update.
1813          */
1814 repeat_nmi:
1815         /*
1816          * Update the stack variable to say we are still in NMI (the update
1817          * is benign for the non-repeat case, where 1 was pushed just above
1818          * to this very stack slot).
1819          */
1820         movq $1, 5*8(%rsp)
1821
1822         /* Make another copy, this one may be modified by nested NMIs */
1823         .rept 5
1824         pushq_cfi 4*8(%rsp)
1825         .endr
1826         CFI_DEF_CFA_OFFSET SS+8-RIP
1827 end_repeat_nmi:
1828
1829         /*
1830          * Everything below this point can be preempted by a nested
1831          * NMI if the first NMI took an exception and reset our iret stack
1832          * so that we repeat another NMI.
1833          */
1834         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1835         subq $ORIG_RAX-R15, %rsp
1836         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1837         /*
1838          * Use save_paranoid to handle SWAPGS, but no need to use paranoid_exit
1839          * as we should not be calling schedule in NMI context.
1840          * Even with normal interrupts enabled. An NMI should not be
1841          * setting NEED_RESCHED or anything that normal interrupts and
1842          * exceptions might do.
1843          */
1844         call save_paranoid
1845         DEFAULT_FRAME 0
1846
1847         /*
1848          * Save off the CR2 register. If we take a page fault in the NMI then
1849          * it could corrupt the CR2 value. If the NMI preempts a page fault
1850          * handler before it was able to read the CR2 register, and then the
1851          * NMI itself takes a page fault, the page fault that was preempted
1852          * will read the information from the NMI page fault and not the
1853          * origin fault. Save it off and restore it if it changes.
1854          * Use the r12 callee-saved register.
1855          */
1856         movq %cr2, %r12
1857
1858         /* paranoidentry do_nmi, 0; without TRACE_IRQS_OFF */
1859         movq %rsp,%rdi
1860         movq $-1,%rsi
1861         call do_nmi
1862
1863         /* Did the NMI take a page fault? Restore cr2 if it did */
1864         movq %cr2, %rcx
1865         cmpq %rcx, %r12
1866         je 1f
1867         movq %r12, %cr2
1868 1:
1869         
1870         testl %ebx,%ebx                         /* swapgs needed? */
1871         jnz nmi_restore
1872 nmi_swapgs:
1873         SWAPGS_UNSAFE_STACK
1874 nmi_restore:
1875         RESTORE_ALL 8
1876         /* Clear the NMI executing stack variable */
1877         movq $0, 10*8(%rsp)
1878         jmp irq_return
1879         CFI_ENDPROC
1880 END(nmi)
1881
1882 ENTRY(ignore_sysret)
1883         CFI_STARTPROC
1884         mov $-ENOSYS,%eax
1885         sysret
1886         CFI_ENDPROC
1887 END(ignore_sysret)
1888
1889 /*
1890  * End of kprobes section
1891  */
1892         .popsection