8ba8dfd0531ed6a59d73c415eec53d9d3de50d33
[linux-3.10.git] / arch / arm / mm / proc-v7-3level.S
1 /*
2  * arch/arm/mm/proc-v7-3level.S
3  *
4  * Copyright (C) 2001 Deep Blue Solutions Ltd.
5  * Copyright (C) 2011 ARM Ltd.
6  * Author: Catalin Marinas <catalin.marinas@arm.com>
7  *   based on arch/arm/mm/proc-v7-2level.S
8  *
9  * This program is free software; you can redistribute it and/or modify
10  * it under the terms of the GNU General Public License version 2 as
11  * published by the Free Software Foundation.
12  *
13  * This program is distributed in the hope that it will be useful,
14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
16  * GNU General Public License for more details.
17  *
18  * You should have received a copy of the GNU General Public License
19  * along with this program; if not, write to the Free Software
20  * Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
21  */
22
23 #define TTB_IRGN_NC     (0 << 8)
24 #define TTB_IRGN_WBWA   (1 << 8)
25 #define TTB_IRGN_WT     (2 << 8)
26 #define TTB_IRGN_WB     (3 << 8)
27 #define TTB_RGN_NC      (0 << 10)
28 #define TTB_RGN_OC_WBWA (1 << 10)
29 #define TTB_RGN_OC_WT   (2 << 10)
30 #define TTB_RGN_OC_WB   (3 << 10)
31 #define TTB_S           (3 << 12)
32 #define TTB_EAE         (1 << 31)
33
34 /* PTWs cacheable, inner WB not shareable, outer WB not shareable */
35 #define TTB_FLAGS_UP    (TTB_IRGN_WB|TTB_RGN_OC_WB)
36 #define PMD_FLAGS_UP    (PMD_SECT_WB)
37
38 /* PTWs cacheable, inner WBWA shareable, outer WBWA not shareable */
39 #define TTB_FLAGS_SMP   (TTB_IRGN_WBWA|TTB_S|TTB_RGN_OC_WBWA)
40 #define PMD_FLAGS_SMP   (PMD_SECT_WBWA|PMD_SECT_S)
41
42 #ifndef __ARMEB__
43 #  define rpgdl r0
44 #  define rpgdh r1
45 #else
46 #  define rpgdl r1
47 #  define rpgdh r0
48 #endif
49
50 /*
51  * cpu_v7_switch_mm(pgd_phys, tsk)
52  *
53  * Set the translation table base pointer to be pgd_phys (physical address of
54  * the new TTB).
55  */
56 ENTRY(cpu_v7_icinv_switch_mm)
57 #ifdef CONFIG_MMU
58         /*
59          * Cortex-A15 requires ACTLR[0] to be set from secure in order
60          * for the icache invalidation to also invalidate the BTB.
61          */
62         mcr     p15, 0, r0, c7, c5, 0           @ ICIALLU
63         /* Fall through to switch_mm... */
64 #endif
65 ENTRY(cpu_v7_switch_mm)
66 #ifdef CONFIG_MMU
67         mmid    r2, r2                          @ get mm->context.id
68         asid    r2, r2
69         mov     r2, r2, lsl #(48 - 32)          @ ASID
70         orr     rpgdh, rpgdh, r2                @ upper 32-bits of pgd phys
71         mcrr    p15, 0, rpgdl, rpgdh, c2        @ set TTB 0
72         isb
73 #endif
74         mov     pc, lr
75 ENDPROC(cpu_v7_switch_mm)
76 ENDPROC(cpu_v7_icinv_switch_mm)
77
78 /*
79  * cpu_v7_set_pte_ext(ptep, pte)
80  *
81  * Set a level 2 translation table entry.
82  * - ptep - pointer to level 3 translation table entry
83  * - pte - PTE value to store (64-bit in r2 and r3)
84  */
85 ENTRY(cpu_v7_set_pte_ext)
86 #ifdef CONFIG_MMU
87         tst     r2, #L_PTE_VALID
88         beq     1f
89         tst     r3, #1 << (57 - 32)             @ L_PTE_NONE
90         bicne   r2, #L_PTE_VALID
91         bne     1f
92         tst     r3, #1 << (55 - 32)             @ L_PTE_DIRTY
93         orreq   r2, #L_PTE_RDONLY
94 1:      strd    r2, r3, [r0]
95         ALT_SMP(W(nop))
96         ALT_UP (mcr     p15, 0, r0, c7, c10, 1)         @ flush_pte
97 #endif
98         mov     pc, lr
99 ENDPROC(cpu_v7_set_pte_ext)
100
101         /*
102          * Memory region attributes for LPAE (defined in pgtable-3level.h):
103          *
104          *   n = AttrIndx[2:0]
105          *
106          *                      n       MAIR
107          *   UNCACHED           000     00000000
108          *   BUFFERABLE         001     01000100
109          *   DEV_WC             001     01000100
110          *   WRITETHROUGH       010     10101010
111          *   WRITEBACK          011     11101110
112          *   DEV_CACHED         011     11101110
113          *   DEV_SHARED         100     00000100
114          *   DEV_NONSHARED      100     00000100
115          *   unused             101
116          *   unused             110
117          *   WRITEALLOC         111     11111111
118          */
119 .equ    PRRR,   0xeeaa4400                      @ MAIR0
120 .equ    NMRR,   0xff000004                      @ MAIR1
121
122         /*
123          * Macro for setting up the TTBRx and TTBCR registers.
124          * - \ttbr1 updated.
125          */
126         .macro  v7_ttb_setup, zero, ttbr0, ttbr1, tmp
127         ldr     \tmp, =swapper_pg_dir           @ swapper_pg_dir virtual address
128         cmp     \ttbr1, \tmp                    @ PHYS_OFFSET > PAGE_OFFSET? (branch below)
129         mrc     p15, 0, \tmp, c2, c0, 2         @ TTB control register
130         orr     \tmp, \tmp, #TTB_EAE
131         ALT_SMP(orr     \tmp, \tmp, #TTB_FLAGS_SMP)
132         ALT_UP(orr      \tmp, \tmp, #TTB_FLAGS_UP)
133         ALT_SMP(orr     \tmp, \tmp, #TTB_FLAGS_SMP << 16)
134         ALT_UP(orr      \tmp, \tmp, #TTB_FLAGS_UP << 16)
135         /*
136          * TTBR0/TTBR1 split (PAGE_OFFSET):
137          *   0x40000000: T0SZ = 2, T1SZ = 0 (not used)
138          *   0x80000000: T0SZ = 0, T1SZ = 1
139          *   0xc0000000: T0SZ = 0, T1SZ = 2
140          *
141          * Only use this feature if PHYS_OFFSET <= PAGE_OFFSET, otherwise
142          * booting secondary CPUs would end up using TTBR1 for the identity
143          * mapping set up in TTBR0.
144          */
145         bhi     9001f                           @ PHYS_OFFSET > PAGE_OFFSET?
146         orr     \tmp, \tmp, #(((PAGE_OFFSET >> 30) - 1) << 16) @ TTBCR.T1SZ
147 #if defined CONFIG_VMSPLIT_2G
148         /* PAGE_OFFSET == 0x80000000, T1SZ == 1 */
149         add     \ttbr1, \ttbr1, #1 << 4         @ skip two L1 entries
150 #elif defined CONFIG_VMSPLIT_3G
151         /* PAGE_OFFSET == 0xc0000000, T1SZ == 2 */
152         add     \ttbr1, \ttbr1, #4096 * (1 + 3) @ only L2 used, skip pgd+3*pmd
153 #endif
154         /* CONFIG_VMSPLIT_1G does not need TTBR1 adjustment */
155 9001:   mcr     p15, 0, \tmp, c2, c0, 2         @ TTB control register
156         mcrr    p15, 1, \ttbr1, \zero, c2       @ load TTBR1
157         .endm
158
159         __CPUINIT
160
161         /*
162          *   AT
163          *  TFR   EV X F   IHD LR    S
164          * .EEE ..EE PUI. .TAT 4RVI ZWRS BLDP WCAM
165          * rxxx rrxx xxx0 0101 xxxx xxxx x111 xxxx < forced
166          *   11    0 110    1  0011 1100 .111 1101 < we want
167          */
168         .align  2
169         .type   v7_crval, #object
170 v7_crval:
171         crval   clear=0x0120c302, mmuset=0x30c23c7d, ucset=0x00c01c7c
172
173         .previous