tracing: Use appropriate perl constructs in recordmcount.pl
[linux-2.6.git] / scripts / recordmcount.pl
1 #!/usr/bin/perl -w
2 # (c) 2008, Steven Rostedt <srostedt@redhat.com>
3 # Licensed under the terms of the GNU GPL License version 2
4 #
5 # recordmcount.pl - makes a section called __mcount_loc that holds
6 #                   all the offsets to the calls to mcount.
7 #
8 #
9 # What we want to end up with this is that each object file will have a
10 # section called __mcount_loc that will hold the list of pointers to mcount
11 # callers. After final linking, the vmlinux will have within .init.data the
12 # list of all callers to mcount between __start_mcount_loc and __stop_mcount_loc.
13 # Later on boot up, the kernel will read this list, save the locations and turn
14 # them into nops. When tracing or profiling is later enabled, these locations
15 # will then be converted back to pointers to some function.
16 #
17 # This is no easy feat. This script is called just after the original
18 # object is compiled and before it is linked.
19 #
20 # When parse this object file using 'objdump', the references to the call
21 # sites are offsets from the section that the call site is in. Hence, all
22 # functions in a section that has a call site to mcount, will have the
23 # offset from the beginning of the section and not the beginning of the
24 # function.
25 #
26 # But where this section will reside finally in vmlinx is undetermined at
27 # this point. So we can't use this kind of offsets to record the final
28 # address of this call site.
29 #
30 # The trick is to change the call offset referring the start of a section to
31 # referring a function symbol in this section. During the link step, 'ld' will
32 # compute the final address according to the information we record.
33 #
34 # e.g.
35 #
36 #  .section ".sched.text", "ax"
37 #        [...]
38 #  func1:
39 #        [...]
40 #        call mcount  (offset: 0x10)
41 #        [...]
42 #        ret
43 #  .globl fun2
44 #  func2:             (offset: 0x20)
45 #        [...]
46 #        [...]
47 #        ret
48 #  func3:
49 #        [...]
50 #        call mcount (offset: 0x30)
51 #        [...]
52 #
53 # Both relocation offsets for the mcounts in the above example will be
54 # offset from .sched.text. If we choose global symbol func2 as a reference and
55 # make another file called tmp.s with the new offsets:
56 #
57 #  .section __mcount_loc
58 #  .quad  func2 - 0x10
59 #  .quad  func2 + 0x10
60 #
61 # We can then compile this tmp.s into tmp.o, and link it back to the original
62 # object.
63 #
64 # In our algorithm, we will choose the first global function we meet in this
65 # section as the reference. But this gets hard if there is no global functions
66 # in this section. In such a case we have to select a local one. E.g. func1:
67 #
68 #  .section ".sched.text", "ax"
69 #  func1:
70 #        [...]
71 #        call mcount  (offset: 0x10)
72 #        [...]
73 #        ret
74 #  func2:
75 #        [...]
76 #        call mcount (offset: 0x20)
77 #        [...]
78 #  .section "other.section"
79 #
80 # If we make the tmp.s the same as above, when we link together with
81 # the original object, we will end up with two symbols for func1:
82 # one local, one global.  After final compile, we will end up with
83 # an undefined reference to func1 or a wrong reference to another global
84 # func1 in other files.
85 #
86 # Since local objects can reference local variables, we need to find
87 # a way to make tmp.o reference the local objects of the original object
88 # file after it is linked together. To do this, we convert func1
89 # into a global symbol before linking tmp.o. Then after we link tmp.o
90 # we will only have a single symbol for func1 that is global.
91 # We can convert func1 back into a local symbol and we are done.
92 #
93 # Here are the steps we take:
94 #
95 # 1) Record all the local and weak symbols by using 'nm'
96 # 2) Use objdump to find all the call site offsets and sections for
97 #    mcount.
98 # 3) Compile the list into its own object.
99 # 4) Do we have to deal with local functions? If not, go to step 8.
100 # 5) Make an object that converts these local functions to global symbols
101 #    with objcopy.
102 # 6) Link together this new object with the list object.
103 # 7) Convert the local functions back to local symbols and rename
104 #    the result as the original object.
105 # 8) Link the object with the list object.
106 # 9) Move the result back to the original object.
107 #
108
109 use strict;
110
111 my $P = $0;
112 $P =~ s@.*/@@g;
113
114 my $V = '0.1';
115
116 if ($#ARGV != 11) {
117         print "usage: $P arch endian bits objdump objcopy cc ld nm rm mv is_module inputfile\n";
118         print "version: $V\n";
119         exit(1);
120 }
121
122 my ($arch, $endian, $bits, $objdump, $objcopy, $cc,
123     $ld, $nm, $rm, $mv, $is_module, $inputfile) = @ARGV;
124
125 # This file refers to mcount and shouldn't be ftraced, so lets' ignore it
126 if ($inputfile =~ m,kernel/trace/ftrace\.o$,) {
127     exit(0);
128 }
129
130 # Acceptable sections to record.
131 my %text_sections = (
132      ".text" => 1,
133      ".sched.text" => 1,
134      ".spinlock.text" => 1,
135      ".irqentry.text" => 1,
136      ".text.unlikely" => 1,
137 );
138
139 # Note: we are nice to C-programmers here, thus we skip the '||='-idiom.
140 $objdump = 'objdump' if (!$objdump);
141 $objcopy = 'objcopy' if (!$objcopy);
142 $cc = 'gcc' if (!$cc);
143 $ld = 'ld' if (!$ld);
144 $nm = 'nm' if (!$nm);
145 $rm = 'rm' if (!$rm);
146 $mv = 'mv' if (!$mv);
147
148 #print STDERR "running: $P '$arch' '$objdump' '$objcopy' '$cc' '$ld' " .
149 #    "'$nm' '$rm' '$mv' '$inputfile'\n";
150
151 my %locals;             # List of local (static) functions
152 my %weak;               # List of weak functions
153 my %convert;            # List of local functions used that needs conversion
154
155 my $type;
156 my $local_regex;        # Match a local function (return function)
157 my $weak_regex;         # Match a weak function (return function)
158 my $section_regex;      # Find the start of a section
159 my $function_regex;     # Find the name of a function
160                         #    (return offset and func name)
161 my $mcount_regex;       # Find the call site to mcount (return offset)
162 my $alignment;          # The .align value to use for $mcount_section
163 my $section_type;       # Section header plus possible alignment command
164 my $can_use_local = 0;  # If we can use local function references
165
166 # Shut up recordmcount if user has older objcopy
167 my $quiet_recordmcount = ".tmp_quiet_recordmcount";
168 my $print_warning = 1;
169 $print_warning = 0 if ( -f $quiet_recordmcount);
170
171 ##
172 # check_objcopy - whether objcopy supports --globalize-symbols
173 #
174 #  --globalize-symbols came out in 2.17, we must test the version
175 #  of objcopy, and if it is less than 2.17, then we can not
176 #  record local functions.
177 sub check_objcopy
178 {
179     open (IN, "$objcopy --version |") or die "error running $objcopy";
180     while (<IN>) {
181         if (/objcopy.*\s(\d+)\.(\d+)/) {
182             $can_use_local = 1 if ($1 > 2 || ($1 == 2 && $2 >= 17));
183             last;
184         }
185     }
186     close (IN);
187
188     if (!$can_use_local && $print_warning) {
189         print STDERR "WARNING: could not find objcopy version or version " .
190             "is less than 2.17.\n" .
191             "\tLocal function references are disabled.\n";
192         open (QUIET, ">$quiet_recordmcount");
193         printf QUIET "Disables the warning from recordmcount.pl\n";
194         close QUIET;
195     }
196 }
197
198 if ($arch eq 'x86') {
199     $arch = ($bits == 64) ? 'x86_64' : 'i386';
200 }
201
202 #
203 # We base the defaults off of i386, the other archs may
204 # feel free to change them in the below if statements.
205 #
206 $local_regex = "^[0-9a-fA-F]+\\s+t\\s+(\\S+)";
207 $weak_regex = "^[0-9a-fA-F]+\\s+([wW])\\s+(\\S+)";
208 $section_regex = "Disassembly of section\\s+(\\S+):";
209 $function_regex = "^([0-9a-fA-F]+)\\s+<(.*?)>:";
210 $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\smcount\$";
211 $section_type = '@progbits';
212 $type = ".long";
213
214 if ($arch eq "x86_64") {
215     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\smcount([+-]0x[0-9a-zA-Z]+)?\$";
216     $type = ".quad";
217     $alignment = 8;
218
219     # force flags for this arch
220     $ld .= " -m elf_x86_64";
221     $objdump .= " -M x86-64";
222     $objcopy .= " -O elf64-x86-64";
223     $cc .= " -m64";
224
225 } elsif ($arch eq "i386") {
226     $alignment = 4;
227
228     # force flags for this arch
229     $ld .= " -m elf_i386";
230     $objdump .= " -M i386";
231     $objcopy .= " -O elf32-i386";
232     $cc .= " -m32";
233
234 } elsif ($arch eq "s390" && $bits == 32) {
235     $mcount_regex = "^\\s*([0-9a-fA-F]+):\\s*R_390_32\\s+_mcount\$";
236     $alignment = 4;
237     $ld .= " -m elf_s390";
238     $cc .= " -m31";
239
240 } elsif ($arch eq "s390" && $bits == 64) {
241     $mcount_regex = "^\\s*([0-9a-fA-F]+):\\s*R_390_(PC|PLT)32DBL\\s+_mcount\\+0x2\$";
242     $alignment = 8;
243     $type = ".quad";
244     $ld .= " -m elf64_s390";
245     $cc .= " -m64";
246
247 } elsif ($arch eq "sh") {
248     $alignment = 2;
249
250     # force flags for this arch
251     $ld .= " -m shlelf_linux";
252     $objcopy .= " -O elf32-sh-linux";
253     $cc .= " -m32";
254
255 } elsif ($arch eq "powerpc") {
256     $local_regex = "^[0-9a-fA-F]+\\s+t\\s+(\\.?\\S+)";
257     $function_regex = "^([0-9a-fA-F]+)\\s+<(\\.?.*?)>:";
258     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s\\.?_mcount\$";
259
260     if ($bits == 64) {
261         $type = ".quad";
262     }
263
264 } elsif ($arch eq "arm") {
265     $alignment = 2;
266     $section_type = '%progbits';
267
268 } elsif ($arch eq "ia64") {
269     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s_mcount\$";
270     $type = "data8";
271
272     if ($is_module eq "0") {
273         $cc .= " -mconstant-gp";
274     }
275 } elsif ($arch eq "sparc64") {
276     # In the objdump output there are giblets like:
277     # 0000000000000000 <igmp_net_exit-0x18>:
278     # As there's some data blobs that get emitted into the
279     # text section before the first instructions and the first
280     # real symbols.  We don't want to match that, so to combat
281     # this we use '\w' so we'll match just plain symbol names,
282     # and not those that also include hex offsets inside of the
283     # '<>' brackets.  Actually the generic function_regex setting
284     # could safely use this too.
285     $function_regex = "^([0-9a-fA-F]+)\\s+<(\\w*?)>:";
286
287     # Sparc64 calls '_mcount' instead of plain 'mcount'.
288     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s_mcount\$";
289
290     $alignment = 8;
291     $type = ".xword";
292     $ld .= " -m elf64_sparc";
293     $cc .= " -m64";
294     $objcopy .= " -O elf64-sparc";
295 } elsif ($arch eq "mips") {
296     # To enable module support, we need to enable the -mlong-calls option
297     # of gcc for module, after using this option, we can not get the real
298     # offset of the calling to _mcount, but the offset of the lui
299     # instruction or the addiu one. herein, we record the address of the
300     # first one, and then we can replace this instruction by a branch
301     # instruction to jump over the profiling function to filter the
302     # indicated functions, or swith back to the lui instruction to trace
303     # them, which means dynamic tracing.
304     #
305     #       c:  3c030000        lui     v1,0x0
306     #                   c: R_MIPS_HI16  _mcount
307     #                   c: R_MIPS_NONE  *ABS*
308     #                   c: R_MIPS_NONE  *ABS*
309     #      10:  64630000        daddiu  v1,v1,0
310     #                   10: R_MIPS_LO16 _mcount
311     #                   10: R_MIPS_NONE *ABS*
312     #                   10: R_MIPS_NONE *ABS*
313     #      14:  03e0082d        move    at,ra
314     #      18:  0060f809        jalr    v1
315     #
316     # for the kernel:
317     #
318     #     10:   03e0082d        move    at,ra
319     #     14:   0c000000        jal     0 <loongson_halt>
320     #                    14: R_MIPS_26   _mcount
321     #                    14: R_MIPS_NONE *ABS*
322     #                    14: R_MIPS_NONE *ABS*
323     #    18:   00020021        nop
324     if ($is_module eq "0") {
325             $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s_mcount\$";
326     } else {
327             $mcount_regex = "^\\s*([0-9a-fA-F]+): R_MIPS_HI16\\s+_mcount\$";
328     }
329     $objdump .= " -Melf-trad".$endian."mips ";
330
331     if ($endian eq "big") {
332             $endian = " -EB ";
333             $ld .= " -melf".$bits."btsmip";
334     } else {
335             $endian = " -EL ";
336             $ld .= " -melf".$bits."ltsmip";
337     }
338
339     $cc .= " -mno-abicalls -fno-pic -mabi=" . $bits . $endian;
340     $ld .= $endian;
341
342     if ($bits == 64) {
343             $function_regex =
344                 "^([0-9a-fA-F]+)\\s+<(.|[^\$]L.*?|\$[^L].*?|[^\$][^L].*?)>:";
345             $type = ".dword";
346     }
347 } elsif ($arch eq "microblaze") {
348     # Microblaze calls '_mcount' instead of plain 'mcount'.
349     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s_mcount\$";
350 } else {
351     die "Arch $arch is not supported with CONFIG_FTRACE_MCOUNT_RECORD";
352 }
353
354 my $text_found = 0;
355 my $read_function = 0;
356 my $opened = 0;
357 my $mcount_section = "__mcount_loc";
358
359 my $dirname;
360 my $filename;
361 my $prefix;
362 my $ext;
363
364 if ($inputfile =~ m,^(.*)/([^/]*)$,) {
365     $dirname = $1;
366     $filename = $2;
367 } else {
368     $dirname = ".";
369     $filename = $inputfile;
370 }
371
372 if ($filename =~ m,^(.*)(\.\S),) {
373     $prefix = $1;
374     $ext = $2;
375 } else {
376     $prefix = $filename;
377     $ext = "";
378 }
379
380 my $mcount_s = $dirname . "/.tmp_mc_" . $prefix . ".s";
381 my $mcount_o = $dirname . "/.tmp_mc_" . $prefix . ".o";
382
383 check_objcopy();
384
385 #
386 # Step 1: find all the local (static functions) and weak symbols.
387 #         't' is local, 'w/W' is weak
388 #
389 open (IN, "$nm $inputfile|") || die "error running $nm";
390 while (<IN>) {
391     if (/$local_regex/) {
392         $locals{$1} = 1;
393     } elsif (/$weak_regex/) {
394         $weak{$2} = $1;
395     }
396 }
397 close(IN);
398
399 my @offsets;            # Array of offsets of mcount callers
400 my $ref_func;           # reference function to use for offsets
401 my $offset = 0;         # offset of ref_func to section beginning
402
403 ##
404 # update_funcs - print out the current mcount callers
405 #
406 #  Go through the list of offsets to callers and write them to
407 #  the output file in a format that can be read by an assembler.
408 #
409 sub update_funcs
410 {
411     return unless ($ref_func and @offsets);
412
413     # Sanity check on weak function. A weak function may be overwritten by
414     # another function of the same name, making all these offsets incorrect.
415     if (defined $weak{$ref_func}) {
416         die "$inputfile: ERROR: referencing weak function" .
417             " $ref_func for mcount\n";
418     }
419
420     # is this function static? If so, note this fact.
421     if (defined $locals{$ref_func}) {
422
423         # only use locals if objcopy supports globalize-symbols
424         if (!$can_use_local) {
425             return;
426         }
427         $convert{$ref_func} = 1;
428     }
429
430     # Loop through all the mcount caller offsets and print a reference
431     # to the caller based from the ref_func.
432     if (!$opened) {
433         open(FILE, ">$mcount_s") || die "can't create $mcount_s\n";
434         $opened = 1;
435         print FILE "\t.section $mcount_section,\"a\",$section_type\n";
436         print FILE "\t.align $alignment\n" if (defined($alignment));
437     }
438     foreach my $cur_offset (@offsets) {
439         printf FILE "\t%s %s + %d\n", $type, $ref_func, $cur_offset - $offset;
440     }
441 }
442
443 #
444 # Step 2: find the sections and mcount call sites
445 #
446 open(IN, "$objdump -hdr $inputfile|") || die "error running $objdump";
447
448 my $text;
449
450
451 # read headers first
452 my $read_headers = 1;
453
454 while (<IN>) {
455
456     if ($read_headers && /$mcount_section/) {
457         #
458         # Somehow the make process can execute this script on an
459         # object twice. If it does, we would duplicate the mcount
460         # section and it will cause the function tracer self test
461         # to fail. Check if the mcount section exists, and if it does,
462         # warn and exit.
463         #
464         print STDERR "ERROR: $mcount_section already in $inputfile\n" .
465             "\tThis may be an indication that your build is corrupted.\n" .
466             "\tDelete $inputfile and try again. If the same object file\n" .
467             "\tstill causes an issue, then disable CONFIG_DYNAMIC_FTRACE.\n";
468         exit(-1);
469     }
470
471     # is it a section?
472     if (/$section_regex/) {
473         $read_headers = 0;
474
475         # Only record text sections that we know are safe
476         $read_function = defined($text_sections{$1});
477         # print out any recorded offsets
478         update_funcs();
479
480         # reset all markers and arrays
481         $text_found = 0;
482         undef($ref_func);
483         undef(@offsets);
484
485     # section found, now is this a start of a function?
486     } elsif ($read_function && /$function_regex/) {
487         $text_found = 1;
488         $text = $2;
489
490         # if this is either a local function or a weak function
491         # keep looking for functions that are global that
492         # we can use safely.
493         if (!defined($locals{$text}) && !defined($weak{$text})) {
494             $ref_func = $text;
495             $read_function = 0;
496             $offset = hex $1;
497         } else {
498             # if we already have a function, and this is weak, skip it
499             if (!defined($ref_func) && !defined($weak{$text}) &&
500                  # PPC64 can have symbols that start with .L and
501                  # gcc considers these special. Don't use them!
502                  $text !~ /^\.L/) {
503                 $ref_func = $text;
504                 $offset = hex $1;
505             }
506         }
507     }
508     # is this a call site to mcount? If so, record it to print later
509     if ($text_found && /$mcount_regex/) {
510         push(@offsets, hex $1);
511     }
512 }
513
514 # dump out anymore offsets that may have been found
515 update_funcs();
516
517 # If we did not find any mcount callers, we are done (do nothing).
518 if (!$opened) {
519     exit(0);
520 }
521
522 close(FILE);
523
524 #
525 # Step 3: Compile the file that holds the list of call sites to mcount.
526 #
527 `$cc -o $mcount_o -c $mcount_s`;
528
529 my @converts = keys %convert;
530
531 #
532 # Step 4: Do we have sections that started with local functions?
533 #
534 if ($#converts >= 0) {
535     my $globallist = "";
536     my $locallist = "";
537
538     foreach my $con (@converts) {
539         $globallist .= " --globalize-symbol $con";
540         $locallist .= " --localize-symbol $con";
541     }
542
543     my $globalobj = $dirname . "/.tmp_gl_" . $filename;
544     my $globalmix = $dirname . "/.tmp_mx_" . $filename;
545
546     #
547     # Step 5: set up each local function as a global
548     #
549     `$objcopy $globallist $inputfile $globalobj`;
550
551     #
552     # Step 6: Link the global version to our list.
553     #
554     `$ld -r $globalobj $mcount_o -o $globalmix`;
555
556     #
557     # Step 7: Convert the local functions back into local symbols
558     #
559     `$objcopy $locallist $globalmix $inputfile`;
560
561     # Remove the temp files
562     `$rm $globalobj $globalmix`;
563
564 } else {
565
566     my $mix = $dirname . "/.tmp_mx_" . $filename;
567
568     #
569     # Step 8: Link the object with our list of call sites object.
570     #
571     `$ld -r $inputfile $mcount_o -o $mix`;
572
573     #
574     # Step 9: Move the result back to the original object.
575     #
576     `$mv $mix $inputfile`;
577 }
578
579 # Clean up the temp files
580 `$rm $mcount_o $mcount_s`;
581
582 exit(0);