ftrace: align __mcount_loc sections
[linux-2.6.git] / scripts / recordmcount.pl
1 #!/usr/bin/perl -w
2 # (c) 2008, Steven Rostedt <srostedt@redhat.com>
3 # Licensed under the terms of the GNU GPL License version 2
4 #
5 # recordmcount.pl - makes a section called __mcount_loc that holds
6 #                   all the offsets to the calls to mcount.
7 #
8 #
9 # What we want to end up with is a section in vmlinux called
10 # __mcount_loc that contains a list of pointers to all the
11 # call sites in the kernel that call mcount. Later on boot up, the kernel
12 # will read this list, save the locations and turn them into nops.
13 # When tracing or profiling is later enabled, these locations will then
14 # be converted back to pointers to some function.
15 #
16 # This is no easy feat. This script is called just after the original
17 # object is compiled and before it is linked.
18 #
19 # The references to the call sites are offsets from the section of text
20 # that the call site is in. Hence, all functions in a section that
21 # has a call site to mcount, will have the offset from the beginning of
22 # the section and not the beginning of the function.
23 #
24 # The trick is to find a way to record the beginning of the section.
25 # The way we do this is to look at the first function in the section
26 # which will also be the location of that section after final link.
27 # e.g.
28 #
29 #  .section ".text.sched"
30 #  .globl my_func
31 #  my_func:
32 #        [...]
33 #        call mcount  (offset: 0x5)
34 #        [...]
35 #        ret
36 #  other_func:
37 #        [...]
38 #        call mcount (offset: 0x1b)
39 #        [...]
40 #
41 # Both relocation offsets for the mcounts in the above example will be
42 # offset from .text.sched. If we make another file called tmp.s with:
43 #
44 #  .section __mcount_loc
45 #  .quad  my_func + 0x5
46 #  .quad  my_func + 0x1b
47 #
48 # We can then compile this tmp.s into tmp.o, and link it to the original
49 # object.
50 #
51 # But this gets hard if my_func is not globl (a static function).
52 # In such a case we have:
53 #
54 #  .section ".text.sched"
55 #  my_func:
56 #        [...]
57 #        call mcount  (offset: 0x5)
58 #        [...]
59 #        ret
60 #  .globl my_func
61 #  other_func:
62 #        [...]
63 #        call mcount (offset: 0x1b)
64 #        [...]
65 #
66 # If we make the tmp.s the same as above, when we link together with
67 # the original object, we will end up with two symbols for my_func:
68 # one local, one global.  After final compile, we will end up with
69 # an undefined reference to my_func.
70 #
71 # Since local objects can reference local variables, we need to find
72 # a way to make tmp.o reference the local objects of the original object
73 # file after it is linked together. To do this, we convert the my_func
74 # into a global symbol before linking tmp.o. Then after we link tmp.o
75 # we will only have a single symbol for my_func that is global.
76 # We can convert my_func back into a local symbol and we are done.
77 #
78 # Here are the steps we take:
79 #
80 # 1) Record all the local symbols by using 'nm'
81 # 2) Use objdump to find all the call site offsets and sections for
82 #    mcount.
83 # 3) Compile the list into its own object.
84 # 4) Do we have to deal with local functions? If not, go to step 8.
85 # 5) Make an object that converts these local functions to global symbols
86 #    with objcopy.
87 # 6) Link together this new object with the list object.
88 # 7) Convert the local functions back to local symbols and rename
89 #    the result as the original object.
90 #    End.
91 # 8) Link the object with the list object.
92 # 9) Move the result back to the original object.
93 #    End.
94 #
95
96 use strict;
97
98 my $P = $0;
99 $P =~ s@.*/@@g;
100
101 my $V = '0.1';
102
103 if ($#ARGV < 6) {
104         print "usage: $P arch objdump objcopy cc ld nm rm mv inputfile\n";
105         print "version: $V\n";
106         exit(1);
107 }
108
109 my ($arch, $bits, $objdump, $objcopy, $cc,
110     $ld, $nm, $rm, $mv, $inputfile) = @ARGV;
111
112 # Acceptable sections to record.
113 my %text_sections = (
114      ".text" => 1,
115 );
116
117 $objdump = "objdump" if ((length $objdump) == 0);
118 $objcopy = "objcopy" if ((length $objcopy) == 0);
119 $cc = "gcc" if ((length $cc) == 0);
120 $ld = "ld" if ((length $ld) == 0);
121 $nm = "nm" if ((length $nm) == 0);
122 $rm = "rm" if ((length $rm) == 0);
123 $mv = "mv" if ((length $mv) == 0);
124
125 #print STDERR "running: $P '$arch' '$objdump' '$objcopy' '$cc' '$ld' " .
126 #    "'$nm' '$rm' '$mv' '$inputfile'\n";
127
128 my %locals;             # List of local (static) functions
129 my %weak;               # List of weak functions
130 my %convert;            # List of local functions used that needs conversion
131
132 my $type;
133 my $section_regex;      # Find the start of a section
134 my $function_regex;     # Find the name of a function
135                         #    (return offset and func name)
136 my $mcount_regex;       # Find the call site to mcount (return offset)
137 my $alignment;         # The .align value to use for $mcount_section
138
139 if ($arch eq "x86") {
140     if ($bits == 64) {
141         $arch = "x86_64";
142     } else {
143         $arch = "i386";
144     }
145 }
146
147 if ($arch eq "x86_64") {
148     $section_regex = "Disassembly of section\\s+(\\S+):";
149     $function_regex = "^([0-9a-fA-F]+)\\s+<(.*?)>:";
150     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\smcount([+-]0x[0-9a-zA-Z]+)?\$";
151     $type = ".quad";
152     $alignment = 8;
153
154     # force flags for this arch
155     $ld .= " -m elf_x86_64";
156     $objdump .= " -M x86-64";
157     $objcopy .= " -O elf64-x86-64";
158     $cc .= " -m64";
159
160 } elsif ($arch eq "i386") {
161     $section_regex = "Disassembly of section\\s+(\\S+):";
162     $function_regex = "^([0-9a-fA-F]+)\\s+<(.*?)>:";
163     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\smcount\$";
164     $type = ".long";
165     $alignment = 4;
166
167     # force flags for this arch
168     $ld .= " -m elf_i386";
169     $objdump .= " -M i386";
170     $objcopy .= " -O elf32-i386";
171     $cc .= " -m32";
172
173 } else {
174     die "Arch $arch is not supported with CONFIG_FTRACE_MCOUNT_RECORD";
175 }
176
177 my $text_found = 0;
178 my $read_function = 0;
179 my $opened = 0;
180 my $mcount_section = "__mcount_loc";
181
182 my $dirname;
183 my $filename;
184 my $prefix;
185 my $ext;
186
187 if ($inputfile =~ m,^(.*)/([^/]*)$,) {
188     $dirname = $1;
189     $filename = $2;
190 } else {
191     $dirname = ".";
192     $filename = $inputfile;
193 }
194
195 if ($filename =~ m,^(.*)(\.\S),) {
196     $prefix = $1;
197     $ext = $2;
198 } else {
199     $prefix = $filename;
200     $ext = "";
201 }
202
203 my $mcount_s = $dirname . "/.tmp_mc_" . $prefix . ".s";
204 my $mcount_o = $dirname . "/.tmp_mc_" . $prefix . ".o";
205
206 #
207 # --globalize-symbols came out in 2.17, we must test the version
208 # of objcopy, and if it is less than 2.17, then we can not
209 # record local functions.
210 my $use_locals = 01;
211 my $local_warn_once = 0;
212 my $found_version = 0;
213
214 open (IN, "$objcopy --version |") || die "error running $objcopy";
215 while (<IN>) {
216     if (/objcopy.*\s(\d+)\.(\d+)/) {
217         my $major = $1;
218         my $minor = $2;
219
220         $found_version = 1;
221         if ($major < 2 ||
222             ($major == 2 && $minor < 17)) {
223             $use_locals = 0;
224         }
225         last;
226     }
227 }
228 close (IN);
229
230 if (!$found_version) {
231     print STDERR "WARNING: could not find objcopy version.\n" .
232         "\tDisabling local function references.\n";
233 }
234
235
236 #
237 # Step 1: find all the local (static functions) and weak symbols.
238 #        't' is local, 'w/W' is weak (we never use a weak function)
239 #
240 open (IN, "$nm $inputfile|") || die "error running $nm";
241 while (<IN>) {
242     if (/^[0-9a-fA-F]+\s+t\s+(\S+)/) {
243         $locals{$1} = 1;
244     } elsif (/^[0-9a-fA-F]+\s+([wW])\s+(\S+)/) {
245         $weak{$2} = $1;
246     }
247 }
248 close(IN);
249
250 my @offsets;            # Array of offsets of mcount callers
251 my $ref_func;           # reference function to use for offsets
252 my $offset = 0;         # offset of ref_func to section beginning
253
254 ##
255 # update_funcs - print out the current mcount callers
256 #
257 #  Go through the list of offsets to callers and write them to
258 #  the output file in a format that can be read by an assembler.
259 #
260 sub update_funcs
261 {
262     return if ($#offsets < 0);
263
264     defined($ref_func) || die "No function to reference";
265
266     # A section only had a weak function, to represent it.
267     # Unfortunately, a weak function may be overwritten by another
268     # function of the same name, making all these offsets incorrect.
269     # To be safe, we simply print a warning and bail.
270     if (defined $weak{$ref_func}) {
271         print STDERR
272             "$inputfile: WARNING: referencing weak function" .
273             " $ref_func for mcount\n";
274         return;
275     }
276
277     # is this function static? If so, note this fact.
278     if (defined $locals{$ref_func}) {
279
280         # only use locals if objcopy supports globalize-symbols
281         if (!$use_locals) {
282             return;
283         }
284         $convert{$ref_func} = 1;
285     }
286
287     # Loop through all the mcount caller offsets and print a reference
288     # to the caller based from the ref_func.
289     for (my $i=0; $i <= $#offsets; $i++) {
290         if (!$opened) {
291             open(FILE, ">$mcount_s") || die "can't create $mcount_s\n";
292             $opened = 1;
293             print FILE "\t.section $mcount_section,\"a\",\@progbits\n";
294             print FILE "\t.align $alignment\n";
295         }
296         printf FILE "\t%s %s + %d\n", $type, $ref_func, $offsets[$i] - $offset;
297     }
298 }
299
300 #
301 # Step 2: find the sections and mcount call sites
302 #
303 open(IN, "$objdump -dr $inputfile|") || die "error running $objdump";
304
305 my $text;
306
307 while (<IN>) {
308     # is it a section?
309     if (/$section_regex/) {
310
311         # Only record text sections that we know are safe
312         if (defined($text_sections{$1})) {
313             $read_function = 1;
314         } else {
315             $read_function = 0;
316         }
317         # print out any recorded offsets
318         update_funcs() if ($text_found);
319
320         # reset all markers and arrays
321         $text_found = 0;
322         undef($ref_func);
323         undef(@offsets);
324
325     # section found, now is this a start of a function?
326     } elsif ($read_function && /$function_regex/) {
327         $text_found = 1;
328         $offset = hex $1;
329         $text = $2;
330
331         # if this is either a local function or a weak function
332         # keep looking for functions that are global that
333         # we can use safely.
334         if (!defined($locals{$text}) && !defined($weak{$text})) {
335             $ref_func = $text;
336             $read_function = 0;
337         } else {
338             # if we already have a function, and this is weak, skip it
339             if (!defined($ref_func) || !defined($weak{$text})) {
340                 $ref_func = $text;
341             }
342         }
343     }
344
345     # is this a call site to mcount? If so, record it to print later
346     if ($text_found && /$mcount_regex/) {
347         $offsets[$#offsets + 1] = hex $1;
348     }
349 }
350
351 # dump out anymore offsets that may have been found
352 update_funcs() if ($text_found);
353
354 # If we did not find any mcount callers, we are done (do nothing).
355 if (!$opened) {
356     exit(0);
357 }
358
359 close(FILE);
360
361 #
362 # Step 3: Compile the file that holds the list of call sites to mcount.
363 #
364 `$cc -o $mcount_o -c $mcount_s`;
365
366 my @converts = keys %convert;
367
368 #
369 # Step 4: Do we have sections that started with local functions?
370 #
371 if ($#converts >= 0) {
372     my $globallist = "";
373     my $locallist = "";
374
375     foreach my $con (@converts) {
376         $globallist .= " --globalize-symbol $con";
377         $locallist .= " --localize-symbol $con";
378     }
379
380     my $globalobj = $dirname . "/.tmp_gl_" . $filename;
381     my $globalmix = $dirname . "/.tmp_mx_" . $filename;
382
383     #
384     # Step 5: set up each local function as a global
385     #
386     `$objcopy $globallist $inputfile $globalobj`;
387
388     #
389     # Step 6: Link the global version to our list.
390     #
391     `$ld -r $globalobj $mcount_o -o $globalmix`;
392
393     #
394     # Step 7: Convert the local functions back into local symbols
395     #
396     `$objcopy $locallist $globalmix $inputfile`;
397
398     # Remove the temp files
399     `$rm $globalobj $globalmix`;
400
401 } else {
402
403     my $mix = $dirname . "/.tmp_mx_" . $filename;
404
405     #
406     # Step 8: Link the object with our list of call sites object.
407     #
408     `$ld -r $inputfile $mcount_o -o $mix`;
409
410     #
411     # Step 9: Move the result back to the original object.
412     #
413     `$mv $mix $inputfile`;
414 }
415
416 # Clean up the temp files
417 `$rm $mcount_o $mcount_s`;
418
419 exit(0);