ARM: 6384/1: Remove the domain switching on ARMv6k/v7 CPUs
[linux-3.10.git] / arch / arm / lib / putuser.S
1 /*
2  *  linux/arch/arm/lib/putuser.S
3  *
4  *  Copyright (C) 2001 Russell King
5  *
6  * This program is free software; you can redistribute it and/or modify
7  * it under the terms of the GNU General Public License version 2 as
8  * published by the Free Software Foundation.
9  *
10  *  Idea from x86 version, (C) Copyright 1998 Linus Torvalds
11  *
12  * These functions have a non-standard call interface to make
13  * them more efficient, especially as they return an error
14  * value in addition to the "real" return value.
15  *
16  * __put_user_X
17  *
18  * Inputs:      r0 contains the address
19  *              r2, r3 contains the value
20  * Outputs:     r0 is the error code
21  *              lr corrupted
22  *
23  * No other registers must be altered.  (see <asm/uaccess.h>
24  * for specific ASM register usage).
25  *
26  * Note that ADDR_LIMIT is either 0 or 0xc0000000
27  * Note also that it is intended that __put_user_bad is not global.
28  */
29 #include <linux/linkage.h>
30 #include <asm/errno.h>
31 #include <asm/domain.h>
32
33 ENTRY(__put_user_1)
34 1:      T(strb) r2, [r0]
35         mov     r0, #0
36         mov     pc, lr
37 ENDPROC(__put_user_1)
38
39 ENTRY(__put_user_2)
40         mov     ip, r2, lsr #8
41 #ifdef CONFIG_THUMB2_KERNEL
42 #ifndef __ARMEB__
43 2:      T(strb) r2, [r0]
44 3:      T(strb) ip, [r0, #1]
45 #else
46 2:      T(strb) ip, [r0]
47 3:      T(strb) r2, [r0, #1]
48 #endif
49 #else   /* !CONFIG_THUMB2_KERNEL */
50 #ifndef __ARMEB__
51 2:      T(strb) r2, [r0], #1
52 3:      T(strb) ip, [r0]
53 #else
54 2:      T(strb) ip, [r0], #1
55 3:      T(strb) r2, [r0]
56 #endif
57 #endif  /* CONFIG_THUMB2_KERNEL */
58         mov     r0, #0
59         mov     pc, lr
60 ENDPROC(__put_user_2)
61
62 ENTRY(__put_user_4)
63 4:      T(str)  r2, [r0]
64         mov     r0, #0
65         mov     pc, lr
66 ENDPROC(__put_user_4)
67
68 ENTRY(__put_user_8)
69 #ifdef CONFIG_THUMB2_KERNEL
70 5:      T(str)  r2, [r0]
71 6:      T(str)  r3, [r0, #4]
72 #else
73 5:      T(str)  r2, [r0], #4
74 6:      T(str)  r3, [r0]
75 #endif
76         mov     r0, #0
77         mov     pc, lr
78 ENDPROC(__put_user_8)
79
80 __put_user_bad:
81         mov     r0, #-EFAULT
82         mov     pc, lr
83 ENDPROC(__put_user_bad)
84
85 .pushsection __ex_table, "a"
86         .long   1b, __put_user_bad
87         .long   2b, __put_user_bad
88         .long   3b, __put_user_bad
89         .long   4b, __put_user_bad
90         .long   5b, __put_user_bad
91         .long   6b, __put_user_bad
92 .popsection