ftrace/x86: mcount offset calculation
[linux-2.6.git] / scripts / recordmcount.pl
1 #!/usr/bin/perl -w
2 # (c) 2008, Steven Rostedt <srostedt@redhat.com>
3 # Licensed under the terms of the GNU GPL License version 2
4 #
5 # recordmcount.pl - makes a section called __mcount_loc that holds
6 #                   all the offsets to the calls to mcount.
7 #
8 #
9 # What we want to end up with this is that each object file will have a
10 # section called __mcount_loc that will hold the list of pointers to mcount
11 # callers. After final linking, the vmlinux will have within .init.data the
12 # list of all callers to mcount between __start_mcount_loc and __stop_mcount_loc.
13 # Later on boot up, the kernel will read this list, save the locations and turn
14 # them into nops. When tracing or profiling is later enabled, these locations
15 # will then be converted back to pointers to some function.
16 #
17 # This is no easy feat. This script is called just after the original
18 # object is compiled and before it is linked.
19 #
20 # When parse this object file using 'objdump', the references to the call
21 # sites are offsets from the section that the call site is in. Hence, all
22 # functions in a section that has a call site to mcount, will have the
23 # offset from the beginning of the section and not the beginning of the
24 # function.
25 #
26 # But where this section will reside finally in vmlinx is undetermined at
27 # this point. So we can't use this kind of offsets to record the final
28 # address of this call site.
29 #
30 # The trick is to change the call offset referring the start of a section to
31 # referring a function symbol in this section. During the link step, 'ld' will
32 # compute the final address according to the information we record.
33 #
34 # e.g.
35 #
36 #  .section ".sched.text", "ax"
37 #        [...]
38 #  func1:
39 #        [...]
40 #        call mcount  (offset: 0x10)
41 #        [...]
42 #        ret
43 #  .globl fun2
44 #  func2:             (offset: 0x20)
45 #        [...]
46 #        [...]
47 #        ret
48 #  func3:
49 #        [...]
50 #        call mcount (offset: 0x30)
51 #        [...]
52 #
53 # Both relocation offsets for the mcounts in the above example will be
54 # offset from .sched.text. If we choose global symbol func2 as a reference and
55 # make another file called tmp.s with the new offsets:
56 #
57 #  .section __mcount_loc
58 #  .quad  func2 - 0x10
59 #  .quad  func2 + 0x10
60 #
61 # We can then compile this tmp.s into tmp.o, and link it back to the original
62 # object.
63 #
64 # In our algorithm, we will choose the first global function we meet in this
65 # section as the reference. But this gets hard if there is no global functions
66 # in this section. In such a case we have to select a local one. E.g. func1:
67 #
68 #  .section ".sched.text", "ax"
69 #  func1:
70 #        [...]
71 #        call mcount  (offset: 0x10)
72 #        [...]
73 #        ret
74 #  func2:
75 #        [...]
76 #        call mcount (offset: 0x20)
77 #        [...]
78 #  .section "other.section"
79 #
80 # If we make the tmp.s the same as above, when we link together with
81 # the original object, we will end up with two symbols for func1:
82 # one local, one global.  After final compile, we will end up with
83 # an undefined reference to func1 or a wrong reference to another global
84 # func1 in other files.
85 #
86 # Since local objects can reference local variables, we need to find
87 # a way to make tmp.o reference the local objects of the original object
88 # file after it is linked together. To do this, we convert func1
89 # into a global symbol before linking tmp.o. Then after we link tmp.o
90 # we will only have a single symbol for func1 that is global.
91 # We can convert func1 back into a local symbol and we are done.
92 #
93 # Here are the steps we take:
94 #
95 # 1) Record all the local and weak symbols by using 'nm'
96 # 2) Use objdump to find all the call site offsets and sections for
97 #    mcount.
98 # 3) Compile the list into its own object.
99 # 4) Do we have to deal with local functions? If not, go to step 8.
100 # 5) Make an object that converts these local functions to global symbols
101 #    with objcopy.
102 # 6) Link together this new object with the list object.
103 # 7) Convert the local functions back to local symbols and rename
104 #    the result as the original object.
105 # 8) Link the object with the list object.
106 # 9) Move the result back to the original object.
107 #
108
109 use strict;
110
111 my $P = $0;
112 $P =~ s@.*/@@g;
113
114 my $V = '0.1';
115
116 if ($#ARGV != 11) {
117         print "usage: $P arch endian bits objdump objcopy cc ld nm rm mv is_module inputfile\n";
118         print "version: $V\n";
119         exit(1);
120 }
121
122 my ($arch, $endian, $bits, $objdump, $objcopy, $cc,
123     $ld, $nm, $rm, $mv, $is_module, $inputfile) = @ARGV;
124
125 # This file refers to mcount and shouldn't be ftraced, so lets' ignore it
126 if ($inputfile =~ m,kernel/trace/ftrace\.o$,) {
127     exit(0);
128 }
129
130 # Acceptable sections to record.
131 my %text_sections = (
132      ".text" => 1,
133      ".ref.text" => 1,
134      ".sched.text" => 1,
135      ".spinlock.text" => 1,
136      ".irqentry.text" => 1,
137      ".kprobes.text" => 1,
138      ".text.unlikely" => 1,
139 );
140
141 # Note: we are nice to C-programmers here, thus we skip the '||='-idiom.
142 $objdump = 'objdump' if (!$objdump);
143 $objcopy = 'objcopy' if (!$objcopy);
144 $cc = 'gcc' if (!$cc);
145 $ld = 'ld' if (!$ld);
146 $nm = 'nm' if (!$nm);
147 $rm = 'rm' if (!$rm);
148 $mv = 'mv' if (!$mv);
149
150 #print STDERR "running: $P '$arch' '$objdump' '$objcopy' '$cc' '$ld' " .
151 #    "'$nm' '$rm' '$mv' '$inputfile'\n";
152
153 my %locals;             # List of local (static) functions
154 my %weak;               # List of weak functions
155 my %convert;            # List of local functions used that needs conversion
156
157 my $type;
158 my $local_regex;        # Match a local function (return function)
159 my $weak_regex;         # Match a weak function (return function)
160 my $section_regex;      # Find the start of a section
161 my $function_regex;     # Find the name of a function
162                         #    (return offset and func name)
163 my $mcount_regex;       # Find the call site to mcount (return offset)
164 my $mcount_adjust;      # Address adjustment to mcount offset
165 my $alignment;          # The .align value to use for $mcount_section
166 my $section_type;       # Section header plus possible alignment command
167 my $can_use_local = 0;  # If we can use local function references
168
169 # Shut up recordmcount if user has older objcopy
170 my $quiet_recordmcount = ".tmp_quiet_recordmcount";
171 my $print_warning = 1;
172 $print_warning = 0 if ( -f $quiet_recordmcount);
173
174 ##
175 # check_objcopy - whether objcopy supports --globalize-symbols
176 #
177 #  --globalize-symbols came out in 2.17, we must test the version
178 #  of objcopy, and if it is less than 2.17, then we can not
179 #  record local functions.
180 sub check_objcopy
181 {
182     open (IN, "$objcopy --version |") or die "error running $objcopy";
183     while (<IN>) {
184         if (/objcopy.*\s(\d+)\.(\d+)/) {
185             $can_use_local = 1 if ($1 > 2 || ($1 == 2 && $2 >= 17));
186             last;
187         }
188     }
189     close (IN);
190
191     if (!$can_use_local && $print_warning) {
192         print STDERR "WARNING: could not find objcopy version or version " .
193             "is less than 2.17.\n" .
194             "\tLocal function references are disabled.\n";
195         open (QUIET, ">$quiet_recordmcount");
196         printf QUIET "Disables the warning from recordmcount.pl\n";
197         close QUIET;
198     }
199 }
200
201 if ($arch =~ /(x86(_64)?)|(i386)/) {
202     if ($bits == 64) {
203         $arch = "x86_64";
204     } else {
205         $arch = "i386";
206     }
207 }
208
209 #
210 # We base the defaults off of i386, the other archs may
211 # feel free to change them in the below if statements.
212 #
213 $local_regex = "^[0-9a-fA-F]+\\s+t\\s+(\\S+)";
214 $weak_regex = "^[0-9a-fA-F]+\\s+([wW])\\s+(\\S+)";
215 $section_regex = "Disassembly of section\\s+(\\S+):";
216 $function_regex = "^([0-9a-fA-F]+)\\s+<(.*?)>:";
217 $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\smcount\$";
218 $section_type = '@progbits';
219 $mcount_adjust = 0;
220 $type = ".long";
221
222 if ($arch eq "x86_64") {
223     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\smcount([+-]0x[0-9a-zA-Z]+)?\$";
224     $type = ".quad";
225     $alignment = 8;
226     $mcount_adjust = -1;
227
228     # force flags for this arch
229     $ld .= " -m elf_x86_64";
230     $objdump .= " -M x86-64";
231     $objcopy .= " -O elf64-x86-64";
232     $cc .= " -m64";
233
234 } elsif ($arch eq "i386") {
235     $alignment = 4;
236     $mcount_adjust = -1;
237
238     # force flags for this arch
239     $ld .= " -m elf_i386";
240     $objdump .= " -M i386";
241     $objcopy .= " -O elf32-i386";
242     $cc .= " -m32";
243
244 } elsif ($arch eq "s390" && $bits == 32) {
245     $mcount_regex = "^\\s*([0-9a-fA-F]+):\\s*R_390_32\\s+_mcount\$";
246     $alignment = 4;
247     $ld .= " -m elf_s390";
248     $cc .= " -m31";
249
250 } elsif ($arch eq "s390" && $bits == 64) {
251     $mcount_regex = "^\\s*([0-9a-fA-F]+):\\s*R_390_(PC|PLT)32DBL\\s+_mcount\\+0x2\$";
252     $alignment = 8;
253     $type = ".quad";
254     $ld .= " -m elf64_s390";
255     $cc .= " -m64";
256
257 } elsif ($arch eq "sh") {
258     $alignment = 2;
259
260     # force flags for this arch
261     $ld .= " -m shlelf_linux";
262     $objcopy .= " -O elf32-sh-linux";
263     $cc .= " -m32";
264
265 } elsif ($arch eq "powerpc") {
266     $local_regex = "^[0-9a-fA-F]+\\s+t\\s+(\\.?\\S+)";
267     $function_regex = "^([0-9a-fA-F]+)\\s+<(\\.?.*?)>:";
268     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s\\.?_mcount\$";
269
270     if ($bits == 64) {
271         $type = ".quad";
272     }
273
274 } elsif ($arch eq "arm") {
275     $alignment = 2;
276     $section_type = '%progbits';
277     $mcount_regex = "^\\s*([0-9a-fA-F]+):\\s*R_ARM_(CALL|PC24|THM_CALL)" .
278                         "\\s+(__gnu_mcount_nc|mcount)\$";
279
280 } elsif ($arch eq "ia64") {
281     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s_mcount\$";
282     $type = "data8";
283
284     if ($is_module eq "0") {
285         $cc .= " -mconstant-gp";
286     }
287 } elsif ($arch eq "sparc64") {
288     # In the objdump output there are giblets like:
289     # 0000000000000000 <igmp_net_exit-0x18>:
290     # As there's some data blobs that get emitted into the
291     # text section before the first instructions and the first
292     # real symbols.  We don't want to match that, so to combat
293     # this we use '\w' so we'll match just plain symbol names,
294     # and not those that also include hex offsets inside of the
295     # '<>' brackets.  Actually the generic function_regex setting
296     # could safely use this too.
297     $function_regex = "^([0-9a-fA-F]+)\\s+<(\\w*?)>:";
298
299     # Sparc64 calls '_mcount' instead of plain 'mcount'.
300     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s_mcount\$";
301
302     $alignment = 8;
303     $type = ".xword";
304     $ld .= " -m elf64_sparc";
305     $cc .= " -m64";
306     $objcopy .= " -O elf64-sparc";
307 } elsif ($arch eq "mips") {
308     # To enable module support, we need to enable the -mlong-calls option
309     # of gcc for module, after using this option, we can not get the real
310     # offset of the calling to _mcount, but the offset of the lui
311     # instruction or the addiu one. herein, we record the address of the
312     # first one, and then we can replace this instruction by a branch
313     # instruction to jump over the profiling function to filter the
314     # indicated functions, or swith back to the lui instruction to trace
315     # them, which means dynamic tracing.
316     #
317     #       c:  3c030000        lui     v1,0x0
318     #                   c: R_MIPS_HI16  _mcount
319     #                   c: R_MIPS_NONE  *ABS*
320     #                   c: R_MIPS_NONE  *ABS*
321     #      10:  64630000        daddiu  v1,v1,0
322     #                   10: R_MIPS_LO16 _mcount
323     #                   10: R_MIPS_NONE *ABS*
324     #                   10: R_MIPS_NONE *ABS*
325     #      14:  03e0082d        move    at,ra
326     #      18:  0060f809        jalr    v1
327     #
328     # for the kernel:
329     #
330     #     10:   03e0082d        move    at,ra
331     #     14:   0c000000        jal     0 <loongson_halt>
332     #                    14: R_MIPS_26   _mcount
333     #                    14: R_MIPS_NONE *ABS*
334     #                    14: R_MIPS_NONE *ABS*
335     #    18:   00020021        nop
336     if ($is_module eq "0") {
337             $mcount_regex = "^\\s*([0-9a-fA-F]+): R_MIPS_26\\s+_mcount\$";
338     } else {
339             $mcount_regex = "^\\s*([0-9a-fA-F]+): R_MIPS_HI16\\s+_mcount\$";
340     }
341     $objdump .= " -Melf-trad".$endian."mips ";
342
343     if ($endian eq "big") {
344             $endian = " -EB ";
345             $ld .= " -melf".$bits."btsmip";
346     } else {
347             $endian = " -EL ";
348             $ld .= " -melf".$bits."ltsmip";
349     }
350
351     $cc .= " -mno-abicalls -fno-pic -mabi=" . $bits . $endian;
352     $ld .= $endian;
353
354     if ($bits == 64) {
355             $function_regex =
356                 "^([0-9a-fA-F]+)\\s+<(.|[^\$]L.*?|\$[^L].*?|[^\$][^L].*?)>:";
357             $type = ".dword";
358     }
359 } elsif ($arch eq "microblaze") {
360     # Microblaze calls '_mcount' instead of plain 'mcount'.
361     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s_mcount\$";
362 } elsif ($arch eq "blackfin") {
363     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s__mcount\$";
364     $mcount_adjust = -4;
365 } else {
366     die "Arch $arch is not supported with CONFIG_FTRACE_MCOUNT_RECORD";
367 }
368
369 my $text_found = 0;
370 my $read_function = 0;
371 my $opened = 0;
372 my $mcount_section = "__mcount_loc";
373
374 my $dirname;
375 my $filename;
376 my $prefix;
377 my $ext;
378
379 if ($inputfile =~ m,^(.*)/([^/]*)$,) {
380     $dirname = $1;
381     $filename = $2;
382 } else {
383     $dirname = ".";
384     $filename = $inputfile;
385 }
386
387 if ($filename =~ m,^(.*)(\.\S),) {
388     $prefix = $1;
389     $ext = $2;
390 } else {
391     $prefix = $filename;
392     $ext = "";
393 }
394
395 my $mcount_s = $dirname . "/.tmp_mc_" . $prefix . ".s";
396 my $mcount_o = $dirname . "/.tmp_mc_" . $prefix . ".o";
397
398 check_objcopy();
399
400 #
401 # Step 1: find all the local (static functions) and weak symbols.
402 #         't' is local, 'w/W' is weak
403 #
404 open (IN, "$nm $inputfile|") || die "error running $nm";
405 while (<IN>) {
406     if (/$local_regex/) {
407         $locals{$1} = 1;
408     } elsif (/$weak_regex/) {
409         $weak{$2} = $1;
410     }
411 }
412 close(IN);
413
414 my @offsets;            # Array of offsets of mcount callers
415 my $ref_func;           # reference function to use for offsets
416 my $offset = 0;         # offset of ref_func to section beginning
417
418 ##
419 # update_funcs - print out the current mcount callers
420 #
421 #  Go through the list of offsets to callers and write them to
422 #  the output file in a format that can be read by an assembler.
423 #
424 sub update_funcs
425 {
426     return unless ($ref_func and @offsets);
427
428     # Sanity check on weak function. A weak function may be overwritten by
429     # another function of the same name, making all these offsets incorrect.
430     if (defined $weak{$ref_func}) {
431         die "$inputfile: ERROR: referencing weak function" .
432             " $ref_func for mcount\n";
433     }
434
435     # is this function static? If so, note this fact.
436     if (defined $locals{$ref_func}) {
437
438         # only use locals if objcopy supports globalize-symbols
439         if (!$can_use_local) {
440             return;
441         }
442         $convert{$ref_func} = 1;
443     }
444
445     # Loop through all the mcount caller offsets and print a reference
446     # to the caller based from the ref_func.
447     if (!$opened) {
448         open(FILE, ">$mcount_s") || die "can't create $mcount_s\n";
449         $opened = 1;
450         print FILE "\t.section $mcount_section,\"a\",$section_type\n";
451         print FILE "\t.align $alignment\n" if (defined($alignment));
452     }
453     foreach my $cur_offset (@offsets) {
454         printf FILE "\t%s %s + %d\n", $type, $ref_func, $cur_offset - $offset;
455     }
456 }
457
458 #
459 # Step 2: find the sections and mcount call sites
460 #
461 open(IN, "$objdump -hdr $inputfile|") || die "error running $objdump";
462
463 my $text;
464
465
466 # read headers first
467 my $read_headers = 1;
468
469 while (<IN>) {
470
471     if ($read_headers && /$mcount_section/) {
472         #
473         # Somehow the make process can execute this script on an
474         # object twice. If it does, we would duplicate the mcount
475         # section and it will cause the function tracer self test
476         # to fail. Check if the mcount section exists, and if it does,
477         # warn and exit.
478         #
479         print STDERR "ERROR: $mcount_section already in $inputfile\n" .
480             "\tThis may be an indication that your build is corrupted.\n" .
481             "\tDelete $inputfile and try again. If the same object file\n" .
482             "\tstill causes an issue, then disable CONFIG_DYNAMIC_FTRACE.\n";
483         exit(-1);
484     }
485
486     # is it a section?
487     if (/$section_regex/) {
488         $read_headers = 0;
489
490         # Only record text sections that we know are safe
491         $read_function = defined($text_sections{$1});
492         # print out any recorded offsets
493         update_funcs();
494
495         # reset all markers and arrays
496         $text_found = 0;
497         undef($ref_func);
498         undef(@offsets);
499
500     # section found, now is this a start of a function?
501     } elsif ($read_function && /$function_regex/) {
502         $text_found = 1;
503         $text = $2;
504
505         # if this is either a local function or a weak function
506         # keep looking for functions that are global that
507         # we can use safely.
508         if (!defined($locals{$text}) && !defined($weak{$text})) {
509             $ref_func = $text;
510             $read_function = 0;
511             $offset = hex $1;
512         } else {
513             # if we already have a function, and this is weak, skip it
514             if (!defined($ref_func) && !defined($weak{$text}) &&
515                  # PPC64 can have symbols that start with .L and
516                  # gcc considers these special. Don't use them!
517                  $text !~ /^\.L/) {
518                 $ref_func = $text;
519                 $offset = hex $1;
520             }
521         }
522     }
523     # is this a call site to mcount? If so, record it to print later
524     if ($text_found && /$mcount_regex/) {
525         push(@offsets, (hex $1) + $mcount_adjust);
526     }
527 }
528
529 # dump out anymore offsets that may have been found
530 update_funcs();
531
532 # If we did not find any mcount callers, we are done (do nothing).
533 if (!$opened) {
534     exit(0);
535 }
536
537 close(FILE);
538
539 #
540 # Step 3: Compile the file that holds the list of call sites to mcount.
541 #
542 `$cc -o $mcount_o -c $mcount_s`;
543
544 my @converts = keys %convert;
545
546 #
547 # Step 4: Do we have sections that started with local functions?
548 #
549 if ($#converts >= 0) {
550     my $globallist = "";
551     my $locallist = "";
552
553     foreach my $con (@converts) {
554         $globallist .= " --globalize-symbol $con";
555         $locallist .= " --localize-symbol $con";
556     }
557
558     my $globalobj = $dirname . "/.tmp_gl_" . $filename;
559     my $globalmix = $dirname . "/.tmp_mx_" . $filename;
560
561     #
562     # Step 5: set up each local function as a global
563     #
564     `$objcopy $globallist $inputfile $globalobj`;
565
566     #
567     # Step 6: Link the global version to our list.
568     #
569     `$ld -r $globalobj $mcount_o -o $globalmix`;
570
571     #
572     # Step 7: Convert the local functions back into local symbols
573     #
574     `$objcopy $locallist $globalmix $inputfile`;
575
576     # Remove the temp files
577     `$rm $globalobj $globalmix`;
578
579 } else {
580
581     my $mix = $dirname . "/.tmp_mx_" . $filename;
582
583     #
584     # Step 8: Link the object with our list of call sites object.
585     #
586     `$ld -r $inputfile $mcount_o -o $mix`;
587
588     #
589     # Step 9: Move the result back to the original object.
590     #
591     `$mv $mix $inputfile`;
592 }
593
594 # Clean up the temp files
595 `$rm $mcount_o $mcount_s`;
596
597 exit(0);