ftrace: handle generic arch calls
[linux-2.6.git] / scripts / recordmcount.pl
1 #!/usr/bin/perl -w
2 # (c) 2008, Steven Rostedt <srostedt@redhat.com>
3 # Licensed under the terms of the GNU GPL License version 2
4 #
5 # recordmcount.pl - makes a section called __mcount_loc that holds
6 #                   all the offsets to the calls to mcount.
7 #
8 #
9 # What we want to end up with is a section in vmlinux called
10 # __mcount_loc that contains a list of pointers to all the
11 # call sites in the kernel that call mcount. Later on boot up, the kernel
12 # will read this list, save the locations and turn them into nops.
13 # When tracing or profiling is later enabled, these locations will then
14 # be converted back to pointers to some function.
15 #
16 # This is no easy feat. This script is called just after the original
17 # object is compiled and before it is linked.
18 #
19 # The references to the call sites are offsets from the section of text
20 # that the call site is in. Hence, all functions in a section that
21 # has a call site to mcount, will have the offset from the beginning of
22 # the section and not the beginning of the function.
23 #
24 # The trick is to find a way to record the beginning of the section.
25 # The way we do this is to look at the first function in the section
26 # which will also be the location of that section after final link.
27 # e.g.
28 #
29 #  .section ".text.sched"
30 #  .globl my_func
31 #  my_func:
32 #        [...]
33 #        call mcount  (offset: 0x5)
34 #        [...]
35 #        ret
36 #  other_func:
37 #        [...]
38 #        call mcount (offset: 0x1b)
39 #        [...]
40 #
41 # Both relocation offsets for the mcounts in the above example will be
42 # offset from .text.sched. If we make another file called tmp.s with:
43 #
44 #  .section __mcount_loc
45 #  .quad  my_func + 0x5
46 #  .quad  my_func + 0x1b
47 #
48 # We can then compile this tmp.s into tmp.o, and link it to the original
49 # object.
50 #
51 # But this gets hard if my_func is not globl (a static function).
52 # In such a case we have:
53 #
54 #  .section ".text.sched"
55 #  my_func:
56 #        [...]
57 #        call mcount  (offset: 0x5)
58 #        [...]
59 #        ret
60 #  .globl my_func
61 #  other_func:
62 #        [...]
63 #        call mcount (offset: 0x1b)
64 #        [...]
65 #
66 # If we make the tmp.s the same as above, when we link together with
67 # the original object, we will end up with two symbols for my_func:
68 # one local, one global.  After final compile, we will end up with
69 # an undefined reference to my_func.
70 #
71 # Since local objects can reference local variables, we need to find
72 # a way to make tmp.o reference the local objects of the original object
73 # file after it is linked together. To do this, we convert the my_func
74 # into a global symbol before linking tmp.o. Then after we link tmp.o
75 # we will only have a single symbol for my_func that is global.
76 # We can convert my_func back into a local symbol and we are done.
77 #
78 # Here are the steps we take:
79 #
80 # 1) Record all the local symbols by using 'nm'
81 # 2) Use objdump to find all the call site offsets and sections for
82 #    mcount.
83 # 3) Compile the list into its own object.
84 # 4) Do we have to deal with local functions? If not, go to step 8.
85 # 5) Make an object that converts these local functions to global symbols
86 #    with objcopy.
87 # 6) Link together this new object with the list object.
88 # 7) Convert the local functions back to local symbols and rename
89 #    the result as the original object.
90 #    End.
91 # 8) Link the object with the list object.
92 # 9) Move the result back to the original object.
93 #    End.
94 #
95
96 use strict;
97
98 my $P = $0;
99 $P =~ s@.*/@@g;
100
101 my $V = '0.1';
102
103 if ($#ARGV < 6) {
104         print "usage: $P arch objdump objcopy cc ld nm rm mv inputfile\n";
105         print "version: $V\n";
106         exit(1);
107 }
108
109 my ($arch, $bits, $objdump, $objcopy, $cc,
110     $ld, $nm, $rm, $mv, $inputfile) = @ARGV;
111
112 $objdump = "objdump" if ((length $objdump) == 0);
113 $objcopy = "objcopy" if ((length $objcopy) == 0);
114 $cc = "gcc" if ((length $cc) == 0);
115 $ld = "ld" if ((length $ld) == 0);
116 $nm = "nm" if ((length $nm) == 0);
117 $rm = "rm" if ((length $rm) == 0);
118 $mv = "mv" if ((length $mv) == 0);
119
120 #print STDERR "running: $P '$arch' '$objdump' '$objcopy' '$cc' '$ld' " .
121 #    "'$nm' '$rm' '$mv' '$inputfile'\n";
122
123 my %locals;             # List of local (static) functions
124 my %weak;               # List of weak functions
125 my %convert;            # List of local functions used that needs conversion
126
127 my $type;
128 my $section_regex;      # Find the start of a section
129 my $function_regex;     # Find the name of a function
130                         #    (return offset and func name)
131 my $mcount_regex;       # Find the call site to mcount (return offset)
132
133 if ($arch eq "x86") {
134     if ($bits == 64) {
135         $arch = "x86_64";
136     } else {
137         $arch = "i386";
138     }
139 }
140
141 if ($arch eq "x86_64") {
142     $section_regex = "Disassembly of section";
143     $function_regex = "^([0-9a-fA-F]+)\\s+<(.*?)>:";
144     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\smcount([+-]0x[0-9a-zA-Z]+)?\$";
145     $type = ".quad";
146
147     # force flags for this arch
148     $ld .= " -m elf_x86_64";
149     $objdump .= " -M x86-64";
150     $objcopy .= " -O elf64-x86-64";
151     $cc .= " -m64";
152
153 } elsif ($arch eq "i386") {
154     $section_regex = "Disassembly of section";
155     $function_regex = "^([0-9a-fA-F]+)\\s+<(.*?)>:";
156     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\smcount\$";
157     $type = ".long";
158
159     # force flags for this arch
160     $ld .= " -m elf_i386";
161     $objdump .= " -M i386";
162     $objcopy .= " -O elf32-i386";
163     $cc .= " -m32";
164
165 } else {
166     die "Arch $arch is not supported with CONFIG_FTRACE_MCOUNT_RECORD";
167 }
168
169 my $text_found = 0;
170 my $read_function = 0;
171 my $opened = 0;
172 my $mcount_section = "__mcount_loc";
173
174 my $dirname;
175 my $filename;
176 my $prefix;
177 my $ext;
178
179 if ($inputfile =~ m,^(.*)/([^/]*)$,) {
180     $dirname = $1;
181     $filename = $2;
182 } else {
183     $dirname = ".";
184     $filename = $inputfile;
185 }
186
187 if ($filename =~ m,^(.*)(\.\S),) {
188     $prefix = $1;
189     $ext = $2;
190 } else {
191     $prefix = $filename;
192     $ext = "";
193 }
194
195 my $mcount_s = $dirname . "/.tmp_mc_" . $prefix . ".s";
196 my $mcount_o = $dirname . "/.tmp_mc_" . $prefix . ".o";
197
198 #
199 # --globalize-symbols came out in 2.17, we must test the version
200 # of objcopy, and if it is less than 2.17, then we can not
201 # record local functions.
202 my $use_locals = 01;
203 my $local_warn_once = 0;
204 my $found_version = 0;
205
206 open (IN, "$objcopy --version |") || die "error running $objcopy";
207 while (<IN>) {
208     if (/objcopy.*\s(\d+)\.(\d+)/) {
209         my $major = $1;
210         my $minor = $2;
211
212         $found_version = 1;
213         if ($major < 2 ||
214             ($major == 2 && $minor < 17)) {
215             $use_locals = 0;
216         }
217         last;
218     }
219 }
220 close (IN);
221
222 if (!$found_version) {
223     print STDERR "WARNING: could not find objcopy version.\n" .
224         "\tDisabling local function references.\n";
225 }
226
227
228 #
229 # Step 1: find all the local (static functions) and weak symbols.
230 #        't' is local, 'w/W' is weak (we never use a weak function)
231 #
232 open (IN, "$nm $inputfile|") || die "error running $nm";
233 while (<IN>) {
234     if (/^[0-9a-fA-F]+\s+t\s+(\S+)/) {
235         $locals{$1} = 1;
236     } elsif (/^[0-9a-fA-F]+\s+([wW])\s+(\S+)/) {
237         $weak{$2} = $1;
238     }
239 }
240 close(IN);
241
242 my @offsets;            # Array of offsets of mcount callers
243 my $ref_func;           # reference function to use for offsets
244 my $offset = 0;         # offset of ref_func to section beginning
245
246 ##
247 # update_funcs - print out the current mcount callers
248 #
249 #  Go through the list of offsets to callers and write them to
250 #  the output file in a format that can be read by an assembler.
251 #
252 sub update_funcs
253 {
254     return if ($#offsets < 0);
255
256     defined($ref_func) || die "No function to reference";
257
258     # A section only had a weak function, to represent it.
259     # Unfortunately, a weak function may be overwritten by another
260     # function of the same name, making all these offsets incorrect.
261     # To be safe, we simply print a warning and bail.
262     if (defined $weak{$ref_func}) {
263         print STDERR
264             "$inputfile: WARNING: referencing weak function" .
265             " $ref_func for mcount\n";
266         return;
267     }
268
269     # is this function static? If so, note this fact.
270     if (defined $locals{$ref_func}) {
271
272         # only use locals if objcopy supports globalize-symbols
273         if (!$use_locals) {
274             return;
275         }
276         $convert{$ref_func} = 1;
277     }
278
279     # Loop through all the mcount caller offsets and print a reference
280     # to the caller based from the ref_func.
281     for (my $i=0; $i <= $#offsets; $i++) {
282         if (!$opened) {
283             open(FILE, ">$mcount_s") || die "can't create $mcount_s\n";
284             $opened = 1;
285             print FILE "\t.section $mcount_section,\"a\",\@progbits\n";
286         }
287         printf FILE "\t%s %s + %d\n", $type, $ref_func, $offsets[$i] - $offset;
288     }
289 }
290
291 #
292 # Step 2: find the sections and mcount call sites
293 #
294 open(IN, "$objdump -dr $inputfile|") || die "error running $objdump";
295
296 my $text;
297
298 while (<IN>) {
299     # is it a section?
300     if (/$section_regex/) {
301         $read_function = 1;
302         # print out any recorded offsets
303         update_funcs() if ($text_found);
304
305         # reset all markers and arrays
306         $text_found = 0;
307         undef($ref_func);
308         undef(@offsets);
309
310     # section found, now is this a start of a function?
311     } elsif ($read_function && /$function_regex/) {
312         $text_found = 1;
313         $offset = hex $1;
314         $text = $2;
315
316         # if this is either a local function or a weak function
317         # keep looking for functions that are global that
318         # we can use safely.
319         if (!defined($locals{$text}) && !defined($weak{$text})) {
320             $ref_func = $text;
321             $read_function = 0;
322         } else {
323             # if we already have a function, and this is weak, skip it
324             if (!defined($ref_func) || !defined($weak{$text})) {
325                 $ref_func = $text;
326             }
327         }
328     }
329
330     # is this a call site to mcount? If so, record it to print later
331     if ($text_found && /$mcount_regex/) {
332         $offsets[$#offsets + 1] = hex $1;
333     }
334 }
335
336 # dump out anymore offsets that may have been found
337 update_funcs() if ($text_found);
338
339 # If we did not find any mcount callers, we are done (do nothing).
340 if (!$opened) {
341     exit(0);
342 }
343
344 close(FILE);
345
346 #
347 # Step 3: Compile the file that holds the list of call sites to mcount.
348 #
349 `$cc -o $mcount_o -c $mcount_s`;
350
351 my @converts = keys %convert;
352
353 #
354 # Step 4: Do we have sections that started with local functions?
355 #
356 if ($#converts >= 0) {
357     my $globallist = "";
358     my $locallist = "";
359
360     foreach my $con (@converts) {
361         $globallist .= " --globalize-symbol $con";
362         $locallist .= " --localize-symbol $con";
363     }
364
365     my $globalobj = $dirname . "/.tmp_gl_" . $filename;
366     my $globalmix = $dirname . "/.tmp_mx_" . $filename;
367
368     #
369     # Step 5: set up each local function as a global
370     #
371     `$objcopy $globallist $inputfile $globalobj`;
372
373     #
374     # Step 6: Link the global version to our list.
375     #
376     `$ld -r $globalobj $mcount_o -o $globalmix`;
377
378     #
379     # Step 7: Convert the local functions back into local symbols
380     #
381     `$objcopy $locallist $globalmix $inputfile`;
382
383     # Remove the temp files
384     `$rm $globalobj $globalmix`;
385
386 } else {
387
388     my $mix = $dirname . "/.tmp_mx_" . $filename;
389
390     #
391     # Step 8: Link the object with our list of call sites object.
392     #
393     `$ld -r $inputfile $mcount_o -o $mix`;
394
395     #
396     # Step 9: Move the result back to the original object.
397     #
398     `$mv $mix $inputfile`;
399 }
400
401 # Clean up the temp files
402 `$rm $mcount_o $mcount_s`;
403
404 exit(0);