tracing: Check absolute path of input file in recordmcount.pl
[linux-2.6.git] / scripts / recordmcount.pl
1 #!/usr/bin/perl -w
2 # (c) 2008, Steven Rostedt <srostedt@redhat.com>
3 # Licensed under the terms of the GNU GPL License version 2
4 #
5 # recordmcount.pl - makes a section called __mcount_loc that holds
6 #                   all the offsets to the calls to mcount.
7 #
8 #
9 # What we want to end up with this is that each object file will have a
10 # section called __mcount_loc that will hold the list of pointers to mcount
11 # callers. After final linking, the vmlinux will have within .init.data the
12 # list of all callers to mcount between __start_mcount_loc and __stop_mcount_loc.
13 # Later on boot up, the kernel will read this list, save the locations and turn
14 # them into nops. When tracing or profiling is later enabled, these locations
15 # will then be converted back to pointers to some function.
16 #
17 # This is no easy feat. This script is called just after the original
18 # object is compiled and before it is linked.
19 #
20 # When parse this object file using 'objdump', the references to the call
21 # sites are offsets from the section that the call site is in. Hence, all
22 # functions in a section that has a call site to mcount, will have the
23 # offset from the beginning of the section and not the beginning of the
24 # function.
25 #
26 # But where this section will reside finally in vmlinx is undetermined at
27 # this point. So we can't use this kind of offsets to record the final
28 # address of this call site.
29 #
30 # The trick is to change the call offset referring the start of a section to
31 # referring a function symbol in this section. During the link step, 'ld' will
32 # compute the final address according to the information we record.
33 #
34 # e.g.
35 #
36 #  .section ".sched.text", "ax"
37 #        [...]
38 #  func1:
39 #        [...]
40 #        call mcount  (offset: 0x10)
41 #        [...]
42 #        ret
43 #  .globl fun2
44 #  func2:             (offset: 0x20)
45 #        [...]
46 #        [...]
47 #        ret
48 #  func3:
49 #        [...]
50 #        call mcount (offset: 0x30)
51 #        [...]
52 #
53 # Both relocation offsets for the mcounts in the above example will be
54 # offset from .sched.text. If we choose global symbol func2 as a reference and
55 # make another file called tmp.s with the new offsets:
56 #
57 #  .section __mcount_loc
58 #  .quad  func2 - 0x10
59 #  .quad  func2 + 0x10
60 #
61 # We can then compile this tmp.s into tmp.o, and link it back to the original
62 # object.
63 #
64 # In our algorithm, we will choose the first global function we meet in this
65 # section as the reference. But this gets hard if there is no global functions
66 # in this section. In such a case we have to select a local one. E.g. func1:
67 #
68 #  .section ".sched.text", "ax"
69 #  func1:
70 #        [...]
71 #        call mcount  (offset: 0x10)
72 #        [...]
73 #        ret
74 #  func2:
75 #        [...]
76 #        call mcount (offset: 0x20)
77 #        [...]
78 #  .section "other.section"
79 #
80 # If we make the tmp.s the same as above, when we link together with
81 # the original object, we will end up with two symbols for func1:
82 # one local, one global.  After final compile, we will end up with
83 # an undefined reference to func1 or a wrong reference to another global
84 # func1 in other files.
85 #
86 # Since local objects can reference local variables, we need to find
87 # a way to make tmp.o reference the local objects of the original object
88 # file after it is linked together. To do this, we convert func1
89 # into a global symbol before linking tmp.o. Then after we link tmp.o
90 # we will only have a single symbol for func1 that is global.
91 # We can convert func1 back into a local symbol and we are done.
92 #
93 # Here are the steps we take:
94 #
95 # 1) Record all the local symbols by using 'nm'
96 # 2) Use objdump to find all the call site offsets and sections for
97 #    mcount.
98 # 3) Compile the list into its own object.
99 # 4) Do we have to deal with local functions? If not, go to step 8.
100 # 5) Make an object that converts these local functions to global symbols
101 #    with objcopy.
102 # 6) Link together this new object with the list object.
103 # 7) Convert the local functions back to local symbols and rename
104 #    the result as the original object.
105 # 8) Link the object with the list object.
106 # 9) Move the result back to the original object.
107 #
108
109 use strict;
110
111 my $P = $0;
112 $P =~ s@.*/@@g;
113
114 my $V = '0.1';
115
116 if ($#ARGV != 10) {
117         print "usage: $P arch bits objdump objcopy cc ld nm rm mv is_module inputfile\n";
118         print "version: $V\n";
119         exit(1);
120 }
121
122 my ($arch, $bits, $objdump, $objcopy, $cc,
123     $ld, $nm, $rm, $mv, $is_module, $inputfile) = @ARGV;
124
125 # This file refers to mcount and shouldn't be ftraced, so lets' ignore it
126 if ($inputfile =~ m,kernel/trace/ftrace\.o$,) {
127     exit(0);
128 }
129
130 # Acceptable sections to record.
131 my %text_sections = (
132      ".text" => 1,
133      ".sched.text" => 1,
134      ".spinlock.text" => 1,
135      ".irqentry.text" => 1,
136      ".text.unlikely" => 1,
137 );
138
139 $objdump = "objdump" if ((length $objdump) == 0);
140 $objcopy = "objcopy" if ((length $objcopy) == 0);
141 $cc = "gcc" if ((length $cc) == 0);
142 $ld = "ld" if ((length $ld) == 0);
143 $nm = "nm" if ((length $nm) == 0);
144 $rm = "rm" if ((length $rm) == 0);
145 $mv = "mv" if ((length $mv) == 0);
146
147 #print STDERR "running: $P '$arch' '$objdump' '$objcopy' '$cc' '$ld' " .
148 #    "'$nm' '$rm' '$mv' '$inputfile'\n";
149
150 my %locals;             # List of local (static) functions
151 my %weak;               # List of weak functions
152 my %convert;            # List of local functions used that needs conversion
153
154 my $type;
155 my $nm_regex;           # Find the local functions (return function)
156 my $section_regex;      # Find the start of a section
157 my $function_regex;     # Find the name of a function
158                         #    (return offset and func name)
159 my $mcount_regex;       # Find the call site to mcount (return offset)
160 my $alignment;          # The .align value to use for $mcount_section
161 my $section_type;       # Section header plus possible alignment command
162
163 if ($arch eq "x86") {
164     if ($bits == 64) {
165         $arch = "x86_64";
166     } else {
167         $arch = "i386";
168     }
169 }
170
171 #
172 # We base the defaults off of i386, the other archs may
173 # feel free to change them in the below if statements.
174 #
175 $nm_regex = "^[0-9a-fA-F]+\\s+t\\s+(\\S+)";
176 $section_regex = "Disassembly of section\\s+(\\S+):";
177 $function_regex = "^([0-9a-fA-F]+)\\s+<(.*?)>:";
178 $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\smcount\$";
179 $section_type = '@progbits';
180 $type = ".long";
181
182 if ($arch eq "x86_64") {
183     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\smcount([+-]0x[0-9a-zA-Z]+)?\$";
184     $type = ".quad";
185     $alignment = 8;
186
187     # force flags for this arch
188     $ld .= " -m elf_x86_64";
189     $objdump .= " -M x86-64";
190     $objcopy .= " -O elf64-x86-64";
191     $cc .= " -m64";
192
193 } elsif ($arch eq "i386") {
194     $alignment = 4;
195
196     # force flags for this arch
197     $ld .= " -m elf_i386";
198     $objdump .= " -M i386";
199     $objcopy .= " -O elf32-i386";
200     $cc .= " -m32";
201
202 } elsif ($arch eq "s390" && $bits == 32) {
203     $mcount_regex = "^\\s*([0-9a-fA-F]+):\\s*R_390_32\\s+_mcount\$";
204     $alignment = 4;
205     $ld .= " -m elf_s390";
206     $cc .= " -m31";
207
208 } elsif ($arch eq "s390" && $bits == 64) {
209     $mcount_regex = "^\\s*([0-9a-fA-F]+):\\s*R_390_(PC|PLT)32DBL\\s+_mcount\\+0x2\$";
210     $alignment = 8;
211     $type = ".quad";
212     $ld .= " -m elf64_s390";
213     $cc .= " -m64";
214
215 } elsif ($arch eq "sh") {
216     $alignment = 2;
217
218     # force flags for this arch
219     $ld .= " -m shlelf_linux";
220     $objcopy .= " -O elf32-sh-linux";
221     $cc .= " -m32";
222
223 } elsif ($arch eq "powerpc") {
224     $nm_regex = "^[0-9a-fA-F]+\\s+t\\s+(\\.?\\S+)";
225     $function_regex = "^([0-9a-fA-F]+)\\s+<(\\.?.*?)>:";
226     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s\\.?_mcount\$";
227
228     if ($bits == 64) {
229         $type = ".quad";
230     }
231
232 } elsif ($arch eq "arm") {
233     $alignment = 2;
234     $section_type = '%progbits';
235
236 } elsif ($arch eq "ia64") {
237     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s_mcount\$";
238     $type = "data8";
239
240     if ($is_module eq "0") {
241         $cc .= " -mconstant-gp";
242     }
243 } elsif ($arch eq "sparc64") {
244     # In the objdump output there are giblets like:
245     # 0000000000000000 <igmp_net_exit-0x18>:
246     # As there's some data blobs that get emitted into the
247     # text section before the first instructions and the first
248     # real symbols.  We don't want to match that, so to combat
249     # this we use '\w' so we'll match just plain symbol names,
250     # and not those that also include hex offsets inside of the
251     # '<>' brackets.  Actually the generic function_regex setting
252     # could safely use this too.
253     $function_regex = "^([0-9a-fA-F]+)\\s+<(\\w*?)>:";
254
255     # Sparc64 calls '_mcount' instead of plain 'mcount'.
256     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s_mcount\$";
257
258     $alignment = 8;
259     $type = ".xword";
260     $ld .= " -m elf64_sparc";
261     $cc .= " -m64";
262     $objcopy .= " -O elf64-sparc";
263 } else {
264     die "Arch $arch is not supported with CONFIG_FTRACE_MCOUNT_RECORD";
265 }
266
267 my $text_found = 0;
268 my $read_function = 0;
269 my $opened = 0;
270 my $mcount_section = "__mcount_loc";
271
272 my $dirname;
273 my $filename;
274 my $prefix;
275 my $ext;
276
277 if ($inputfile =~ m,^(.*)/([^/]*)$,) {
278     $dirname = $1;
279     $filename = $2;
280 } else {
281     $dirname = ".";
282     $filename = $inputfile;
283 }
284
285 if ($filename =~ m,^(.*)(\.\S),) {
286     $prefix = $1;
287     $ext = $2;
288 } else {
289     $prefix = $filename;
290     $ext = "";
291 }
292
293 my $mcount_s = $dirname . "/.tmp_mc_" . $prefix . ".s";
294 my $mcount_o = $dirname . "/.tmp_mc_" . $prefix . ".o";
295
296 #
297 # --globalize-symbols came out in 2.17, we must test the version
298 # of objcopy, and if it is less than 2.17, then we can not
299 # record local functions.
300 my $use_locals = 01;
301 my $local_warn_once = 0;
302 my $found_version = 0;
303
304 open (IN, "$objcopy --version |") || die "error running $objcopy";
305 while (<IN>) {
306     if (/objcopy.*\s(\d+)\.(\d+)/) {
307         my $major = $1;
308         my $minor = $2;
309
310         $found_version = 1;
311         if ($major < 2 ||
312             ($major == 2 && $minor < 17)) {
313             $use_locals = 0;
314         }
315         last;
316     }
317 }
318 close (IN);
319
320 if (!$found_version) {
321     print STDERR "WARNING: could not find objcopy version.\n" .
322         "\tDisabling local function references.\n";
323 }
324
325 #
326 # Step 1: find all the local (static functions) and weak symbols.
327 #        't' is local, 'w/W' is weak (we never use a weak function)
328 #
329 open (IN, "$nm $inputfile|") || die "error running $nm";
330 while (<IN>) {
331     if (/$nm_regex/) {
332         $locals{$1} = 1;
333     } elsif (/^[0-9a-fA-F]+\s+([wW])\s+(\S+)/) {
334         $weak{$2} = $1;
335     }
336 }
337 close(IN);
338
339 my @offsets;            # Array of offsets of mcount callers
340 my $ref_func;           # reference function to use for offsets
341 my $offset = 0;         # offset of ref_func to section beginning
342
343 ##
344 # update_funcs - print out the current mcount callers
345 #
346 #  Go through the list of offsets to callers and write them to
347 #  the output file in a format that can be read by an assembler.
348 #
349 sub update_funcs
350 {
351     return if ($#offsets < 0);
352
353     defined($ref_func) || die "No function to reference";
354
355     # A section only had a weak function, to represent it.
356     # Unfortunately, a weak function may be overwritten by another
357     # function of the same name, making all these offsets incorrect.
358     # To be safe, we simply print a warning and bail.
359     if (defined $weak{$ref_func}) {
360         print STDERR
361             "$inputfile: WARNING: referencing weak function" .
362             " $ref_func for mcount\n";
363         return;
364     }
365
366     # is this function static? If so, note this fact.
367     if (defined $locals{$ref_func}) {
368
369         # only use locals if objcopy supports globalize-symbols
370         if (!$use_locals) {
371             return;
372         }
373         $convert{$ref_func} = 1;
374     }
375
376     # Loop through all the mcount caller offsets and print a reference
377     # to the caller based from the ref_func.
378     for (my $i=0; $i <= $#offsets; $i++) {
379         if (!$opened) {
380             open(FILE, ">$mcount_s") || die "can't create $mcount_s\n";
381             $opened = 1;
382             print FILE "\t.section $mcount_section,\"a\",$section_type\n";
383             print FILE "\t.align $alignment\n" if (defined($alignment));
384         }
385         printf FILE "\t%s %s + %d\n", $type, $ref_func, $offsets[$i] - $offset;
386     }
387 }
388
389 #
390 # Step 2: find the sections and mcount call sites
391 #
392 open(IN, "$objdump -hdr $inputfile|") || die "error running $objdump";
393
394 my $text;
395
396 my $read_headers = 1;
397
398 while (<IN>) {
399     # is it a section?
400     if (/$section_regex/) {
401         $read_headers = 0;
402
403         # Only record text sections that we know are safe
404         if (defined($text_sections{$1})) {
405             $read_function = 1;
406         } else {
407             $read_function = 0;
408         }
409         # print out any recorded offsets
410         update_funcs() if (defined($ref_func));
411
412         # reset all markers and arrays
413         $text_found = 0;
414         undef($ref_func);
415         undef(@offsets);
416
417     # section found, now is this a start of a function?
418     } elsif ($read_function && /$function_regex/) {
419         $text_found = 1;
420         $text = $2;
421
422         # if this is either a local function or a weak function
423         # keep looking for functions that are global that
424         # we can use safely.
425         if (!defined($locals{$text}) && !defined($weak{$text})) {
426             $ref_func = $text;
427             $read_function = 0;
428             $offset = hex $1;
429         } else {
430             # if we already have a function, and this is weak, skip it
431             if (!defined($ref_func) && !defined($weak{$text}) &&
432                  # PPC64 can have symbols that start with .L and
433                  # gcc considers these special. Don't use them!
434                  $text !~ /^\.L/) {
435                 $ref_func = $text;
436                 $offset = hex $1;
437             }
438         }
439     } elsif ($read_headers && /$mcount_section/) {
440         #
441         # Somehow the make process can execute this script on an
442         # object twice. If it does, we would duplicate the mcount
443         # section and it will cause the function tracer self test
444         # to fail. Check if the mcount section exists, and if it does,
445         # warn and exit.
446         #
447         print STDERR "ERROR: $mcount_section already in $inputfile\n" .
448             "\tThis may be an indication that your build is corrupted.\n" .
449             "\tDelete $inputfile and try again. If the same object file\n" .
450             "\tstill causes an issue, then disable CONFIG_DYNAMIC_FTRACE.\n";
451         exit(-1);
452     }
453
454     # is this a call site to mcount? If so, record it to print later
455     if ($text_found && /$mcount_regex/) {
456         $offsets[$#offsets + 1] = hex $1;
457     }
458 }
459
460 # dump out anymore offsets that may have been found
461 update_funcs() if (defined($ref_func));
462
463 # If we did not find any mcount callers, we are done (do nothing).
464 if (!$opened) {
465     exit(0);
466 }
467
468 close(FILE);
469
470 #
471 # Step 3: Compile the file that holds the list of call sites to mcount.
472 #
473 `$cc -o $mcount_o -c $mcount_s`;
474
475 my @converts = keys %convert;
476
477 #
478 # Step 4: Do we have sections that started with local functions?
479 #
480 if ($#converts >= 0) {
481     my $globallist = "";
482     my $locallist = "";
483
484     foreach my $con (@converts) {
485         $globallist .= " --globalize-symbol $con";
486         $locallist .= " --localize-symbol $con";
487     }
488
489     my $globalobj = $dirname . "/.tmp_gl_" . $filename;
490     my $globalmix = $dirname . "/.tmp_mx_" . $filename;
491
492     #
493     # Step 5: set up each local function as a global
494     #
495     `$objcopy $globallist $inputfile $globalobj`;
496
497     #
498     # Step 6: Link the global version to our list.
499     #
500     `$ld -r $globalobj $mcount_o -o $globalmix`;
501
502     #
503     # Step 7: Convert the local functions back into local symbols
504     #
505     `$objcopy $locallist $globalmix $inputfile`;
506
507     # Remove the temp files
508     `$rm $globalobj $globalmix`;
509
510 } else {
511
512     my $mix = $dirname . "/.tmp_mx_" . $filename;
513
514     #
515     # Step 8: Link the object with our list of call sites object.
516     #
517     `$ld -r $inputfile $mcount_o -o $mix`;
518
519     #
520     # Step 9: Move the result back to the original object.
521     #
522     `$mv $mix $inputfile`;
523 }
524
525 # Clean up the temp files
526 `$rm $mcount_o $mcount_s`;
527
528 exit(0);