sh: dynamic ftrace support.
[linux-2.6.git] / scripts / recordmcount.pl
1 #!/usr/bin/perl -w
2 # (c) 2008, Steven Rostedt <srostedt@redhat.com>
3 # Licensed under the terms of the GNU GPL License version 2
4 #
5 # recordmcount.pl - makes a section called __mcount_loc that holds
6 #                   all the offsets to the calls to mcount.
7 #
8 #
9 # What we want to end up with is a section in vmlinux called
10 # __mcount_loc that contains a list of pointers to all the
11 # call sites in the kernel that call mcount. Later on boot up, the kernel
12 # will read this list, save the locations and turn them into nops.
13 # When tracing or profiling is later enabled, these locations will then
14 # be converted back to pointers to some function.
15 #
16 # This is no easy feat. This script is called just after the original
17 # object is compiled and before it is linked.
18 #
19 # The references to the call sites are offsets from the section of text
20 # that the call site is in. Hence, all functions in a section that
21 # has a call site to mcount, will have the offset from the beginning of
22 # the section and not the beginning of the function.
23 #
24 # The trick is to find a way to record the beginning of the section.
25 # The way we do this is to look at the first function in the section
26 # which will also be the location of that section after final link.
27 # e.g.
28 #
29 #  .section ".text.sched"
30 #  .globl my_func
31 #  my_func:
32 #        [...]
33 #        call mcount  (offset: 0x5)
34 #        [...]
35 #        ret
36 #  other_func:
37 #        [...]
38 #        call mcount (offset: 0x1b)
39 #        [...]
40 #
41 # Both relocation offsets for the mcounts in the above example will be
42 # offset from .text.sched. If we make another file called tmp.s with:
43 #
44 #  .section __mcount_loc
45 #  .quad  my_func + 0x5
46 #  .quad  my_func + 0x1b
47 #
48 # We can then compile this tmp.s into tmp.o, and link it to the original
49 # object.
50 #
51 # But this gets hard if my_func is not globl (a static function).
52 # In such a case we have:
53 #
54 #  .section ".text.sched"
55 #  my_func:
56 #        [...]
57 #        call mcount  (offset: 0x5)
58 #        [...]
59 #        ret
60 #  .globl my_func
61 #  other_func:
62 #        [...]
63 #        call mcount (offset: 0x1b)
64 #        [...]
65 #
66 # If we make the tmp.s the same as above, when we link together with
67 # the original object, we will end up with two symbols for my_func:
68 # one local, one global.  After final compile, we will end up with
69 # an undefined reference to my_func.
70 #
71 # Since local objects can reference local variables, we need to find
72 # a way to make tmp.o reference the local objects of the original object
73 # file after it is linked together. To do this, we convert the my_func
74 # into a global symbol before linking tmp.o. Then after we link tmp.o
75 # we will only have a single symbol for my_func that is global.
76 # We can convert my_func back into a local symbol and we are done.
77 #
78 # Here are the steps we take:
79 #
80 # 1) Record all the local symbols by using 'nm'
81 # 2) Use objdump to find all the call site offsets and sections for
82 #    mcount.
83 # 3) Compile the list into its own object.
84 # 4) Do we have to deal with local functions? If not, go to step 8.
85 # 5) Make an object that converts these local functions to global symbols
86 #    with objcopy.
87 # 6) Link together this new object with the list object.
88 # 7) Convert the local functions back to local symbols and rename
89 #    the result as the original object.
90 #    End.
91 # 8) Link the object with the list object.
92 # 9) Move the result back to the original object.
93 #    End.
94 #
95
96 use strict;
97
98 my $P = $0;
99 $P =~ s@.*/@@g;
100
101 my $V = '0.1';
102
103 if ($#ARGV < 6) {
104         print "usage: $P arch objdump objcopy cc ld nm rm mv inputfile\n";
105         print "version: $V\n";
106         exit(1);
107 }
108
109 my ($arch, $bits, $objdump, $objcopy, $cc,
110     $ld, $nm, $rm, $mv, $inputfile) = @ARGV;
111
112 # Acceptable sections to record.
113 my %text_sections = (
114      ".text" => 1,
115 );
116
117 $objdump = "objdump" if ((length $objdump) == 0);
118 $objcopy = "objcopy" if ((length $objcopy) == 0);
119 $cc = "gcc" if ((length $cc) == 0);
120 $ld = "ld" if ((length $ld) == 0);
121 $nm = "nm" if ((length $nm) == 0);
122 $rm = "rm" if ((length $rm) == 0);
123 $mv = "mv" if ((length $mv) == 0);
124
125 #print STDERR "running: $P '$arch' '$objdump' '$objcopy' '$cc' '$ld' " .
126 #    "'$nm' '$rm' '$mv' '$inputfile'\n";
127
128 my %locals;             # List of local (static) functions
129 my %weak;               # List of weak functions
130 my %convert;            # List of local functions used that needs conversion
131
132 my $type;
133 my $section_regex;      # Find the start of a section
134 my $function_regex;     # Find the name of a function
135                         #    (return offset and func name)
136 my $mcount_regex;       # Find the call site to mcount (return offset)
137 my $alignment;         # The .align value to use for $mcount_section
138
139 if ($arch eq "x86") {
140     if ($bits == 64) {
141         $arch = "x86_64";
142     } else {
143         $arch = "i386";
144     }
145 }
146
147 if ($arch eq "x86_64") {
148     $section_regex = "Disassembly of section\\s+(\\S+):";
149     $function_regex = "^([0-9a-fA-F]+)\\s+<(.*?)>:";
150     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\smcount([+-]0x[0-9a-zA-Z]+)?\$";
151     $type = ".quad";
152     $alignment = 8;
153
154     # force flags for this arch
155     $ld .= " -m elf_x86_64";
156     $objdump .= " -M x86-64";
157     $objcopy .= " -O elf64-x86-64";
158     $cc .= " -m64";
159
160 } elsif ($arch eq "i386") {
161     $section_regex = "Disassembly of section\\s+(\\S+):";
162     $function_regex = "^([0-9a-fA-F]+)\\s+<(.*?)>:";
163     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\smcount\$";
164     $type = ".long";
165     $alignment = 4;
166
167     # force flags for this arch
168     $ld .= " -m elf_i386";
169     $objdump .= " -M i386";
170     $objcopy .= " -O elf32-i386";
171     $cc .= " -m32";
172
173 } elsif ($arch eq "sh") {
174     $section_regex = "Disassembly of section\\s+(\\S+):";
175     $function_regex = "^([0-9a-fA-F]+)\\s+<(.*?)>:";
176     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\smcount\$";
177     $type = ".long";
178
179     # force flags for this arch
180     $ld .= " -m shlelf_linux";
181     $objcopy .= " -O elf32-sh-linux";
182     $cc .= " -m32";
183
184 } else {
185     die "Arch $arch is not supported with CONFIG_FTRACE_MCOUNT_RECORD";
186 }
187
188 my $text_found = 0;
189 my $read_function = 0;
190 my $opened = 0;
191 my $mcount_section = "__mcount_loc";
192
193 my $dirname;
194 my $filename;
195 my $prefix;
196 my $ext;
197
198 if ($inputfile =~ m,^(.*)/([^/]*)$,) {
199     $dirname = $1;
200     $filename = $2;
201 } else {
202     $dirname = ".";
203     $filename = $inputfile;
204 }
205
206 if ($filename =~ m,^(.*)(\.\S),) {
207     $prefix = $1;
208     $ext = $2;
209 } else {
210     $prefix = $filename;
211     $ext = "";
212 }
213
214 my $mcount_s = $dirname . "/.tmp_mc_" . $prefix . ".s";
215 my $mcount_o = $dirname . "/.tmp_mc_" . $prefix . ".o";
216
217 #
218 # --globalize-symbols came out in 2.17, we must test the version
219 # of objcopy, and if it is less than 2.17, then we can not
220 # record local functions.
221 my $use_locals = 01;
222 my $local_warn_once = 0;
223 my $found_version = 0;
224
225 open (IN, "$objcopy --version |") || die "error running $objcopy";
226 while (<IN>) {
227     if (/objcopy.*\s(\d+)\.(\d+)/) {
228         my $major = $1;
229         my $minor = $2;
230
231         $found_version = 1;
232         if ($major < 2 ||
233             ($major == 2 && $minor < 17)) {
234             $use_locals = 0;
235         }
236         last;
237     }
238 }
239 close (IN);
240
241 if (!$found_version) {
242     print STDERR "WARNING: could not find objcopy version.\n" .
243         "\tDisabling local function references.\n";
244 }
245
246
247 #
248 # Step 1: find all the local (static functions) and weak symbols.
249 #        't' is local, 'w/W' is weak (we never use a weak function)
250 #
251 open (IN, "$nm $inputfile|") || die "error running $nm";
252 while (<IN>) {
253     if (/^[0-9a-fA-F]+\s+t\s+(\S+)/) {
254         $locals{$1} = 1;
255     } elsif (/^[0-9a-fA-F]+\s+([wW])\s+(\S+)/) {
256         $weak{$2} = $1;
257     }
258 }
259 close(IN);
260
261 my @offsets;            # Array of offsets of mcount callers
262 my $ref_func;           # reference function to use for offsets
263 my $offset = 0;         # offset of ref_func to section beginning
264
265 ##
266 # update_funcs - print out the current mcount callers
267 #
268 #  Go through the list of offsets to callers and write them to
269 #  the output file in a format that can be read by an assembler.
270 #
271 sub update_funcs
272 {
273     return if ($#offsets < 0);
274
275     defined($ref_func) || die "No function to reference";
276
277     # A section only had a weak function, to represent it.
278     # Unfortunately, a weak function may be overwritten by another
279     # function of the same name, making all these offsets incorrect.
280     # To be safe, we simply print a warning and bail.
281     if (defined $weak{$ref_func}) {
282         print STDERR
283             "$inputfile: WARNING: referencing weak function" .
284             " $ref_func for mcount\n";
285         return;
286     }
287
288     # is this function static? If so, note this fact.
289     if (defined $locals{$ref_func}) {
290
291         # only use locals if objcopy supports globalize-symbols
292         if (!$use_locals) {
293             return;
294         }
295         $convert{$ref_func} = 1;
296     }
297
298     # Loop through all the mcount caller offsets and print a reference
299     # to the caller based from the ref_func.
300     for (my $i=0; $i <= $#offsets; $i++) {
301         if (!$opened) {
302             open(FILE, ">$mcount_s") || die "can't create $mcount_s\n";
303             $opened = 1;
304             print FILE "\t.section $mcount_section,\"a\",\@progbits\n";
305             print FILE "\t.align $alignment\n";
306         }
307         printf FILE "\t%s %s + %d\n", $type, $ref_func, $offsets[$i] - $offset;
308     }
309 }
310
311 #
312 # Step 2: find the sections and mcount call sites
313 #
314 open(IN, "$objdump -dr $inputfile|") || die "error running $objdump";
315
316 my $text;
317
318 while (<IN>) {
319     # is it a section?
320     if (/$section_regex/) {
321
322         # Only record text sections that we know are safe
323         if (defined($text_sections{$1})) {
324             $read_function = 1;
325         } else {
326             $read_function = 0;
327         }
328         # print out any recorded offsets
329         update_funcs() if ($text_found);
330
331         # reset all markers and arrays
332         $text_found = 0;
333         undef($ref_func);
334         undef(@offsets);
335
336     # section found, now is this a start of a function?
337     } elsif ($read_function && /$function_regex/) {
338         $text_found = 1;
339         $offset = hex $1;
340         $text = $2;
341
342         # if this is either a local function or a weak function
343         # keep looking for functions that are global that
344         # we can use safely.
345         if (!defined($locals{$text}) && !defined($weak{$text})) {
346             $ref_func = $text;
347             $read_function = 0;
348         } else {
349             # if we already have a function, and this is weak, skip it
350             if (!defined($ref_func) || !defined($weak{$text})) {
351                 $ref_func = $text;
352             }
353         }
354     }
355
356     # is this a call site to mcount? If so, record it to print later
357     if ($text_found && /$mcount_regex/) {
358         $offsets[$#offsets + 1] = hex $1;
359     }
360 }
361
362 # dump out anymore offsets that may have been found
363 update_funcs() if ($text_found);
364
365 # If we did not find any mcount callers, we are done (do nothing).
366 if (!$opened) {
367     exit(0);
368 }
369
370 close(FILE);
371
372 #
373 # Step 3: Compile the file that holds the list of call sites to mcount.
374 #
375 `$cc -o $mcount_o -c $mcount_s`;
376
377 my @converts = keys %convert;
378
379 #
380 # Step 4: Do we have sections that started with local functions?
381 #
382 if ($#converts >= 0) {
383     my $globallist = "";
384     my $locallist = "";
385
386     foreach my $con (@converts) {
387         $globallist .= " --globalize-symbol $con";
388         $locallist .= " --localize-symbol $con";
389     }
390
391     my $globalobj = $dirname . "/.tmp_gl_" . $filename;
392     my $globalmix = $dirname . "/.tmp_mx_" . $filename;
393
394     #
395     # Step 5: set up each local function as a global
396     #
397     `$objcopy $globallist $inputfile $globalobj`;
398
399     #
400     # Step 6: Link the global version to our list.
401     #
402     `$ld -r $globalobj $mcount_o -o $globalmix`;
403
404     #
405     # Step 7: Convert the local functions back into local symbols
406     #
407     `$objcopy $locallist $globalmix $inputfile`;
408
409     # Remove the temp files
410     `$rm $globalobj $globalmix`;
411
412 } else {
413
414     my $mix = $dirname . "/.tmp_mx_" . $filename;
415
416     #
417     # Step 8: Link the object with our list of call sites object.
418     #
419     `$ld -r $inputfile $mcount_o -o $mix`;
420
421     #
422     # Step 9: Move the result back to the original object.
423     #
424     `$mv $mix $inputfile`;
425 }
426
427 # Clean up the temp files
428 `$rm $mcount_o $mcount_s`;
429
430 exit(0);