Merge branch 'for-linus-3.6-rc1' of git://git.kernel.org/pub/scm/linux/kernel/git...
[linux-3.10.git] / arch / powerpc / kernel / vdso64 / vdso64.lds.S
1 /*
2  * This is the infamous ld script for the 64 bits vdso
3  * library
4  */
5 #include <asm/vdso.h>
6
7 OUTPUT_FORMAT("elf64-powerpc", "elf64-powerpc", "elf64-powerpc")
8 OUTPUT_ARCH(powerpc:common64)
9 ENTRY(_start)
10
11 SECTIONS
12 {
13         . = VDSO64_LBASE + SIZEOF_HEADERS;
14
15         .hash           : { *(.hash) }                  :text
16         .gnu.hash       : { *(.gnu.hash) }
17         .dynsym         : { *(.dynsym) }
18         .dynstr         : { *(.dynstr) }
19         .gnu.version    : { *(.gnu.version) }
20         .gnu.version_d  : { *(.gnu.version_d) }
21         .gnu.version_r  : { *(.gnu.version_r) }
22
23         .note           : { *(.note.*) }                :text   :note
24
25         . = ALIGN(16);
26         .text           : {
27                 *(.text .stub .text.* .gnu.linkonce.t.* __ftr_alt_*)
28                 *(.sfpr .glink)
29         }                                               :text
30         PROVIDE(__etext = .);
31         PROVIDE(_etext = .);
32         PROVIDE(etext = .);
33
34         . = ALIGN(8);
35         __ftr_fixup     : { *(__ftr_fixup) }
36
37         . = ALIGN(8);
38         __mmu_ftr_fixup : { *(__mmu_ftr_fixup) }
39
40         . = ALIGN(8);
41         __lwsync_fixup  : { *(__lwsync_fixup) }
42
43         . = ALIGN(8);
44         __fw_ftr_fixup  : { *(__fw_ftr_fixup) }
45
46         /*
47          * Other stuff is appended to the text segment:
48          */
49         .rodata         : { *(.rodata .rodata.* .gnu.linkonce.r.*) }
50         .rodata1        : { *(.rodata1) }
51
52         .dynamic        : { *(.dynamic) }               :text   :dynamic
53
54         .eh_frame_hdr   : { *(.eh_frame_hdr) }          :text   :eh_frame_hdr
55         .eh_frame       : { KEEP (*(.eh_frame)) }       :text
56         .gcc_except_table : { *(.gcc_except_table) }
57         .rela.dyn ALIGN(8) : { *(.rela.dyn) }
58
59         .opd ALIGN(8)   : { KEEP (*(.opd)) }
60         .got ALIGN(8)   : { *(.got .toc) }
61
62         _end = .;
63         PROVIDE(end = .);
64
65         /*
66          * Stabs debugging sections are here too.
67          */
68         .stab          0 : { *(.stab) }
69         .stabstr       0 : { *(.stabstr) }
70         .stab.excl     0 : { *(.stab.excl) }
71         .stab.exclstr  0 : { *(.stab.exclstr) }
72         .stab.index    0 : { *(.stab.index) }
73         .stab.indexstr 0 : { *(.stab.indexstr) }
74         .comment       0 : { *(.comment) }
75
76         /*
77          * DWARF debug sections.
78          * Symbols in the DWARF debugging sections are relative to the beginning
79          * of the section so we begin them at 0.
80          */
81         /* DWARF 1 */
82         .debug          0 : { *(.debug) }
83         .line           0 : { *(.line) }
84         /* GNU DWARF 1 extensions */
85         .debug_srcinfo  0 : { *(.debug_srcinfo) }
86         .debug_sfnames  0 : { *(.debug_sfnames) }
87         /* DWARF 1.1 and DWARF 2 */
88         .debug_aranges  0 : { *(.debug_aranges) }
89         .debug_pubnames 0 : { *(.debug_pubnames) }
90         /* DWARF 2 */
91         .debug_info     0 : { *(.debug_info .gnu.linkonce.wi.*) }
92         .debug_abbrev   0 : { *(.debug_abbrev) }
93         .debug_line     0 : { *(.debug_line) }
94         .debug_frame    0 : { *(.debug_frame) }
95         .debug_str      0 : { *(.debug_str) }
96         .debug_loc      0 : { *(.debug_loc) }
97         .debug_macinfo  0 : { *(.debug_macinfo) }
98         /* SGI/MIPS DWARF 2 extensions */
99         .debug_weaknames 0 : { *(.debug_weaknames) }
100         .debug_funcnames 0 : { *(.debug_funcnames) }
101         .debug_typenames 0 : { *(.debug_typenames) }
102         .debug_varnames  0 : { *(.debug_varnames) }
103
104         /DISCARD/       : {
105                 *(.note.GNU-stack)
106                 *(.branch_lt)
107                 *(.data .data.* .gnu.linkonce.d.* .sdata*)
108                 *(.bss .sbss .dynbss .dynsbss)
109         }
110 }
111
112 /*
113  * Very old versions of ld do not recognize this name token; use the constant.
114  */
115 #define PT_GNU_EH_FRAME 0x6474e550
116
117 /*
118  * We must supply the ELF program headers explicitly to get just one
119  * PT_LOAD segment, and set the flags explicitly to make segments read-only.
120  */
121 PHDRS
122 {
123         text            PT_LOAD FILEHDR PHDRS FLAGS(5); /* PF_R|PF_X */
124         dynamic         PT_DYNAMIC FLAGS(4);            /* PF_R */
125         note            PT_NOTE FLAGS(4);               /* PF_R */
126         eh_frame_hdr    PT_GNU_EH_FRAME;
127 }
128
129 /*
130  * This controls what symbols we export from the DSO.
131  */
132 VERSION
133 {
134         VDSO_VERSION_STRING {
135         global:
136                 /*
137                  * Has to be there for the kernel to find
138                  */
139                 __kernel_datapage_offset;
140
141                 __kernel_get_syscall_map;
142                 __kernel_gettimeofday;
143                 __kernel_clock_gettime;
144                 __kernel_clock_getres;
145                 __kernel_get_tbfreq;
146                 __kernel_sync_dicache;
147                 __kernel_sync_dicache_p5;
148                 __kernel_sigtramp_rt64;
149                 __kernel_getcpu;
150
151         local: *;
152         };
153 }