powerpc: irq: Use irqdata based information
[linux-2.6.git] / scripts / recordmcount.pl
1 #!/usr/bin/perl -w
2 # (c) 2008, Steven Rostedt <srostedt@redhat.com>
3 # Licensed under the terms of the GNU GPL License version 2
4 #
5 # recordmcount.pl - makes a section called __mcount_loc that holds
6 #                   all the offsets to the calls to mcount.
7 #
8 #
9 # What we want to end up with this is that each object file will have a
10 # section called __mcount_loc that will hold the list of pointers to mcount
11 # callers. After final linking, the vmlinux will have within .init.data the
12 # list of all callers to mcount between __start_mcount_loc and __stop_mcount_loc.
13 # Later on boot up, the kernel will read this list, save the locations and turn
14 # them into nops. When tracing or profiling is later enabled, these locations
15 # will then be converted back to pointers to some function.
16 #
17 # This is no easy feat. This script is called just after the original
18 # object is compiled and before it is linked.
19 #
20 # When parse this object file using 'objdump', the references to the call
21 # sites are offsets from the section that the call site is in. Hence, all
22 # functions in a section that has a call site to mcount, will have the
23 # offset from the beginning of the section and not the beginning of the
24 # function.
25 #
26 # But where this section will reside finally in vmlinx is undetermined at
27 # this point. So we can't use this kind of offsets to record the final
28 # address of this call site.
29 #
30 # The trick is to change the call offset referring the start of a section to
31 # referring a function symbol in this section. During the link step, 'ld' will
32 # compute the final address according to the information we record.
33 #
34 # e.g.
35 #
36 #  .section ".sched.text", "ax"
37 #        [...]
38 #  func1:
39 #        [...]
40 #        call mcount  (offset: 0x10)
41 #        [...]
42 #        ret
43 #  .globl fun2
44 #  func2:             (offset: 0x20)
45 #        [...]
46 #        [...]
47 #        ret
48 #  func3:
49 #        [...]
50 #        call mcount (offset: 0x30)
51 #        [...]
52 #
53 # Both relocation offsets for the mcounts in the above example will be
54 # offset from .sched.text. If we choose global symbol func2 as a reference and
55 # make another file called tmp.s with the new offsets:
56 #
57 #  .section __mcount_loc
58 #  .quad  func2 - 0x10
59 #  .quad  func2 + 0x10
60 #
61 # We can then compile this tmp.s into tmp.o, and link it back to the original
62 # object.
63 #
64 # In our algorithm, we will choose the first global function we meet in this
65 # section as the reference. But this gets hard if there is no global functions
66 # in this section. In such a case we have to select a local one. E.g. func1:
67 #
68 #  .section ".sched.text", "ax"
69 #  func1:
70 #        [...]
71 #        call mcount  (offset: 0x10)
72 #        [...]
73 #        ret
74 #  func2:
75 #        [...]
76 #        call mcount (offset: 0x20)
77 #        [...]
78 #  .section "other.section"
79 #
80 # If we make the tmp.s the same as above, when we link together with
81 # the original object, we will end up with two symbols for func1:
82 # one local, one global.  After final compile, we will end up with
83 # an undefined reference to func1 or a wrong reference to another global
84 # func1 in other files.
85 #
86 # Since local objects can reference local variables, we need to find
87 # a way to make tmp.o reference the local objects of the original object
88 # file after it is linked together. To do this, we convert func1
89 # into a global symbol before linking tmp.o. Then after we link tmp.o
90 # we will only have a single symbol for func1 that is global.
91 # We can convert func1 back into a local symbol and we are done.
92 #
93 # Here are the steps we take:
94 #
95 # 1) Record all the local and weak symbols by using 'nm'
96 # 2) Use objdump to find all the call site offsets and sections for
97 #    mcount.
98 # 3) Compile the list into its own object.
99 # 4) Do we have to deal with local functions? If not, go to step 8.
100 # 5) Make an object that converts these local functions to global symbols
101 #    with objcopy.
102 # 6) Link together this new object with the list object.
103 # 7) Convert the local functions back to local symbols and rename
104 #    the result as the original object.
105 # 8) Link the object with the list object.
106 # 9) Move the result back to the original object.
107 #
108
109 use strict;
110
111 my $P = $0;
112 $P =~ s@.*/@@g;
113
114 my $V = '0.1';
115
116 if ($#ARGV != 11) {
117         print "usage: $P arch endian bits objdump objcopy cc ld nm rm mv is_module inputfile\n";
118         print "version: $V\n";
119         exit(1);
120 }
121
122 my ($arch, $endian, $bits, $objdump, $objcopy, $cc,
123     $ld, $nm, $rm, $mv, $is_module, $inputfile) = @ARGV;
124
125 # This file refers to mcount and shouldn't be ftraced, so lets' ignore it
126 if ($inputfile =~ m,kernel/trace/ftrace\.o$,) {
127     exit(0);
128 }
129
130 # Acceptable sections to record.
131 my %text_sections = (
132      ".text" => 1,
133      ".ref.text" => 1,
134      ".sched.text" => 1,
135      ".spinlock.text" => 1,
136      ".irqentry.text" => 1,
137      ".text.unlikely" => 1,
138 );
139
140 # Note: we are nice to C-programmers here, thus we skip the '||='-idiom.
141 $objdump = 'objdump' if (!$objdump);
142 $objcopy = 'objcopy' if (!$objcopy);
143 $cc = 'gcc' if (!$cc);
144 $ld = 'ld' if (!$ld);
145 $nm = 'nm' if (!$nm);
146 $rm = 'rm' if (!$rm);
147 $mv = 'mv' if (!$mv);
148
149 #print STDERR "running: $P '$arch' '$objdump' '$objcopy' '$cc' '$ld' " .
150 #    "'$nm' '$rm' '$mv' '$inputfile'\n";
151
152 my %locals;             # List of local (static) functions
153 my %weak;               # List of weak functions
154 my %convert;            # List of local functions used that needs conversion
155
156 my $type;
157 my $local_regex;        # Match a local function (return function)
158 my $weak_regex;         # Match a weak function (return function)
159 my $section_regex;      # Find the start of a section
160 my $function_regex;     # Find the name of a function
161                         #    (return offset and func name)
162 my $mcount_regex;       # Find the call site to mcount (return offset)
163 my $mcount_adjust;      # Address adjustment to mcount offset
164 my $alignment;          # The .align value to use for $mcount_section
165 my $section_type;       # Section header plus possible alignment command
166 my $can_use_local = 0;  # If we can use local function references
167
168 # Shut up recordmcount if user has older objcopy
169 my $quiet_recordmcount = ".tmp_quiet_recordmcount";
170 my $print_warning = 1;
171 $print_warning = 0 if ( -f $quiet_recordmcount);
172
173 ##
174 # check_objcopy - whether objcopy supports --globalize-symbols
175 #
176 #  --globalize-symbols came out in 2.17, we must test the version
177 #  of objcopy, and if it is less than 2.17, then we can not
178 #  record local functions.
179 sub check_objcopy
180 {
181     open (IN, "$objcopy --version |") or die "error running $objcopy";
182     while (<IN>) {
183         if (/objcopy.*\s(\d+)\.(\d+)/) {
184             $can_use_local = 1 if ($1 > 2 || ($1 == 2 && $2 >= 17));
185             last;
186         }
187     }
188     close (IN);
189
190     if (!$can_use_local && $print_warning) {
191         print STDERR "WARNING: could not find objcopy version or version " .
192             "is less than 2.17.\n" .
193             "\tLocal function references are disabled.\n";
194         open (QUIET, ">$quiet_recordmcount");
195         printf QUIET "Disables the warning from recordmcount.pl\n";
196         close QUIET;
197     }
198 }
199
200 if ($arch =~ /(x86(_64)?)|(i386)/) {
201     if ($bits == 64) {
202         $arch = "x86_64";
203     } else {
204         $arch = "i386";
205     }
206 }
207
208 #
209 # We base the defaults off of i386, the other archs may
210 # feel free to change them in the below if statements.
211 #
212 $local_regex = "^[0-9a-fA-F]+\\s+t\\s+(\\S+)";
213 $weak_regex = "^[0-9a-fA-F]+\\s+([wW])\\s+(\\S+)";
214 $section_regex = "Disassembly of section\\s+(\\S+):";
215 $function_regex = "^([0-9a-fA-F]+)\\s+<(.*?)>:";
216 $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\smcount\$";
217 $section_type = '@progbits';
218 $mcount_adjust = 0;
219 $type = ".long";
220
221 if ($arch eq "x86_64") {
222     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\smcount([+-]0x[0-9a-zA-Z]+)?\$";
223     $type = ".quad";
224     $alignment = 8;
225
226     # force flags for this arch
227     $ld .= " -m elf_x86_64";
228     $objdump .= " -M x86-64";
229     $objcopy .= " -O elf64-x86-64";
230     $cc .= " -m64";
231
232 } elsif ($arch eq "i386") {
233     $alignment = 4;
234
235     # force flags for this arch
236     $ld .= " -m elf_i386";
237     $objdump .= " -M i386";
238     $objcopy .= " -O elf32-i386";
239     $cc .= " -m32";
240
241 } elsif ($arch eq "s390" && $bits == 32) {
242     $mcount_regex = "^\\s*([0-9a-fA-F]+):\\s*R_390_32\\s+_mcount\$";
243     $alignment = 4;
244     $ld .= " -m elf_s390";
245     $cc .= " -m31";
246
247 } elsif ($arch eq "s390" && $bits == 64) {
248     $mcount_regex = "^\\s*([0-9a-fA-F]+):\\s*R_390_(PC|PLT)32DBL\\s+_mcount\\+0x2\$";
249     $alignment = 8;
250     $type = ".quad";
251     $ld .= " -m elf64_s390";
252     $cc .= " -m64";
253
254 } elsif ($arch eq "sh") {
255     $alignment = 2;
256
257     # force flags for this arch
258     $ld .= " -m shlelf_linux";
259     $objcopy .= " -O elf32-sh-linux";
260     $cc .= " -m32";
261
262 } elsif ($arch eq "powerpc") {
263     $local_regex = "^[0-9a-fA-F]+\\s+t\\s+(\\.?\\S+)";
264     $function_regex = "^([0-9a-fA-F]+)\\s+<(\\.?.*?)>:";
265     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s\\.?_mcount\$";
266
267     if ($bits == 64) {
268         $type = ".quad";
269     }
270
271 } elsif ($arch eq "arm") {
272     $alignment = 2;
273     $section_type = '%progbits';
274     $mcount_regex = "^\\s*([0-9a-fA-F]+):\\s*R_ARM_(CALL|PC24|THM_CALL)" .
275                         "\\s+(__gnu_mcount_nc|mcount)\$";
276
277 } elsif ($arch eq "ia64") {
278     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s_mcount\$";
279     $type = "data8";
280
281     if ($is_module eq "0") {
282         $cc .= " -mconstant-gp";
283     }
284 } elsif ($arch eq "sparc64") {
285     # In the objdump output there are giblets like:
286     # 0000000000000000 <igmp_net_exit-0x18>:
287     # As there's some data blobs that get emitted into the
288     # text section before the first instructions and the first
289     # real symbols.  We don't want to match that, so to combat
290     # this we use '\w' so we'll match just plain symbol names,
291     # and not those that also include hex offsets inside of the
292     # '<>' brackets.  Actually the generic function_regex setting
293     # could safely use this too.
294     $function_regex = "^([0-9a-fA-F]+)\\s+<(\\w*?)>:";
295
296     # Sparc64 calls '_mcount' instead of plain 'mcount'.
297     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s_mcount\$";
298
299     $alignment = 8;
300     $type = ".xword";
301     $ld .= " -m elf64_sparc";
302     $cc .= " -m64";
303     $objcopy .= " -O elf64-sparc";
304 } elsif ($arch eq "mips") {
305     # To enable module support, we need to enable the -mlong-calls option
306     # of gcc for module, after using this option, we can not get the real
307     # offset of the calling to _mcount, but the offset of the lui
308     # instruction or the addiu one. herein, we record the address of the
309     # first one, and then we can replace this instruction by a branch
310     # instruction to jump over the profiling function to filter the
311     # indicated functions, or swith back to the lui instruction to trace
312     # them, which means dynamic tracing.
313     #
314     #       c:  3c030000        lui     v1,0x0
315     #                   c: R_MIPS_HI16  _mcount
316     #                   c: R_MIPS_NONE  *ABS*
317     #                   c: R_MIPS_NONE  *ABS*
318     #      10:  64630000        daddiu  v1,v1,0
319     #                   10: R_MIPS_LO16 _mcount
320     #                   10: R_MIPS_NONE *ABS*
321     #                   10: R_MIPS_NONE *ABS*
322     #      14:  03e0082d        move    at,ra
323     #      18:  0060f809        jalr    v1
324     #
325     # for the kernel:
326     #
327     #     10:   03e0082d        move    at,ra
328     #     14:   0c000000        jal     0 <loongson_halt>
329     #                    14: R_MIPS_26   _mcount
330     #                    14: R_MIPS_NONE *ABS*
331     #                    14: R_MIPS_NONE *ABS*
332     #    18:   00020021        nop
333     if ($is_module eq "0") {
334             $mcount_regex = "^\\s*([0-9a-fA-F]+): R_MIPS_26\\s+_mcount\$";
335     } else {
336             $mcount_regex = "^\\s*([0-9a-fA-F]+): R_MIPS_HI16\\s+_mcount\$";
337     }
338     $objdump .= " -Melf-trad".$endian."mips ";
339
340     if ($endian eq "big") {
341             $endian = " -EB ";
342             $ld .= " -melf".$bits."btsmip";
343     } else {
344             $endian = " -EL ";
345             $ld .= " -melf".$bits."ltsmip";
346     }
347
348     $cc .= " -mno-abicalls -fno-pic -mabi=" . $bits . $endian;
349     $ld .= $endian;
350
351     if ($bits == 64) {
352             $function_regex =
353                 "^([0-9a-fA-F]+)\\s+<(.|[^\$]L.*?|\$[^L].*?|[^\$][^L].*?)>:";
354             $type = ".dword";
355     }
356 } elsif ($arch eq "microblaze") {
357     # Microblaze calls '_mcount' instead of plain 'mcount'.
358     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s_mcount\$";
359 } elsif ($arch eq "blackfin") {
360     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s__mcount\$";
361     $mcount_adjust = -4;
362 } else {
363     die "Arch $arch is not supported with CONFIG_FTRACE_MCOUNT_RECORD";
364 }
365
366 my $text_found = 0;
367 my $read_function = 0;
368 my $opened = 0;
369 my $mcount_section = "__mcount_loc";
370
371 my $dirname;
372 my $filename;
373 my $prefix;
374 my $ext;
375
376 if ($inputfile =~ m,^(.*)/([^/]*)$,) {
377     $dirname = $1;
378     $filename = $2;
379 } else {
380     $dirname = ".";
381     $filename = $inputfile;
382 }
383
384 if ($filename =~ m,^(.*)(\.\S),) {
385     $prefix = $1;
386     $ext = $2;
387 } else {
388     $prefix = $filename;
389     $ext = "";
390 }
391
392 my $mcount_s = $dirname . "/.tmp_mc_" . $prefix . ".s";
393 my $mcount_o = $dirname . "/.tmp_mc_" . $prefix . ".o";
394
395 check_objcopy();
396
397 #
398 # Step 1: find all the local (static functions) and weak symbols.
399 #         't' is local, 'w/W' is weak
400 #
401 open (IN, "$nm $inputfile|") || die "error running $nm";
402 while (<IN>) {
403     if (/$local_regex/) {
404         $locals{$1} = 1;
405     } elsif (/$weak_regex/) {
406         $weak{$2} = $1;
407     }
408 }
409 close(IN);
410
411 my @offsets;            # Array of offsets of mcount callers
412 my $ref_func;           # reference function to use for offsets
413 my $offset = 0;         # offset of ref_func to section beginning
414
415 ##
416 # update_funcs - print out the current mcount callers
417 #
418 #  Go through the list of offsets to callers and write them to
419 #  the output file in a format that can be read by an assembler.
420 #
421 sub update_funcs
422 {
423     return unless ($ref_func and @offsets);
424
425     # Sanity check on weak function. A weak function may be overwritten by
426     # another function of the same name, making all these offsets incorrect.
427     if (defined $weak{$ref_func}) {
428         die "$inputfile: ERROR: referencing weak function" .
429             " $ref_func for mcount\n";
430     }
431
432     # is this function static? If so, note this fact.
433     if (defined $locals{$ref_func}) {
434
435         # only use locals if objcopy supports globalize-symbols
436         if (!$can_use_local) {
437             return;
438         }
439         $convert{$ref_func} = 1;
440     }
441
442     # Loop through all the mcount caller offsets and print a reference
443     # to the caller based from the ref_func.
444     if (!$opened) {
445         open(FILE, ">$mcount_s") || die "can't create $mcount_s\n";
446         $opened = 1;
447         print FILE "\t.section $mcount_section,\"a\",$section_type\n";
448         print FILE "\t.align $alignment\n" if (defined($alignment));
449     }
450     foreach my $cur_offset (@offsets) {
451         printf FILE "\t%s %s + %d\n", $type, $ref_func, $cur_offset - $offset;
452     }
453 }
454
455 #
456 # Step 2: find the sections and mcount call sites
457 #
458 open(IN, "$objdump -hdr $inputfile|") || die "error running $objdump";
459
460 my $text;
461
462
463 # read headers first
464 my $read_headers = 1;
465
466 while (<IN>) {
467
468     if ($read_headers && /$mcount_section/) {
469         #
470         # Somehow the make process can execute this script on an
471         # object twice. If it does, we would duplicate the mcount
472         # section and it will cause the function tracer self test
473         # to fail. Check if the mcount section exists, and if it does,
474         # warn and exit.
475         #
476         print STDERR "ERROR: $mcount_section already in $inputfile\n" .
477             "\tThis may be an indication that your build is corrupted.\n" .
478             "\tDelete $inputfile and try again. If the same object file\n" .
479             "\tstill causes an issue, then disable CONFIG_DYNAMIC_FTRACE.\n";
480         exit(-1);
481     }
482
483     # is it a section?
484     if (/$section_regex/) {
485         $read_headers = 0;
486
487         # Only record text sections that we know are safe
488         $read_function = defined($text_sections{$1});
489         # print out any recorded offsets
490         update_funcs();
491
492         # reset all markers and arrays
493         $text_found = 0;
494         undef($ref_func);
495         undef(@offsets);
496
497     # section found, now is this a start of a function?
498     } elsif ($read_function && /$function_regex/) {
499         $text_found = 1;
500         $text = $2;
501
502         # if this is either a local function or a weak function
503         # keep looking for functions that are global that
504         # we can use safely.
505         if (!defined($locals{$text}) && !defined($weak{$text})) {
506             $ref_func = $text;
507             $read_function = 0;
508             $offset = hex $1;
509         } else {
510             # if we already have a function, and this is weak, skip it
511             if (!defined($ref_func) && !defined($weak{$text}) &&
512                  # PPC64 can have symbols that start with .L and
513                  # gcc considers these special. Don't use them!
514                  $text !~ /^\.L/) {
515                 $ref_func = $text;
516                 $offset = hex $1;
517             }
518         }
519     }
520     # is this a call site to mcount? If so, record it to print later
521     if ($text_found && /$mcount_regex/) {
522         push(@offsets, (hex $1) + $mcount_adjust);
523     }
524 }
525
526 # dump out anymore offsets that may have been found
527 update_funcs();
528
529 # If we did not find any mcount callers, we are done (do nothing).
530 if (!$opened) {
531     exit(0);
532 }
533
534 close(FILE);
535
536 #
537 # Step 3: Compile the file that holds the list of call sites to mcount.
538 #
539 `$cc -o $mcount_o -c $mcount_s`;
540
541 my @converts = keys %convert;
542
543 #
544 # Step 4: Do we have sections that started with local functions?
545 #
546 if ($#converts >= 0) {
547     my $globallist = "";
548     my $locallist = "";
549
550     foreach my $con (@converts) {
551         $globallist .= " --globalize-symbol $con";
552         $locallist .= " --localize-symbol $con";
553     }
554
555     my $globalobj = $dirname . "/.tmp_gl_" . $filename;
556     my $globalmix = $dirname . "/.tmp_mx_" . $filename;
557
558     #
559     # Step 5: set up each local function as a global
560     #
561     `$objcopy $globallist $inputfile $globalobj`;
562
563     #
564     # Step 6: Link the global version to our list.
565     #
566     `$ld -r $globalobj $mcount_o -o $globalmix`;
567
568     #
569     # Step 7: Convert the local functions back into local symbols
570     #
571     `$objcopy $locallist $globalmix $inputfile`;
572
573     # Remove the temp files
574     `$rm $globalobj $globalmix`;
575
576 } else {
577
578     my $mix = $dirname . "/.tmp_mx_" . $filename;
579
580     #
581     # Step 8: Link the object with our list of call sites object.
582     #
583     `$ld -r $inputfile $mcount_o -o $mix`;
584
585     #
586     # Step 9: Move the result back to the original object.
587     #
588     `$mv $mix $inputfile`;
589 }
590
591 # Clean up the temp files
592 `$rm $mcount_o $mcount_s`;
593
594 exit(0);