03b6af1388eac2efee1fa41731b053182fd887f1
[linux-2.6.git] / scripts / recordmcount.pl
1 #!/usr/bin/perl -w
2 # (c) 2008, Steven Rostedt <srostedt@redhat.com>
3 # Licensed under the terms of the GNU GPL License version 2
4 #
5 # recordmcount.pl - makes a section called __mcount_loc that holds
6 #                   all the offsets to the calls to mcount.
7 #
8 #
9 # What we want to end up with is a section in vmlinux called
10 # __mcount_loc that contains a list of pointers to all the
11 # call sites in the kernel that call mcount. Later on boot up, the kernel
12 # will read this list, save the locations and turn them into nops.
13 # When tracing or profiling is later enabled, these locations will then
14 # be converted back to pointers to some function.
15 #
16 # This is no easy feat. This script is called just after the original
17 # object is compiled and before it is linked.
18 #
19 # The references to the call sites are offsets from the section of text
20 # that the call site is in. Hence, all functions in a section that
21 # has a call site to mcount, will have the offset from the beginning of
22 # the section and not the beginning of the function.
23 #
24 # The trick is to find a way to record the beginning of the section.
25 # The way we do this is to look at the first function in the section
26 # which will also be the location of that section after final link.
27 # e.g.
28 #
29 #  .section ".text.sched"
30 #  .globl my_func
31 #  my_func:
32 #        [...]
33 #        call mcount  (offset: 0x5)
34 #        [...]
35 #        ret
36 #  other_func:
37 #        [...]
38 #        call mcount (offset: 0x1b)
39 #        [...]
40 #
41 # Both relocation offsets for the mcounts in the above example will be
42 # offset from .text.sched. If we make another file called tmp.s with:
43 #
44 #  .section __mcount_loc
45 #  .quad  my_func + 0x5
46 #  .quad  my_func + 0x1b
47 #
48 # We can then compile this tmp.s into tmp.o, and link it to the original
49 # object.
50 #
51 # But this gets hard if my_func is not globl (a static function).
52 # In such a case we have:
53 #
54 #  .section ".text.sched"
55 #  my_func:
56 #        [...]
57 #        call mcount  (offset: 0x5)
58 #        [...]
59 #        ret
60 #  .globl my_func
61 #  other_func:
62 #        [...]
63 #        call mcount (offset: 0x1b)
64 #        [...]
65 #
66 # If we make the tmp.s the same as above, when we link together with
67 # the original object, we will end up with two symbols for my_func:
68 # one local, one global.  After final compile, we will end up with
69 # an undefined reference to my_func.
70 #
71 # Since local objects can reference local variables, we need to find
72 # a way to make tmp.o reference the local objects of the original object
73 # file after it is linked together. To do this, we convert the my_func
74 # into a global symbol before linking tmp.o. Then after we link tmp.o
75 # we will only have a single symbol for my_func that is global.
76 # We can convert my_func back into a local symbol and we are done.
77 #
78 # Here are the steps we take:
79 #
80 # 1) Record all the local symbols by using 'nm'
81 # 2) Use objdump to find all the call site offsets and sections for
82 #    mcount.
83 # 3) Compile the list into its own object.
84 # 4) Do we have to deal with local functions? If not, go to step 8.
85 # 5) Make an object that converts these local functions to global symbols
86 #    with objcopy.
87 # 6) Link together this new object with the list object.
88 # 7) Convert the local functions back to local symbols and rename
89 #    the result as the original object.
90 #    End.
91 # 8) Link the object with the list object.
92 # 9) Move the result back to the original object.
93 #    End.
94 #
95
96 use strict;
97
98 my $P = $0;
99 $P =~ s@.*/@@g;
100
101 my $V = '0.1';
102
103 if ($#ARGV < 6) {
104         print "usage: $P arch objdump objcopy cc ld nm rm mv inputfile\n";
105         print "version: $V\n";
106         exit(1);
107 }
108
109 my ($arch, $bits, $objdump, $objcopy, $cc,
110     $ld, $nm, $rm, $mv, $inputfile) = @ARGV;
111
112 # Acceptable sections to record.
113 my %text_sections = (
114      ".text" => 1,
115 );
116
117 $objdump = "objdump" if ((length $objdump) == 0);
118 $objcopy = "objcopy" if ((length $objcopy) == 0);
119 $cc = "gcc" if ((length $cc) == 0);
120 $ld = "ld" if ((length $ld) == 0);
121 $nm = "nm" if ((length $nm) == 0);
122 $rm = "rm" if ((length $rm) == 0);
123 $mv = "mv" if ((length $mv) == 0);
124
125 #print STDERR "running: $P '$arch' '$objdump' '$objcopy' '$cc' '$ld' " .
126 #    "'$nm' '$rm' '$mv' '$inputfile'\n";
127
128 my %locals;             # List of local (static) functions
129 my %weak;               # List of weak functions
130 my %convert;            # List of local functions used that needs conversion
131
132 my $type;
133 my $nm_regex;           # Find the local functions (return function)
134 my $section_regex;      # Find the start of a section
135 my $function_regex;     # Find the name of a function
136                         #    (return offset and func name)
137 my $mcount_regex;       # Find the call site to mcount (return offset)
138 my $alignment;          # The .align value to use for $mcount_section
139
140 if ($arch eq "x86") {
141     if ($bits == 64) {
142         $arch = "x86_64";
143     } else {
144         $arch = "i386";
145     }
146 }
147
148 #
149 # We base the defaults off of i386, the other archs may
150 # feel free to change them in the below if statements.
151 #
152 $nm_regex = "^[0-9a-fA-F]+\\s+t\\s+(\\S+)";
153 $section_regex = "Disassembly of section\\s+(\\S+):";
154 $function_regex = "^([0-9a-fA-F]+)\\s+<(.*?)>:";
155 $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\smcount\$";
156 $type = ".long";
157
158 if ($arch eq "x86_64") {
159     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\smcount([+-]0x[0-9a-zA-Z]+)?\$";
160     $type = ".quad";
161     $alignment = 8;
162
163     # force flags for this arch
164     $ld .= " -m elf_x86_64";
165     $objdump .= " -M x86-64";
166     $objcopy .= " -O elf64-x86-64";
167     $cc .= " -m64";
168
169 } elsif ($arch eq "i386") {
170     $alignment = 4;
171
172     # force flags for this arch
173     $ld .= " -m elf_i386";
174     $objdump .= " -M i386";
175     $objcopy .= " -O elf32-i386";
176     $cc .= " -m32";
177
178 } elsif ($arch eq "sh") {
179     $alignment = 2;
180
181     # force flags for this arch
182     $ld .= " -m shlelf_linux";
183     $objcopy .= " -O elf32-sh-linux";
184     $cc .= " -m32";
185
186 } elsif ($arch eq "powerpc") {
187     $nm_regex = "^[0-9a-fA-F]+\\s+t\\s+(\\.?\\S+)";
188     $function_regex = "^([0-9a-fA-F]+)\\s+<(\\.?.*?)>:";
189     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s\\.?_mcount\$";
190
191     if ($bits == 64) {
192         $type = ".quad";
193     }
194
195 } else {
196     die "Arch $arch is not supported with CONFIG_FTRACE_MCOUNT_RECORD";
197 }
198
199 my $text_found = 0;
200 my $read_function = 0;
201 my $opened = 0;
202 my $mcount_section = "__mcount_loc";
203
204 my $dirname;
205 my $filename;
206 my $prefix;
207 my $ext;
208
209 if ($inputfile =~ m,^(.*)/([^/]*)$,) {
210     $dirname = $1;
211     $filename = $2;
212 } else {
213     $dirname = ".";
214     $filename = $inputfile;
215 }
216
217 if ($filename =~ m,^(.*)(\.\S),) {
218     $prefix = $1;
219     $ext = $2;
220 } else {
221     $prefix = $filename;
222     $ext = "";
223 }
224
225 my $mcount_s = $dirname . "/.tmp_mc_" . $prefix . ".s";
226 my $mcount_o = $dirname . "/.tmp_mc_" . $prefix . ".o";
227
228 #
229 # --globalize-symbols came out in 2.17, we must test the version
230 # of objcopy, and if it is less than 2.17, then we can not
231 # record local functions.
232 my $use_locals = 01;
233 my $local_warn_once = 0;
234 my $found_version = 0;
235
236 open (IN, "$objcopy --version |") || die "error running $objcopy";
237 while (<IN>) {
238     if (/objcopy.*\s(\d+)\.(\d+)/) {
239         my $major = $1;
240         my $minor = $2;
241
242         $found_version = 1;
243         if ($major < 2 ||
244             ($major == 2 && $minor < 17)) {
245             $use_locals = 0;
246         }
247         last;
248     }
249 }
250 close (IN);
251
252 if (!$found_version) {
253     print STDERR "WARNING: could not find objcopy version.\n" .
254         "\tDisabling local function references.\n";
255 }
256
257
258 #
259 # Step 1: find all the local (static functions) and weak symbols.
260 #        't' is local, 'w/W' is weak (we never use a weak function)
261 #
262 open (IN, "$nm $inputfile|") || die "error running $nm";
263 while (<IN>) {
264     if (/$nm_regex/) {
265         $locals{$1} = 1;
266     } elsif (/^[0-9a-fA-F]+\s+([wW])\s+(\S+)/) {
267         $weak{$2} = $1;
268     }
269 }
270 close(IN);
271
272 my @offsets;            # Array of offsets of mcount callers
273 my $ref_func;           # reference function to use for offsets
274 my $offset = 0;         # offset of ref_func to section beginning
275
276 ##
277 # update_funcs - print out the current mcount callers
278 #
279 #  Go through the list of offsets to callers and write them to
280 #  the output file in a format that can be read by an assembler.
281 #
282 sub update_funcs
283 {
284     return if ($#offsets < 0);
285
286     defined($ref_func) || die "No function to reference";
287
288     # A section only had a weak function, to represent it.
289     # Unfortunately, a weak function may be overwritten by another
290     # function of the same name, making all these offsets incorrect.
291     # To be safe, we simply print a warning and bail.
292     if (defined $weak{$ref_func}) {
293         print STDERR
294             "$inputfile: WARNING: referencing weak function" .
295             " $ref_func for mcount\n";
296         return;
297     }
298
299     # is this function static? If so, note this fact.
300     if (defined $locals{$ref_func}) {
301
302         # only use locals if objcopy supports globalize-symbols
303         if (!$use_locals) {
304             return;
305         }
306         $convert{$ref_func} = 1;
307     }
308
309     # Loop through all the mcount caller offsets and print a reference
310     # to the caller based from the ref_func.
311     for (my $i=0; $i <= $#offsets; $i++) {
312         if (!$opened) {
313             open(FILE, ">$mcount_s") || die "can't create $mcount_s\n";
314             $opened = 1;
315             print FILE "\t.section $mcount_section,\"a\",\@progbits\n";
316             print FILE "\t.align $alignment\n" if (defined($alignment));
317         }
318         printf FILE "\t%s %s + %d\n", $type, $ref_func, $offsets[$i] - $offset;
319     }
320 }
321
322 #
323 # Step 2: find the sections and mcount call sites
324 #
325 open(IN, "$objdump -dr $inputfile|") || die "error running $objdump";
326
327 my $text;
328
329 while (<IN>) {
330     # is it a section?
331     if (/$section_regex/) {
332
333         # Only record text sections that we know are safe
334         if (defined($text_sections{$1})) {
335             $read_function = 1;
336         } else {
337             $read_function = 0;
338         }
339         # print out any recorded offsets
340         update_funcs() if ($text_found);
341
342         # reset all markers and arrays
343         $text_found = 0;
344         undef($ref_func);
345         undef(@offsets);
346
347     # section found, now is this a start of a function?
348     } elsif ($read_function && /$function_regex/) {
349         $text_found = 1;
350         $offset = hex $1;
351         $text = $2;
352
353         # if this is either a local function or a weak function
354         # keep looking for functions that are global that
355         # we can use safely.
356         if (!defined($locals{$text}) && !defined($weak{$text})) {
357             $ref_func = $text;
358             $read_function = 0;
359         } else {
360             # if we already have a function, and this is weak, skip it
361             if (!defined($ref_func) || !defined($weak{$text})) {
362                 $ref_func = $text;
363             }
364         }
365     }
366
367     # is this a call site to mcount? If so, record it to print later
368     if ($text_found && /$mcount_regex/) {
369         $offsets[$#offsets + 1] = hex $1;
370     }
371 }
372
373 # dump out anymore offsets that may have been found
374 update_funcs() if ($text_found);
375
376 # If we did not find any mcount callers, we are done (do nothing).
377 if (!$opened) {
378     exit(0);
379 }
380
381 close(FILE);
382
383 #
384 # Step 3: Compile the file that holds the list of call sites to mcount.
385 #
386 `$cc -o $mcount_o -c $mcount_s`;
387
388 my @converts = keys %convert;
389
390 #
391 # Step 4: Do we have sections that started with local functions?
392 #
393 if ($#converts >= 0) {
394     my $globallist = "";
395     my $locallist = "";
396
397     foreach my $con (@converts) {
398         $globallist .= " --globalize-symbol $con";
399         $locallist .= " --localize-symbol $con";
400     }
401
402     my $globalobj = $dirname . "/.tmp_gl_" . $filename;
403     my $globalmix = $dirname . "/.tmp_mx_" . $filename;
404
405     #
406     # Step 5: set up each local function as a global
407     #
408     `$objcopy $globallist $inputfile $globalobj`;
409
410     #
411     # Step 6: Link the global version to our list.
412     #
413     `$ld -r $globalobj $mcount_o -o $globalmix`;
414
415     #
416     # Step 7: Convert the local functions back into local symbols
417     #
418     `$objcopy $locallist $globalmix $inputfile`;
419
420     # Remove the temp files
421     `$rm $globalobj $globalmix`;
422
423 } else {
424
425     my $mix = $dirname . "/.tmp_mx_" . $filename;
426
427     #
428     # Step 8: Link the object with our list of call sites object.
429     #
430     `$ld -r $inputfile $mcount_o -o $mix`;
431
432     #
433     # Step 9: Move the result back to the original object.
434     #
435     `$mv $mix $inputfile`;
436 }
437
438 # Clean up the temp files
439 `$rm $mcount_o $mcount_s`;
440
441 exit(0);