x86: Move <asm/asm-offsets.h> from trace_syscalls.c to asm/syscall.h
[linux-3.10.git] / arch / x86 / kernel / entry_32.S
1 /*
2  *
3  *  Copyright (C) 1991, 1992  Linus Torvalds
4  */
5
6 /*
7  * entry.S contains the system-call and fault low-level handling routines.
8  * This also contains the timer-interrupt handler, as well as all interrupts
9  * and faults that can result in a task-switch.
10  *
11  * NOTE: This code handles signal-recognition, which happens every time
12  * after a timer-interrupt and after each system call.
13  *
14  * I changed all the .align's to 4 (16 byte alignment), as that's faster
15  * on a 486.
16  *
17  * Stack layout in 'syscall_exit':
18  *      ptrace needs to have all regs on the stack.
19  *      if the order here is changed, it needs to be
20  *      updated in fork.c:copy_process, signal.c:do_signal,
21  *      ptrace.c and ptrace.h
22  *
23  *       0(%esp) - %ebx
24  *       4(%esp) - %ecx
25  *       8(%esp) - %edx
26  *       C(%esp) - %esi
27  *      10(%esp) - %edi
28  *      14(%esp) - %ebp
29  *      18(%esp) - %eax
30  *      1C(%esp) - %ds
31  *      20(%esp) - %es
32  *      24(%esp) - %fs
33  *      28(%esp) - %gs          saved iff !CONFIG_X86_32_LAZY_GS
34  *      2C(%esp) - orig_eax
35  *      30(%esp) - %eip
36  *      34(%esp) - %cs
37  *      38(%esp) - %eflags
38  *      3C(%esp) - %oldesp
39  *      40(%esp) - %oldss
40  *
41  * "current" is in register %ebx during any slow entries.
42  */
43
44 #include <linux/linkage.h>
45 #include <asm/thread_info.h>
46 #include <asm/irqflags.h>
47 #include <asm/errno.h>
48 #include <asm/segment.h>
49 #include <asm/smp.h>
50 #include <asm/page_types.h>
51 #include <asm/percpu.h>
52 #include <asm/dwarf2.h>
53 #include <asm/processor-flags.h>
54 #include <asm/ftrace.h>
55 #include <asm/irq_vectors.h>
56 #include <asm/cpufeature.h>
57 #include <asm/alternative-asm.h>
58
59 /* Avoid __ASSEMBLER__'ifying <linux/audit.h> just for this.  */
60 #include <linux/elf-em.h>
61 #define AUDIT_ARCH_I386         (EM_386|__AUDIT_ARCH_LE)
62 #define __AUDIT_ARCH_LE    0x40000000
63
64 #ifndef CONFIG_AUDITSYSCALL
65 #define sysenter_audit  syscall_trace_entry
66 #define sysexit_audit   syscall_exit_work
67 #endif
68
69         .section .entry.text, "ax"
70
71 /*
72  * We use macros for low-level operations which need to be overridden
73  * for paravirtualization.  The following will never clobber any registers:
74  *   INTERRUPT_RETURN (aka. "iret")
75  *   GET_CR0_INTO_EAX (aka. "movl %cr0, %eax")
76  *   ENABLE_INTERRUPTS_SYSEXIT (aka "sti; sysexit").
77  *
78  * For DISABLE_INTERRUPTS/ENABLE_INTERRUPTS (aka "cli"/"sti"), you must
79  * specify what registers can be overwritten (CLBR_NONE, CLBR_EAX/EDX/ECX/ANY).
80  * Allowing a register to be clobbered can shrink the paravirt replacement
81  * enough to patch inline, increasing performance.
82  */
83
84 #ifdef CONFIG_PREEMPT
85 #define preempt_stop(clobbers)  DISABLE_INTERRUPTS(clobbers); TRACE_IRQS_OFF
86 #else
87 #define preempt_stop(clobbers)
88 #define resume_kernel           restore_all
89 #endif
90
91 .macro TRACE_IRQS_IRET
92 #ifdef CONFIG_TRACE_IRQFLAGS
93         testl $X86_EFLAGS_IF,PT_EFLAGS(%esp)     # interrupts off?
94         jz 1f
95         TRACE_IRQS_ON
96 1:
97 #endif
98 .endm
99
100 #ifdef CONFIG_VM86
101 #define resume_userspace_sig    check_userspace
102 #else
103 #define resume_userspace_sig    resume_userspace
104 #endif
105
106 /*
107  * User gs save/restore
108  *
109  * %gs is used for userland TLS and kernel only uses it for stack
110  * canary which is required to be at %gs:20 by gcc.  Read the comment
111  * at the top of stackprotector.h for more info.
112  *
113  * Local labels 98 and 99 are used.
114  */
115 #ifdef CONFIG_X86_32_LAZY_GS
116
117  /* unfortunately push/pop can't be no-op */
118 .macro PUSH_GS
119         pushl_cfi $0
120 .endm
121 .macro POP_GS pop=0
122         addl $(4 + \pop), %esp
123         CFI_ADJUST_CFA_OFFSET -(4 + \pop)
124 .endm
125 .macro POP_GS_EX
126 .endm
127
128  /* all the rest are no-op */
129 .macro PTGS_TO_GS
130 .endm
131 .macro PTGS_TO_GS_EX
132 .endm
133 .macro GS_TO_REG reg
134 .endm
135 .macro REG_TO_PTGS reg
136 .endm
137 .macro SET_KERNEL_GS reg
138 .endm
139
140 #else   /* CONFIG_X86_32_LAZY_GS */
141
142 .macro PUSH_GS
143         pushl_cfi %gs
144         /*CFI_REL_OFFSET gs, 0*/
145 .endm
146
147 .macro POP_GS pop=0
148 98:     popl_cfi %gs
149         /*CFI_RESTORE gs*/
150   .if \pop <> 0
151         add $\pop, %esp
152         CFI_ADJUST_CFA_OFFSET -\pop
153   .endif
154 .endm
155 .macro POP_GS_EX
156 .pushsection .fixup, "ax"
157 99:     movl $0, (%esp)
158         jmp 98b
159 .section __ex_table, "a"
160         .align 4
161         .long 98b, 99b
162 .popsection
163 .endm
164
165 .macro PTGS_TO_GS
166 98:     mov PT_GS(%esp), %gs
167 .endm
168 .macro PTGS_TO_GS_EX
169 .pushsection .fixup, "ax"
170 99:     movl $0, PT_GS(%esp)
171         jmp 98b
172 .section __ex_table, "a"
173         .align 4
174         .long 98b, 99b
175 .popsection
176 .endm
177
178 .macro GS_TO_REG reg
179         movl %gs, \reg
180         /*CFI_REGISTER gs, \reg*/
181 .endm
182 .macro REG_TO_PTGS reg
183         movl \reg, PT_GS(%esp)
184         /*CFI_REL_OFFSET gs, PT_GS*/
185 .endm
186 .macro SET_KERNEL_GS reg
187         movl $(__KERNEL_STACK_CANARY), \reg
188         movl \reg, %gs
189 .endm
190
191 #endif  /* CONFIG_X86_32_LAZY_GS */
192
193 .macro SAVE_ALL
194         cld
195         PUSH_GS
196         pushl_cfi %fs
197         /*CFI_REL_OFFSET fs, 0;*/
198         pushl_cfi %es
199         /*CFI_REL_OFFSET es, 0;*/
200         pushl_cfi %ds
201         /*CFI_REL_OFFSET ds, 0;*/
202         pushl_cfi %eax
203         CFI_REL_OFFSET eax, 0
204         pushl_cfi %ebp
205         CFI_REL_OFFSET ebp, 0
206         pushl_cfi %edi
207         CFI_REL_OFFSET edi, 0
208         pushl_cfi %esi
209         CFI_REL_OFFSET esi, 0
210         pushl_cfi %edx
211         CFI_REL_OFFSET edx, 0
212         pushl_cfi %ecx
213         CFI_REL_OFFSET ecx, 0
214         pushl_cfi %ebx
215         CFI_REL_OFFSET ebx, 0
216         movl $(__USER_DS), %edx
217         movl %edx, %ds
218         movl %edx, %es
219         movl $(__KERNEL_PERCPU), %edx
220         movl %edx, %fs
221         SET_KERNEL_GS %edx
222 .endm
223
224 .macro RESTORE_INT_REGS
225         popl_cfi %ebx
226         CFI_RESTORE ebx
227         popl_cfi %ecx
228         CFI_RESTORE ecx
229         popl_cfi %edx
230         CFI_RESTORE edx
231         popl_cfi %esi
232         CFI_RESTORE esi
233         popl_cfi %edi
234         CFI_RESTORE edi
235         popl_cfi %ebp
236         CFI_RESTORE ebp
237         popl_cfi %eax
238         CFI_RESTORE eax
239 .endm
240
241 .macro RESTORE_REGS pop=0
242         RESTORE_INT_REGS
243 1:      popl_cfi %ds
244         /*CFI_RESTORE ds;*/
245 2:      popl_cfi %es
246         /*CFI_RESTORE es;*/
247 3:      popl_cfi %fs
248         /*CFI_RESTORE fs;*/
249         POP_GS \pop
250 .pushsection .fixup, "ax"
251 4:      movl $0, (%esp)
252         jmp 1b
253 5:      movl $0, (%esp)
254         jmp 2b
255 6:      movl $0, (%esp)
256         jmp 3b
257 .section __ex_table, "a"
258         .align 4
259         .long 1b, 4b
260         .long 2b, 5b
261         .long 3b, 6b
262 .popsection
263         POP_GS_EX
264 .endm
265
266 .macro RING0_INT_FRAME
267         CFI_STARTPROC simple
268         CFI_SIGNAL_FRAME
269         CFI_DEF_CFA esp, 3*4
270         /*CFI_OFFSET cs, -2*4;*/
271         CFI_OFFSET eip, -3*4
272 .endm
273
274 .macro RING0_EC_FRAME
275         CFI_STARTPROC simple
276         CFI_SIGNAL_FRAME
277         CFI_DEF_CFA esp, 4*4
278         /*CFI_OFFSET cs, -2*4;*/
279         CFI_OFFSET eip, -3*4
280 .endm
281
282 .macro RING0_PTREGS_FRAME
283         CFI_STARTPROC simple
284         CFI_SIGNAL_FRAME
285         CFI_DEF_CFA esp, PT_OLDESP-PT_EBX
286         /*CFI_OFFSET cs, PT_CS-PT_OLDESP;*/
287         CFI_OFFSET eip, PT_EIP-PT_OLDESP
288         /*CFI_OFFSET es, PT_ES-PT_OLDESP;*/
289         /*CFI_OFFSET ds, PT_DS-PT_OLDESP;*/
290         CFI_OFFSET eax, PT_EAX-PT_OLDESP
291         CFI_OFFSET ebp, PT_EBP-PT_OLDESP
292         CFI_OFFSET edi, PT_EDI-PT_OLDESP
293         CFI_OFFSET esi, PT_ESI-PT_OLDESP
294         CFI_OFFSET edx, PT_EDX-PT_OLDESP
295         CFI_OFFSET ecx, PT_ECX-PT_OLDESP
296         CFI_OFFSET ebx, PT_EBX-PT_OLDESP
297 .endm
298
299 ENTRY(ret_from_fork)
300         CFI_STARTPROC
301         pushl_cfi %eax
302         call schedule_tail
303         GET_THREAD_INFO(%ebp)
304         popl_cfi %eax
305         pushl_cfi $0x0202               # Reset kernel eflags
306         popfl_cfi
307         jmp syscall_exit
308         CFI_ENDPROC
309 END(ret_from_fork)
310
311 /*
312  * Interrupt exit functions should be protected against kprobes
313  */
314         .pushsection .kprobes.text, "ax"
315 /*
316  * Return to user mode is not as complex as all this looks,
317  * but we want the default path for a system call return to
318  * go as quickly as possible which is why some of this is
319  * less clear than it otherwise should be.
320  */
321
322         # userspace resumption stub bypassing syscall exit tracing
323         ALIGN
324         RING0_PTREGS_FRAME
325 ret_from_exception:
326         preempt_stop(CLBR_ANY)
327 ret_from_intr:
328         GET_THREAD_INFO(%ebp)
329 check_userspace:
330         movl PT_EFLAGS(%esp), %eax      # mix EFLAGS and CS
331         movb PT_CS(%esp), %al
332         andl $(X86_EFLAGS_VM | SEGMENT_RPL_MASK), %eax
333         cmpl $USER_RPL, %eax
334         jb resume_kernel                # not returning to v8086 or userspace
335
336 ENTRY(resume_userspace)
337         LOCKDEP_SYS_EXIT
338         DISABLE_INTERRUPTS(CLBR_ANY)    # make sure we don't miss an interrupt
339                                         # setting need_resched or sigpending
340                                         # between sampling and the iret
341         TRACE_IRQS_OFF
342         movl TI_flags(%ebp), %ecx
343         andl $_TIF_WORK_MASK, %ecx      # is there any work to be done on
344                                         # int/exception return?
345         jne work_pending
346         jmp restore_all
347 END(ret_from_exception)
348
349 #ifdef CONFIG_PREEMPT
350 ENTRY(resume_kernel)
351         DISABLE_INTERRUPTS(CLBR_ANY)
352         cmpl $0,TI_preempt_count(%ebp)  # non-zero preempt_count ?
353         jnz restore_all
354 need_resched:
355         movl TI_flags(%ebp), %ecx       # need_resched set ?
356         testb $_TIF_NEED_RESCHED, %cl
357         jz restore_all
358         testl $X86_EFLAGS_IF,PT_EFLAGS(%esp)    # interrupts off (exception path) ?
359         jz restore_all
360         call preempt_schedule_irq
361         jmp need_resched
362 END(resume_kernel)
363 #endif
364         CFI_ENDPROC
365 /*
366  * End of kprobes section
367  */
368         .popsection
369
370 /* SYSENTER_RETURN points to after the "sysenter" instruction in
371    the vsyscall page.  See vsyscall-sysentry.S, which defines the symbol.  */
372
373         # sysenter call handler stub
374 ENTRY(ia32_sysenter_target)
375         CFI_STARTPROC simple
376         CFI_SIGNAL_FRAME
377         CFI_DEF_CFA esp, 0
378         CFI_REGISTER esp, ebp
379         movl TSS_sysenter_sp0(%esp),%esp
380 sysenter_past_esp:
381         /*
382          * Interrupts are disabled here, but we can't trace it until
383          * enough kernel state to call TRACE_IRQS_OFF can be called - but
384          * we immediately enable interrupts at that point anyway.
385          */
386         pushl_cfi $__USER_DS
387         /*CFI_REL_OFFSET ss, 0*/
388         pushl_cfi %ebp
389         CFI_REL_OFFSET esp, 0
390         pushfl_cfi
391         orl $X86_EFLAGS_IF, (%esp)
392         pushl_cfi $__USER_CS
393         /*CFI_REL_OFFSET cs, 0*/
394         /*
395          * Push current_thread_info()->sysenter_return to the stack.
396          * A tiny bit of offset fixup is necessary - 4*4 means the 4 words
397          * pushed above; +8 corresponds to copy_thread's esp0 setting.
398          */
399         pushl_cfi ((TI_sysenter_return)-THREAD_SIZE+8+4*4)(%esp)
400         CFI_REL_OFFSET eip, 0
401
402         pushl_cfi %eax
403         SAVE_ALL
404         ENABLE_INTERRUPTS(CLBR_NONE)
405
406 /*
407  * Load the potential sixth argument from user stack.
408  * Careful about security.
409  */
410         cmpl $__PAGE_OFFSET-3,%ebp
411         jae syscall_fault
412 1:      movl (%ebp),%ebp
413         movl %ebp,PT_EBP(%esp)
414 .section __ex_table,"a"
415         .align 4
416         .long 1b,syscall_fault
417 .previous
418
419         GET_THREAD_INFO(%ebp)
420
421         testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags(%ebp)
422         jnz sysenter_audit
423 sysenter_do_call:
424         cmpl $(NR_syscalls), %eax
425         jae syscall_badsys
426         call *sys_call_table(,%eax,4)
427         movl %eax,PT_EAX(%esp)
428         LOCKDEP_SYS_EXIT
429         DISABLE_INTERRUPTS(CLBR_ANY)
430         TRACE_IRQS_OFF
431         movl TI_flags(%ebp), %ecx
432         testl $_TIF_ALLWORK_MASK, %ecx
433         jne sysexit_audit
434 sysenter_exit:
435 /* if something modifies registers it must also disable sysexit */
436         movl PT_EIP(%esp), %edx
437         movl PT_OLDESP(%esp), %ecx
438         xorl %ebp,%ebp
439         TRACE_IRQS_ON
440 1:      mov  PT_FS(%esp), %fs
441         PTGS_TO_GS
442         ENABLE_INTERRUPTS_SYSEXIT
443
444 #ifdef CONFIG_AUDITSYSCALL
445 sysenter_audit:
446         testl $(_TIF_WORK_SYSCALL_ENTRY & ~_TIF_SYSCALL_AUDIT),TI_flags(%ebp)
447         jnz syscall_trace_entry
448         addl $4,%esp
449         CFI_ADJUST_CFA_OFFSET -4
450         /* %esi already in 8(%esp)         6th arg: 4th syscall arg */
451         /* %edx already in 4(%esp)         5th arg: 3rd syscall arg */
452         /* %ecx already in 0(%esp)         4th arg: 2nd syscall arg */
453         movl %ebx,%ecx                  /* 3rd arg: 1st syscall arg */
454         movl %eax,%edx                  /* 2nd arg: syscall number */
455         movl $AUDIT_ARCH_I386,%eax      /* 1st arg: audit arch */
456         call audit_syscall_entry
457         pushl_cfi %ebx
458         movl PT_EAX(%esp),%eax          /* reload syscall number */
459         jmp sysenter_do_call
460
461 sysexit_audit:
462         testl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT), %ecx
463         jne syscall_exit_work
464         TRACE_IRQS_ON
465         ENABLE_INTERRUPTS(CLBR_ANY)
466         movl %eax,%edx          /* second arg, syscall return value */
467         cmpl $0,%eax            /* is it < 0? */
468         setl %al                /* 1 if so, 0 if not */
469         movzbl %al,%eax         /* zero-extend that */
470         inc %eax /* first arg, 0->1(AUDITSC_SUCCESS), 1->2(AUDITSC_FAILURE) */
471         call audit_syscall_exit
472         DISABLE_INTERRUPTS(CLBR_ANY)
473         TRACE_IRQS_OFF
474         movl TI_flags(%ebp), %ecx
475         testl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT), %ecx
476         jne syscall_exit_work
477         movl PT_EAX(%esp),%eax  /* reload syscall return value */
478         jmp sysenter_exit
479 #endif
480
481         CFI_ENDPROC
482 .pushsection .fixup,"ax"
483 2:      movl $0,PT_FS(%esp)
484         jmp 1b
485 .section __ex_table,"a"
486         .align 4
487         .long 1b,2b
488 .popsection
489         PTGS_TO_GS_EX
490 ENDPROC(ia32_sysenter_target)
491
492 /*
493  * syscall stub including irq exit should be protected against kprobes
494  */
495         .pushsection .kprobes.text, "ax"
496         # system call handler stub
497 ENTRY(system_call)
498         RING0_INT_FRAME                 # can't unwind into user space anyway
499         pushl_cfi %eax                  # save orig_eax
500         SAVE_ALL
501         GET_THREAD_INFO(%ebp)
502                                         # system call tracing in operation / emulation
503         testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags(%ebp)
504         jnz syscall_trace_entry
505         cmpl $(NR_syscalls), %eax
506         jae syscall_badsys
507 syscall_call:
508         call *sys_call_table(,%eax,4)
509         movl %eax,PT_EAX(%esp)          # store the return value
510 syscall_exit:
511         LOCKDEP_SYS_EXIT
512         DISABLE_INTERRUPTS(CLBR_ANY)    # make sure we don't miss an interrupt
513                                         # setting need_resched or sigpending
514                                         # between sampling and the iret
515         TRACE_IRQS_OFF
516         movl TI_flags(%ebp), %ecx
517         testl $_TIF_ALLWORK_MASK, %ecx  # current->work
518         jne syscall_exit_work
519
520 restore_all:
521         TRACE_IRQS_IRET
522 restore_all_notrace:
523         movl PT_EFLAGS(%esp), %eax      # mix EFLAGS, SS and CS
524         # Warning: PT_OLDSS(%esp) contains the wrong/random values if we
525         # are returning to the kernel.
526         # See comments in process.c:copy_thread() for details.
527         movb PT_OLDSS(%esp), %ah
528         movb PT_CS(%esp), %al
529         andl $(X86_EFLAGS_VM | (SEGMENT_TI_MASK << 8) | SEGMENT_RPL_MASK), %eax
530         cmpl $((SEGMENT_LDT << 8) | USER_RPL), %eax
531         CFI_REMEMBER_STATE
532         je ldt_ss                       # returning to user-space with LDT SS
533 restore_nocheck:
534         RESTORE_REGS 4                  # skip orig_eax/error_code
535 irq_return:
536         INTERRUPT_RETURN
537 .section .fixup,"ax"
538 ENTRY(iret_exc)
539         pushl $0                        # no error code
540         pushl $do_iret_error
541         jmp error_code
542 .previous
543 .section __ex_table,"a"
544         .align 4
545         .long irq_return,iret_exc
546 .previous
547
548         CFI_RESTORE_STATE
549 ldt_ss:
550         larl PT_OLDSS(%esp), %eax
551         jnz restore_nocheck
552         testl $0x00400000, %eax         # returning to 32bit stack?
553         jnz restore_nocheck             # allright, normal return
554
555 #ifdef CONFIG_PARAVIRT
556         /*
557          * The kernel can't run on a non-flat stack if paravirt mode
558          * is active.  Rather than try to fixup the high bits of
559          * ESP, bypass this code entirely.  This may break DOSemu
560          * and/or Wine support in a paravirt VM, although the option
561          * is still available to implement the setting of the high
562          * 16-bits in the INTERRUPT_RETURN paravirt-op.
563          */
564         cmpl $0, pv_info+PARAVIRT_enabled
565         jne restore_nocheck
566 #endif
567
568 /*
569  * Setup and switch to ESPFIX stack
570  *
571  * We're returning to userspace with a 16 bit stack. The CPU will not
572  * restore the high word of ESP for us on executing iret... This is an
573  * "official" bug of all the x86-compatible CPUs, which we can work
574  * around to make dosemu and wine happy. We do this by preloading the
575  * high word of ESP with the high word of the userspace ESP while
576  * compensating for the offset by changing to the ESPFIX segment with
577  * a base address that matches for the difference.
578  */
579 #define GDT_ESPFIX_SS PER_CPU_VAR(gdt_page) + (GDT_ENTRY_ESPFIX_SS * 8)
580         mov %esp, %edx                  /* load kernel esp */
581         mov PT_OLDESP(%esp), %eax       /* load userspace esp */
582         mov %dx, %ax                    /* eax: new kernel esp */
583         sub %eax, %edx                  /* offset (low word is 0) */
584         shr $16, %edx
585         mov %dl, GDT_ESPFIX_SS + 4 /* bits 16..23 */
586         mov %dh, GDT_ESPFIX_SS + 7 /* bits 24..31 */
587         pushl_cfi $__ESPFIX_SS
588         pushl_cfi %eax                  /* new kernel esp */
589         /* Disable interrupts, but do not irqtrace this section: we
590          * will soon execute iret and the tracer was already set to
591          * the irqstate after the iret */
592         DISABLE_INTERRUPTS(CLBR_EAX)
593         lss (%esp), %esp                /* switch to espfix segment */
594         CFI_ADJUST_CFA_OFFSET -8
595         jmp restore_nocheck
596         CFI_ENDPROC
597 ENDPROC(system_call)
598
599         # perform work that needs to be done immediately before resumption
600         ALIGN
601         RING0_PTREGS_FRAME              # can't unwind into user space anyway
602 work_pending:
603         testb $_TIF_NEED_RESCHED, %cl
604         jz work_notifysig
605 work_resched:
606         call schedule
607         LOCKDEP_SYS_EXIT
608         DISABLE_INTERRUPTS(CLBR_ANY)    # make sure we don't miss an interrupt
609                                         # setting need_resched or sigpending
610                                         # between sampling and the iret
611         TRACE_IRQS_OFF
612         movl TI_flags(%ebp), %ecx
613         andl $_TIF_WORK_MASK, %ecx      # is there any work to be done other
614                                         # than syscall tracing?
615         jz restore_all
616         testb $_TIF_NEED_RESCHED, %cl
617         jnz work_resched
618
619 work_notifysig:                         # deal with pending signals and
620                                         # notify-resume requests
621 #ifdef CONFIG_VM86
622         testl $X86_EFLAGS_VM, PT_EFLAGS(%esp)
623         movl %esp, %eax
624         jne work_notifysig_v86          # returning to kernel-space or
625                                         # vm86-space
626         xorl %edx, %edx
627         call do_notify_resume
628         jmp resume_userspace_sig
629
630         ALIGN
631 work_notifysig_v86:
632         pushl_cfi %ecx                  # save ti_flags for do_notify_resume
633         call save_v86_state             # %eax contains pt_regs pointer
634         popl_cfi %ecx
635         movl %eax, %esp
636 #else
637         movl %esp, %eax
638 #endif
639         xorl %edx, %edx
640         call do_notify_resume
641         jmp resume_userspace_sig
642 END(work_pending)
643
644         # perform syscall exit tracing
645         ALIGN
646 syscall_trace_entry:
647         movl $-ENOSYS,PT_EAX(%esp)
648         movl %esp, %eax
649         call syscall_trace_enter
650         /* What it returned is what we'll actually use.  */
651         cmpl $(NR_syscalls), %eax
652         jnae syscall_call
653         jmp syscall_exit
654 END(syscall_trace_entry)
655
656         # perform syscall exit tracing
657         ALIGN
658 syscall_exit_work:
659         testl $_TIF_WORK_SYSCALL_EXIT, %ecx
660         jz work_pending
661         TRACE_IRQS_ON
662         ENABLE_INTERRUPTS(CLBR_ANY)     # could let syscall_trace_leave() call
663                                         # schedule() instead
664         movl %esp, %eax
665         call syscall_trace_leave
666         jmp resume_userspace
667 END(syscall_exit_work)
668         CFI_ENDPROC
669
670         RING0_INT_FRAME                 # can't unwind into user space anyway
671 syscall_fault:
672         GET_THREAD_INFO(%ebp)
673         movl $-EFAULT,PT_EAX(%esp)
674         jmp resume_userspace
675 END(syscall_fault)
676
677 syscall_badsys:
678         movl $-ENOSYS,PT_EAX(%esp)
679         jmp resume_userspace
680 END(syscall_badsys)
681         CFI_ENDPROC
682 /*
683  * End of kprobes section
684  */
685         .popsection
686
687 /*
688  * System calls that need a pt_regs pointer.
689  */
690 #define PTREGSCALL0(name) \
691 ENTRY(ptregs_##name) ;  \
692         leal 4(%esp),%eax; \
693         jmp sys_##name; \
694 ENDPROC(ptregs_##name)
695
696 #define PTREGSCALL1(name) \
697 ENTRY(ptregs_##name) ; \
698         leal 4(%esp),%edx; \
699         movl (PT_EBX+4)(%esp),%eax; \
700         jmp sys_##name; \
701 ENDPROC(ptregs_##name)
702
703 #define PTREGSCALL2(name) \
704 ENTRY(ptregs_##name) ; \
705         leal 4(%esp),%ecx; \
706         movl (PT_ECX+4)(%esp),%edx; \
707         movl (PT_EBX+4)(%esp),%eax; \
708         jmp sys_##name; \
709 ENDPROC(ptregs_##name)
710
711 #define PTREGSCALL3(name) \
712 ENTRY(ptregs_##name) ; \
713         CFI_STARTPROC; \
714         leal 4(%esp),%eax; \
715         pushl_cfi %eax; \
716         movl PT_EDX(%eax),%ecx; \
717         movl PT_ECX(%eax),%edx; \
718         movl PT_EBX(%eax),%eax; \
719         call sys_##name; \
720         addl $4,%esp; \
721         CFI_ADJUST_CFA_OFFSET -4; \
722         ret; \
723         CFI_ENDPROC; \
724 ENDPROC(ptregs_##name)
725
726 PTREGSCALL1(iopl)
727 PTREGSCALL0(fork)
728 PTREGSCALL0(vfork)
729 PTREGSCALL3(execve)
730 PTREGSCALL2(sigaltstack)
731 PTREGSCALL0(sigreturn)
732 PTREGSCALL0(rt_sigreturn)
733 PTREGSCALL2(vm86)
734 PTREGSCALL1(vm86old)
735
736 /* Clone is an oddball.  The 4th arg is in %edi */
737 ENTRY(ptregs_clone)
738         CFI_STARTPROC
739         leal 4(%esp),%eax
740         pushl_cfi %eax
741         pushl_cfi PT_EDI(%eax)
742         movl PT_EDX(%eax),%ecx
743         movl PT_ECX(%eax),%edx
744         movl PT_EBX(%eax),%eax
745         call sys_clone
746         addl $8,%esp
747         CFI_ADJUST_CFA_OFFSET -8
748         ret
749         CFI_ENDPROC
750 ENDPROC(ptregs_clone)
751
752 .macro FIXUP_ESPFIX_STACK
753 /*
754  * Switch back for ESPFIX stack to the normal zerobased stack
755  *
756  * We can't call C functions using the ESPFIX stack. This code reads
757  * the high word of the segment base from the GDT and swiches to the
758  * normal stack and adjusts ESP with the matching offset.
759  */
760         /* fixup the stack */
761         mov GDT_ESPFIX_SS + 4, %al /* bits 16..23 */
762         mov GDT_ESPFIX_SS + 7, %ah /* bits 24..31 */
763         shl $16, %eax
764         addl %esp, %eax                 /* the adjusted stack pointer */
765         pushl_cfi $__KERNEL_DS
766         pushl_cfi %eax
767         lss (%esp), %esp                /* switch to the normal stack segment */
768         CFI_ADJUST_CFA_OFFSET -8
769 .endm
770 .macro UNWIND_ESPFIX_STACK
771         movl %ss, %eax
772         /* see if on espfix stack */
773         cmpw $__ESPFIX_SS, %ax
774         jne 27f
775         movl $__KERNEL_DS, %eax
776         movl %eax, %ds
777         movl %eax, %es
778         /* switch to normal stack */
779         FIXUP_ESPFIX_STACK
780 27:
781 .endm
782
783 /*
784  * Build the entry stubs and pointer table with some assembler magic.
785  * We pack 7 stubs into a single 32-byte chunk, which will fit in a
786  * single cache line on all modern x86 implementations.
787  */
788 .section .init.rodata,"a"
789 ENTRY(interrupt)
790 .section .entry.text, "ax"
791         .p2align 5
792         .p2align CONFIG_X86_L1_CACHE_SHIFT
793 ENTRY(irq_entries_start)
794         RING0_INT_FRAME
795 vector=FIRST_EXTERNAL_VECTOR
796 .rept (NR_VECTORS-FIRST_EXTERNAL_VECTOR+6)/7
797         .balign 32
798   .rept 7
799     .if vector < NR_VECTORS
800       .if vector <> FIRST_EXTERNAL_VECTOR
801         CFI_ADJUST_CFA_OFFSET -4
802       .endif
803 1:      pushl_cfi $(~vector+0x80)       /* Note: always in signed byte range */
804       .if ((vector-FIRST_EXTERNAL_VECTOR)%7) <> 6
805         jmp 2f
806       .endif
807       .previous
808         .long 1b
809       .section .entry.text, "ax"
810 vector=vector+1
811     .endif
812   .endr
813 2:      jmp common_interrupt
814 .endr
815 END(irq_entries_start)
816
817 .previous
818 END(interrupt)
819 .previous
820
821 /*
822  * the CPU automatically disables interrupts when executing an IRQ vector,
823  * so IRQ-flags tracing has to follow that:
824  */
825         .p2align CONFIG_X86_L1_CACHE_SHIFT
826 common_interrupt:
827         addl $-0x80,(%esp)      /* Adjust vector into the [-256,-1] range */
828         SAVE_ALL
829         TRACE_IRQS_OFF
830         movl %esp,%eax
831         call do_IRQ
832         jmp ret_from_intr
833 ENDPROC(common_interrupt)
834         CFI_ENDPROC
835
836 /*
837  *  Irq entries should be protected against kprobes
838  */
839         .pushsection .kprobes.text, "ax"
840 #define BUILD_INTERRUPT3(name, nr, fn)  \
841 ENTRY(name)                             \
842         RING0_INT_FRAME;                \
843         pushl_cfi $~(nr);               \
844         SAVE_ALL;                       \
845         TRACE_IRQS_OFF                  \
846         movl %esp,%eax;                 \
847         call fn;                        \
848         jmp ret_from_intr;              \
849         CFI_ENDPROC;                    \
850 ENDPROC(name)
851
852 #define BUILD_INTERRUPT(name, nr)       BUILD_INTERRUPT3(name, nr, smp_##name)
853
854 /* The include is where all of the SMP etc. interrupts come from */
855 #include <asm/entry_arch.h>
856
857 ENTRY(coprocessor_error)
858         RING0_INT_FRAME
859         pushl_cfi $0
860         pushl_cfi $do_coprocessor_error
861         jmp error_code
862         CFI_ENDPROC
863 END(coprocessor_error)
864
865 ENTRY(simd_coprocessor_error)
866         RING0_INT_FRAME
867         pushl_cfi $0
868 #ifdef CONFIG_X86_INVD_BUG
869         /* AMD 486 bug: invd from userspace calls exception 19 instead of #GP */
870 661:    pushl_cfi $do_general_protection
871 662:
872 .section .altinstructions,"a"
873         altinstruction_entry 661b, 663f, X86_FEATURE_XMM, 662b-661b, 664f-663f
874 .previous
875 .section .altinstr_replacement,"ax"
876 663:    pushl $do_simd_coprocessor_error
877 664:
878 .previous
879 #else
880         pushl_cfi $do_simd_coprocessor_error
881 #endif
882         jmp error_code
883         CFI_ENDPROC
884 END(simd_coprocessor_error)
885
886 ENTRY(device_not_available)
887         RING0_INT_FRAME
888         pushl_cfi $-1                   # mark this as an int
889         pushl_cfi $do_device_not_available
890         jmp error_code
891         CFI_ENDPROC
892 END(device_not_available)
893
894 #ifdef CONFIG_PARAVIRT
895 ENTRY(native_iret)
896         iret
897 .section __ex_table,"a"
898         .align 4
899         .long native_iret, iret_exc
900 .previous
901 END(native_iret)
902
903 ENTRY(native_irq_enable_sysexit)
904         sti
905         sysexit
906 END(native_irq_enable_sysexit)
907 #endif
908
909 ENTRY(overflow)
910         RING0_INT_FRAME
911         pushl_cfi $0
912         pushl_cfi $do_overflow
913         jmp error_code
914         CFI_ENDPROC
915 END(overflow)
916
917 ENTRY(bounds)
918         RING0_INT_FRAME
919         pushl_cfi $0
920         pushl_cfi $do_bounds
921         jmp error_code
922         CFI_ENDPROC
923 END(bounds)
924
925 ENTRY(invalid_op)
926         RING0_INT_FRAME
927         pushl_cfi $0
928         pushl_cfi $do_invalid_op
929         jmp error_code
930         CFI_ENDPROC
931 END(invalid_op)
932
933 ENTRY(coprocessor_segment_overrun)
934         RING0_INT_FRAME
935         pushl_cfi $0
936         pushl_cfi $do_coprocessor_segment_overrun
937         jmp error_code
938         CFI_ENDPROC
939 END(coprocessor_segment_overrun)
940
941 ENTRY(invalid_TSS)
942         RING0_EC_FRAME
943         pushl_cfi $do_invalid_TSS
944         jmp error_code
945         CFI_ENDPROC
946 END(invalid_TSS)
947
948 ENTRY(segment_not_present)
949         RING0_EC_FRAME
950         pushl_cfi $do_segment_not_present
951         jmp error_code
952         CFI_ENDPROC
953 END(segment_not_present)
954
955 ENTRY(stack_segment)
956         RING0_EC_FRAME
957         pushl_cfi $do_stack_segment
958         jmp error_code
959         CFI_ENDPROC
960 END(stack_segment)
961
962 ENTRY(alignment_check)
963         RING0_EC_FRAME
964         pushl_cfi $do_alignment_check
965         jmp error_code
966         CFI_ENDPROC
967 END(alignment_check)
968
969 ENTRY(divide_error)
970         RING0_INT_FRAME
971         pushl_cfi $0                    # no error code
972         pushl_cfi $do_divide_error
973         jmp error_code
974         CFI_ENDPROC
975 END(divide_error)
976
977 #ifdef CONFIG_X86_MCE
978 ENTRY(machine_check)
979         RING0_INT_FRAME
980         pushl_cfi $0
981         pushl_cfi machine_check_vector
982         jmp error_code
983         CFI_ENDPROC
984 END(machine_check)
985 #endif
986
987 ENTRY(spurious_interrupt_bug)
988         RING0_INT_FRAME
989         pushl_cfi $0
990         pushl_cfi $do_spurious_interrupt_bug
991         jmp error_code
992         CFI_ENDPROC
993 END(spurious_interrupt_bug)
994 /*
995  * End of kprobes section
996  */
997         .popsection
998
999 ENTRY(kernel_thread_helper)
1000         pushl $0                # fake return address for unwinder
1001         CFI_STARTPROC
1002         movl %edi,%eax
1003         call *%esi
1004         call do_exit
1005         ud2                     # padding for call trace
1006         CFI_ENDPROC
1007 ENDPROC(kernel_thread_helper)
1008
1009 #ifdef CONFIG_XEN
1010 /* Xen doesn't set %esp to be precisely what the normal sysenter
1011    entrypoint expects, so fix it up before using the normal path. */
1012 ENTRY(xen_sysenter_target)
1013         RING0_INT_FRAME
1014         addl $5*4, %esp         /* remove xen-provided frame */
1015         CFI_ADJUST_CFA_OFFSET -5*4
1016         jmp sysenter_past_esp
1017         CFI_ENDPROC
1018
1019 ENTRY(xen_hypervisor_callback)
1020         CFI_STARTPROC
1021         pushl_cfi $0
1022         SAVE_ALL
1023         TRACE_IRQS_OFF
1024
1025         /* Check to see if we got the event in the critical
1026            region in xen_iret_direct, after we've reenabled
1027            events and checked for pending events.  This simulates
1028            iret instruction's behaviour where it delivers a
1029            pending interrupt when enabling interrupts. */
1030         movl PT_EIP(%esp),%eax
1031         cmpl $xen_iret_start_crit,%eax
1032         jb   1f
1033         cmpl $xen_iret_end_crit,%eax
1034         jae  1f
1035
1036         jmp  xen_iret_crit_fixup
1037
1038 ENTRY(xen_do_upcall)
1039 1:      mov %esp, %eax
1040         call xen_evtchn_do_upcall
1041         jmp  ret_from_intr
1042         CFI_ENDPROC
1043 ENDPROC(xen_hypervisor_callback)
1044
1045 # Hypervisor uses this for application faults while it executes.
1046 # We get here for two reasons:
1047 #  1. Fault while reloading DS, ES, FS or GS
1048 #  2. Fault while executing IRET
1049 # Category 1 we fix up by reattempting the load, and zeroing the segment
1050 # register if the load fails.
1051 # Category 2 we fix up by jumping to do_iret_error. We cannot use the
1052 # normal Linux return path in this case because if we use the IRET hypercall
1053 # to pop the stack frame we end up in an infinite loop of failsafe callbacks.
1054 # We distinguish between categories by maintaining a status value in EAX.
1055 ENTRY(xen_failsafe_callback)
1056         CFI_STARTPROC
1057         pushl_cfi %eax
1058         movl $1,%eax
1059 1:      mov 4(%esp),%ds
1060 2:      mov 8(%esp),%es
1061 3:      mov 12(%esp),%fs
1062 4:      mov 16(%esp),%gs
1063         testl %eax,%eax
1064         popl_cfi %eax
1065         lea 16(%esp),%esp
1066         CFI_ADJUST_CFA_OFFSET -16
1067         jz 5f
1068         addl $16,%esp
1069         jmp iret_exc            # EAX != 0 => Category 2 (Bad IRET)
1070 5:      pushl_cfi $0            # EAX == 0 => Category 1 (Bad segment)
1071         SAVE_ALL
1072         jmp ret_from_exception
1073         CFI_ENDPROC
1074
1075 .section .fixup,"ax"
1076 6:      xorl %eax,%eax
1077         movl %eax,4(%esp)
1078         jmp 1b
1079 7:      xorl %eax,%eax
1080         movl %eax,8(%esp)
1081         jmp 2b
1082 8:      xorl %eax,%eax
1083         movl %eax,12(%esp)
1084         jmp 3b
1085 9:      xorl %eax,%eax
1086         movl %eax,16(%esp)
1087         jmp 4b
1088 .previous
1089 .section __ex_table,"a"
1090         .align 4
1091         .long 1b,6b
1092         .long 2b,7b
1093         .long 3b,8b
1094         .long 4b,9b
1095 .previous
1096 ENDPROC(xen_failsafe_callback)
1097
1098 BUILD_INTERRUPT3(xen_hvm_callback_vector, XEN_HVM_EVTCHN_CALLBACK,
1099                 xen_evtchn_do_upcall)
1100
1101 #endif  /* CONFIG_XEN */
1102
1103 #ifdef CONFIG_FUNCTION_TRACER
1104 #ifdef CONFIG_DYNAMIC_FTRACE
1105
1106 ENTRY(mcount)
1107         ret
1108 END(mcount)
1109
1110 ENTRY(ftrace_caller)
1111         cmpl $0, function_trace_stop
1112         jne  ftrace_stub
1113
1114         pushl %eax
1115         pushl %ecx
1116         pushl %edx
1117         movl 0xc(%esp), %eax
1118         movl 0x4(%ebp), %edx
1119         subl $MCOUNT_INSN_SIZE, %eax
1120
1121 .globl ftrace_call
1122 ftrace_call:
1123         call ftrace_stub
1124
1125         popl %edx
1126         popl %ecx
1127         popl %eax
1128 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
1129 .globl ftrace_graph_call
1130 ftrace_graph_call:
1131         jmp ftrace_stub
1132 #endif
1133
1134 .globl ftrace_stub
1135 ftrace_stub:
1136         ret
1137 END(ftrace_caller)
1138
1139 #else /* ! CONFIG_DYNAMIC_FTRACE */
1140
1141 ENTRY(mcount)
1142         cmpl $0, function_trace_stop
1143         jne  ftrace_stub
1144
1145         cmpl $ftrace_stub, ftrace_trace_function
1146         jnz trace
1147 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
1148         cmpl $ftrace_stub, ftrace_graph_return
1149         jnz ftrace_graph_caller
1150
1151         cmpl $ftrace_graph_entry_stub, ftrace_graph_entry
1152         jnz ftrace_graph_caller
1153 #endif
1154 .globl ftrace_stub
1155 ftrace_stub:
1156         ret
1157
1158         /* taken from glibc */
1159 trace:
1160         pushl %eax
1161         pushl %ecx
1162         pushl %edx
1163         movl 0xc(%esp), %eax
1164         movl 0x4(%ebp), %edx
1165         subl $MCOUNT_INSN_SIZE, %eax
1166
1167         call *ftrace_trace_function
1168
1169         popl %edx
1170         popl %ecx
1171         popl %eax
1172         jmp ftrace_stub
1173 END(mcount)
1174 #endif /* CONFIG_DYNAMIC_FTRACE */
1175 #endif /* CONFIG_FUNCTION_TRACER */
1176
1177 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
1178 ENTRY(ftrace_graph_caller)
1179         cmpl $0, function_trace_stop
1180         jne ftrace_stub
1181
1182         pushl %eax
1183         pushl %ecx
1184         pushl %edx
1185         movl 0xc(%esp), %edx
1186         lea 0x4(%ebp), %eax
1187         movl (%ebp), %ecx
1188         subl $MCOUNT_INSN_SIZE, %edx
1189         call prepare_ftrace_return
1190         popl %edx
1191         popl %ecx
1192         popl %eax
1193         ret
1194 END(ftrace_graph_caller)
1195
1196 .globl return_to_handler
1197 return_to_handler:
1198         pushl %eax
1199         pushl %edx
1200         movl %ebp, %eax
1201         call ftrace_return_to_handler
1202         movl %eax, %ecx
1203         popl %edx
1204         popl %eax
1205         jmp *%ecx
1206 #endif
1207
1208 /*
1209  * Some functions should be protected against kprobes
1210  */
1211         .pushsection .kprobes.text, "ax"
1212
1213 ENTRY(page_fault)
1214         RING0_EC_FRAME
1215         pushl_cfi $do_page_fault
1216         ALIGN
1217 error_code:
1218         /* the function address is in %gs's slot on the stack */
1219         pushl_cfi %fs
1220         /*CFI_REL_OFFSET fs, 0*/
1221         pushl_cfi %es
1222         /*CFI_REL_OFFSET es, 0*/
1223         pushl_cfi %ds
1224         /*CFI_REL_OFFSET ds, 0*/
1225         pushl_cfi %eax
1226         CFI_REL_OFFSET eax, 0
1227         pushl_cfi %ebp
1228         CFI_REL_OFFSET ebp, 0
1229         pushl_cfi %edi
1230         CFI_REL_OFFSET edi, 0
1231         pushl_cfi %esi
1232         CFI_REL_OFFSET esi, 0
1233         pushl_cfi %edx
1234         CFI_REL_OFFSET edx, 0
1235         pushl_cfi %ecx
1236         CFI_REL_OFFSET ecx, 0
1237         pushl_cfi %ebx
1238         CFI_REL_OFFSET ebx, 0
1239         cld
1240         movl $(__KERNEL_PERCPU), %ecx
1241         movl %ecx, %fs
1242         UNWIND_ESPFIX_STACK
1243         GS_TO_REG %ecx
1244         movl PT_GS(%esp), %edi          # get the function address
1245         movl PT_ORIG_EAX(%esp), %edx    # get the error code
1246         movl $-1, PT_ORIG_EAX(%esp)     # no syscall to restart
1247         REG_TO_PTGS %ecx
1248         SET_KERNEL_GS %ecx
1249         movl $(__USER_DS), %ecx
1250         movl %ecx, %ds
1251         movl %ecx, %es
1252         TRACE_IRQS_OFF
1253         movl %esp,%eax                  # pt_regs pointer
1254         call *%edi
1255         jmp ret_from_exception
1256         CFI_ENDPROC
1257 END(page_fault)
1258
1259 /*
1260  * Debug traps and NMI can happen at the one SYSENTER instruction
1261  * that sets up the real kernel stack. Check here, since we can't
1262  * allow the wrong stack to be used.
1263  *
1264  * "TSS_sysenter_sp0+12" is because the NMI/debug handler will have
1265  * already pushed 3 words if it hits on the sysenter instruction:
1266  * eflags, cs and eip.
1267  *
1268  * We just load the right stack, and push the three (known) values
1269  * by hand onto the new stack - while updating the return eip past
1270  * the instruction that would have done it for sysenter.
1271  */
1272 .macro FIX_STACK offset ok label
1273         cmpw $__KERNEL_CS, 4(%esp)
1274         jne \ok
1275 \label:
1276         movl TSS_sysenter_sp0 + \offset(%esp), %esp
1277         CFI_DEF_CFA esp, 0
1278         CFI_UNDEFINED eip
1279         pushfl_cfi
1280         pushl_cfi $__KERNEL_CS
1281         pushl_cfi $sysenter_past_esp
1282         CFI_REL_OFFSET eip, 0
1283 .endm
1284
1285 ENTRY(debug)
1286         RING0_INT_FRAME
1287         cmpl $ia32_sysenter_target,(%esp)
1288         jne debug_stack_correct
1289         FIX_STACK 12, debug_stack_correct, debug_esp_fix_insn
1290 debug_stack_correct:
1291         pushl_cfi $-1                   # mark this as an int
1292         SAVE_ALL
1293         TRACE_IRQS_OFF
1294         xorl %edx,%edx                  # error code 0
1295         movl %esp,%eax                  # pt_regs pointer
1296         call do_debug
1297         jmp ret_from_exception
1298         CFI_ENDPROC
1299 END(debug)
1300
1301 /*
1302  * NMI is doubly nasty. It can happen _while_ we're handling
1303  * a debug fault, and the debug fault hasn't yet been able to
1304  * clear up the stack. So we first check whether we got  an
1305  * NMI on the sysenter entry path, but after that we need to
1306  * check whether we got an NMI on the debug path where the debug
1307  * fault happened on the sysenter path.
1308  */
1309 ENTRY(nmi)
1310         RING0_INT_FRAME
1311         pushl_cfi %eax
1312         movl %ss, %eax
1313         cmpw $__ESPFIX_SS, %ax
1314         popl_cfi %eax
1315         je nmi_espfix_stack
1316         cmpl $ia32_sysenter_target,(%esp)
1317         je nmi_stack_fixup
1318         pushl_cfi %eax
1319         movl %esp,%eax
1320         /* Do not access memory above the end of our stack page,
1321          * it might not exist.
1322          */
1323         andl $(THREAD_SIZE-1),%eax
1324         cmpl $(THREAD_SIZE-20),%eax
1325         popl_cfi %eax
1326         jae nmi_stack_correct
1327         cmpl $ia32_sysenter_target,12(%esp)
1328         je nmi_debug_stack_check
1329 nmi_stack_correct:
1330         /* We have a RING0_INT_FRAME here */
1331         pushl_cfi %eax
1332         SAVE_ALL
1333         xorl %edx,%edx          # zero error code
1334         movl %esp,%eax          # pt_regs pointer
1335         call do_nmi
1336         jmp restore_all_notrace
1337         CFI_ENDPROC
1338
1339 nmi_stack_fixup:
1340         RING0_INT_FRAME
1341         FIX_STACK 12, nmi_stack_correct, 1
1342         jmp nmi_stack_correct
1343
1344 nmi_debug_stack_check:
1345         /* We have a RING0_INT_FRAME here */
1346         cmpw $__KERNEL_CS,16(%esp)
1347         jne nmi_stack_correct
1348         cmpl $debug,(%esp)
1349         jb nmi_stack_correct
1350         cmpl $debug_esp_fix_insn,(%esp)
1351         ja nmi_stack_correct
1352         FIX_STACK 24, nmi_stack_correct, 1
1353         jmp nmi_stack_correct
1354
1355 nmi_espfix_stack:
1356         /* We have a RING0_INT_FRAME here.
1357          *
1358          * create the pointer to lss back
1359          */
1360         pushl_cfi %ss
1361         pushl_cfi %esp
1362         addl $4, (%esp)
1363         /* copy the iret frame of 12 bytes */
1364         .rept 3
1365         pushl_cfi 16(%esp)
1366         .endr
1367         pushl_cfi %eax
1368         SAVE_ALL
1369         FIXUP_ESPFIX_STACK              # %eax == %esp
1370         xorl %edx,%edx                  # zero error code
1371         call do_nmi
1372         RESTORE_REGS
1373         lss 12+4(%esp), %esp            # back to espfix stack
1374         CFI_ADJUST_CFA_OFFSET -24
1375         jmp irq_return
1376         CFI_ENDPROC
1377 END(nmi)
1378
1379 ENTRY(int3)
1380         RING0_INT_FRAME
1381         pushl_cfi $-1                   # mark this as an int
1382         SAVE_ALL
1383         TRACE_IRQS_OFF
1384         xorl %edx,%edx          # zero error code
1385         movl %esp,%eax          # pt_regs pointer
1386         call do_int3
1387         jmp ret_from_exception
1388         CFI_ENDPROC
1389 END(int3)
1390
1391 ENTRY(general_protection)
1392         RING0_EC_FRAME
1393         pushl_cfi $do_general_protection
1394         jmp error_code
1395         CFI_ENDPROC
1396 END(general_protection)
1397
1398 #ifdef CONFIG_KVM_GUEST
1399 ENTRY(async_page_fault)
1400         RING0_EC_FRAME
1401         pushl_cfi $do_async_page_fault
1402         jmp error_code
1403         CFI_ENDPROC
1404 END(async_page_fault)
1405 #endif
1406
1407 /*
1408  * End of kprobes section
1409  */
1410         .popsection