ARM: 6384/1: Remove the domain switching on ARMv6k/v7 CPUs
[linux-3.10.git] / arch / arm / lib / getuser.S
1 /*
2  *  linux/arch/arm/lib/getuser.S
3  *
4  *  Copyright (C) 2001 Russell King
5  *
6  * This program is free software; you can redistribute it and/or modify
7  * it under the terms of the GNU General Public License version 2 as
8  * published by the Free Software Foundation.
9  *
10  *  Idea from x86 version, (C) Copyright 1998 Linus Torvalds
11  *
12  * These functions have a non-standard call interface to make them more
13  * efficient, especially as they return an error value in addition to
14  * the "real" return value.
15  *
16  * __get_user_X
17  *
18  * Inputs:      r0 contains the address
19  * Outputs:     r0 is the error code
20  *              r2, r3 contains the zero-extended value
21  *              lr corrupted
22  *
23  * No other registers must be altered.  (see <asm/uaccess.h>
24  * for specific ASM register usage).
25  *
26  * Note that ADDR_LIMIT is either 0 or 0xc0000000.
27  * Note also that it is intended that __get_user_bad is not global.
28  */
29 #include <linux/linkage.h>
30 #include <asm/errno.h>
31 #include <asm/domain.h>
32
33 ENTRY(__get_user_1)
34 1:      T(ldrb) r2, [r0]
35         mov     r0, #0
36         mov     pc, lr
37 ENDPROC(__get_user_1)
38
39 ENTRY(__get_user_2)
40 #ifdef CONFIG_THUMB2_KERNEL
41 2:      T(ldrb) r2, [r0]
42 3:      T(ldrb) r3, [r0, #1]
43 #else
44 2:      T(ldrb) r2, [r0], #1
45 3:      T(ldrb) r3, [r0]
46 #endif
47 #ifndef __ARMEB__
48         orr     r2, r2, r3, lsl #8
49 #else
50         orr     r2, r3, r2, lsl #8
51 #endif
52         mov     r0, #0
53         mov     pc, lr
54 ENDPROC(__get_user_2)
55
56 ENTRY(__get_user_4)
57 4:      T(ldr)  r2, [r0]
58         mov     r0, #0
59         mov     pc, lr
60 ENDPROC(__get_user_4)
61
62 __get_user_bad:
63         mov     r2, #0
64         mov     r0, #-EFAULT
65         mov     pc, lr
66 ENDPROC(__get_user_bad)
67
68 .pushsection __ex_table, "a"
69         .long   1b, __get_user_bad
70         .long   2b, __get_user_bad
71         .long   3b, __get_user_bad
72         .long   4b, __get_user_bad
73 .popsection