KVM: PPC: Book3S HV: Make secondary threads more robust against stray IPIs
[linux-3.10.git] / arch / powerpc / kvm / book3s_hv_rmhandlers.S
1 /*
2  * This program is free software; you can redistribute it and/or modify
3  * it under the terms of the GNU General Public License, version 2, as
4  * published by the Free Software Foundation.
5  *
6  * This program is distributed in the hope that it will be useful,
7  * but WITHOUT ANY WARRANTY; without even the implied warranty of
8  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
9  * GNU General Public License for more details.
10  *
11  * Copyright 2011 Paul Mackerras, IBM Corp. <paulus@au1.ibm.com>
12  *
13  * Derived from book3s_rmhandlers.S and other files, which are:
14  *
15  * Copyright SUSE Linux Products GmbH 2009
16  *
17  * Authors: Alexander Graf <agraf@suse.de>
18  */
19
20 #include <asm/ppc_asm.h>
21 #include <asm/kvm_asm.h>
22 #include <asm/reg.h>
23 #include <asm/mmu.h>
24 #include <asm/page.h>
25 #include <asm/ptrace.h>
26 #include <asm/hvcall.h>
27 #include <asm/asm-offsets.h>
28 #include <asm/exception-64s.h>
29 #include <asm/kvm_book3s_asm.h>
30
31 /*****************************************************************************
32  *                                                                           *
33  *        Real Mode handlers that need to be in the linear mapping           *
34  *                                                                           *
35  ****************************************************************************/
36
37         .globl  kvmppc_skip_interrupt
38 kvmppc_skip_interrupt:
39         mfspr   r13,SPRN_SRR0
40         addi    r13,r13,4
41         mtspr   SPRN_SRR0,r13
42         GET_SCRATCH0(r13)
43         rfid
44         b       .
45
46         .globl  kvmppc_skip_Hinterrupt
47 kvmppc_skip_Hinterrupt:
48         mfspr   r13,SPRN_HSRR0
49         addi    r13,r13,4
50         mtspr   SPRN_HSRR0,r13
51         GET_SCRATCH0(r13)
52         hrfid
53         b       .
54
55 /*
56  * Call kvmppc_hv_entry in real mode.
57  * Must be called with interrupts hard-disabled.
58  *
59  * Input Registers:
60  *
61  * LR = return address to continue at after eventually re-enabling MMU
62  */
63 _GLOBAL(kvmppc_hv_entry_trampoline)
64         mfmsr   r10
65         LOAD_REG_ADDR(r5, kvmppc_hv_entry)
66         li      r0,MSR_RI
67         andc    r0,r10,r0
68         li      r6,MSR_IR | MSR_DR
69         andc    r6,r10,r6
70         mtmsrd  r0,1            /* clear RI in MSR */
71         mtsrr0  r5
72         mtsrr1  r6
73         RFI
74
75 #define ULONG_SIZE              8
76 #define VCPU_GPR(n)             (VCPU_GPRS + (n * ULONG_SIZE))
77
78 /******************************************************************************
79  *                                                                            *
80  *                               Entry code                                   *
81  *                                                                            *
82  *****************************************************************************/
83
84 #define XICS_XIRR               4
85 #define XICS_QIRR               0xc
86 #define XICS_IPI                2       /* interrupt source # for IPIs */
87
88 /*
89  * We come in here when wakened from nap mode on a secondary hw thread.
90  * Relocation is off and most register values are lost.
91  * r13 points to the PACA.
92  */
93         .globl  kvm_start_guest
94 kvm_start_guest:
95         ld      r1,PACAEMERGSP(r13)
96         subi    r1,r1,STACK_FRAME_OVERHEAD
97         ld      r2,PACATOC(r13)
98
99         li      r0,KVM_HWTHREAD_IN_KVM
100         stb     r0,HSTATE_HWTHREAD_STATE(r13)
101
102         /* NV GPR values from power7_idle() will no longer be valid */
103         li      r0,1
104         stb     r0,PACA_NAPSTATELOST(r13)
105
106         /* get vcpu pointer, NULL if we have no vcpu to run */
107         ld      r4,HSTATE_KVM_VCPU(r13)
108         cmpdi   cr1,r4,0
109
110         /* Check the wake reason in SRR1 to see why we got here */
111         mfspr   r3,SPRN_SRR1
112         rlwinm  r3,r3,44-31,0x7         /* extract wake reason field */
113         cmpwi   r3,4                    /* was it an external interrupt? */
114         bne     27f
115
116         /*
117          * External interrupt - for now assume it is an IPI, since we
118          * should never get any other interrupts sent to offline threads.
119          * Only do this for secondary threads.
120          */
121         beq     cr1,25f
122         lwz     r3,VCPU_PTID(r4)
123         cmpwi   r3,0
124         beq     27f
125 25:     ld      r5,HSTATE_XICS_PHYS(r13)
126         li      r0,0xff
127         li      r6,XICS_QIRR
128         li      r7,XICS_XIRR
129         lwzcix  r8,r5,r7                /* get and ack the interrupt */
130         sync
131         clrldi. r9,r8,40                /* get interrupt source ID. */
132         beq     27f                     /* none there? */
133         cmpwi   r9,XICS_IPI
134         bne     26f
135         stbcix  r0,r5,r6                /* clear IPI */
136 26:     stwcix  r8,r5,r7                /* EOI the interrupt */
137
138 27:     /* XXX should handle hypervisor maintenance interrupts etc. here */
139
140         /* if we have no vcpu to run, go back to sleep */
141         beq     cr1,kvm_no_guest
142
143         /* were we napping due to cede? */
144         lbz     r0,HSTATE_NAPPING(r13)
145         cmpwi   r0,0
146         bne     kvm_end_cede
147
148 .global kvmppc_hv_entry
149 kvmppc_hv_entry:
150
151         /* Required state:
152          *
153          * R4 = vcpu pointer
154          * MSR = ~IR|DR
155          * R13 = PACA
156          * R1 = host R1
157          * all other volatile GPRS = free
158          */
159         mflr    r0
160         std     r0, HSTATE_VMHANDLER(r13)
161
162         ld      r14, VCPU_GPR(r14)(r4)
163         ld      r15, VCPU_GPR(r15)(r4)
164         ld      r16, VCPU_GPR(r16)(r4)
165         ld      r17, VCPU_GPR(r17)(r4)
166         ld      r18, VCPU_GPR(r18)(r4)
167         ld      r19, VCPU_GPR(r19)(r4)
168         ld      r20, VCPU_GPR(r20)(r4)
169         ld      r21, VCPU_GPR(r21)(r4)
170         ld      r22, VCPU_GPR(r22)(r4)
171         ld      r23, VCPU_GPR(r23)(r4)
172         ld      r24, VCPU_GPR(r24)(r4)
173         ld      r25, VCPU_GPR(r25)(r4)
174         ld      r26, VCPU_GPR(r26)(r4)
175         ld      r27, VCPU_GPR(r27)(r4)
176         ld      r28, VCPU_GPR(r28)(r4)
177         ld      r29, VCPU_GPR(r29)(r4)
178         ld      r30, VCPU_GPR(r30)(r4)
179         ld      r31, VCPU_GPR(r31)(r4)
180
181         /* Load guest PMU registers */
182         /* R4 is live here (vcpu pointer) */
183         li      r3, 1
184         sldi    r3, r3, 31              /* MMCR0_FC (freeze counters) bit */
185         mtspr   SPRN_MMCR0, r3          /* freeze all counters, disable ints */
186         isync
187         lwz     r3, VCPU_PMC(r4)        /* always load up guest PMU registers */
188         lwz     r5, VCPU_PMC + 4(r4)    /* to prevent information leak */
189         lwz     r6, VCPU_PMC + 8(r4)
190         lwz     r7, VCPU_PMC + 12(r4)
191         lwz     r8, VCPU_PMC + 16(r4)
192         lwz     r9, VCPU_PMC + 20(r4)
193 BEGIN_FTR_SECTION
194         lwz     r10, VCPU_PMC + 24(r4)
195         lwz     r11, VCPU_PMC + 28(r4)
196 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_201)
197         mtspr   SPRN_PMC1, r3
198         mtspr   SPRN_PMC2, r5
199         mtspr   SPRN_PMC3, r6
200         mtspr   SPRN_PMC4, r7
201         mtspr   SPRN_PMC5, r8
202         mtspr   SPRN_PMC6, r9
203 BEGIN_FTR_SECTION
204         mtspr   SPRN_PMC7, r10
205         mtspr   SPRN_PMC8, r11
206 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_201)
207         ld      r3, VCPU_MMCR(r4)
208         ld      r5, VCPU_MMCR + 8(r4)
209         ld      r6, VCPU_MMCR + 16(r4)
210         mtspr   SPRN_MMCR1, r5
211         mtspr   SPRN_MMCRA, r6
212         mtspr   SPRN_MMCR0, r3
213         isync
214
215         /* Load up FP, VMX and VSX registers */
216         bl      kvmppc_load_fp
217
218 BEGIN_FTR_SECTION
219         /* Switch DSCR to guest value */
220         ld      r5, VCPU_DSCR(r4)
221         mtspr   SPRN_DSCR, r5
222 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_206)
223
224         /*
225          * Set the decrementer to the guest decrementer.
226          */
227         ld      r8,VCPU_DEC_EXPIRES(r4)
228         mftb    r7
229         subf    r3,r7,r8
230         mtspr   SPRN_DEC,r3
231         stw     r3,VCPU_DEC(r4)
232
233         ld      r5, VCPU_SPRG0(r4)
234         ld      r6, VCPU_SPRG1(r4)
235         ld      r7, VCPU_SPRG2(r4)
236         ld      r8, VCPU_SPRG3(r4)
237         mtspr   SPRN_SPRG0, r5
238         mtspr   SPRN_SPRG1, r6
239         mtspr   SPRN_SPRG2, r7
240         mtspr   SPRN_SPRG3, r8
241
242         /* Save R1 in the PACA */
243         std     r1, HSTATE_HOST_R1(r13)
244
245         /* Increment yield count if they have a VPA */
246         ld      r3, VCPU_VPA(r4)
247         cmpdi   r3, 0
248         beq     25f
249         lwz     r5, LPPACA_YIELDCOUNT(r3)
250         addi    r5, r5, 1
251         stw     r5, LPPACA_YIELDCOUNT(r3)
252 25:
253         /* Load up DAR and DSISR */
254         ld      r5, VCPU_DAR(r4)
255         lwz     r6, VCPU_DSISR(r4)
256         mtspr   SPRN_DAR, r5
257         mtspr   SPRN_DSISR, r6
258
259         /* Set partition DABR */
260         li      r5,3
261         ld      r6,VCPU_DABR(r4)
262         mtspr   SPRN_DABRX,r5
263         mtspr   SPRN_DABR,r6
264
265 BEGIN_FTR_SECTION
266         /* Restore AMR and UAMOR, set AMOR to all 1s */
267         ld      r5,VCPU_AMR(r4)
268         ld      r6,VCPU_UAMOR(r4)
269         li      r7,-1
270         mtspr   SPRN_AMR,r5
271         mtspr   SPRN_UAMOR,r6
272         mtspr   SPRN_AMOR,r7
273 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_206)
274
275         /* Clear out SLB */
276         li      r6,0
277         slbmte  r6,r6
278         slbia
279         ptesync
280
281 BEGIN_FTR_SECTION
282         b       30f
283 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_201)
284         /*
285          * POWER7 host -> guest partition switch code.
286          * We don't have to lock against concurrent tlbies,
287          * but we do have to coordinate across hardware threads.
288          */
289         /* Increment entry count iff exit count is zero. */
290         ld      r5,HSTATE_KVM_VCORE(r13)
291         addi    r9,r5,VCORE_ENTRY_EXIT
292 21:     lwarx   r3,0,r9
293         cmpwi   r3,0x100                /* any threads starting to exit? */
294         bge     secondary_too_late      /* if so we're too late to the party */
295         addi    r3,r3,1
296         stwcx.  r3,0,r9
297         bne     21b
298
299         /* Primary thread switches to guest partition. */
300         ld      r9,VCPU_KVM(r4)         /* pointer to struct kvm */
301         lwz     r6,VCPU_PTID(r4)
302         cmpwi   r6,0
303         bne     20f
304         ld      r6,KVM_SDR1(r9)
305         lwz     r7,KVM_LPID(r9)
306         li      r0,LPID_RSVD            /* switch to reserved LPID */
307         mtspr   SPRN_LPID,r0
308         ptesync
309         mtspr   SPRN_SDR1,r6            /* switch to partition page table */
310         mtspr   SPRN_LPID,r7
311         isync
312         li      r0,1
313         stb     r0,VCORE_IN_GUEST(r5)   /* signal secondaries to continue */
314         b       10f
315
316         /* Secondary threads wait for primary to have done partition switch */
317 20:     lbz     r0,VCORE_IN_GUEST(r5)
318         cmpwi   r0,0
319         beq     20b
320
321         /* Set LPCR and RMOR. */
322 10:     ld      r8,KVM_LPCR(r9)
323         mtspr   SPRN_LPCR,r8
324         ld      r8,KVM_RMOR(r9)
325         mtspr   SPRN_RMOR,r8
326         isync
327
328         /* Check if HDEC expires soon */
329         mfspr   r3,SPRN_HDEC
330         cmpwi   r3,10
331         li      r12,BOOK3S_INTERRUPT_HV_DECREMENTER
332         mr      r9,r4
333         blt     hdec_soon
334
335         /*
336          * Invalidate the TLB if we could possibly have stale TLB
337          * entries for this partition on this core due to the use
338          * of tlbiel.
339          * XXX maybe only need this on primary thread?
340          */
341         ld      r9,VCPU_KVM(r4)         /* pointer to struct kvm */
342         lwz     r5,VCPU_VCPUID(r4)
343         lhz     r6,PACAPACAINDEX(r13)
344         rldimi  r6,r5,0,62              /* XXX map as if threads 1:1 p:v */
345         lhz     r8,VCPU_LAST_CPU(r4)
346         sldi    r7,r6,1                 /* see if this is the same vcpu */
347         add     r7,r7,r9                /* as last ran on this pcpu */
348         lhz     r0,KVM_LAST_VCPU(r7)
349         cmpw    r6,r8                   /* on the same cpu core as last time? */
350         bne     3f
351         cmpw    r0,r5                   /* same vcpu as this core last ran? */
352         beq     1f
353 3:      sth     r6,VCPU_LAST_CPU(r4)    /* if not, invalidate partition TLB */
354         sth     r5,KVM_LAST_VCPU(r7)
355         li      r6,128
356         mtctr   r6
357         li      r7,0x800                /* IS field = 0b10 */
358         ptesync
359 2:      tlbiel  r7
360         addi    r7,r7,0x1000
361         bdnz    2b
362         ptesync
363 1:
364
365         /* Save purr/spurr */
366         mfspr   r5,SPRN_PURR
367         mfspr   r6,SPRN_SPURR
368         std     r5,HSTATE_PURR(r13)
369         std     r6,HSTATE_SPURR(r13)
370         ld      r7,VCPU_PURR(r4)
371         ld      r8,VCPU_SPURR(r4)
372         mtspr   SPRN_PURR,r7
373         mtspr   SPRN_SPURR,r8
374         b       31f
375
376         /*
377          * PPC970 host -> guest partition switch code.
378          * We have to lock against concurrent tlbies,
379          * using native_tlbie_lock to lock against host tlbies
380          * and kvm->arch.tlbie_lock to lock against guest tlbies.
381          * We also have to invalidate the TLB since its
382          * entries aren't tagged with the LPID.
383          */
384 30:     ld      r9,VCPU_KVM(r4)         /* pointer to struct kvm */
385
386         /* first take native_tlbie_lock */
387         .section ".toc","aw"
388 toc_tlbie_lock:
389         .tc     native_tlbie_lock[TC],native_tlbie_lock
390         .previous
391         ld      r3,toc_tlbie_lock@toc(2)
392         lwz     r8,PACA_LOCK_TOKEN(r13)
393 24:     lwarx   r0,0,r3
394         cmpwi   r0,0
395         bne     24b
396         stwcx.  r8,0,r3
397         bne     24b
398         isync
399
400         ld      r7,KVM_LPCR(r9)         /* use kvm->arch.lpcr to store HID4 */
401         li      r0,0x18f
402         rotldi  r0,r0,HID4_LPID5_SH     /* all lpid bits in HID4 = 1 */
403         or      r0,r7,r0
404         ptesync
405         sync
406         mtspr   SPRN_HID4,r0            /* switch to reserved LPID */
407         isync
408         li      r0,0
409         stw     r0,0(r3)                /* drop native_tlbie_lock */
410
411         /* invalidate the whole TLB */
412         li      r0,256
413         mtctr   r0
414         li      r6,0
415 25:     tlbiel  r6
416         addi    r6,r6,0x1000
417         bdnz    25b
418         ptesync
419
420         /* Take the guest's tlbie_lock */
421         addi    r3,r9,KVM_TLBIE_LOCK
422 24:     lwarx   r0,0,r3
423         cmpwi   r0,0
424         bne     24b
425         stwcx.  r8,0,r3
426         bne     24b
427         isync
428         ld      r6,KVM_SDR1(r9)
429         mtspr   SPRN_SDR1,r6            /* switch to partition page table */
430
431         /* Set up HID4 with the guest's LPID etc. */
432         sync
433         mtspr   SPRN_HID4,r7
434         isync
435
436         /* drop the guest's tlbie_lock */
437         li      r0,0
438         stw     r0,0(r3)
439
440         /* Check if HDEC expires soon */
441         mfspr   r3,SPRN_HDEC
442         cmpwi   r3,10
443         li      r12,BOOK3S_INTERRUPT_HV_DECREMENTER
444         mr      r9,r4
445         blt     hdec_soon
446
447         /* Enable HDEC interrupts */
448         mfspr   r0,SPRN_HID0
449         li      r3,1
450         rldimi  r0,r3, HID0_HDICE_SH, 64-HID0_HDICE_SH-1
451         sync
452         mtspr   SPRN_HID0,r0
453         mfspr   r0,SPRN_HID0
454         mfspr   r0,SPRN_HID0
455         mfspr   r0,SPRN_HID0
456         mfspr   r0,SPRN_HID0
457         mfspr   r0,SPRN_HID0
458         mfspr   r0,SPRN_HID0
459
460         /* Load up guest SLB entries */
461 31:     lwz     r5,VCPU_SLB_MAX(r4)
462         cmpwi   r5,0
463         beq     9f
464         mtctr   r5
465         addi    r6,r4,VCPU_SLB
466 1:      ld      r8,VCPU_SLB_E(r6)
467         ld      r9,VCPU_SLB_V(r6)
468         slbmte  r9,r8
469         addi    r6,r6,VCPU_SLB_SIZE
470         bdnz    1b
471 9:
472
473         /* Restore state of CTRL run bit; assume 1 on entry */
474         lwz     r5,VCPU_CTRL(r4)
475         andi.   r5,r5,1
476         bne     4f
477         mfspr   r6,SPRN_CTRLF
478         clrrdi  r6,r6,1
479         mtspr   SPRN_CTRLT,r6
480 4:
481         ld      r6, VCPU_CTR(r4)
482         lwz     r7, VCPU_XER(r4)
483
484         mtctr   r6
485         mtxer   r7
486
487 kvmppc_cede_reentry:            /* r4 = vcpu, r13 = paca */
488         ld      r6, VCPU_SRR0(r4)
489         ld      r7, VCPU_SRR1(r4)
490         ld      r10, VCPU_PC(r4)
491         ld      r11, VCPU_MSR(r4)       /* r11 = vcpu->arch.msr & ~MSR_HV */
492
493         rldicl  r11, r11, 63 - MSR_HV_LG, 1
494         rotldi  r11, r11, 1 + MSR_HV_LG
495         ori     r11, r11, MSR_ME
496
497         /* Check if we can deliver an external or decrementer interrupt now */
498         ld      r0,VCPU_PENDING_EXC(r4)
499         li      r8,(1 << BOOK3S_IRQPRIO_EXTERNAL)
500         oris    r8,r8,(1 << BOOK3S_IRQPRIO_EXTERNAL_LEVEL)@h
501         and     r0,r0,r8
502         cmpdi   cr1,r0,0
503         andi.   r0,r11,MSR_EE
504         beq     cr1,11f
505 BEGIN_FTR_SECTION
506         mfspr   r8,SPRN_LPCR
507         ori     r8,r8,LPCR_MER
508         mtspr   SPRN_LPCR,r8
509         isync
510 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_206)
511         beq     5f
512         li      r0,BOOK3S_INTERRUPT_EXTERNAL
513 12:     mr      r6,r10
514         mr      r10,r0
515         mr      r7,r11
516         li      r11,(MSR_ME << 1) | 1   /* synthesize MSR_SF | MSR_ME */
517         rotldi  r11,r11,63
518         b       5f
519 11:     beq     5f
520         mfspr   r0,SPRN_DEC
521         cmpwi   r0,0
522         li      r0,BOOK3S_INTERRUPT_DECREMENTER
523         blt     12b
524
525         /* Move SRR0 and SRR1 into the respective regs */
526 5:      mtspr   SPRN_SRR0, r6
527         mtspr   SPRN_SRR1, r7
528         li      r0,0
529         stb     r0,VCPU_CEDED(r4)       /* cancel cede */
530
531 fast_guest_return:
532         mtspr   SPRN_HSRR0,r10
533         mtspr   SPRN_HSRR1,r11
534
535         /* Activate guest mode, so faults get handled by KVM */
536         li      r9, KVM_GUEST_MODE_GUEST
537         stb     r9, HSTATE_IN_GUEST(r13)
538
539         /* Enter guest */
540
541         ld      r5, VCPU_LR(r4)
542         lwz     r6, VCPU_CR(r4)
543         mtlr    r5
544         mtcr    r6
545
546         ld      r0, VCPU_GPR(r0)(r4)
547         ld      r1, VCPU_GPR(r1)(r4)
548         ld      r2, VCPU_GPR(r2)(r4)
549         ld      r3, VCPU_GPR(r3)(r4)
550         ld      r5, VCPU_GPR(r5)(r4)
551         ld      r6, VCPU_GPR(r6)(r4)
552         ld      r7, VCPU_GPR(r7)(r4)
553         ld      r8, VCPU_GPR(r8)(r4)
554         ld      r9, VCPU_GPR(r9)(r4)
555         ld      r10, VCPU_GPR(r10)(r4)
556         ld      r11, VCPU_GPR(r11)(r4)
557         ld      r12, VCPU_GPR(r12)(r4)
558         ld      r13, VCPU_GPR(r13)(r4)
559
560         ld      r4, VCPU_GPR(r4)(r4)
561
562         hrfid
563         b       .
564
565 /******************************************************************************
566  *                                                                            *
567  *                               Exit code                                    *
568  *                                                                            *
569  *****************************************************************************/
570
571 /*
572  * We come here from the first-level interrupt handlers.
573  */
574         .globl  kvmppc_interrupt
575 kvmppc_interrupt:
576         /*
577          * Register contents:
578          * R12          = interrupt vector
579          * R13          = PACA
580          * guest CR, R12 saved in shadow VCPU SCRATCH1/0
581          * guest R13 saved in SPRN_SCRATCH0
582          */
583         /* abuse host_r2 as third scratch area; we get r2 from PACATOC(r13) */
584         std     r9, HSTATE_HOST_R2(r13)
585         ld      r9, HSTATE_KVM_VCPU(r13)
586
587         /* Save registers */
588
589         std     r0, VCPU_GPR(r0)(r9)
590         std     r1, VCPU_GPR(r1)(r9)
591         std     r2, VCPU_GPR(r2)(r9)
592         std     r3, VCPU_GPR(r3)(r9)
593         std     r4, VCPU_GPR(r4)(r9)
594         std     r5, VCPU_GPR(r5)(r9)
595         std     r6, VCPU_GPR(r6)(r9)
596         std     r7, VCPU_GPR(r7)(r9)
597         std     r8, VCPU_GPR(r8)(r9)
598         ld      r0, HSTATE_HOST_R2(r13)
599         std     r0, VCPU_GPR(r9)(r9)
600         std     r10, VCPU_GPR(r10)(r9)
601         std     r11, VCPU_GPR(r11)(r9)
602         ld      r3, HSTATE_SCRATCH0(r13)
603         lwz     r4, HSTATE_SCRATCH1(r13)
604         std     r3, VCPU_GPR(r12)(r9)
605         stw     r4, VCPU_CR(r9)
606
607         /* Restore R1/R2 so we can handle faults */
608         ld      r1, HSTATE_HOST_R1(r13)
609         ld      r2, PACATOC(r13)
610
611         mfspr   r10, SPRN_SRR0
612         mfspr   r11, SPRN_SRR1
613         std     r10, VCPU_SRR0(r9)
614         std     r11, VCPU_SRR1(r9)
615         andi.   r0, r12, 2              /* need to read HSRR0/1? */
616         beq     1f
617         mfspr   r10, SPRN_HSRR0
618         mfspr   r11, SPRN_HSRR1
619         clrrdi  r12, r12, 2
620 1:      std     r10, VCPU_PC(r9)
621         std     r11, VCPU_MSR(r9)
622
623         GET_SCRATCH0(r3)
624         mflr    r4
625         std     r3, VCPU_GPR(r13)(r9)
626         std     r4, VCPU_LR(r9)
627
628         /* Unset guest mode */
629         li      r0, KVM_GUEST_MODE_NONE
630         stb     r0, HSTATE_IN_GUEST(r13)
631
632         stw     r12,VCPU_TRAP(r9)
633
634         /* Save HEIR (HV emulation assist reg) in last_inst
635            if this is an HEI (HV emulation interrupt, e40) */
636         li      r3,KVM_INST_FETCH_FAILED
637 BEGIN_FTR_SECTION
638         cmpwi   r12,BOOK3S_INTERRUPT_H_EMUL_ASSIST
639         bne     11f
640         mfspr   r3,SPRN_HEIR
641 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_206)
642 11:     stw     r3,VCPU_LAST_INST(r9)
643
644         /* these are volatile across C function calls */
645         mfctr   r3
646         mfxer   r4
647         std     r3, VCPU_CTR(r9)
648         stw     r4, VCPU_XER(r9)
649
650 BEGIN_FTR_SECTION
651         /* If this is a page table miss then see if it's theirs or ours */
652         cmpwi   r12, BOOK3S_INTERRUPT_H_DATA_STORAGE
653         beq     kvmppc_hdsi
654         cmpwi   r12, BOOK3S_INTERRUPT_H_INST_STORAGE
655         beq     kvmppc_hisi
656 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_206)
657
658         /* See if this is a leftover HDEC interrupt */
659         cmpwi   r12,BOOK3S_INTERRUPT_HV_DECREMENTER
660         bne     2f
661         mfspr   r3,SPRN_HDEC
662         cmpwi   r3,0
663         bge     ignore_hdec
664 2:
665         /* See if this is an hcall we can handle in real mode */
666         cmpwi   r12,BOOK3S_INTERRUPT_SYSCALL
667         beq     hcall_try_real_mode
668
669         /* Check for mediated interrupts (could be done earlier really ...) */
670 BEGIN_FTR_SECTION
671         cmpwi   r12,BOOK3S_INTERRUPT_EXTERNAL
672         bne+    1f
673         andi.   r0,r11,MSR_EE
674         beq     1f
675         mfspr   r5,SPRN_LPCR
676         andi.   r0,r5,LPCR_MER
677         bne     bounce_ext_interrupt
678 1:
679 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_206)
680
681 nohpte_cont:
682 hcall_real_cont:                /* r9 = vcpu, r12 = trap, r13 = paca */
683         /* Save DEC */
684         mfspr   r5,SPRN_DEC
685         mftb    r6
686         extsw   r5,r5
687         add     r5,r5,r6
688         std     r5,VCPU_DEC_EXPIRES(r9)
689
690         /* Save more register state  */
691         mfdar   r6
692         mfdsisr r7
693         std     r6, VCPU_DAR(r9)
694         stw     r7, VCPU_DSISR(r9)
695 BEGIN_FTR_SECTION
696         /* don't overwrite fault_dar/fault_dsisr if HDSI */
697         cmpwi   r12,BOOK3S_INTERRUPT_H_DATA_STORAGE
698         beq     6f
699 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_206)
700         std     r6, VCPU_FAULT_DAR(r9)
701         stw     r7, VCPU_FAULT_DSISR(r9)
702
703         /* Save guest CTRL register, set runlatch to 1 */
704 6:      mfspr   r6,SPRN_CTRLF
705         stw     r6,VCPU_CTRL(r9)
706         andi.   r0,r6,1
707         bne     4f
708         ori     r6,r6,1
709         mtspr   SPRN_CTRLT,r6
710 4:
711         /* Read the guest SLB and save it away */
712         lwz     r0,VCPU_SLB_NR(r9)      /* number of entries in SLB */
713         mtctr   r0
714         li      r6,0
715         addi    r7,r9,VCPU_SLB
716         li      r5,0
717 1:      slbmfee r8,r6
718         andis.  r0,r8,SLB_ESID_V@h
719         beq     2f
720         add     r8,r8,r6                /* put index in */
721         slbmfev r3,r6
722         std     r8,VCPU_SLB_E(r7)
723         std     r3,VCPU_SLB_V(r7)
724         addi    r7,r7,VCPU_SLB_SIZE
725         addi    r5,r5,1
726 2:      addi    r6,r6,1
727         bdnz    1b
728         stw     r5,VCPU_SLB_MAX(r9)
729
730         /*
731          * Save the guest PURR/SPURR
732          */
733 BEGIN_FTR_SECTION
734         mfspr   r5,SPRN_PURR
735         mfspr   r6,SPRN_SPURR
736         ld      r7,VCPU_PURR(r9)
737         ld      r8,VCPU_SPURR(r9)
738         std     r5,VCPU_PURR(r9)
739         std     r6,VCPU_SPURR(r9)
740         subf    r5,r7,r5
741         subf    r6,r8,r6
742
743         /*
744          * Restore host PURR/SPURR and add guest times
745          * so that the time in the guest gets accounted.
746          */
747         ld      r3,HSTATE_PURR(r13)
748         ld      r4,HSTATE_SPURR(r13)
749         add     r3,r3,r5
750         add     r4,r4,r6
751         mtspr   SPRN_PURR,r3
752         mtspr   SPRN_SPURR,r4
753 END_FTR_SECTION_IFCLR(CPU_FTR_ARCH_201)
754
755         /* Clear out SLB */
756         li      r5,0
757         slbmte  r5,r5
758         slbia
759         ptesync
760
761 hdec_soon:                      /* r9 = vcpu, r12 = trap, r13 = paca */
762 BEGIN_FTR_SECTION
763         b       32f
764 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_201)
765         /*
766          * POWER7 guest -> host partition switch code.
767          * We don't have to lock against tlbies but we do
768          * have to coordinate the hardware threads.
769          */
770         /* Increment the threads-exiting-guest count in the 0xff00
771            bits of vcore->entry_exit_count */
772         lwsync
773         ld      r5,HSTATE_KVM_VCORE(r13)
774         addi    r6,r5,VCORE_ENTRY_EXIT
775 41:     lwarx   r3,0,r6
776         addi    r0,r3,0x100
777         stwcx.  r0,0,r6
778         bne     41b
779         lwsync
780
781         /*
782          * At this point we have an interrupt that we have to pass
783          * up to the kernel or qemu; we can't handle it in real mode.
784          * Thus we have to do a partition switch, so we have to
785          * collect the other threads, if we are the first thread
786          * to take an interrupt.  To do this, we set the HDEC to 0,
787          * which causes an HDEC interrupt in all threads within 2ns
788          * because the HDEC register is shared between all 4 threads.
789          * However, we don't need to bother if this is an HDEC
790          * interrupt, since the other threads will already be on their
791          * way here in that case.
792          */
793         cmpwi   r3,0x100        /* Are we the first here? */
794         bge     43f
795         cmpwi   r3,1            /* Are any other threads in the guest? */
796         ble     43f
797         cmpwi   r12,BOOK3S_INTERRUPT_HV_DECREMENTER
798         beq     40f
799         li      r0,0
800         mtspr   SPRN_HDEC,r0
801 40:
802         /*
803          * Send an IPI to any napping threads, since an HDEC interrupt
804          * doesn't wake CPUs up from nap.
805          */
806         lwz     r3,VCORE_NAPPING_THREADS(r5)
807         lwz     r4,VCPU_PTID(r9)
808         li      r0,1
809         sldi    r0,r0,r4
810         andc.   r3,r3,r0                /* no sense IPI'ing ourselves */
811         beq     43f
812         mulli   r4,r4,PACA_SIZE         /* get paca for thread 0 */
813         subf    r6,r4,r13
814 42:     andi.   r0,r3,1
815         beq     44f
816         ld      r8,HSTATE_XICS_PHYS(r6) /* get thread's XICS reg addr */
817         li      r0,IPI_PRIORITY
818         li      r7,XICS_QIRR
819         stbcix  r0,r7,r8                /* trigger the IPI */
820 44:     srdi.   r3,r3,1
821         addi    r6,r6,PACA_SIZE
822         bne     42b
823
824         /* Secondary threads wait for primary to do partition switch */
825 43:     ld      r4,VCPU_KVM(r9)         /* pointer to struct kvm */
826         ld      r5,HSTATE_KVM_VCORE(r13)
827         lwz     r3,VCPU_PTID(r9)
828         cmpwi   r3,0
829         beq     15f
830         HMT_LOW
831 13:     lbz     r3,VCORE_IN_GUEST(r5)
832         cmpwi   r3,0
833         bne     13b
834         HMT_MEDIUM
835         b       16f
836
837         /* Primary thread waits for all the secondaries to exit guest */
838 15:     lwz     r3,VCORE_ENTRY_EXIT(r5)
839         srwi    r0,r3,8
840         clrldi  r3,r3,56
841         cmpw    r3,r0
842         bne     15b
843         isync
844
845         /* Primary thread switches back to host partition */
846         ld      r6,KVM_HOST_SDR1(r4)
847         lwz     r7,KVM_HOST_LPID(r4)
848         li      r8,LPID_RSVD            /* switch to reserved LPID */
849         mtspr   SPRN_LPID,r8
850         ptesync
851         mtspr   SPRN_SDR1,r6            /* switch to partition page table */
852         mtspr   SPRN_LPID,r7
853         isync
854         li      r0,0
855         stb     r0,VCORE_IN_GUEST(r5)
856         lis     r8,0x7fff               /* MAX_INT@h */
857         mtspr   SPRN_HDEC,r8
858
859 16:     ld      r8,KVM_HOST_LPCR(r4)
860         mtspr   SPRN_LPCR,r8
861         isync
862         b       33f
863
864         /*
865          * PPC970 guest -> host partition switch code.
866          * We have to lock against concurrent tlbies, and
867          * we have to flush the whole TLB.
868          */
869 32:     ld      r4,VCPU_KVM(r9)         /* pointer to struct kvm */
870
871         /* Take the guest's tlbie_lock */
872         lwz     r8,PACA_LOCK_TOKEN(r13)
873         addi    r3,r4,KVM_TLBIE_LOCK
874 24:     lwarx   r0,0,r3
875         cmpwi   r0,0
876         bne     24b
877         stwcx.  r8,0,r3
878         bne     24b
879         isync
880
881         ld      r7,KVM_HOST_LPCR(r4)    /* use kvm->arch.host_lpcr for HID4 */
882         li      r0,0x18f
883         rotldi  r0,r0,HID4_LPID5_SH     /* all lpid bits in HID4 = 1 */
884         or      r0,r7,r0
885         ptesync
886         sync
887         mtspr   SPRN_HID4,r0            /* switch to reserved LPID */
888         isync
889         li      r0,0
890         stw     r0,0(r3)                /* drop guest tlbie_lock */
891
892         /* invalidate the whole TLB */
893         li      r0,256
894         mtctr   r0
895         li      r6,0
896 25:     tlbiel  r6
897         addi    r6,r6,0x1000
898         bdnz    25b
899         ptesync
900
901         /* take native_tlbie_lock */
902         ld      r3,toc_tlbie_lock@toc(2)
903 24:     lwarx   r0,0,r3
904         cmpwi   r0,0
905         bne     24b
906         stwcx.  r8,0,r3
907         bne     24b
908         isync
909
910         ld      r6,KVM_HOST_SDR1(r4)
911         mtspr   SPRN_SDR1,r6            /* switch to host page table */
912
913         /* Set up host HID4 value */
914         sync
915         mtspr   SPRN_HID4,r7
916         isync
917         li      r0,0
918         stw     r0,0(r3)                /* drop native_tlbie_lock */
919
920         lis     r8,0x7fff               /* MAX_INT@h */
921         mtspr   SPRN_HDEC,r8
922
923         /* Disable HDEC interrupts */
924         mfspr   r0,SPRN_HID0
925         li      r3,0
926         rldimi  r0,r3, HID0_HDICE_SH, 64-HID0_HDICE_SH-1
927         sync
928         mtspr   SPRN_HID0,r0
929         mfspr   r0,SPRN_HID0
930         mfspr   r0,SPRN_HID0
931         mfspr   r0,SPRN_HID0
932         mfspr   r0,SPRN_HID0
933         mfspr   r0,SPRN_HID0
934         mfspr   r0,SPRN_HID0
935
936         /* load host SLB entries */
937 33:     ld      r8,PACA_SLBSHADOWPTR(r13)
938
939         .rept   SLB_NUM_BOLTED
940         ld      r5,SLBSHADOW_SAVEAREA(r8)
941         ld      r6,SLBSHADOW_SAVEAREA+8(r8)
942         andis.  r7,r5,SLB_ESID_V@h
943         beq     1f
944         slbmte  r6,r5
945 1:      addi    r8,r8,16
946         .endr
947
948         /* Save and reset AMR and UAMOR before turning on the MMU */
949 BEGIN_FTR_SECTION
950         mfspr   r5,SPRN_AMR
951         mfspr   r6,SPRN_UAMOR
952         std     r5,VCPU_AMR(r9)
953         std     r6,VCPU_UAMOR(r9)
954         li      r6,0
955         mtspr   SPRN_AMR,r6
956 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_206)
957
958         /* Restore host DABR and DABRX */
959         ld      r5,HSTATE_DABR(r13)
960         li      r6,7
961         mtspr   SPRN_DABR,r5
962         mtspr   SPRN_DABRX,r6
963
964         /* Switch DSCR back to host value */
965 BEGIN_FTR_SECTION
966         mfspr   r8, SPRN_DSCR
967         ld      r7, HSTATE_DSCR(r13)
968         std     r8, VCPU_DSCR(r7)
969         mtspr   SPRN_DSCR, r7
970 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_206)
971
972         /* Save non-volatile GPRs */
973         std     r14, VCPU_GPR(r14)(r9)
974         std     r15, VCPU_GPR(r15)(r9)
975         std     r16, VCPU_GPR(r16)(r9)
976         std     r17, VCPU_GPR(r17)(r9)
977         std     r18, VCPU_GPR(r18)(r9)
978         std     r19, VCPU_GPR(r19)(r9)
979         std     r20, VCPU_GPR(r20)(r9)
980         std     r21, VCPU_GPR(r21)(r9)
981         std     r22, VCPU_GPR(r22)(r9)
982         std     r23, VCPU_GPR(r23)(r9)
983         std     r24, VCPU_GPR(r24)(r9)
984         std     r25, VCPU_GPR(r25)(r9)
985         std     r26, VCPU_GPR(r26)(r9)
986         std     r27, VCPU_GPR(r27)(r9)
987         std     r28, VCPU_GPR(r28)(r9)
988         std     r29, VCPU_GPR(r29)(r9)
989         std     r30, VCPU_GPR(r30)(r9)
990         std     r31, VCPU_GPR(r31)(r9)
991
992         /* Save SPRGs */
993         mfspr   r3, SPRN_SPRG0
994         mfspr   r4, SPRN_SPRG1
995         mfspr   r5, SPRN_SPRG2
996         mfspr   r6, SPRN_SPRG3
997         std     r3, VCPU_SPRG0(r9)
998         std     r4, VCPU_SPRG1(r9)
999         std     r5, VCPU_SPRG2(r9)
1000         std     r6, VCPU_SPRG3(r9)
1001
1002         /* Increment yield count if they have a VPA */
1003         ld      r8, VCPU_VPA(r9)        /* do they have a VPA? */
1004         cmpdi   r8, 0
1005         beq     25f
1006         lwz     r3, LPPACA_YIELDCOUNT(r8)
1007         addi    r3, r3, 1
1008         stw     r3, LPPACA_YIELDCOUNT(r8)
1009 25:
1010         /* Save PMU registers if requested */
1011         /* r8 and cr0.eq are live here */
1012         li      r3, 1
1013         sldi    r3, r3, 31              /* MMCR0_FC (freeze counters) bit */
1014         mfspr   r4, SPRN_MMCR0          /* save MMCR0 */
1015         mtspr   SPRN_MMCR0, r3          /* freeze all counters, disable ints */
1016         isync
1017         beq     21f                     /* if no VPA, save PMU stuff anyway */
1018         lbz     r7, LPPACA_PMCINUSE(r8)
1019         cmpwi   r7, 0                   /* did they ask for PMU stuff to be saved? */
1020         bne     21f
1021         std     r3, VCPU_MMCR(r9)       /* if not, set saved MMCR0 to FC */
1022         b       22f
1023 21:     mfspr   r5, SPRN_MMCR1
1024         mfspr   r6, SPRN_MMCRA
1025         std     r4, VCPU_MMCR(r9)
1026         std     r5, VCPU_MMCR + 8(r9)
1027         std     r6, VCPU_MMCR + 16(r9)
1028         mfspr   r3, SPRN_PMC1
1029         mfspr   r4, SPRN_PMC2
1030         mfspr   r5, SPRN_PMC3
1031         mfspr   r6, SPRN_PMC4
1032         mfspr   r7, SPRN_PMC5
1033         mfspr   r8, SPRN_PMC6
1034 BEGIN_FTR_SECTION
1035         mfspr   r10, SPRN_PMC7
1036         mfspr   r11, SPRN_PMC8
1037 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_201)
1038         stw     r3, VCPU_PMC(r9)
1039         stw     r4, VCPU_PMC + 4(r9)
1040         stw     r5, VCPU_PMC + 8(r9)
1041         stw     r6, VCPU_PMC + 12(r9)
1042         stw     r7, VCPU_PMC + 16(r9)
1043         stw     r8, VCPU_PMC + 20(r9)
1044 BEGIN_FTR_SECTION
1045         stw     r10, VCPU_PMC + 24(r9)
1046         stw     r11, VCPU_PMC + 28(r9)
1047 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_201)
1048 22:
1049         /* save FP state */
1050         mr      r3, r9
1051         bl      .kvmppc_save_fp
1052
1053         /* Secondary threads go off to take a nap on POWER7 */
1054 BEGIN_FTR_SECTION
1055         lwz     r0,VCPU_PTID(r3)
1056         cmpwi   r0,0
1057         bne     secondary_nap
1058 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_206)
1059
1060         /*
1061          * Reload DEC.  HDEC interrupts were disabled when
1062          * we reloaded the host's LPCR value.
1063          */
1064         ld      r3, HSTATE_DECEXP(r13)
1065         mftb    r4
1066         subf    r4, r4, r3
1067         mtspr   SPRN_DEC, r4
1068
1069         /* Reload the host's PMU registers */
1070         ld      r3, PACALPPACAPTR(r13)  /* is the host using the PMU? */
1071         lbz     r4, LPPACA_PMCINUSE(r3)
1072         cmpwi   r4, 0
1073         beq     23f                     /* skip if not */
1074         lwz     r3, HSTATE_PMC(r13)
1075         lwz     r4, HSTATE_PMC + 4(r13)
1076         lwz     r5, HSTATE_PMC + 8(r13)
1077         lwz     r6, HSTATE_PMC + 12(r13)
1078         lwz     r8, HSTATE_PMC + 16(r13)
1079         lwz     r9, HSTATE_PMC + 20(r13)
1080 BEGIN_FTR_SECTION
1081         lwz     r10, HSTATE_PMC + 24(r13)
1082         lwz     r11, HSTATE_PMC + 28(r13)
1083 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_201)
1084         mtspr   SPRN_PMC1, r3
1085         mtspr   SPRN_PMC2, r4
1086         mtspr   SPRN_PMC3, r5
1087         mtspr   SPRN_PMC4, r6
1088         mtspr   SPRN_PMC5, r8
1089         mtspr   SPRN_PMC6, r9
1090 BEGIN_FTR_SECTION
1091         mtspr   SPRN_PMC7, r10
1092         mtspr   SPRN_PMC8, r11
1093 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_201)
1094         ld      r3, HSTATE_MMCR(r13)
1095         ld      r4, HSTATE_MMCR + 8(r13)
1096         ld      r5, HSTATE_MMCR + 16(r13)
1097         mtspr   SPRN_MMCR1, r4
1098         mtspr   SPRN_MMCRA, r5
1099         mtspr   SPRN_MMCR0, r3
1100         isync
1101 23:
1102         /*
1103          * For external and machine check interrupts, we need
1104          * to call the Linux handler to process the interrupt.
1105          * We do that by jumping to the interrupt vector address
1106          * which we have in r12.  The [h]rfid at the end of the
1107          * handler will return to the book3s_hv_interrupts.S code.
1108          * For other interrupts we do the rfid to get back
1109          * to the book3s_interrupts.S code here.
1110          */
1111         ld      r8, HSTATE_VMHANDLER(r13)
1112         ld      r7, HSTATE_HOST_MSR(r13)
1113
1114         cmpwi   r12, BOOK3S_INTERRUPT_EXTERNAL
1115         beq     11f
1116         cmpwi   r12, BOOK3S_INTERRUPT_MACHINE_CHECK
1117
1118         /* RFI into the highmem handler, or branch to interrupt handler */
1119 12:     mfmsr   r6
1120         mtctr   r12
1121         li      r0, MSR_RI
1122         andc    r6, r6, r0
1123         mtmsrd  r6, 1                   /* Clear RI in MSR */
1124         mtsrr0  r8
1125         mtsrr1  r7
1126         beqctr
1127         RFI
1128
1129 11:
1130 BEGIN_FTR_SECTION
1131         b       12b
1132 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_201)
1133         mtspr   SPRN_HSRR0, r8
1134         mtspr   SPRN_HSRR1, r7
1135         ba      0x500
1136
1137 /*
1138  * Check whether an HDSI is an HPTE not found fault or something else.
1139  * If it is an HPTE not found fault that is due to the guest accessing
1140  * a page that they have mapped but which we have paged out, then
1141  * we continue on with the guest exit path.  In all other cases,
1142  * reflect the HDSI to the guest as a DSI.
1143  */
1144 kvmppc_hdsi:
1145         mfspr   r4, SPRN_HDAR
1146         mfspr   r6, SPRN_HDSISR
1147         /* HPTE not found fault or protection fault? */
1148         andis.  r0, r6, (DSISR_NOHPTE | DSISR_PROTFAULT)@h
1149         beq     1f                      /* if not, send it to the guest */
1150         andi.   r0, r11, MSR_DR         /* data relocation enabled? */
1151         beq     3f
1152         clrrdi  r0, r4, 28
1153         PPC_SLBFEE_DOT(r5, r0)          /* if so, look up SLB */
1154         bne     1f                      /* if no SLB entry found */
1155 4:      std     r4, VCPU_FAULT_DAR(r9)
1156         stw     r6, VCPU_FAULT_DSISR(r9)
1157
1158         /* Search the hash table. */
1159         mr      r3, r9                  /* vcpu pointer */
1160         li      r7, 1                   /* data fault */
1161         bl      .kvmppc_hpte_hv_fault
1162         ld      r9, HSTATE_KVM_VCPU(r13)
1163         ld      r10, VCPU_PC(r9)
1164         ld      r11, VCPU_MSR(r9)
1165         li      r12, BOOK3S_INTERRUPT_H_DATA_STORAGE
1166         cmpdi   r3, 0                   /* retry the instruction */
1167         beq     6f
1168         cmpdi   r3, -1                  /* handle in kernel mode */
1169         beq     nohpte_cont
1170         cmpdi   r3, -2                  /* MMIO emulation; need instr word */
1171         beq     2f
1172
1173         /* Synthesize a DSI for the guest */
1174         ld      r4, VCPU_FAULT_DAR(r9)
1175         mr      r6, r3
1176 1:      mtspr   SPRN_DAR, r4
1177         mtspr   SPRN_DSISR, r6
1178         mtspr   SPRN_SRR0, r10
1179         mtspr   SPRN_SRR1, r11
1180         li      r10, BOOK3S_INTERRUPT_DATA_STORAGE
1181         li      r11, (MSR_ME << 1) | 1  /* synthesize MSR_SF | MSR_ME */
1182         rotldi  r11, r11, 63
1183 6:      ld      r7, VCPU_CTR(r9)
1184         lwz     r8, VCPU_XER(r9)
1185         mtctr   r7
1186         mtxer   r8
1187         mr      r4, r9
1188         b       fast_guest_return
1189
1190 3:      ld      r5, VCPU_KVM(r9)        /* not relocated, use VRMA */
1191         ld      r5, KVM_VRMA_SLB_V(r5)
1192         b       4b
1193
1194         /* If this is for emulated MMIO, load the instruction word */
1195 2:      li      r8, KVM_INST_FETCH_FAILED       /* In case lwz faults */
1196
1197         /* Set guest mode to 'jump over instruction' so if lwz faults
1198          * we'll just continue at the next IP. */
1199         li      r0, KVM_GUEST_MODE_SKIP
1200         stb     r0, HSTATE_IN_GUEST(r13)
1201
1202         /* Do the access with MSR:DR enabled */
1203         mfmsr   r3
1204         ori     r4, r3, MSR_DR          /* Enable paging for data */
1205         mtmsrd  r4
1206         lwz     r8, 0(r10)
1207         mtmsrd  r3
1208
1209         /* Store the result */
1210         stw     r8, VCPU_LAST_INST(r9)
1211
1212         /* Unset guest mode. */
1213         li      r0, KVM_GUEST_MODE_NONE
1214         stb     r0, HSTATE_IN_GUEST(r13)
1215         b       nohpte_cont
1216
1217 /*
1218  * Similarly for an HISI, reflect it to the guest as an ISI unless
1219  * it is an HPTE not found fault for a page that we have paged out.
1220  */
1221 kvmppc_hisi:
1222         andis.  r0, r11, SRR1_ISI_NOPT@h
1223         beq     1f
1224         andi.   r0, r11, MSR_IR         /* instruction relocation enabled? */
1225         beq     3f
1226         clrrdi  r0, r10, 28
1227         PPC_SLBFEE_DOT(r5, r0)          /* if so, look up SLB */
1228         bne     1f                      /* if no SLB entry found */
1229 4:
1230         /* Search the hash table. */
1231         mr      r3, r9                  /* vcpu pointer */
1232         mr      r4, r10
1233         mr      r6, r11
1234         li      r7, 0                   /* instruction fault */
1235         bl      .kvmppc_hpte_hv_fault
1236         ld      r9, HSTATE_KVM_VCPU(r13)
1237         ld      r10, VCPU_PC(r9)
1238         ld      r11, VCPU_MSR(r9)
1239         li      r12, BOOK3S_INTERRUPT_H_INST_STORAGE
1240         cmpdi   r3, 0                   /* retry the instruction */
1241         beq     6f
1242         cmpdi   r3, -1                  /* handle in kernel mode */
1243         beq     nohpte_cont
1244
1245         /* Synthesize an ISI for the guest */
1246         mr      r11, r3
1247 1:      mtspr   SPRN_SRR0, r10
1248         mtspr   SPRN_SRR1, r11
1249         li      r10, BOOK3S_INTERRUPT_INST_STORAGE
1250         li      r11, (MSR_ME << 1) | 1  /* synthesize MSR_SF | MSR_ME */
1251         rotldi  r11, r11, 63
1252 6:      ld      r7, VCPU_CTR(r9)
1253         lwz     r8, VCPU_XER(r9)
1254         mtctr   r7
1255         mtxer   r8
1256         mr      r4, r9
1257         b       fast_guest_return
1258
1259 3:      ld      r6, VCPU_KVM(r9)        /* not relocated, use VRMA */
1260         ld      r5, KVM_VRMA_SLB_V(r6)
1261         b       4b
1262
1263 /*
1264  * Try to handle an hcall in real mode.
1265  * Returns to the guest if we handle it, or continues on up to
1266  * the kernel if we can't (i.e. if we don't have a handler for
1267  * it, or if the handler returns H_TOO_HARD).
1268  */
1269         .globl  hcall_try_real_mode
1270 hcall_try_real_mode:
1271         ld      r3,VCPU_GPR(r3)(r9)
1272         andi.   r0,r11,MSR_PR
1273         bne     hcall_real_cont
1274         clrrdi  r3,r3,2
1275         cmpldi  r3,hcall_real_table_end - hcall_real_table
1276         bge     hcall_real_cont
1277         LOAD_REG_ADDR(r4, hcall_real_table)
1278         lwzx    r3,r3,r4
1279         cmpwi   r3,0
1280         beq     hcall_real_cont
1281         add     r3,r3,r4
1282         mtctr   r3
1283         mr      r3,r9           /* get vcpu pointer */
1284         ld      r4,VCPU_GPR(r4)(r9)
1285         bctrl
1286         cmpdi   r3,H_TOO_HARD
1287         beq     hcall_real_fallback
1288         ld      r4,HSTATE_KVM_VCPU(r13)
1289         std     r3,VCPU_GPR(r3)(r4)
1290         ld      r10,VCPU_PC(r4)
1291         ld      r11,VCPU_MSR(r4)
1292         b       fast_guest_return
1293
1294         /* We've attempted a real mode hcall, but it's punted it back
1295          * to userspace.  We need to restore some clobbered volatiles
1296          * before resuming the pass-it-to-qemu path */
1297 hcall_real_fallback:
1298         li      r12,BOOK3S_INTERRUPT_SYSCALL
1299         ld      r9, HSTATE_KVM_VCPU(r13)
1300
1301         b       hcall_real_cont
1302
1303         .globl  hcall_real_table
1304 hcall_real_table:
1305         .long   0               /* 0 - unused */
1306         .long   .kvmppc_h_remove - hcall_real_table
1307         .long   .kvmppc_h_enter - hcall_real_table
1308         .long   .kvmppc_h_read - hcall_real_table
1309         .long   0               /* 0x10 - H_CLEAR_MOD */
1310         .long   0               /* 0x14 - H_CLEAR_REF */
1311         .long   .kvmppc_h_protect - hcall_real_table
1312         .long   0               /* 0x1c - H_GET_TCE */
1313         .long   .kvmppc_h_put_tce - hcall_real_table
1314         .long   0               /* 0x24 - H_SET_SPRG0 */
1315         .long   .kvmppc_h_set_dabr - hcall_real_table
1316         .long   0               /* 0x2c */
1317         .long   0               /* 0x30 */
1318         .long   0               /* 0x34 */
1319         .long   0               /* 0x38 */
1320         .long   0               /* 0x3c */
1321         .long   0               /* 0x40 */
1322         .long   0               /* 0x44 */
1323         .long   0               /* 0x48 */
1324         .long   0               /* 0x4c */
1325         .long   0               /* 0x50 */
1326         .long   0               /* 0x54 */
1327         .long   0               /* 0x58 */
1328         .long   0               /* 0x5c */
1329         .long   0               /* 0x60 */
1330         .long   0               /* 0x64 */
1331         .long   0               /* 0x68 */
1332         .long   0               /* 0x6c */
1333         .long   0               /* 0x70 */
1334         .long   0               /* 0x74 */
1335         .long   0               /* 0x78 */
1336         .long   0               /* 0x7c */
1337         .long   0               /* 0x80 */
1338         .long   0               /* 0x84 */
1339         .long   0               /* 0x88 */
1340         .long   0               /* 0x8c */
1341         .long   0               /* 0x90 */
1342         .long   0               /* 0x94 */
1343         .long   0               /* 0x98 */
1344         .long   0               /* 0x9c */
1345         .long   0               /* 0xa0 */
1346         .long   0               /* 0xa4 */
1347         .long   0               /* 0xa8 */
1348         .long   0               /* 0xac */
1349         .long   0               /* 0xb0 */
1350         .long   0               /* 0xb4 */
1351         .long   0               /* 0xb8 */
1352         .long   0               /* 0xbc */
1353         .long   0               /* 0xc0 */
1354         .long   0               /* 0xc4 */
1355         .long   0               /* 0xc8 */
1356         .long   0               /* 0xcc */
1357         .long   0               /* 0xd0 */
1358         .long   0               /* 0xd4 */
1359         .long   0               /* 0xd8 */
1360         .long   0               /* 0xdc */
1361         .long   .kvmppc_h_cede - hcall_real_table
1362         .long   0               /* 0xe4 */
1363         .long   0               /* 0xe8 */
1364         .long   0               /* 0xec */
1365         .long   0               /* 0xf0 */
1366         .long   0               /* 0xf4 */
1367         .long   0               /* 0xf8 */
1368         .long   0               /* 0xfc */
1369         .long   0               /* 0x100 */
1370         .long   0               /* 0x104 */
1371         .long   0               /* 0x108 */
1372         .long   0               /* 0x10c */
1373         .long   0               /* 0x110 */
1374         .long   0               /* 0x114 */
1375         .long   0               /* 0x118 */
1376         .long   0               /* 0x11c */
1377         .long   0               /* 0x120 */
1378         .long   .kvmppc_h_bulk_remove - hcall_real_table
1379 hcall_real_table_end:
1380
1381 ignore_hdec:
1382         mr      r4,r9
1383         b       fast_guest_return
1384
1385 bounce_ext_interrupt:
1386         mr      r4,r9
1387         mtspr   SPRN_SRR0,r10
1388         mtspr   SPRN_SRR1,r11
1389         li      r10,BOOK3S_INTERRUPT_EXTERNAL
1390         li      r11,(MSR_ME << 1) | 1   /* synthesize MSR_SF | MSR_ME */
1391         rotldi  r11,r11,63
1392         b       fast_guest_return
1393
1394 _GLOBAL(kvmppc_h_set_dabr)
1395         std     r4,VCPU_DABR(r3)
1396         mtspr   SPRN_DABR,r4
1397         li      r3,0
1398         blr
1399
1400 _GLOBAL(kvmppc_h_cede)
1401         ori     r11,r11,MSR_EE
1402         std     r11,VCPU_MSR(r3)
1403         li      r0,1
1404         stb     r0,VCPU_CEDED(r3)
1405         sync                    /* order setting ceded vs. testing prodded */
1406         lbz     r5,VCPU_PRODDED(r3)
1407         cmpwi   r5,0
1408         bne     1f
1409         li      r0,0            /* set trap to 0 to say hcall is handled */
1410         stw     r0,VCPU_TRAP(r3)
1411         li      r0,H_SUCCESS
1412         std     r0,VCPU_GPR(r3)(r3)
1413 BEGIN_FTR_SECTION
1414         b       2f              /* just send it up to host on 970 */
1415 END_FTR_SECTION_IFCLR(CPU_FTR_ARCH_206)
1416
1417         /*
1418          * Set our bit in the bitmask of napping threads unless all the
1419          * other threads are already napping, in which case we send this
1420          * up to the host.
1421          */
1422         ld      r5,HSTATE_KVM_VCORE(r13)
1423         lwz     r6,VCPU_PTID(r3)
1424         lwz     r8,VCORE_ENTRY_EXIT(r5)
1425         clrldi  r8,r8,56
1426         li      r0,1
1427         sld     r0,r0,r6
1428         addi    r6,r5,VCORE_NAPPING_THREADS
1429 31:     lwarx   r4,0,r6
1430         or      r4,r4,r0
1431         PPC_POPCNTW(r7,r4)
1432         cmpw    r7,r8
1433         bge     2f
1434         stwcx.  r4,0,r6
1435         bne     31b
1436         li      r0,1
1437         stb     r0,HSTATE_NAPPING(r13)
1438         /* order napping_threads update vs testing entry_exit_count */
1439         lwsync
1440         mr      r4,r3
1441         lwz     r7,VCORE_ENTRY_EXIT(r5)
1442         cmpwi   r7,0x100
1443         bge     33f             /* another thread already exiting */
1444
1445 /*
1446  * Although not specifically required by the architecture, POWER7
1447  * preserves the following registers in nap mode, even if an SMT mode
1448  * switch occurs: SLB entries, PURR, SPURR, AMOR, UAMOR, AMR, SPRG0-3,
1449  * DAR, DSISR, DABR, DABRX, DSCR, PMCx, MMCRx, SIAR, SDAR.
1450  */
1451         /* Save non-volatile GPRs */
1452         std     r14, VCPU_GPR(r14)(r3)
1453         std     r15, VCPU_GPR(r15)(r3)
1454         std     r16, VCPU_GPR(r16)(r3)
1455         std     r17, VCPU_GPR(r17)(r3)
1456         std     r18, VCPU_GPR(r18)(r3)
1457         std     r19, VCPU_GPR(r19)(r3)
1458         std     r20, VCPU_GPR(r20)(r3)
1459         std     r21, VCPU_GPR(r21)(r3)
1460         std     r22, VCPU_GPR(r22)(r3)
1461         std     r23, VCPU_GPR(r23)(r3)
1462         std     r24, VCPU_GPR(r24)(r3)
1463         std     r25, VCPU_GPR(r25)(r3)
1464         std     r26, VCPU_GPR(r26)(r3)
1465         std     r27, VCPU_GPR(r27)(r3)
1466         std     r28, VCPU_GPR(r28)(r3)
1467         std     r29, VCPU_GPR(r29)(r3)
1468         std     r30, VCPU_GPR(r30)(r3)
1469         std     r31, VCPU_GPR(r31)(r3)
1470
1471         /* save FP state */
1472         bl      .kvmppc_save_fp
1473
1474         /*
1475          * Take a nap until a decrementer or external interrupt occurs,
1476          * with PECE1 (wake on decr) and PECE0 (wake on external) set in LPCR
1477          */
1478         li      r0,1
1479         stb     r0,HSTATE_HWTHREAD_REQ(r13)
1480         mfspr   r5,SPRN_LPCR
1481         ori     r5,r5,LPCR_PECE0 | LPCR_PECE1
1482         mtspr   SPRN_LPCR,r5
1483         isync
1484         li      r0, 0
1485         std     r0, HSTATE_SCRATCH0(r13)
1486         ptesync
1487         ld      r0, HSTATE_SCRATCH0(r13)
1488 1:      cmpd    r0, r0
1489         bne     1b
1490         nap
1491         b       .
1492
1493 kvm_end_cede:
1494         /* Woken by external or decrementer interrupt */
1495         ld      r1, HSTATE_HOST_R1(r13)
1496
1497         /* load up FP state */
1498         bl      kvmppc_load_fp
1499
1500         /* Load NV GPRS */
1501         ld      r14, VCPU_GPR(r14)(r4)
1502         ld      r15, VCPU_GPR(r15)(r4)
1503         ld      r16, VCPU_GPR(r16)(r4)
1504         ld      r17, VCPU_GPR(r17)(r4)
1505         ld      r18, VCPU_GPR(r18)(r4)
1506         ld      r19, VCPU_GPR(r19)(r4)
1507         ld      r20, VCPU_GPR(r20)(r4)
1508         ld      r21, VCPU_GPR(r21)(r4)
1509         ld      r22, VCPU_GPR(r22)(r4)
1510         ld      r23, VCPU_GPR(r23)(r4)
1511         ld      r24, VCPU_GPR(r24)(r4)
1512         ld      r25, VCPU_GPR(r25)(r4)
1513         ld      r26, VCPU_GPR(r26)(r4)
1514         ld      r27, VCPU_GPR(r27)(r4)
1515         ld      r28, VCPU_GPR(r28)(r4)
1516         ld      r29, VCPU_GPR(r29)(r4)
1517         ld      r30, VCPU_GPR(r30)(r4)
1518         ld      r31, VCPU_GPR(r31)(r4)
1519
1520         /* clear our bit in vcore->napping_threads */
1521 33:     ld      r5,HSTATE_KVM_VCORE(r13)
1522         lwz     r3,VCPU_PTID(r4)
1523         li      r0,1
1524         sld     r0,r0,r3
1525         addi    r6,r5,VCORE_NAPPING_THREADS
1526 32:     lwarx   r7,0,r6
1527         andc    r7,r7,r0
1528         stwcx.  r7,0,r6
1529         bne     32b
1530         li      r0,0
1531         stb     r0,HSTATE_NAPPING(r13)
1532
1533         /* see if any other thread is already exiting */
1534         lwz     r0,VCORE_ENTRY_EXIT(r5)
1535         cmpwi   r0,0x100
1536         blt     kvmppc_cede_reentry     /* if not go back to guest */
1537
1538         /* some threads are exiting, so go to the guest exit path */
1539         b       hcall_real_fallback
1540
1541         /* cede when already previously prodded case */
1542 1:      li      r0,0
1543         stb     r0,VCPU_PRODDED(r3)
1544         sync                    /* order testing prodded vs. clearing ceded */
1545         stb     r0,VCPU_CEDED(r3)
1546         li      r3,H_SUCCESS
1547         blr
1548
1549         /* we've ceded but we want to give control to the host */
1550 2:      li      r3,H_TOO_HARD
1551         blr
1552
1553 secondary_too_late:
1554         ld      r5,HSTATE_KVM_VCORE(r13)
1555         HMT_LOW
1556 13:     lbz     r3,VCORE_IN_GUEST(r5)
1557         cmpwi   r3,0
1558         bne     13b
1559         HMT_MEDIUM
1560         ld      r11,PACA_SLBSHADOWPTR(r13)
1561
1562         .rept   SLB_NUM_BOLTED
1563         ld      r5,SLBSHADOW_SAVEAREA(r11)
1564         ld      r6,SLBSHADOW_SAVEAREA+8(r11)
1565         andis.  r7,r5,SLB_ESID_V@h
1566         beq     1f
1567         slbmte  r6,r5
1568 1:      addi    r11,r11,16
1569         .endr
1570
1571 secondary_nap:
1572         /* Clear any pending IPI - assume we're a secondary thread */
1573         ld      r5, HSTATE_XICS_PHYS(r13)
1574         li      r7, XICS_XIRR
1575         lwzcix  r3, r5, r7              /* ack any pending interrupt */
1576         rlwinm. r0, r3, 0, 0xffffff     /* any pending? */
1577         beq     37f
1578         sync
1579         li      r0, 0xff
1580         li      r6, XICS_QIRR
1581         stbcix  r0, r5, r6              /* clear the IPI */
1582         stwcix  r3, r5, r7              /* EOI it */
1583 37:     sync
1584
1585         /* increment the nap count and then go to nap mode */
1586         ld      r4, HSTATE_KVM_VCORE(r13)
1587         addi    r4, r4, VCORE_NAP_COUNT
1588         lwsync                          /* make previous updates visible */
1589 51:     lwarx   r3, 0, r4
1590         addi    r3, r3, 1
1591         stwcx.  r3, 0, r4
1592         bne     51b
1593
1594 kvm_no_guest:
1595         li      r0, KVM_HWTHREAD_IN_NAP
1596         stb     r0, HSTATE_HWTHREAD_STATE(r13)
1597         li      r0, 0
1598         std     r0, HSTATE_KVM_VCPU(r13)
1599
1600         li      r3, LPCR_PECE0
1601         mfspr   r4, SPRN_LPCR
1602         rlwimi  r4, r3, 0, LPCR_PECE0 | LPCR_PECE1
1603         mtspr   SPRN_LPCR, r4
1604         isync
1605         std     r0, HSTATE_SCRATCH0(r13)
1606         ptesync
1607         ld      r0, HSTATE_SCRATCH0(r13)
1608 1:      cmpd    r0, r0
1609         bne     1b
1610         nap
1611         b       .
1612
1613 /*
1614  * Save away FP, VMX and VSX registers.
1615  * r3 = vcpu pointer
1616  */
1617 _GLOBAL(kvmppc_save_fp)
1618         mfmsr   r9
1619         ori     r8,r9,MSR_FP
1620 #ifdef CONFIG_ALTIVEC
1621 BEGIN_FTR_SECTION
1622         oris    r8,r8,MSR_VEC@h
1623 END_FTR_SECTION_IFSET(CPU_FTR_ALTIVEC)
1624 #endif
1625 #ifdef CONFIG_VSX
1626 BEGIN_FTR_SECTION
1627         oris    r8,r8,MSR_VSX@h
1628 END_FTR_SECTION_IFSET(CPU_FTR_VSX)
1629 #endif
1630         mtmsrd  r8
1631         isync
1632 #ifdef CONFIG_VSX
1633 BEGIN_FTR_SECTION
1634         reg = 0
1635         .rept   32
1636         li      r6,reg*16+VCPU_VSRS
1637         STXVD2X(reg,r6,r3)
1638         reg = reg + 1
1639         .endr
1640 FTR_SECTION_ELSE
1641 #endif
1642         reg = 0
1643         .rept   32
1644         stfd    reg,reg*8+VCPU_FPRS(r3)
1645         reg = reg + 1
1646         .endr
1647 #ifdef CONFIG_VSX
1648 ALT_FTR_SECTION_END_IFSET(CPU_FTR_VSX)
1649 #endif
1650         mffs    fr0
1651         stfd    fr0,VCPU_FPSCR(r3)
1652
1653 #ifdef CONFIG_ALTIVEC
1654 BEGIN_FTR_SECTION
1655         reg = 0
1656         .rept   32
1657         li      r6,reg*16+VCPU_VRS
1658         stvx    reg,r6,r3
1659         reg = reg + 1
1660         .endr
1661         mfvscr  vr0
1662         li      r6,VCPU_VSCR
1663         stvx    vr0,r6,r3
1664 END_FTR_SECTION_IFSET(CPU_FTR_ALTIVEC)
1665 #endif
1666         mfspr   r6,SPRN_VRSAVE
1667         stw     r6,VCPU_VRSAVE(r3)
1668         mtmsrd  r9
1669         isync
1670         blr
1671
1672 /*
1673  * Load up FP, VMX and VSX registers
1674  * r4 = vcpu pointer
1675  */
1676         .globl  kvmppc_load_fp
1677 kvmppc_load_fp:
1678         mfmsr   r9
1679         ori     r8,r9,MSR_FP
1680 #ifdef CONFIG_ALTIVEC
1681 BEGIN_FTR_SECTION
1682         oris    r8,r8,MSR_VEC@h
1683 END_FTR_SECTION_IFSET(CPU_FTR_ALTIVEC)
1684 #endif
1685 #ifdef CONFIG_VSX
1686 BEGIN_FTR_SECTION
1687         oris    r8,r8,MSR_VSX@h
1688 END_FTR_SECTION_IFSET(CPU_FTR_VSX)
1689 #endif
1690         mtmsrd  r8
1691         isync
1692         lfd     fr0,VCPU_FPSCR(r4)
1693         MTFSF_L(fr0)
1694 #ifdef CONFIG_VSX
1695 BEGIN_FTR_SECTION
1696         reg = 0
1697         .rept   32
1698         li      r7,reg*16+VCPU_VSRS
1699         LXVD2X(reg,r7,r4)
1700         reg = reg + 1
1701         .endr
1702 FTR_SECTION_ELSE
1703 #endif
1704         reg = 0
1705         .rept   32
1706         lfd     reg,reg*8+VCPU_FPRS(r4)
1707         reg = reg + 1
1708         .endr
1709 #ifdef CONFIG_VSX
1710 ALT_FTR_SECTION_END_IFSET(CPU_FTR_VSX)
1711 #endif
1712
1713 #ifdef CONFIG_ALTIVEC
1714 BEGIN_FTR_SECTION
1715         li      r7,VCPU_VSCR
1716         lvx     vr0,r7,r4
1717         mtvscr  vr0
1718         reg = 0
1719         .rept   32
1720         li      r7,reg*16+VCPU_VRS
1721         lvx     reg,r7,r4
1722         reg = reg + 1
1723         .endr
1724 END_FTR_SECTION_IFSET(CPU_FTR_ALTIVEC)
1725 #endif
1726         lwz     r7,VCPU_VRSAVE(r4)
1727         mtspr   SPRN_VRSAVE,r7
1728         blr