MIPS: Tracing: Add dynamic function tracer support
[linux-2.6.git] / scripts / recordmcount.pl
1 #!/usr/bin/perl -w
2 # (c) 2008, Steven Rostedt <srostedt@redhat.com>
3 # Licensed under the terms of the GNU GPL License version 2
4 #
5 # recordmcount.pl - makes a section called __mcount_loc that holds
6 #                   all the offsets to the calls to mcount.
7 #
8 #
9 # What we want to end up with this is that each object file will have a
10 # section called __mcount_loc that will hold the list of pointers to mcount
11 # callers. After final linking, the vmlinux will have within .init.data the
12 # list of all callers to mcount between __start_mcount_loc and __stop_mcount_loc.
13 # Later on boot up, the kernel will read this list, save the locations and turn
14 # them into nops. When tracing or profiling is later enabled, these locations
15 # will then be converted back to pointers to some function.
16 #
17 # This is no easy feat. This script is called just after the original
18 # object is compiled and before it is linked.
19 #
20 # When parse this object file using 'objdump', the references to the call
21 # sites are offsets from the section that the call site is in. Hence, all
22 # functions in a section that has a call site to mcount, will have the
23 # offset from the beginning of the section and not the beginning of the
24 # function.
25 #
26 # But where this section will reside finally in vmlinx is undetermined at
27 # this point. So we can't use this kind of offsets to record the final
28 # address of this call site.
29 #
30 # The trick is to change the call offset referring the start of a section to
31 # referring a function symbol in this section. During the link step, 'ld' will
32 # compute the final address according to the information we record.
33 #
34 # e.g.
35 #
36 #  .section ".sched.text", "ax"
37 #        [...]
38 #  func1:
39 #        [...]
40 #        call mcount  (offset: 0x10)
41 #        [...]
42 #        ret
43 #  .globl fun2
44 #  func2:             (offset: 0x20)
45 #        [...]
46 #        [...]
47 #        ret
48 #  func3:
49 #        [...]
50 #        call mcount (offset: 0x30)
51 #        [...]
52 #
53 # Both relocation offsets for the mcounts in the above example will be
54 # offset from .sched.text. If we choose global symbol func2 as a reference and
55 # make another file called tmp.s with the new offsets:
56 #
57 #  .section __mcount_loc
58 #  .quad  func2 - 0x10
59 #  .quad  func2 + 0x10
60 #
61 # We can then compile this tmp.s into tmp.o, and link it back to the original
62 # object.
63 #
64 # In our algorithm, we will choose the first global function we meet in this
65 # section as the reference. But this gets hard if there is no global functions
66 # in this section. In such a case we have to select a local one. E.g. func1:
67 #
68 #  .section ".sched.text", "ax"
69 #  func1:
70 #        [...]
71 #        call mcount  (offset: 0x10)
72 #        [...]
73 #        ret
74 #  func2:
75 #        [...]
76 #        call mcount (offset: 0x20)
77 #        [...]
78 #  .section "other.section"
79 #
80 # If we make the tmp.s the same as above, when we link together with
81 # the original object, we will end up with two symbols for func1:
82 # one local, one global.  After final compile, we will end up with
83 # an undefined reference to func1 or a wrong reference to another global
84 # func1 in other files.
85 #
86 # Since local objects can reference local variables, we need to find
87 # a way to make tmp.o reference the local objects of the original object
88 # file after it is linked together. To do this, we convert func1
89 # into a global symbol before linking tmp.o. Then after we link tmp.o
90 # we will only have a single symbol for func1 that is global.
91 # We can convert func1 back into a local symbol and we are done.
92 #
93 # Here are the steps we take:
94 #
95 # 1) Record all the local and weak symbols by using 'nm'
96 # 2) Use objdump to find all the call site offsets and sections for
97 #    mcount.
98 # 3) Compile the list into its own object.
99 # 4) Do we have to deal with local functions? If not, go to step 8.
100 # 5) Make an object that converts these local functions to global symbols
101 #    with objcopy.
102 # 6) Link together this new object with the list object.
103 # 7) Convert the local functions back to local symbols and rename
104 #    the result as the original object.
105 # 8) Link the object with the list object.
106 # 9) Move the result back to the original object.
107 #
108
109 use strict;
110
111 my $P = $0;
112 $P =~ s@.*/@@g;
113
114 my $V = '0.1';
115
116 if ($#ARGV != 11) {
117         print "usage: $P arch endian bits objdump objcopy cc ld nm rm mv is_module inputfile\n";
118         print "version: $V\n";
119         exit(1);
120 }
121
122 my ($arch, $endian, $bits, $objdump, $objcopy, $cc,
123     $ld, $nm, $rm, $mv, $is_module, $inputfile) = @ARGV;
124
125 # This file refers to mcount and shouldn't be ftraced, so lets' ignore it
126 if ($inputfile =~ m,kernel/trace/ftrace\.o$,) {
127     exit(0);
128 }
129
130 # Acceptable sections to record.
131 my %text_sections = (
132      ".text" => 1,
133      ".sched.text" => 1,
134      ".spinlock.text" => 1,
135      ".irqentry.text" => 1,
136      ".text.unlikely" => 1,
137 );
138
139 $objdump = "objdump" if ((length $objdump) == 0);
140 $objcopy = "objcopy" if ((length $objcopy) == 0);
141 $cc = "gcc" if ((length $cc) == 0);
142 $ld = "ld" if ((length $ld) == 0);
143 $nm = "nm" if ((length $nm) == 0);
144 $rm = "rm" if ((length $rm) == 0);
145 $mv = "mv" if ((length $mv) == 0);
146
147 #print STDERR "running: $P '$arch' '$objdump' '$objcopy' '$cc' '$ld' " .
148 #    "'$nm' '$rm' '$mv' '$inputfile'\n";
149
150 my %locals;             # List of local (static) functions
151 my %weak;               # List of weak functions
152 my %convert;            # List of local functions used that needs conversion
153
154 my $type;
155 my $local_regex;        # Match a local function (return function)
156 my $weak_regex;         # Match a weak function (return function)
157 my $section_regex;      # Find the start of a section
158 my $function_regex;     # Find the name of a function
159                         #    (return offset and func name)
160 my $mcount_regex;       # Find the call site to mcount (return offset)
161 my $alignment;          # The .align value to use for $mcount_section
162 my $section_type;       # Section header plus possible alignment command
163 my $can_use_local = 0;  # If we can use local function references
164
165 # Shut up recordmcount if user has older objcopy
166 my $quiet_recordmcount = ".tmp_quiet_recordmcount";
167 my $print_warning = 1;
168 $print_warning = 0 if ( -f $quiet_recordmcount);
169
170 ##
171 # check_objcopy - whether objcopy supports --globalize-symbols
172 #
173 #  --globalize-symbols came out in 2.17, we must test the version
174 #  of objcopy, and if it is less than 2.17, then we can not
175 #  record local functions.
176 sub check_objcopy
177 {
178     open (IN, "$objcopy --version |") or die "error running $objcopy";
179     while (<IN>) {
180         if (/objcopy.*\s(\d+)\.(\d+)/) {
181             $can_use_local = 1 if ($1 > 2 || ($1 == 2 && $2 >= 17));
182             last;
183         }
184     }
185     close (IN);
186
187     if (!$can_use_local && $print_warning) {
188         print STDERR "WARNING: could not find objcopy version or version " .
189             "is less than 2.17.\n" .
190             "\tLocal function references are disabled.\n";
191         open (QUIET, ">$quiet_recordmcount");
192         printf QUIET "Disables the warning from recordmcount.pl\n";
193         close QUIET;
194     }
195 }
196
197 if ($arch eq "x86") {
198     if ($bits == 64) {
199         $arch = "x86_64";
200     } else {
201         $arch = "i386";
202     }
203 }
204
205 #
206 # We base the defaults off of i386, the other archs may
207 # feel free to change them in the below if statements.
208 #
209 $local_regex = "^[0-9a-fA-F]+\\s+t\\s+(\\S+)";
210 $weak_regex = "^[0-9a-fA-F]+\\s+([wW])\\s+(\\S+)";
211 $section_regex = "Disassembly of section\\s+(\\S+):";
212 $function_regex = "^([0-9a-fA-F]+)\\s+<(.*?)>:";
213 $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\smcount\$";
214 $section_type = '@progbits';
215 $type = ".long";
216
217 if ($arch eq "x86_64") {
218     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\smcount([+-]0x[0-9a-zA-Z]+)?\$";
219     $type = ".quad";
220     $alignment = 8;
221
222     # force flags for this arch
223     $ld .= " -m elf_x86_64";
224     $objdump .= " -M x86-64";
225     $objcopy .= " -O elf64-x86-64";
226     $cc .= " -m64";
227
228 } elsif ($arch eq "i386") {
229     $alignment = 4;
230
231     # force flags for this arch
232     $ld .= " -m elf_i386";
233     $objdump .= " -M i386";
234     $objcopy .= " -O elf32-i386";
235     $cc .= " -m32";
236
237 } elsif ($arch eq "s390" && $bits == 32) {
238     $mcount_regex = "^\\s*([0-9a-fA-F]+):\\s*R_390_32\\s+_mcount\$";
239     $alignment = 4;
240     $ld .= " -m elf_s390";
241     $cc .= " -m31";
242
243 } elsif ($arch eq "s390" && $bits == 64) {
244     $mcount_regex = "^\\s*([0-9a-fA-F]+):\\s*R_390_(PC|PLT)32DBL\\s+_mcount\\+0x2\$";
245     $alignment = 8;
246     $type = ".quad";
247     $ld .= " -m elf64_s390";
248     $cc .= " -m64";
249
250 } elsif ($arch eq "sh") {
251     $alignment = 2;
252
253     # force flags for this arch
254     $ld .= " -m shlelf_linux";
255     $objcopy .= " -O elf32-sh-linux";
256     $cc .= " -m32";
257
258 } elsif ($arch eq "powerpc") {
259     $local_regex = "^[0-9a-fA-F]+\\s+t\\s+(\\.?\\S+)";
260     $function_regex = "^([0-9a-fA-F]+)\\s+<(\\.?.*?)>:";
261     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s\\.?_mcount\$";
262
263     if ($bits == 64) {
264         $type = ".quad";
265     }
266
267 } elsif ($arch eq "arm") {
268     $alignment = 2;
269     $section_type = '%progbits';
270
271 } elsif ($arch eq "ia64") {
272     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s_mcount\$";
273     $type = "data8";
274
275     if ($is_module eq "0") {
276         $cc .= " -mconstant-gp";
277     }
278 } elsif ($arch eq "sparc64") {
279     # In the objdump output there are giblets like:
280     # 0000000000000000 <igmp_net_exit-0x18>:
281     # As there's some data blobs that get emitted into the
282     # text section before the first instructions and the first
283     # real symbols.  We don't want to match that, so to combat
284     # this we use '\w' so we'll match just plain symbol names,
285     # and not those that also include hex offsets inside of the
286     # '<>' brackets.  Actually the generic function_regex setting
287     # could safely use this too.
288     $function_regex = "^([0-9a-fA-F]+)\\s+<(\\w*?)>:";
289
290     # Sparc64 calls '_mcount' instead of plain 'mcount'.
291     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s_mcount\$";
292
293     $alignment = 8;
294     $type = ".xword";
295     $ld .= " -m elf64_sparc";
296     $cc .= " -m64";
297     $objcopy .= " -O elf64-sparc";
298 } elsif ($arch eq "mips") {
299     # To enable module support, we need to enable the -mlong-calls option
300     # of gcc for module, after using this option, we can not get the real
301     # offset of the calling to _mcount, but the offset of the lui
302     # instruction or the addiu one. herein, we record the address of the
303     # first one, and then we can replace this instruction by a branch
304     # instruction to jump over the profiling function to filter the
305     # indicated functions, or swith back to the lui instruction to trace
306     # them, which means dynamic tracing.
307     #
308     #       c:  3c030000        lui     v1,0x0
309     #                   c: R_MIPS_HI16  _mcount
310     #                   c: R_MIPS_NONE  *ABS*
311     #                   c: R_MIPS_NONE  *ABS*
312     #      10:  64630000        daddiu  v1,v1,0
313     #                   10: R_MIPS_LO16 _mcount
314     #                   10: R_MIPS_NONE *ABS*
315     #                   10: R_MIPS_NONE *ABS*
316     #      14:  03e0082d        move    at,ra
317     #      18:  0060f809        jalr    v1
318     #
319     # for the kernel:
320     #
321     #     10:   03e0082d        move    at,ra
322     #     14:   0c000000        jal     0 <loongson_halt>
323     #                    14: R_MIPS_26   _mcount
324     #                    14: R_MIPS_NONE *ABS*
325     #                    14: R_MIPS_NONE *ABS*
326     #    18:   00020021        nop
327     if ($is_module eq "0") {
328             $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s_mcount\$";
329     } else {
330             $mcount_regex = "^\\s*([0-9a-fA-F]+): R_MIPS_HI16\\s+_mcount\$";
331     }
332     $objdump .= " -Melf-trad".$endian."mips ";
333
334     if ($endian eq "big") {
335             $endian = " -EB ";
336             $ld .= " -melf".$bits."btsmip";
337     } else {
338             $endian = " -EL ";
339             $ld .= " -melf".$bits."ltsmip";
340     }
341
342     $cc .= " -mno-abicalls -fno-pic -mabi=" . $bits . $endian;
343     $ld .= $endian;
344
345     if ($bits == 64) {
346             $function_regex =
347                 "^([0-9a-fA-F]+)\\s+<(.|[^\$]L.*?|\$[^L].*?|[^\$][^L].*?)>:";
348             $type = ".dword";
349     }
350 } elsif ($arch eq "microblaze") {
351     # Microblaze calls '_mcount' instead of plain 'mcount'.
352     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s_mcount\$";
353 } else {
354     die "Arch $arch is not supported with CONFIG_FTRACE_MCOUNT_RECORD";
355 }
356
357 my $text_found = 0;
358 my $read_function = 0;
359 my $opened = 0;
360 my $mcount_section = "__mcount_loc";
361
362 my $dirname;
363 my $filename;
364 my $prefix;
365 my $ext;
366
367 if ($inputfile =~ m,^(.*)/([^/]*)$,) {
368     $dirname = $1;
369     $filename = $2;
370 } else {
371     $dirname = ".";
372     $filename = $inputfile;
373 }
374
375 if ($filename =~ m,^(.*)(\.\S),) {
376     $prefix = $1;
377     $ext = $2;
378 } else {
379     $prefix = $filename;
380     $ext = "";
381 }
382
383 my $mcount_s = $dirname . "/.tmp_mc_" . $prefix . ".s";
384 my $mcount_o = $dirname . "/.tmp_mc_" . $prefix . ".o";
385
386 check_objcopy();
387
388 #
389 # Step 1: find all the local (static functions) and weak symbols.
390 #         't' is local, 'w/W' is weak
391 #
392 open (IN, "$nm $inputfile|") || die "error running $nm";
393 while (<IN>) {
394     if (/$local_regex/) {
395         $locals{$1} = 1;
396     } elsif (/$weak_regex/) {
397         $weak{$2} = $1;
398     }
399 }
400 close(IN);
401
402 my @offsets;            # Array of offsets of mcount callers
403 my $ref_func;           # reference function to use for offsets
404 my $offset = 0;         # offset of ref_func to section beginning
405
406 ##
407 # update_funcs - print out the current mcount callers
408 #
409 #  Go through the list of offsets to callers and write them to
410 #  the output file in a format that can be read by an assembler.
411 #
412 sub update_funcs
413 {
414     return unless ($ref_func and @offsets);
415
416     # Sanity check on weak function. A weak function may be overwritten by
417     # another function of the same name, making all these offsets incorrect.
418     if (defined $weak{$ref_func}) {
419         die "$inputfile: ERROR: referencing weak function" .
420             " $ref_func for mcount\n";
421     }
422
423     # is this function static? If so, note this fact.
424     if (defined $locals{$ref_func}) {
425
426         # only use locals if objcopy supports globalize-symbols
427         if (!$can_use_local) {
428             return;
429         }
430         $convert{$ref_func} = 1;
431     }
432
433     # Loop through all the mcount caller offsets and print a reference
434     # to the caller based from the ref_func.
435     for (my $i=0; $i <= $#offsets; $i++) {
436         if (!$opened) {
437             open(FILE, ">$mcount_s") || die "can't create $mcount_s\n";
438             $opened = 1;
439             print FILE "\t.section $mcount_section,\"a\",$section_type\n";
440             print FILE "\t.align $alignment\n" if (defined($alignment));
441         }
442         printf FILE "\t%s %s + %d\n", $type, $ref_func, $offsets[$i] - $offset;
443     }
444 }
445
446 #
447 # Step 2: find the sections and mcount call sites
448 #
449 open(IN, "$objdump -hdr $inputfile|") || die "error running $objdump";
450
451 my $text;
452
453
454 # read headers first
455 my $read_headers = 1;
456
457 while (<IN>) {
458
459     if ($read_headers && /$mcount_section/) {
460         #
461         # Somehow the make process can execute this script on an
462         # object twice. If it does, we would duplicate the mcount
463         # section and it will cause the function tracer self test
464         # to fail. Check if the mcount section exists, and if it does,
465         # warn and exit.
466         #
467         print STDERR "ERROR: $mcount_section already in $inputfile\n" .
468             "\tThis may be an indication that your build is corrupted.\n" .
469             "\tDelete $inputfile and try again. If the same object file\n" .
470             "\tstill causes an issue, then disable CONFIG_DYNAMIC_FTRACE.\n";
471         exit(-1);
472     }
473
474     # is it a section?
475     if (/$section_regex/) {
476         $read_headers = 0;
477
478         # Only record text sections that we know are safe
479         if (defined($text_sections{$1})) {
480             $read_function = 1;
481         } else {
482             $read_function = 0;
483         }
484         # print out any recorded offsets
485         update_funcs();
486
487         # reset all markers and arrays
488         $text_found = 0;
489         undef($ref_func);
490         undef(@offsets);
491
492     # section found, now is this a start of a function?
493     } elsif ($read_function && /$function_regex/) {
494         $text_found = 1;
495         $text = $2;
496
497         # if this is either a local function or a weak function
498         # keep looking for functions that are global that
499         # we can use safely.
500         if (!defined($locals{$text}) && !defined($weak{$text})) {
501             $ref_func = $text;
502             $read_function = 0;
503             $offset = hex $1;
504         } else {
505             # if we already have a function, and this is weak, skip it
506             if (!defined($ref_func) && !defined($weak{$text}) &&
507                  # PPC64 can have symbols that start with .L and
508                  # gcc considers these special. Don't use them!
509                  $text !~ /^\.L/) {
510                 $ref_func = $text;
511                 $offset = hex $1;
512             }
513         }
514     }
515     # is this a call site to mcount? If so, record it to print later
516     if ($text_found && /$mcount_regex/) {
517         $offsets[$#offsets + 1] = hex $1;
518     }
519 }
520
521 # dump out anymore offsets that may have been found
522 update_funcs();
523
524 # If we did not find any mcount callers, we are done (do nothing).
525 if (!$opened) {
526     exit(0);
527 }
528
529 close(FILE);
530
531 #
532 # Step 3: Compile the file that holds the list of call sites to mcount.
533 #
534 `$cc -o $mcount_o -c $mcount_s`;
535
536 my @converts = keys %convert;
537
538 #
539 # Step 4: Do we have sections that started with local functions?
540 #
541 if ($#converts >= 0) {
542     my $globallist = "";
543     my $locallist = "";
544
545     foreach my $con (@converts) {
546         $globallist .= " --globalize-symbol $con";
547         $locallist .= " --localize-symbol $con";
548     }
549
550     my $globalobj = $dirname . "/.tmp_gl_" . $filename;
551     my $globalmix = $dirname . "/.tmp_mx_" . $filename;
552
553     #
554     # Step 5: set up each local function as a global
555     #
556     `$objcopy $globallist $inputfile $globalobj`;
557
558     #
559     # Step 6: Link the global version to our list.
560     #
561     `$ld -r $globalobj $mcount_o -o $globalmix`;
562
563     #
564     # Step 7: Convert the local functions back into local symbols
565     #
566     `$objcopy $locallist $globalmix $inputfile`;
567
568     # Remove the temp files
569     `$rm $globalobj $globalmix`;
570
571 } else {
572
573     my $mix = $dirname . "/.tmp_mx_" . $filename;
574
575     #
576     # Step 8: Link the object with our list of call sites object.
577     #
578     `$ld -r $inputfile $mcount_o -o $mix`;
579
580     #
581     # Step 9: Move the result back to the original object.
582     #
583     `$mv $mix $inputfile`;
584 }
585
586 # Clean up the temp files
587 `$rm $mcount_o $mcount_s`;
588
589 exit(0);