ARM: convert to use __HEAD and HEAD_TEXT macros.
[linux-3.10.git] / arch / arm / kernel / vmlinux.lds.S
1 /* ld script to make ARM Linux kernel
2  * taken from the i386 version by Russell King
3  * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>
4  */
5
6 #include <asm-generic/vmlinux.lds.h>
7 #include <asm/thread_info.h>
8 #include <asm/memory.h>
9 #include <asm/page.h>
10         
11 OUTPUT_ARCH(arm)
12 ENTRY(stext)
13
14 #ifndef __ARMEB__
15 jiffies = jiffies_64;
16 #else
17 jiffies = jiffies_64 + 4;
18 #endif
19
20 SECTIONS
21 {
22 #ifdef CONFIG_XIP_KERNEL
23         . = XIP_VIRT_ADDR(CONFIG_XIP_PHYS_ADDR);
24 #else
25         . = PAGE_OFFSET + TEXT_OFFSET;
26 #endif
27
28         .init : {                       /* Init code and data           */
29                 _stext = .;
30                 _sinittext = .;
31                         HEAD_TEXT
32                         INIT_TEXT
33                 _einittext = .;
34                 __proc_info_begin = .;
35                         *(.proc.info.init)
36                 __proc_info_end = .;
37                 __arch_info_begin = .;
38                         *(.arch.info.init)
39                 __arch_info_end = .;
40                 __tagtable_begin = .;
41                         *(.taglist.init)
42                 __tagtable_end = .;
43                 . = ALIGN(16);
44                 __setup_start = .;
45                         *(.init.setup)
46                 __setup_end = .;
47                 __early_begin = .;
48                         *(.early_param.init)
49                 __early_end = .;
50                 __initcall_start = .;
51                         INITCALLS
52                 __initcall_end = .;
53                 __con_initcall_start = .;
54                         *(.con_initcall.init)
55                 __con_initcall_end = .;
56                 __security_initcall_start = .;
57                         *(.security_initcall.init)
58                 __security_initcall_end = .;
59 #ifdef CONFIG_BLK_DEV_INITRD
60                 . = ALIGN(32);
61                 __initramfs_start = .;
62                         usr/built-in.o(.init.ramfs)
63                 __initramfs_end = .;
64 #endif
65                 . = ALIGN(PAGE_SIZE);
66                 __per_cpu_load = .;
67                 __per_cpu_start = .;
68                         *(.data.percpu.page_aligned)
69                         *(.data.percpu)
70                         *(.data.percpu.shared_aligned)
71                 __per_cpu_end = .;
72 #ifndef CONFIG_XIP_KERNEL
73                 __init_begin = _stext;
74                 INIT_DATA
75                 . = ALIGN(PAGE_SIZE);
76                 __init_end = .;
77 #endif
78         }
79
80         /DISCARD/ : {                   /* Exit code and data           */
81                 EXIT_TEXT
82                 EXIT_DATA
83                 *(.exitcall.exit)
84                 *(.discard)
85                 *(.ARM.exidx.exit.text)
86                 *(.ARM.extab.exit.text)
87 #ifndef CONFIG_HOTPLUG_CPU
88                 *(.ARM.exidx.cpuexit.text)
89                 *(.ARM.extab.cpuexit.text)
90 #endif
91 #ifndef CONFIG_HOTPLUG
92                 *(.ARM.exidx.devexit.text)
93                 *(.ARM.extab.devexit.text)
94 #endif
95 #ifndef CONFIG_MMU
96                 *(.fixup)
97                 *(__ex_table)
98 #endif
99         }
100
101         .text : {                       /* Real text segment            */
102                 _text = .;              /* Text and read-only data      */
103                         __exception_text_start = .;
104                         *(.exception.text)
105                         __exception_text_end = .;
106                         TEXT_TEXT
107                         SCHED_TEXT
108                         LOCK_TEXT
109                         KPROBES_TEXT
110 #ifdef CONFIG_MMU
111                         *(.fixup)
112 #endif
113                         *(.gnu.warning)
114                         *(.rodata)
115                         *(.rodata.*)
116                         *(.glue_7)
117                         *(.glue_7t)
118                 *(.got)                 /* Global offset table          */
119         }
120
121         RO_DATA(PAGE_SIZE)
122
123         _etext = .;                     /* End of text and rodata section */
124
125 #ifdef CONFIG_ARM_UNWIND
126         /*
127          * Stack unwinding tables
128          */
129         . = ALIGN(8);
130         .ARM.unwind_idx : {
131                 __start_unwind_idx = .;
132                 *(.ARM.exidx*)
133                 __stop_unwind_idx = .;
134         }
135         .ARM.unwind_tab : {
136                 __start_unwind_tab = .;
137                 *(.ARM.extab*)
138                 __stop_unwind_tab = .;
139         }
140 #endif
141
142 #ifdef CONFIG_XIP_KERNEL
143         __data_loc = ALIGN(4);          /* location in binary */
144         . = PAGE_OFFSET + TEXT_OFFSET;
145 #else
146         . = ALIGN(THREAD_SIZE);
147         __data_loc = .;
148 #endif
149
150         .data : AT(__data_loc) {
151                 _data = .;              /* address in memory */
152                 _sdata = .;
153
154                 /*
155                  * first, the init task union, aligned
156                  * to an 8192 byte boundary.
157                  */
158                 *(.data.init_task)
159
160 #ifdef CONFIG_XIP_KERNEL
161                 . = ALIGN(PAGE_SIZE);
162                 __init_begin = .;
163                 INIT_DATA
164                 . = ALIGN(PAGE_SIZE);
165                 __init_end = .;
166 #endif
167
168                 . = ALIGN(PAGE_SIZE);
169                 __nosave_begin = .;
170                 *(.data.nosave)
171                 . = ALIGN(PAGE_SIZE);
172                 __nosave_end = .;
173
174                 /*
175                  * then the cacheline aligned data
176                  */
177                 . = ALIGN(32);
178                 *(.data.cacheline_aligned)
179
180                 /*
181                  * The exception fixup table (might need resorting at runtime)
182                  */
183                 . = ALIGN(32);
184                 __start___ex_table = .;
185 #ifdef CONFIG_MMU
186                 *(__ex_table)
187 #endif
188                 __stop___ex_table = .;
189
190                 /*
191                  * and the usual data section
192                  */
193                 DATA_DATA
194                 CONSTRUCTORS
195
196                 _edata = .;
197         }
198         _edata_loc = __data_loc + SIZEOF(.data);
199
200 #ifdef CONFIG_HAVE_TCM
201         /*
202          * We align everything to a page boundary so we can
203          * free it after init has commenced and TCM contents have
204          * been copied to its destination.
205          */
206         .tcm_start : {
207                 . = ALIGN(PAGE_SIZE);
208                 __tcm_start = .;
209                 __itcm_start = .;
210         }
211
212         /*
213          * Link these to the ITCM RAM
214          * Put VMA to the TCM address and LMA to the common RAM
215          * and we'll upload the contents from RAM to TCM and free
216          * the used RAM after that.
217          */
218         .text_itcm ITCM_OFFSET : AT(__itcm_start)
219         {
220                 __sitcm_text = .;
221                 *(.tcm.text)
222                 *(.tcm.rodata)
223                 . = ALIGN(4);
224                 __eitcm_text = .;
225         }
226
227         /*
228          * Reset the dot pointer, this is needed to create the
229          * relative __dtcm_start below (to be used as extern in code).
230          */
231         . = ADDR(.tcm_start) + SIZEOF(.tcm_start) + SIZEOF(.text_itcm);
232
233         .dtcm_start : {
234                 __dtcm_start = .;
235         }
236
237         /* TODO: add remainder of ITCM as well, that can be used for data! */
238         .data_dtcm DTCM_OFFSET : AT(__dtcm_start)
239         {
240                 . = ALIGN(4);
241                 __sdtcm_data = .;
242                 *(.tcm.data)
243                 . = ALIGN(4);
244                 __edtcm_data = .;
245         }
246
247         /* Reset the dot pointer or the linker gets confused */
248         . = ADDR(.dtcm_start) + SIZEOF(.data_dtcm);
249
250         /* End marker for freeing TCM copy in linked object */
251         .tcm_end : AT(ADDR(.dtcm_start) + SIZEOF(.data_dtcm)){
252                 . = ALIGN(PAGE_SIZE);
253                 __tcm_end = .;
254         }
255 #endif
256
257         .bss : {
258                 __bss_start = .;        /* BSS                          */
259                 *(.bss)
260                 *(COMMON)
261                 __bss_stop = .;
262                 _end = .;
263         }
264                                         /* Stabs debugging sections.    */
265         .stab 0 : { *(.stab) }
266         .stabstr 0 : { *(.stabstr) }
267         .stab.excl 0 : { *(.stab.excl) }
268         .stab.exclstr 0 : { *(.stab.exclstr) }
269         .stab.index 0 : { *(.stab.index) }
270         .stab.indexstr 0 : { *(.stab.indexstr) }
271         .comment 0 : { *(.comment) }
272 }
273
274 /*
275  * These must never be empty
276  * If you have to comment these two assert statements out, your
277  * binutils is too old (for other reasons as well)
278  */
279 ASSERT((__proc_info_end - __proc_info_begin), "missing CPU support")
280 ASSERT((__arch_info_end - __arch_info_begin), "no machine record defined")