checkpatch: add a "prefer __aligned" check
[linux-2.6.git] / scripts / headers_install.pl
1 #!/usr/bin/perl -w
2 #
3 # headers_install prepare the listed header files for use in
4 # user space and copy the files to their destination.
5 #
6 # Usage: headers_install.pl readdir installdir arch [files...]
7 # readdir:    dir to open files
8 # installdir: dir to install the files
9 # arch:       current architecture
10 #             arch is used to force a reinstallation when the arch
11 #             changes because kbuild then detect a command line change.
12 # files:      list of files to check
13 #
14 # Step in preparation for users space:
15 # 1) Drop all use of compiler.h definitions
16 # 2) Drop include of compiler.h
17 # 3) Drop all sections defined out by __KERNEL__ (using unifdef)
18
19 use strict;
20
21 my ($readdir, $installdir, $arch, @files) = @ARGV;
22
23 my $unifdef = "scripts/unifdef -U__KERNEL__ -D__EXPORTED_HEADERS__";
24
25 foreach my $file (@files) {
26         my $tmpfile = "$installdir/$file.tmp";
27
28         open(my $in, '<', "$readdir/$file")
29             or die "$readdir/$file: $!\n";
30         open(my $out, '>', $tmpfile)
31             or die "$tmpfile: $!\n";
32         while (my $line = <$in>) {
33                 $line =~ s/([\s(])__user\s/$1/g;
34                 $line =~ s/([\s(])__force\s/$1/g;
35                 $line =~ s/([\s(])__iomem\s/$1/g;
36                 $line =~ s/\s__attribute_const__\s/ /g;
37                 $line =~ s/\s__attribute_const__$//g;
38                 $line =~ s/^#include <linux\/compiler.h>//;
39                 $line =~ s/(^|\s)(inline)\b/$1__$2__/g;
40                 $line =~ s/(^|\s)(asm)\b(\s|[(]|$)/$1__$2__$3/g;
41                 $line =~ s/(^|\s|[(])(volatile)\b(\s|[(]|$)/$1__$2__$3/g;
42                 printf {$out} "%s", $line;
43         }
44         close $out;
45         close $in;
46
47         system $unifdef . " $tmpfile > $installdir/$file";
48         # unifdef will exit 0 on success, and will exit 1 when the
49         # file was processed successfully but no changes were made,
50         # so abort only when it's higher than that.
51         my $e = $? >> 8;
52         if ($e > 1) {
53                 die "$tmpfile: $!\n";
54         }
55         unlink $tmpfile;
56 }
57 exit 0;