6a57c9bc11f1fd5cf18389c9694b44bac82a5754
[linux-3.10.git] / arch / arm / mach-tegra / headsmp.S
1 /*
2  * arch/arm/mach-tegra/headsmp.S
3  *
4  * CPU initialization routines for Tegra SoCs
5  *
6  * Copyright (c) 2009-2012, NVIDIA Corporation.
7  * Copyright (c) 2011 Google, Inc.
8  * Author: Colin Cross <ccross@android.com>
9  *         Gary King <gking@nvidia.com>
10  *
11  * This program is free software; you can redistribute it and/or modify
12  * it under the terms of the GNU General Public License as published by
13  * the Free Software Foundation; either version 2 of the License.
14  *
15  * This program is distributed in the hope that it will be useful, but WITHOUT
16  * ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
17  * FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License for
18  * more details.
19  */
20
21 #include <linux/linkage.h>
22 #include <linux/init.h>
23
24 #include <asm/assembler.h>
25 #include <asm/cache.h>
26 #include <asm/page.h>
27
28 #include "flowctrl.h"
29 #include "iomap.h"
30 #include "sleep.h"
31 #include "reset.h"
32
33 #define APB_MISC_GP_HIDREV      0x804
34 #define PMC_SCRATCH41   0x140
35
36 #define DEBUG_CPU_RESET_HANDLER 0       /* Non-zero enables debug code */
37
38 #define RESET_DATA(x)   ((TEGRA_RESET_##x)*4)
39
40 #ifdef CONFIG_SMP
41 /*
42  *      tegra_secondary_startup
43  *
44  *       Initial secondary processor boot vector; jumps to kernel's
45  *       secondary_startup routine. Used for initial boot and hotplug
46  *       of secondary CPUs.
47  */
48         __CPUINIT
49 ENTRY(tegra_secondary_startup)
50         bl      __invalidate_cpu_state
51
52         /* enable user space perf counter access */
53         /* only accessible in secure state       */
54         mrc     p15, 0, r0, c9, c12, 0
55         lsr     r0, #11
56         and     r0, r0, #0x1f
57         movt    r0, #0x8000
58         mcr     p15, 0, r0, c9, c14, 2
59         mov     r0, #1
60         mcr     p15, 0, r0, c9, c14, 0
61
62 #ifdef CONFIG_ARCH_TEGRA_11x_SOC
63         cpu_id  r0
64         cpu_to_csr_reg  r1, r0
65         mov32   r2, TEGRA_FLOW_CTRL_BASE
66         mov     r0, #0
67         str     r0, [r2, r1]
68 #endif
69
70         b       secondary_startup
71 ENDPROC(tegra_secondary_startup)
72 #endif
73
74         .section ".text.head", "ax"
75 #ifdef CONFIG_PM_SLEEP
76 /*
77  *      tegra_resume
78  *
79  *        CPU boot vector when restarting the a CPU following
80  *        an LP2 transition. Also branched to by LP0 and LP1 resume after
81  *        re-enabling sdram.
82  */
83 ENTRY(tegra_resume)
84         bl      __invalidate_cpu_state
85
86         cpu_id  r0
87 #ifndef CONFIG_TEGRA_VIRTUAL_CPUID
88         cmp     r0, #0                          @ CPU0?
89         bne     cpu_resume                      @ no
90 #endif
91
92 #ifndef CONFIG_ARCH_TEGRA_2x_SOC
93         @ Clear the flow controller flags for this CPU.
94         cpu_to_csr_reg  r1, r0
95         mov32   r2, TEGRA_FLOW_CTRL_BASE
96         ldr     r1, [r2, r1]
97         orr     r1, r1, #(1 << 15) | (1 << 14)  @ write to clear event & intr
98         movw    r0, #0x3FFD     @ enable, enable_ext, cluster_switch, immed, & bitmaps
99         bic     r1, r1, r0
100         str     r1, [r2]
101 #endif
102
103 #if defined(CONFIG_HAVE_ARM_SCU)
104         /* enable SCU */
105         mov32   r0, TEGRA_ARM_PERIF_BASE
106         ldr     r1, [r0]
107         orr     r1, r1, #1
108         str     r1, [r0]
109 #endif
110
111 #ifdef CONFIG_TRUSTED_FOUNDATIONS
112         /* wake up (should have specified args?) */
113         bl      tegra_generic_smc
114 #endif
115
116         b       cpu_resume
117 ENDPROC(tegra_resume)
118 #endif
119
120 /*
121  *      __invalidate_cpu_state
122  *
123  *        Invalidates volatile CPU state (SCU tags, caches, branch address
124  *        arrays, exclusive monitor, etc.) so that they can be safely enabled
125  *        instruction caching and branch predicition enabled
126  */
127 __invalidate_cpu_state:
128         clrex
129         mov     r0, #0
130         mcr     p15, 0, r0, c1, c0, 1   @ disable SMP, prefetch, broadcast
131         isb
132         mcr     p15, 0, r0, c7, c5, 0   @ invalidate BTAC, i-cache
133         mcr     p15, 0, r0, c7, c5, 6   @ invalidate branch pred array
134         mcr     p15, 0, r0, c8, c5, 0   @ invalidate instruction TLB
135         mcr     p15, 0, r0, c8, c6, 0   @ invalidate data TLB
136         mcr     p15, 0, r0, c8, c7, 0   @ invalidate unified TLB
137         dsb
138         isb
139
140 #if defined(CONFIG_HAVE_ARM_SCU)
141         cpu_id  r0
142         cmp     r0, #0
143         mov32   r1, (TEGRA_ARM_PERIF_BASE + 0xC)
144         movne   r0, r0, lsl #2
145         movne   r2, #0xf
146         movne   r2, r2, lsl r0
147         strne   r2, [r1]                @ invalidate SCU tags for CPU
148 #else
149         /*      This is only needed for cluster 0 with integrated L2 cache */
150         mov32   r0, TEGRA_FLOW_CTRL_BASE+0x2c   @ CLUSTER_CONTROL
151         ldr     r0, [r0]
152         tst     r0, #1
153         movne   pc, lr
154         mrc     p15, 0x1, r0, c9, c0, 2
155         and     r1, r0, #7
156         cmp     r1, #2
157         moveq   pc, lr
158         bic     r0, r0, #7
159         orr     r0, r0, #2
160         mcr     p15, 0x1, r0, c9, c0, 2
161         mov     pc, lr
162 #endif
163
164         dsb
165         mov     r0, #0x1800
166         mcr     p15, 0, r0, c1, c0, 0   @ enable branch prediction, i-cache
167         isb
168         /* fall through */
169
170 /*
171  *      tegra_invalidate_cache
172  *
173  *        Invalidates the L1 data cache (no clean) during initial boot of a cpu
174  *
175  *        Corrupted registers: r0-r6
176  */
177 tegra_invalidate_cache:
178         mov     r0, #0
179         mcr     p15, 2, r0, c0, c0, 0
180         mrc     p15, 1, r0, c0, c0, 0
181
182         movw    r1, #0x7fff
183         and     r2, r1, r0, lsr #13
184
185         movw    r1, #0x3ff
186
187         and     r3, r1, r0, lsr #3      @ NumWays - 1
188         add     r2, r2, #1      @ NumSets
189
190         and     r0, r0, #0x7
191         add     r0, r0, #4      @ SetShift
192
193         clz     r1, r3          @ WayShift
194         add     r4, r3, #1      @ NumWays
195 1:      sub     r2, r2, #1      @ NumSets--
196         mov     r3, r4          @ Temp = NumWays
197 2:      subs    r3, r3, #1      @ Temp--
198         mov     r5, r3, lsl r1
199         mov     r6, r2, lsl r0
200         orr     r5, r5, r6      @ Reg = (Temp<<WayShift)|(NumSets<<SetShift)
201         mcr     p15, 0, r5, c7, c6, 2
202         bgt     2b
203         cmp     r2, #0
204         bgt     1b
205         dsb
206         isb
207         mov     pc, lr
208
209 /*
210  * __tegra_cpu_reset_handler_halt_failed:
211  *
212  * Alternate entry point for reset handler for cases where the
213  * WFI halt failed to take effect.
214  *
215  */
216         .align L1_CACHE_SHIFT
217 ENTRY(__tegra_cpu_reset_handler_start)
218
219 /*
220  * __tegra_cpu_reset_handler:
221  *
222  * Common handler for all CPU reset events.
223  *
224  * Register usage within the reset handler:
225  *
226  *      R7  = CPU present (to the OS) mask
227  *      R8  = CPU in LP1 state mask
228  *      R9  = CPU in LP2 state mask
229  *      R10 = CPU number
230  *      R11 = CPU mask
231  *      R12 = pointer to reset handler data
232  *
233  * NOTE: This code is copied to IRAM. All code and data accesses
234  *       must be position-independent.
235  */
236
237         .align L1_CACHE_SHIFT
238 ENTRY(__tegra_cpu_reset_handler)
239
240 /* DO NOT put any code before the !defined(CONFIG_ARM_SAVE_DEBUG_CONTEXT)
241    block below. It must be the first thing in this subroutine. */
242
243 #if !defined(CONFIG_ARM_SAVE_DEBUG_CONTEXT) || DEBUG_CPU_RESET_HANDLER
244         /* If Debug Architecture v7.1 or later, unlock the OS lock. */
245         mrc     p15, 0, r0, c0, c1, 2           @ ID_DFR0
246         and     r0, r0, #0xF                    @ coprocessor debug model
247         cmp     r0, #5                          @ debug arch >= v7.1?
248         movge   r0, #0                          @ yes, unlock debug
249         mcrge   p14, 0, r0, c1, c0, 4           @ DBGOSLAR
250 #endif
251 #if DEBUG_CPU_RESET_HANDLER
252         b       .
253 #endif
254 #ifndef CONFIG_TRUSTED_FOUNDATIONS
255         cpsid   aif, 0x13                       @ SVC mode, interrupts disabled
256         mrc     p15, 0, r0, c0, c0, 0           @ read main ID register
257         and     r5, r0, #0x00f00000             @ variant
258         and     r6, r0, #0x0000000f             @ revision
259         orr     r6, r6, r5, lsr #20-4           @ combine variant and revision
260 #ifdef CONFIG_ARM_ERRATA_743622
261         teq     r6, #0x20                       @ present in r2p0
262         teqne   r6, #0x21                       @ present in r2p1
263         teqne   r6, #0x22                       @ present in r2p2
264         teqne   r6, #0x27                       @ present in r2p7
265         teqne   r6, #0x29                       @ present in r2p9
266         mrceq   p15, 0, r10, c15, c0, 1         @ read diagnostic register
267         orreq   r10, r10, #1 << 6               @ set bit #6
268         mcreq   p15, 0, r10, c15, c0, 1         @ write diagnostic register
269 #endif
270 #endif
271         mrc     p15, 0, r10, c0, c0, 5          @ MPIDR
272         and     r10, r10, #0x3                  @ R10 = CPU number
273         mov     r11, #1
274         mov     r11, r11, lsl r10               @ R11 = CPU mask
275         adr     r12, __tegra_cpu_reset_handler_data
276
277 #ifdef CONFIG_SMP
278         /* Does the OS know about this CPU? */
279         ldr     r7, [r12, #RESET_DATA(MASK_PRESENT)]
280         tst     r7, r11                         @ if !present
281         bleq    __die                           @ CPU not present (to OS)
282 #endif
283
284 #ifdef CONFIG_ARCH_TEGRA_2x_SOC
285         /* If CPU1, don't let CPU0 reset CPU1 now that CPU1 is coming up. */
286         mov32   r6, TEGRA_PMC_BASE
287         mov     r0, #0
288         cmp     r10, #0
289         strne   r0, [r6, #PMC_SCRATCH41]
290 #endif
291
292 #ifdef CONFIG_PM_SLEEP
293         /* Waking up from LP1? */
294         ldr     r8, [r12, #RESET_DATA(MASK_LP1)]
295         tst     r8, r11                         @ if in_lp1
296         beq     __is_not_lp1
297         cmp     r10, #0
298         bne     __die                           @ only CPU0 can be here
299         ldr     lr, [r12, #RESET_DATA(STARTUP_LP1)]
300         cmp     lr, #0
301         bleq    __die                           @ no LP1 startup handler
302         bx      lr
303 __is_not_lp1:
304 #endif
305
306         /* Waking up from LP2? */
307         ldr     r9, [r12, #RESET_DATA(MASK_LP2)]
308         tst     r9, r11                         @ if in_lp2
309         beq     __is_not_lp2
310         ldr     lr, [r12, #RESET_DATA(STARTUP_LP2)]
311         cmp     lr, #0
312         bleq    __die                           @ no LP2 startup handler
313         bx      lr
314
315 __is_not_lp2:
316
317 #ifdef CONFIG_SMP
318 #ifndef CONFIG_TEGRA_VIRTUAL_CPUID
319         /* Can only be secondary boot (initial or hotplug) but CPU 0
320            cannot be here. */
321         cmp     r10, #0
322         bleq    __die                           @ CPU0 cannot be here
323 #endif
324         ldr     lr, [r12, #RESET_DATA(STARTUP_SECONDARY)]
325         cmp     lr, #0
326         bleq    __die                           @ no secondary startup handler
327         bx      lr
328 #endif
329
330 /*
331  * We don't know why the CPU reset. Just kill it.
332  * The LR register will contain the address we died at + 4.
333  */
334
335 __die:
336         sub     lr, lr, #4
337         mov32   r7, TEGRA_PMC_BASE
338         str     lr, [r7, #PMC_SCRATCH41]
339
340         mov32   r7, TEGRA_CLK_RESET_BASE
341
342         /* Are we on Tegra20? */
343         mov32   r6, TEGRA_APB_MISC_BASE
344         ldr     r0, [r6, #APB_MISC_GP_HIDREV]
345         and     r0, r0, #0xff00
346         cmp     r0, #(0x20 << 8)
347         bne     1f
348
349 #ifdef CONFIG_ARCH_TEGRA_2x_SOC
350         mov32   r0, 0x1111
351         mov     r1, r0, lsl r10
352         str     r1, [r7, #0x340]                @ CLK_RST_CPU_CMPLX_SET
353 #endif
354 1:
355 #ifdef CONFIG_ARCH_TEGRA_3x_SOC
356         mov32   r6, TEGRA_FLOW_CTRL_BASE
357
358         cmp     r10, #0
359         moveq   r1, #FLOW_CTRL_HALT_CPU0_EVENTS
360         moveq   r2, #FLOW_CTRL_CPU0_CSR
361         movne   r1, r10, lsl #3
362         addne   r2, r1, #(FLOW_CTRL_CPU1_CSR-8)
363         addne   r1, r1, #(FLOW_CTRL_HALT_CPU1_EVENTS-8)
364
365         /* Clear CPU "event" and "interrupt" flags and power gate
366            it when halting but not before it is in the "WFI" state. */
367         ldr     r0, [r6, +r2]
368         orr     r0, r0, #FLOW_CTRL_CSR_INTR_FLAG | FLOW_CTRL_CSR_EVENT_FLAG
369         orr     r0, r0, #FLOW_CTRL_CSR_ENABLE
370         str     r0, [r6, +r2]
371
372         /* Unconditionally halt this CPU */
373         mov     r0, #FLOW_CTRL_WAITEVENT
374         str     r0, [r6, +r1]
375         ldr     r0, [r6, +r1]                   @ memory barrier
376
377         dsb
378         isb
379         wfi                                     @ CPU should be power gated here
380
381         /* If the CPU didn't power gate above just kill it's clock. */
382
383         mov     r0, r11, lsl #8
384         str     r0, [r7, #348]                  @ CLK_CPU_CMPLX_SET
385 #endif
386
387         /* If the CPU still isn't dead, just spin here. */
388         b       .
389 ENDPROC(__tegra_cpu_reset_handler)
390
391         .align L1_CACHE_SHIFT
392         .type   __tegra_cpu_reset_handler_data, %object
393         .globl  __tegra_cpu_reset_handler_data
394 __tegra_cpu_reset_handler_data:
395         .rept   TEGRA_RESET_DATA_SIZE
396         .long   0
397         .endr
398         .size   __tegra_cpu_reset_handler_data, . - __tegra_cpu_reset_handler_data
399         .align L1_CACHE_SHIFT
400 ENTRY(__tegra_cpu_reset_handler_end)