tracing: Enable "__cold" functions
[linux-2.6.git] / scripts / recordmcount.pl
1 #!/usr/bin/perl -w
2 # (c) 2008, Steven Rostedt <srostedt@redhat.com>
3 # Licensed under the terms of the GNU GPL License version 2
4 #
5 # recordmcount.pl - makes a section called __mcount_loc that holds
6 #                   all the offsets to the calls to mcount.
7 #
8 #
9 # What we want to end up with is a section in vmlinux called
10 # __mcount_loc that contains a list of pointers to all the
11 # call sites in the kernel that call mcount. Later on boot up, the kernel
12 # will read this list, save the locations and turn them into nops.
13 # When tracing or profiling is later enabled, these locations will then
14 # be converted back to pointers to some function.
15 #
16 # This is no easy feat. This script is called just after the original
17 # object is compiled and before it is linked.
18 #
19 # The references to the call sites are offsets from the section of text
20 # that the call site is in. Hence, all functions in a section that
21 # has a call site to mcount, will have the offset from the beginning of
22 # the section and not the beginning of the function.
23 #
24 # The trick is to find a way to record the beginning of the section.
25 # The way we do this is to look at the first function in the section
26 # which will also be the location of that section after final link.
27 # e.g.
28 #
29 #  .section ".sched.text", "ax"
30 #  .globl my_func
31 #  my_func:
32 #        [...]
33 #        call mcount  (offset: 0x5)
34 #        [...]
35 #        ret
36 #  other_func:
37 #        [...]
38 #        call mcount (offset: 0x1b)
39 #        [...]
40 #
41 # Both relocation offsets for the mcounts in the above example will be
42 # offset from .sched.text. If we make another file called tmp.s with:
43 #
44 #  .section __mcount_loc
45 #  .quad  my_func + 0x5
46 #  .quad  my_func + 0x1b
47 #
48 # We can then compile this tmp.s into tmp.o, and link it to the original
49 # object.
50 #
51 # But this gets hard if my_func is not globl (a static function).
52 # In such a case we have:
53 #
54 #  .section ".sched.text", "ax"
55 #  my_func:
56 #        [...]
57 #        call mcount  (offset: 0x5)
58 #        [...]
59 #        ret
60 #  other_func:
61 #        [...]
62 #        call mcount (offset: 0x1b)
63 #        [...]
64 #
65 # If we make the tmp.s the same as above, when we link together with
66 # the original object, we will end up with two symbols for my_func:
67 # one local, one global.  After final compile, we will end up with
68 # an undefined reference to my_func.
69 #
70 # Since local objects can reference local variables, we need to find
71 # a way to make tmp.o reference the local objects of the original object
72 # file after it is linked together. To do this, we convert the my_func
73 # into a global symbol before linking tmp.o. Then after we link tmp.o
74 # we will only have a single symbol for my_func that is global.
75 # We can convert my_func back into a local symbol and we are done.
76 #
77 # Here are the steps we take:
78 #
79 # 1) Record all the local symbols by using 'nm'
80 # 2) Use objdump to find all the call site offsets and sections for
81 #    mcount.
82 # 3) Compile the list into its own object.
83 # 4) Do we have to deal with local functions? If not, go to step 8.
84 # 5) Make an object that converts these local functions to global symbols
85 #    with objcopy.
86 # 6) Link together this new object with the list object.
87 # 7) Convert the local functions back to local symbols and rename
88 #    the result as the original object.
89 #    End.
90 # 8) Link the object with the list object.
91 # 9) Move the result back to the original object.
92 #    End.
93 #
94
95 use strict;
96
97 my $P = $0;
98 $P =~ s@.*/@@g;
99
100 my $V = '0.1';
101
102 if ($#ARGV < 7) {
103         print "usage: $P arch bits objdump objcopy cc ld nm rm mv is_module inputfile\n";
104         print "version: $V\n";
105         exit(1);
106 }
107
108 my ($arch, $bits, $objdump, $objcopy, $cc,
109     $ld, $nm, $rm, $mv, $is_module, $inputfile) = @ARGV;
110
111 # This file refers to mcount and shouldn't be ftraced, so lets' ignore it
112 if ($inputfile eq "kernel/trace/ftrace.o") {
113     exit(0);
114 }
115
116 # Acceptable sections to record.
117 my %text_sections = (
118      ".text" => 1,
119      ".sched.text" => 1,
120      ".spinlock.text" => 1,
121      ".irqentry.text" => 1,
122      ".text.unlikely" => 1,
123 );
124
125 $objdump = "objdump" if ((length $objdump) == 0);
126 $objcopy = "objcopy" if ((length $objcopy) == 0);
127 $cc = "gcc" if ((length $cc) == 0);
128 $ld = "ld" if ((length $ld) == 0);
129 $nm = "nm" if ((length $nm) == 0);
130 $rm = "rm" if ((length $rm) == 0);
131 $mv = "mv" if ((length $mv) == 0);
132
133 #print STDERR "running: $P '$arch' '$objdump' '$objcopy' '$cc' '$ld' " .
134 #    "'$nm' '$rm' '$mv' '$inputfile'\n";
135
136 my %locals;             # List of local (static) functions
137 my %weak;               # List of weak functions
138 my %convert;            # List of local functions used that needs conversion
139
140 my $type;
141 my $nm_regex;           # Find the local functions (return function)
142 my $section_regex;      # Find the start of a section
143 my $function_regex;     # Find the name of a function
144                         #    (return offset and func name)
145 my $mcount_regex;       # Find the call site to mcount (return offset)
146 my $alignment;          # The .align value to use for $mcount_section
147 my $section_type;       # Section header plus possible alignment command
148
149 if ($arch eq "x86") {
150     if ($bits == 64) {
151         $arch = "x86_64";
152     } else {
153         $arch = "i386";
154     }
155 }
156
157 #
158 # We base the defaults off of i386, the other archs may
159 # feel free to change them in the below if statements.
160 #
161 $nm_regex = "^[0-9a-fA-F]+\\s+t\\s+(\\S+)";
162 $section_regex = "Disassembly of section\\s+(\\S+):";
163 $function_regex = "^([0-9a-fA-F]+)\\s+<(.*?)>:";
164 $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\smcount\$";
165 $section_type = '@progbits';
166 $type = ".long";
167
168 if ($arch eq "x86_64") {
169     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\smcount([+-]0x[0-9a-zA-Z]+)?\$";
170     $type = ".quad";
171     $alignment = 8;
172
173     # force flags for this arch
174     $ld .= " -m elf_x86_64";
175     $objdump .= " -M x86-64";
176     $objcopy .= " -O elf64-x86-64";
177     $cc .= " -m64";
178
179 } elsif ($arch eq "i386") {
180     $alignment = 4;
181
182     # force flags for this arch
183     $ld .= " -m elf_i386";
184     $objdump .= " -M i386";
185     $objcopy .= " -O elf32-i386";
186     $cc .= " -m32";
187
188 } elsif ($arch eq "s390" && $bits == 32) {
189     $mcount_regex = "^\\s*([0-9a-fA-F]+):\\s*R_390_32\\s+_mcount\$";
190     $alignment = 4;
191     $ld .= " -m elf_s390";
192     $cc .= " -m31";
193
194 } elsif ($arch eq "s390" && $bits == 64) {
195     $mcount_regex = "^\\s*([0-9a-fA-F]+):\\s*R_390_(PC|PLT)32DBL\\s+_mcount\\+0x2\$";
196     $alignment = 8;
197     $type = ".quad";
198     $ld .= " -m elf64_s390";
199     $cc .= " -m64";
200
201 } elsif ($arch eq "sh") {
202     $alignment = 2;
203
204     # force flags for this arch
205     $ld .= " -m shlelf_linux";
206     $objcopy .= " -O elf32-sh-linux";
207     $cc .= " -m32";
208
209 } elsif ($arch eq "powerpc") {
210     $nm_regex = "^[0-9a-fA-F]+\\s+t\\s+(\\.?\\S+)";
211     $function_regex = "^([0-9a-fA-F]+)\\s+<(\\.?.*?)>:";
212     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s\\.?_mcount\$";
213
214     if ($bits == 64) {
215         $type = ".quad";
216     }
217
218 } elsif ($arch eq "arm") {
219     $alignment = 2;
220     $section_type = '%progbits';
221
222 } elsif ($arch eq "ia64") {
223     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s_mcount\$";
224     $type = "data8";
225
226     if ($is_module eq "0") {
227         $cc .= " -mconstant-gp";
228     }
229 } elsif ($arch eq "sparc64") {
230     # In the objdump output there are giblets like:
231     # 0000000000000000 <igmp_net_exit-0x18>:
232     # As there's some data blobs that get emitted into the
233     # text section before the first instructions and the first
234     # real symbols.  We don't want to match that, so to combat
235     # this we use '\w' so we'll match just plain symbol names,
236     # and not those that also include hex offsets inside of the
237     # '<>' brackets.  Actually the generic function_regex setting
238     # could safely use this too.
239     $function_regex = "^([0-9a-fA-F]+)\\s+<(\\w*?)>:";
240
241     # Sparc64 calls '_mcount' instead of plain 'mcount'.
242     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s_mcount\$";
243
244     $alignment = 8;
245     $type = ".xword";
246     $ld .= " -m elf64_sparc";
247     $cc .= " -m64";
248     $objcopy .= " -O elf64-sparc";
249 } else {
250     die "Arch $arch is not supported with CONFIG_FTRACE_MCOUNT_RECORD";
251 }
252
253 my $text_found = 0;
254 my $read_function = 0;
255 my $opened = 0;
256 my $mcount_section = "__mcount_loc";
257
258 my $dirname;
259 my $filename;
260 my $prefix;
261 my $ext;
262
263 if ($inputfile =~ m,^(.*)/([^/]*)$,) {
264     $dirname = $1;
265     $filename = $2;
266 } else {
267     $dirname = ".";
268     $filename = $inputfile;
269 }
270
271 if ($filename =~ m,^(.*)(\.\S),) {
272     $prefix = $1;
273     $ext = $2;
274 } else {
275     $prefix = $filename;
276     $ext = "";
277 }
278
279 my $mcount_s = $dirname . "/.tmp_mc_" . $prefix . ".s";
280 my $mcount_o = $dirname . "/.tmp_mc_" . $prefix . ".o";
281
282 #
283 # --globalize-symbols came out in 2.17, we must test the version
284 # of objcopy, and if it is less than 2.17, then we can not
285 # record local functions.
286 my $use_locals = 01;
287 my $local_warn_once = 0;
288 my $found_version = 0;
289
290 open (IN, "$objcopy --version |") || die "error running $objcopy";
291 while (<IN>) {
292     if (/objcopy.*\s(\d+)\.(\d+)/) {
293         my $major = $1;
294         my $minor = $2;
295
296         $found_version = 1;
297         if ($major < 2 ||
298             ($major == 2 && $minor < 17)) {
299             $use_locals = 0;
300         }
301         last;
302     }
303 }
304 close (IN);
305
306 if (!$found_version) {
307     print STDERR "WARNING: could not find objcopy version.\n" .
308         "\tDisabling local function references.\n";
309 }
310
311 #
312 # Step 1: find all the local (static functions) and weak symbols.
313 #        't' is local, 'w/W' is weak (we never use a weak function)
314 #
315 open (IN, "$nm $inputfile|") || die "error running $nm";
316 while (<IN>) {
317     if (/$nm_regex/) {
318         $locals{$1} = 1;
319     } elsif (/^[0-9a-fA-F]+\s+([wW])\s+(\S+)/) {
320         $weak{$2} = $1;
321     }
322 }
323 close(IN);
324
325 my @offsets;            # Array of offsets of mcount callers
326 my $ref_func;           # reference function to use for offsets
327 my $offset = 0;         # offset of ref_func to section beginning
328
329 ##
330 # update_funcs - print out the current mcount callers
331 #
332 #  Go through the list of offsets to callers and write them to
333 #  the output file in a format that can be read by an assembler.
334 #
335 sub update_funcs
336 {
337     return if ($#offsets < 0);
338
339     defined($ref_func) || die "No function to reference";
340
341     # A section only had a weak function, to represent it.
342     # Unfortunately, a weak function may be overwritten by another
343     # function of the same name, making all these offsets incorrect.
344     # To be safe, we simply print a warning and bail.
345     if (defined $weak{$ref_func}) {
346         print STDERR
347             "$inputfile: WARNING: referencing weak function" .
348             " $ref_func for mcount\n";
349         return;
350     }
351
352     # is this function static? If so, note this fact.
353     if (defined $locals{$ref_func}) {
354
355         # only use locals if objcopy supports globalize-symbols
356         if (!$use_locals) {
357             return;
358         }
359         $convert{$ref_func} = 1;
360     }
361
362     # Loop through all the mcount caller offsets and print a reference
363     # to the caller based from the ref_func.
364     for (my $i=0; $i <= $#offsets; $i++) {
365         if (!$opened) {
366             open(FILE, ">$mcount_s") || die "can't create $mcount_s\n";
367             $opened = 1;
368             print FILE "\t.section $mcount_section,\"a\",$section_type\n";
369             print FILE "\t.align $alignment\n" if (defined($alignment));
370         }
371         printf FILE "\t%s %s + %d\n", $type, $ref_func, $offsets[$i] - $offset;
372     }
373 }
374
375 #
376 # Step 2: find the sections and mcount call sites
377 #
378 open(IN, "$objdump -hdr $inputfile|") || die "error running $objdump";
379
380 my $text;
381
382 my $read_headers = 1;
383
384 while (<IN>) {
385     # is it a section?
386     if (/$section_regex/) {
387         $read_headers = 0;
388
389         # Only record text sections that we know are safe
390         if (defined($text_sections{$1})) {
391             $read_function = 1;
392         } else {
393             $read_function = 0;
394         }
395         # print out any recorded offsets
396         update_funcs() if (defined($ref_func));
397
398         # reset all markers and arrays
399         $text_found = 0;
400         undef($ref_func);
401         undef(@offsets);
402
403     # section found, now is this a start of a function?
404     } elsif ($read_function && /$function_regex/) {
405         $text_found = 1;
406         $text = $2;
407
408         # if this is either a local function or a weak function
409         # keep looking for functions that are global that
410         # we can use safely.
411         if (!defined($locals{$text}) && !defined($weak{$text})) {
412             $ref_func = $text;
413             $read_function = 0;
414             $offset = hex $1;
415         } else {
416             # if we already have a function, and this is weak, skip it
417             if (!defined($ref_func) && !defined($weak{$text}) &&
418                  # PPC64 can have symbols that start with .L and
419                  # gcc considers these special. Don't use them!
420                  $text !~ /^\.L/) {
421                 $ref_func = $text;
422                 $offset = hex $1;
423             }
424         }
425     } elsif ($read_headers && /$mcount_section/) {
426         #
427         # Somehow the make process can execute this script on an
428         # object twice. If it does, we would duplicate the mcount
429         # section and it will cause the function tracer self test
430         # to fail. Check if the mcount section exists, and if it does,
431         # warn and exit.
432         #
433         print STDERR "ERROR: $mcount_section already in $inputfile\n" .
434             "\tThis may be an indication that your build is corrupted.\n" .
435             "\tDelete $inputfile and try again. If the same object file\n" .
436             "\tstill causes an issue, then disable CONFIG_DYNAMIC_FTRACE.\n";
437         exit(-1);
438     }
439
440     # is this a call site to mcount? If so, record it to print later
441     if ($text_found && /$mcount_regex/) {
442         $offsets[$#offsets + 1] = hex $1;
443     }
444 }
445
446 # dump out anymore offsets that may have been found
447 update_funcs() if (defined($ref_func));
448
449 # If we did not find any mcount callers, we are done (do nothing).
450 if (!$opened) {
451     exit(0);
452 }
453
454 close(FILE);
455
456 #
457 # Step 3: Compile the file that holds the list of call sites to mcount.
458 #
459 `$cc -o $mcount_o -c $mcount_s`;
460
461 my @converts = keys %convert;
462
463 #
464 # Step 4: Do we have sections that started with local functions?
465 #
466 if ($#converts >= 0) {
467     my $globallist = "";
468     my $locallist = "";
469
470     foreach my $con (@converts) {
471         $globallist .= " --globalize-symbol $con";
472         $locallist .= " --localize-symbol $con";
473     }
474
475     my $globalobj = $dirname . "/.tmp_gl_" . $filename;
476     my $globalmix = $dirname . "/.tmp_mx_" . $filename;
477
478     #
479     # Step 5: set up each local function as a global
480     #
481     `$objcopy $globallist $inputfile $globalobj`;
482
483     #
484     # Step 6: Link the global version to our list.
485     #
486     `$ld -r $globalobj $mcount_o -o $globalmix`;
487
488     #
489     # Step 7: Convert the local functions back into local symbols
490     #
491     `$objcopy $locallist $globalmix $inputfile`;
492
493     # Remove the temp files
494     `$rm $globalobj $globalmix`;
495
496 } else {
497
498     my $mix = $dirname . "/.tmp_mx_" . $filename;
499
500     #
501     # Step 8: Link the object with our list of call sites object.
502     #
503     `$ld -r $inputfile $mcount_o -o $mix`;
504
505     #
506     # Step 9: Move the result back to the original object.
507     #
508     `$mv $mix $inputfile`;
509 }
510
511 # Clean up the temp files
512 `$rm $mcount_o $mcount_s`;
513
514 exit(0);