arch/arm/kernel/vmlinux.lds.S

   1 /* ld script to make ARM Linux kernel
   2  * taken from the i386 version by Russell King
   3  * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>
   4  */
   5
   6 #include <asm-generic/vmlinux.lds.h>
   7 #include <asm/cache.h>
   8 #include <asm/thread_info.h>
   9 #include <asm/memory.h>
  10 #include <asm/page.h>
  11
  12 #define PROC_INFO                                                       \
  13         . = ALIGN(4);                                                   \
  14         VMLINUX_SYMBOL(__proc_info_begin) = .;                          \
  15         *(.proc.info.init)                                              \
  16         VMLINUX_SYMBOL(__proc_info_end) = .;
  17
  18 #define IDMAP_TEXT                                                      \
  19         ALIGN_FUNCTION();                                               \
  20         VMLINUX_SYMBOL(__idmap_text_start) = .;                         \
  21         *(.idmap.text)                                                  \
  22         VMLINUX_SYMBOL(__idmap_text_end) = .;                           \
  23         . = ALIGN(32);                                                  \
  24         VMLINUX_SYMBOL(__hyp_idmap_text_start) = .;                     \
  25         *(.hyp.idmap.text)                                              \
  26         VMLINUX_SYMBOL(__hyp_idmap_text_end) = .;
  27
  28 #ifdef CONFIG_HOTPLUG_CPU
  29 #define ARM_CPU_DISCARD(x)
  30 #define ARM_CPU_KEEP(x)         x
  31 #else
  32 #define ARM_CPU_DISCARD(x)      x
  33 #define ARM_CPU_KEEP(x)
  34 #endif
  35
  36 #if (defined(CONFIG_SMP_ON_UP) && !defined(CONFIG_DEBUG_SPINLOCK)) || \
  37         defined(CONFIG_GENERIC_BUG)
  38 #define ARM_EXIT_KEEP(x)        x
  39 #define ARM_EXIT_DISCARD(x)
  40 #else
  41 #define ARM_EXIT_KEEP(x)
  42 #define ARM_EXIT_DISCARD(x)     x
  43 #endif
  44
  45 OUTPUT_ARCH(arm)
  46 ENTRY(stext)
  47
  48 #ifndef __ARMEB__
  49 jiffies = jiffies_64;
  50 #else
  51 jiffies = jiffies_64 + 4;
  52 #endif
  53
  54 SECTIONS
  55 {
  56         /*
  57          * XXX: The linker does not define how output sections are
  58          * assigned to input sections when there are multiple statements
  59          * matching the same input section name.  There is no documented
  60          * order of matching.
  61          *
  62          * unwind exit sections must be discarded before the rest of the
  63          * unwind sections get included.
  64          */
  65         /DISCARD/ : {
  66                 *(.ARM.exidx.exit.text)
  67                 *(.ARM.extab.exit.text)
  68                 ARM_CPU_DISCARD(*(.ARM.exidx.cpuexit.text))
  69                 ARM_CPU_DISCARD(*(.ARM.extab.cpuexit.text))
  70                 ARM_EXIT_DISCARD(EXIT_TEXT)
  71                 ARM_EXIT_DISCARD(EXIT_DATA)
  72                 EXIT_CALL
  73 #ifndef CONFIG_HOTPLUG
  74                 *(.ARM.exidx.devexit.text)
  75                 *(.ARM.extab.devexit.text)
  76 #endif
  77 #ifndef CONFIG_MMU
  78                 *(.fixup)
  79                 *(__ex_table)
  80 #endif
  81 #ifndef CONFIG_SMP_ON_UP
  82                 *(.alt.smp.init)
  83 #endif
  84                 *(.discard)
  85                 *(.discard.*)
  86         }
  87
  88 #ifdef CONFIG_XIP_KERNEL
  89         . = XIP_VIRT_ADDR(CONFIG_XIP_PHYS_ADDR);
  90 #else
  91         . = PAGE_OFFSET + TEXT_OFFSET;
  92 #endif
  93         .head.text : {
  94                 _text = .;
  95                 HEAD_TEXT
  96         }
  97         .text : {                       /* Real text segment            */
  98                 _stext = .;             /* Text and read-only data      */
  99                         __exception_text_start = .;
 100                         *(.exception.text)
 101                         __exception_text_end = .;
 102                         IRQENTRY_TEXT
 103                         TEXT_TEXT
 104                         SCHED_TEXT
 105                         LOCK_TEXT
 106                         KPROBES_TEXT
 107                         IDMAP_TEXT
 108 #ifdef CONFIG_MMU
 109                         *(.fixup)
 110 #endif
 111                         *(.gnu.warning)
 112                         *(.glue_7)
 113                         *(.glue_7t)
 114                 . = ALIGN(4);
 115                 *(.got)                 /* Global offset table          */
 116                         ARM_CPU_KEEP(PROC_INFO)
 117         }
 118
 119         RO_DATA(PAGE_SIZE)
 120
 121         . = ALIGN(4);
 122         __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET) {
 123                 __start___ex_table = .;
 124 #ifdef CONFIG_MMU
 125                 *(__ex_table)
 126 #endif
 127                 __stop___ex_table = .;
 128         }
 129
 130 #ifdef CONFIG_ARM_UNWIND
 131         /*
 132          * Stack unwinding tables
 133          */
 134         . = ALIGN(8);
 135         .ARM.unwind_idx : {
 136                 __start_unwind_idx = .;
 137                 *(.ARM.exidx*)
 138                 __stop_unwind_idx = .;
 139         }
 140         .ARM.unwind_tab : {
 141                 __start_unwind_tab = .;
 142                 *(.ARM.extab*)
 143                 __stop_unwind_tab = .;
 144         }
 145 #endif
 146
 147         NOTES
 148
 149         _etext = .;                     /* End of text and rodata section */
 150
 151 #ifndef CONFIG_XIP_KERNEL
 152         . = ALIGN(PAGE_SIZE);
 153         __init_begin = .;
 154 #endif
 155         /*
 156          * The vectors and stubs are relocatable code, and the
 157          * only thing that matters is their relative offsets
 158          */
 159         __vectors_start = .;
 160         .vectors 0 : AT(__vectors_start) {
 161                 *(.vectors)
 162         }
 163         . = __vectors_start + SIZEOF(.vectors);
 164         __vectors_end = .;
 165
 166         __stubs_start = .;
 167         .stubs 0x1000 : AT(__stubs_start) {
 168                 *(.stubs)
 169         }
 170         . = __stubs_start + SIZEOF(.stubs);
 171         __stubs_end = .;
 172
 173         INIT_TEXT_SECTION(8)
 174         .exit.text : {
 175                 ARM_EXIT_KEEP(EXIT_TEXT)
 176         }
 177         .init.proc.info : {
 178                 ARM_CPU_DISCARD(PROC_INFO)
 179         }
 180         .init.arch.info : {
 181                 __arch_info_begin = .;
 182                 *(.arch.info.init)
 183                 __arch_info_end = .;
 184         }
 185         .init.tagtable : {
 186                 __tagtable_begin = .;
 187                 *(.taglist.init)
 188                 __tagtable_end = .;
 189         }
 190 #ifdef CONFIG_SMP_ON_UP
 191         .init.smpalt : {
 192                 __smpalt_begin = .;
 193                 *(.alt.smp.init)
 194                 __smpalt_end = .;
 195         }
 196 #endif
 197         .init.pv_table : {
 198                 __pv_table_begin = .;
 199                 *(.pv_table)
 200                 __pv_table_end = .;
 201         }
 202         .init.data : {
 203 #ifndef CONFIG_XIP_KERNEL
 204                 INIT_DATA
 205 #endif
 206                 INIT_SETUP(16)
 207                 INIT_CALLS
 208                 CON_INITCALL
 209                 SECURITY_INITCALL
 210                 INIT_RAM_FS
 211         }
 212 #ifndef CONFIG_XIP_KERNEL
 213         .exit.data : {
 214                 ARM_EXIT_KEEP(EXIT_DATA)
 215         }
 216 #endif
 217
 218 #ifdef CONFIG_SMP
 219         PERCPU_SECTION(L1_CACHE_BYTES)
 220 #endif
 221
 222 #ifdef CONFIG_XIP_KERNEL
 223         __data_loc = ALIGN(4);          /* location in binary */
 224         . = PAGE_OFFSET + TEXT_OFFSET;
 225 #else
 226         __init_end = .;
 227         . = ALIGN(THREAD_SIZE);
 228         __data_loc = .;
 229 #endif
 230
 231         .data : AT(__data_loc) {
 232                 _data = .;              /* address in memory */
 233                 _sdata = .;
 234
 235                 /*
 236                  * first, the init task union, aligned
 237                  * to an 8192 byte boundary.
 238                  */
 239                 INIT_TASK_DATA(THREAD_SIZE)
 240
 241 #ifdef CONFIG_XIP_KERNEL
 242                 . = ALIGN(PAGE_SIZE);
 243                 __init_begin = .;
 244                 INIT_DATA
 245                 ARM_EXIT_KEEP(EXIT_DATA)
 246                 . = ALIGN(PAGE_SIZE);
 247                 __init_end = .;
 248 #endif
 249
 250                 NOSAVE_DATA
 251                 CACHELINE_ALIGNED_DATA(L1_CACHE_BYTES)
 252                 READ_MOSTLY_DATA(L1_CACHE_BYTES)
 253
 254                 /*
 255                  * and the usual data section
 256                  */
 257                 DATA_DATA
 258                 CONSTRUCTORS
 259
 260                 _edata = .;
 261         }
 262         _edata_loc = __data_loc + SIZEOF(.data);
 263
 264 #ifdef CONFIG_HAVE_TCM
 265         /*
 266          * We align everything to a page boundary so we can
 267          * free it after init has commenced and TCM contents have
 268          * been copied to its destination.
 269          */
 270         .tcm_start : {
 271                 . = ALIGN(PAGE_SIZE);
 272                 __tcm_start = .;
 273                 __itcm_start = .;
 274         }
 275
 276         /*
 277          * Link these to the ITCM RAM
 278          * Put VMA to the TCM address and LMA to the common RAM
 279          * and we'll upload the contents from RAM to TCM and free
 280          * the used RAM after that.
 281          */
 282         .text_itcm ITCM_OFFSET : AT(__itcm_start)
 283         {
 284                 __sitcm_text = .;
 285                 *(.tcm.text)
 286                 *(.tcm.rodata)
 287                 . = ALIGN(4);
 288                 __eitcm_text = .;
 289         }
 290
 291         /*
 292          * Reset the dot pointer, this is needed to create the
 293          * relative __dtcm_start below (to be used as extern in code).
 294          */
 295         . = ADDR(.tcm_start) + SIZEOF(.tcm_start) + SIZEOF(.text_itcm);
 296
 297         .dtcm_start : {
 298                 __dtcm_start = .;
 299         }
 300
 301         /* TODO: add remainder of ITCM as well, that can be used for data! */
 302         .data_dtcm DTCM_OFFSET : AT(__dtcm_start)
 303         {
 304                 . = ALIGN(4);
 305                 __sdtcm_data = .;
 306                 *(.tcm.data)
 307                 . = ALIGN(4);
 308                 __edtcm_data = .;
 309         }
 310
 311         /* Reset the dot pointer or the linker gets confused */
 312         . = ADDR(.dtcm_start) + SIZEOF(.data_dtcm);
 313
 314         /* End marker for freeing TCM copy in linked object */
 315         .tcm_end : AT(ADDR(.dtcm_start) + SIZEOF(.data_dtcm)){
 316                 . = ALIGN(PAGE_SIZE);
 317                 __tcm_end = .;
 318         }
 319 #endif
 320
 321         BSS_SECTION(0, 0, 0)
 322         _end = .;
 323
 324         STABS_DEBUG
 325         .comment 0 : { *(.comment) }
 326 }
 327
 328 /*
 329  * These must never be empty
 330  * If you have to comment these two assert statements out, your
 331  * binutils is too old (for other reasons as well)
 332  */
 333 ASSERT((__proc_info_end - __proc_info_begin), "missing CPU support")
 334 ASSERT((__arch_info_end - __arch_info_begin), "no machine record defined")
 335 /*
 336  * The HYP init code can't be more than a page long.
 337  * The above comment applies as well.
 338  */
 339 ASSERT(((__hyp_idmap_text_end - __hyp_idmap_text_start) <= PAGE_SIZE), "HYP init code too big")