ftrace: objcopy version test for local symbols
[linux-2.6.git] / scripts / recordmcount.pl
1 #!/usr/bin/perl -w
2 # (c) 2008, Steven Rostedt <srostedt@redhat.com>
3 # Licensed under the terms of the GNU GPL License version 2
4 #
5 # recordmcount.pl - makes a section called __mcount_loc that holds
6 #                   all the offsets to the calls to mcount.
7 #
8 #
9 # What we want to end up with is a section in vmlinux called
10 # __mcount_loc that contains a list of pointers to all the
11 # call sites in the kernel that call mcount. Later on boot up, the kernel
12 # will read this list, save the locations and turn them into nops.
13 # When tracing or profiling is later enabled, these locations will then
14 # be converted back to pointers to some function.
15 #
16 # This is no easy feat. This script is called just after the original
17 # object is compiled and before it is linked.
18 #
19 # The references to the call sites are offsets from the section of text
20 # that the call site is in. Hence, all functions in a section that
21 # has a call site to mcount, will have the offset from the beginning of
22 # the section and not the beginning of the function.
23 #
24 # The trick is to find a way to record the beginning of the section.
25 # The way we do this is to look at the first function in the section
26 # which will also be the location of that section after final link.
27 # e.g.
28 #
29 #  .section ".text.sched"
30 #  .globl my_func
31 #  my_func:
32 #        [...]
33 #        call mcount  (offset: 0x5)
34 #        [...]
35 #        ret
36 #  other_func:
37 #        [...]
38 #        call mcount (offset: 0x1b)
39 #        [...]
40 #
41 # Both relocation offsets for the mcounts in the above example will be
42 # offset from .text.sched. If we make another file called tmp.s with:
43 #
44 #  .section __mcount_loc
45 #  .quad  my_func + 0x5
46 #  .quad  my_func + 0x1b
47 #
48 # We can then compile this tmp.s into tmp.o, and link it to the original
49 # object.
50 #
51 # But this gets hard if my_func is not globl (a static function).
52 # In such a case we have:
53 #
54 #  .section ".text.sched"
55 #  my_func:
56 #        [...]
57 #        call mcount  (offset: 0x5)
58 #        [...]
59 #        ret
60 #  .globl my_func
61 #  other_func:
62 #        [...]
63 #        call mcount (offset: 0x1b)
64 #        [...]
65 #
66 # If we make the tmp.s the same as above, when we link together with
67 # the original object, we will end up with two symbols for my_func:
68 # one local, one global.  After final compile, we will end up with
69 # an undefined reference to my_func.
70 #
71 # Since local objects can reference local variables, we need to find
72 # a way to make tmp.o reference the local objects of the original object
73 # file after it is linked together. To do this, we convert the my_func
74 # into a global symbol before linking tmp.o. Then after we link tmp.o
75 # we will only have a single symbol for my_func that is global.
76 # We can convert my_func back into a local symbol and we are done.
77 #
78 # Here are the steps we take:
79 #
80 # 1) Record all the local symbols by using 'nm'
81 # 2) Use objdump to find all the call site offsets and sections for
82 #    mcount.
83 # 3) Compile the list into its own object.
84 # 4) Do we have to deal with local functions? If not, go to step 8.
85 # 5) Make an object that converts these local functions to global symbols
86 #    with objcopy.
87 # 6) Link together this new object with the list object.
88 # 7) Convert the local functions back to local symbols and rename
89 #    the result as the original object.
90 #    End.
91 # 8) Link the object with the list object.
92 # 9) Move the result back to the original object.
93 #    End.
94 #
95
96 use strict;
97
98 my $P = $0;
99 $P =~ s@.*/@@g;
100
101 my $V = '0.1';
102
103 if ($#ARGV < 6) {
104         print "usage: $P arch objdump objcopy cc ld nm rm mv inputfile\n";
105         print "version: $V\n";
106         exit(1);
107 }
108
109 my ($arch, $objdump, $objcopy, $cc, $ld, $nm, $rm, $mv, $inputfile) = @ARGV;
110
111 $objdump = "objdump" if ((length $objdump) == 0);
112 $objcopy = "objcopy" if ((length $objcopy) == 0);
113 $cc = "gcc" if ((length $cc) == 0);
114 $ld = "ld" if ((length $ld) == 0);
115 $nm = "nm" if ((length $nm) == 0);
116 $rm = "rm" if ((length $rm) == 0);
117 $mv = "mv" if ((length $mv) == 0);
118
119 #print STDERR "running: $P '$arch' '$objdump' '$objcopy' '$cc' '$ld' " .
120 #    "'$nm' '$rm' '$mv' '$inputfile'\n";
121
122 my %locals;             # List of local (static) functions
123 my %weak;               # List of weak functions
124 my %convert;            # List of local functions used that needs conversion
125
126 my $type;
127 my $section_regex;      # Find the start of a section
128 my $function_regex;     # Find the name of a function
129                         #    (return offset and func name)
130 my $mcount_regex;       # Find the call site to mcount (return offset)
131
132 if ($arch eq "x86_64") {
133     $section_regex = "Disassembly of section";
134     $function_regex = "^([0-9a-fA-F]+)\\s+<(.*?)>:";
135     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\smcount([+-]0x[0-9a-zA-Z]+)?\$";
136     $type = ".quad";
137
138     # force flags for this arch
139     $ld .= " -m elf_x86_64";
140     $objdump .= " -M x86-64";
141     $objcopy .= " -O elf64-x86-64";
142     $cc .= " -m64";
143
144 } elsif ($arch eq "i386") {
145     $section_regex = "Disassembly of section";
146     $function_regex = "^([0-9a-fA-F]+)\\s+<(.*?)>:";
147     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\smcount\$";
148     $type = ".long";
149
150     # force flags for this arch
151     $ld .= " -m elf_i386";
152     $objdump .= " -M i386";
153     $objcopy .= " -O elf32-i386";
154     $cc .= " -m32";
155
156 } else {
157     die "Arch $arch is not supported with CONFIG_FTRACE_MCOUNT_RECORD";
158 }
159
160 my $text_found = 0;
161 my $read_function = 0;
162 my $opened = 0;
163 my $mcount_section = "__mcount_loc";
164
165 my $dirname;
166 my $filename;
167 my $prefix;
168 my $ext;
169
170 if ($inputfile =~ m,^(.*)/([^/]*)$,) {
171     $dirname = $1;
172     $filename = $2;
173 } else {
174     $dirname = ".";
175     $filename = $inputfile;
176 }
177
178 if ($filename =~ m,^(.*)(\.\S),) {
179     $prefix = $1;
180     $ext = $2;
181 } else {
182     $prefix = $filename;
183     $ext = "";
184 }
185
186 my $mcount_s = $dirname . "/.tmp_mc_" . $prefix . ".s";
187 my $mcount_o = $dirname . "/.tmp_mc_" . $prefix . ".o";
188
189 #
190 # --globalize-symbols came out in 2.17, we must test the version
191 # of objcopy, and if it is less than 2.17, then we can not
192 # record local functions.
193 my $use_locals = 01;
194 my $local_warn_once = 0;
195 my $found_version = 0;
196
197 open (IN, "$objcopy --version |") || die "error running $objcopy";
198 while (<IN>) {
199     if (/objcopy.*\s(\d+)\.(\d+)/) {
200         my $major = $1;
201         my $minor = $2;
202
203         $found_version = 1;
204         if ($major < 2 ||
205             ($major == 2 && $minor < 17)) {
206             $use_locals = 0;
207         }
208         last;
209     }
210 }
211 close (IN);
212
213 if (!$found_version) {
214     print STDERR "WARNING: could not find objcopy version.\n" .
215         "\tDisabling local function references.\n";
216 }
217
218
219 #
220 # Step 1: find all the local (static functions) and weak symbols.
221 #        't' is local, 'w/W' is weak (we never use a weak function)
222 #
223 open (IN, "$nm $inputfile|") || die "error running $nm";
224 while (<IN>) {
225     if (/^[0-9a-fA-F]+\s+t\s+(\S+)/) {
226         $locals{$1} = 1;
227     } elsif (/^[0-9a-fA-F]+\s+([wW])\s+(\S+)/) {
228         $weak{$2} = $1;
229     }
230 }
231 close(IN);
232
233 my @offsets;            # Array of offsets of mcount callers
234 my $ref_func;           # reference function to use for offsets
235 my $offset = 0;         # offset of ref_func to section beginning
236
237 ##
238 # update_funcs - print out the current mcount callers
239 #
240 #  Go through the list of offsets to callers and write them to
241 #  the output file in a format that can be read by an assembler.
242 #
243 sub update_funcs
244 {
245     return if ($#offsets < 0);
246
247     defined($ref_func) || die "No function to reference";
248
249     # A section only had a weak function, to represent it.
250     # Unfortunately, a weak function may be overwritten by another
251     # function of the same name, making all these offsets incorrect.
252     # To be safe, we simply print a warning and bail.
253     if (defined $weak{$ref_func}) {
254         print STDERR
255             "$inputfile: WARNING: referencing weak function" .
256             " $ref_func for mcount\n";
257         return;
258     }
259
260     # is this function static? If so, note this fact.
261     if (defined $locals{$ref_func}) {
262
263         # only use locals if objcopy supports globalize-symbols
264         if (!$use_locals) {
265             print STDERR
266                 "$inputfile: WARNING: referencing local function " .
267                 "$ref_func for mcount\n" .
268                 "\tConsider upgrading objcopy to support the globalize-" .
269                 "symbols option.\n"
270                 if (!$local_warn_once++);
271             return;
272         }
273         $convert{$ref_func} = 1;
274     }
275
276     # Loop through all the mcount caller offsets and print a reference
277     # to the caller based from the ref_func.
278     for (my $i=0; $i <= $#offsets; $i++) {
279         if (!$opened) {
280             open(FILE, ">$mcount_s") || die "can't create $mcount_s\n";
281             $opened = 1;
282             print FILE "\t.section $mcount_section,\"a\",\@progbits\n";
283         }
284         printf FILE "\t%s %s + %d\n", $type, $ref_func, $offsets[$i] - $offset;
285     }
286 }
287
288 #
289 # Step 2: find the sections and mcount call sites
290 #
291 open(IN, "$objdump -dr $inputfile|") || die "error running $objdump";
292
293 my $text;
294
295 while (<IN>) {
296     # is it a section?
297     if (/$section_regex/) {
298         $read_function = 1;
299         # print out any recorded offsets
300         update_funcs() if ($text_found);
301
302         # reset all markers and arrays
303         $text_found = 0;
304         undef($ref_func);
305         undef(@offsets);
306
307     # section found, now is this a start of a function?
308     } elsif ($read_function && /$function_regex/) {
309         $text_found = 1;
310         $offset = hex $1;
311         $text = $2;
312
313         # if this is either a local function or a weak function
314         # keep looking for functions that are global that
315         # we can use safely.
316         if (!defined($locals{$text}) && !defined($weak{$text})) {
317             $ref_func = $text;
318             $read_function = 0;
319         } else {
320             # if we already have a function, and this is weak, skip it
321             if (!defined($ref_func) || !defined($weak{$text})) {
322                 $ref_func = $text;
323             }
324         }
325     }
326
327     # is this a call site to mcount? If so, record it to print later
328     if ($text_found && /$mcount_regex/) {
329         $offsets[$#offsets + 1] = hex $1;
330     }
331 }
332
333 # dump out anymore offsets that may have been found
334 update_funcs() if ($text_found);
335
336 # If we did not find any mcount callers, we are done (do nothing).
337 if (!$opened) {
338     exit(0);
339 }
340
341 close(FILE);
342
343 #
344 # Step 3: Compile the file that holds the list of call sites to mcount.
345 #
346 `$cc -o $mcount_o -c $mcount_s`;
347
348 my @converts = keys %convert;
349
350 #
351 # Step 4: Do we have sections that started with local functions?
352 #
353 if ($#converts >= 0) {
354     my $globallist = "";
355     my $locallist = "";
356
357     foreach my $con (@converts) {
358         $globallist .= " --globalize-symbol $con";
359         $locallist .= " --localize-symbol $con";
360     }
361
362     my $globalobj = $dirname . "/.tmp_gl_" . $filename;
363     my $globalmix = $dirname . "/.tmp_mx_" . $filename;
364
365     #
366     # Step 5: set up each local function as a global
367     #
368     `$objcopy $globallist $inputfile $globalobj`;
369
370     #
371     # Step 6: Link the global version to our list.
372     #
373     `$ld -r $globalobj $mcount_o -o $globalmix`;
374
375     #
376     # Step 7: Convert the local functions back into local symbols
377     #
378     `$objcopy $locallist $globalmix $inputfile`;
379
380     # Remove the temp files
381     `$rm $globalobj $globalmix`;
382
383 } else {
384
385     my $mix = $dirname . "/.tmp_mx_" . $filename;
386
387     #
388     # Step 8: Link the object with our list of call sites object.
389     #
390     `$ld -r $inputfile $mcount_o -o $mix`;
391
392     #
393     # Step 9: Move the result back to the original object.
394     #
395     `$mv $mix $inputfile`;
396 }
397
398 # Clean up the temp files
399 `$rm $mcount_o $mcount_s`;
400
401 exit(0);