find dynamic stack allocations in checkstack.pl
[linux-2.6.git] / scripts / checkstack.pl
1 #!/usr/bin/perl
2
3 #       Check the stack usage of functions
4 #
5 #       Copyright Joern Engel <joern@lazybastard.org>
6 #       Inspired by Linus Torvalds
7 #       Original idea maybe from Keith Owens
8 #       s390 port and big speedup by Arnd Bergmann <arnd@bergmann-dalldorf.de>
9 #       Mips port by Juan Quintela <quintela@mandrakesoft.com>
10 #       IA64 port via Andreas Dilger
11 #       Arm port by Holger Schurig
12 #       sh64 port by Paul Mundt
13 #       Random bits by Matt Mackall <mpm@selenic.com>
14 #       M68k port by Geert Uytterhoeven and Andreas Schwab
15 #       AVR32 port by Haavard Skinnemoen <hskinnemoen@atmel.com>
16 #       PARISC port by Kyle McMartin <kyle@parisc-linux.org>
17 #
18 #       Usage:
19 #       objdump -d vmlinux | scripts/checkstack.pl [arch]
20 #
21 #       TODO :  Port to all architectures (one regex per arch)
22
23 # check for arch
24 #
25 # $re is used for two matches:
26 # $& (whole re) matches the complete objdump line with the stack growth
27 # $1 (first bracket) matches the size of the stack growth
28 #
29 # $dre is similar, but for dynamic stack redutions:
30 # $& (whole re) matches the complete objdump line with the stack growth
31 # $1 (first bracket) matches the dynamic amount of the stack growth
32 #
33 # use anything else and feel the pain ;)
34 my (@stack, $re, $dre, $x, $xs);
35 {
36         my $arch = shift;
37         if ($arch eq "") {
38                 $arch = `uname -m`;
39         }
40
41         $x      = "[0-9a-f]";   # hex character
42         $xs     = "[0-9a-f ]";  # hex character or space
43         if ($arch eq 'arm') {
44                 #c0008ffc:      e24dd064        sub     sp, sp, #100    ; 0x64
45                 $re = qr/.*sub.*sp, sp, #(([0-9]{2}|[3-9])[0-9]{2})/o;
46         } elsif ($arch eq 'avr32') {
47                 #8000008a:       20 1d           sub sp,4
48                 #80000ca8:       fa cd 05 b0     sub sp,sp,1456
49                 $re = qr/^.*sub.*sp.*,([0-9]{1,8})/o;
50         } elsif ($arch =~ /^i[3456]86$/) {
51                 #c0105234:       81 ec ac 05 00 00       sub    $0x5ac,%esp
52                 $re = qr/^.*[as][du][db]    \$(0x$x{1,8}),\%esp$/o;
53                 $dre = qr/^.*[as][du][db]    (%.*),\%esp$/o;
54         } elsif ($arch eq 'x86_64') {
55                 #    2f60:      48 81 ec e8 05 00 00    sub    $0x5e8,%rsp
56                 $re = qr/^.*[as][du][db]    \$(0x$x{1,8}),\%rsp$/o;
57                 $dre = qr/^.*[as][du][db]    (\%.*),\%rsp$/o;
58         } elsif ($arch eq 'ia64') {
59                 #e0000000044011fc:       01 0f fc 8c     adds r12=-384,r12
60                 $re = qr/.*adds.*r12=-(([0-9]{2}|[3-9])[0-9]{2}),r12/o;
61         } elsif ($arch eq 'm68k') {
62                 #    2b6c:       4e56 fb70       linkw %fp,#-1168
63                 #  1df770:       defc ffe4       addaw #-28,%sp
64                 $re = qr/.*(?:linkw %fp,|addaw )#-([0-9]{1,4})(?:,%sp)?$/o;
65         } elsif ($arch eq 'mips64') {
66                 #8800402c:       67bdfff0        daddiu  sp,sp,-16
67                 $re = qr/.*daddiu.*sp,sp,-(([0-9]{2}|[3-9])[0-9]{2})/o;
68         } elsif ($arch eq 'mips') {
69                 #88003254:       27bdffe0        addiu   sp,sp,-32
70                 $re = qr/.*addiu.*sp,sp,-(([0-9]{2}|[3-9])[0-9]{2})/o;
71         } elsif ($arch eq 'parisc' || $arch eq 'parisc64') {
72                 $re = qr/.*ldo ($x{1,8})\(sp\),sp/o;
73         } elsif ($arch eq 'ppc') {
74                 #c00029f4:       94 21 ff 30     stwu    r1,-208(r1)
75                 $re = qr/.*stwu.*r1,-($x{1,8})\(r1\)/o;
76         } elsif ($arch eq 'ppc64') {
77                 #XXX
78                 $re = qr/.*stdu.*r1,-($x{1,8})\(r1\)/o;
79         } elsif ($arch eq 'powerpc') {
80                 $re = qr/.*st[dw]u.*r1,-($x{1,8})\(r1\)/o;
81         } elsif ($arch =~ /^s390x?$/) {
82                 #   11160:       a7 fb ff 60             aghi   %r15,-160
83                 $re = qr/.*ag?hi.*\%r15,-(([0-9]{2}|[3-9])[0-9]{2})/o;
84         } elsif ($arch =~ /^sh64$/) {
85                 #XXX: we only check for the immediate case presently,
86                 #     though we will want to check for the movi/sub
87                 #     pair for larger users. -- PFM.
88                 #a00048e0:       d4fc40f0        addi.l  r15,-240,r15
89                 $re = qr/.*addi\.l.*r15,-(([0-9]{2}|[3-9])[0-9]{2}),r15/o;
90         } elsif ($arch =~ /^blackfin$/) {
91                 #   0:   00 e8 38 01     LINK 0x4e0;
92                 $re = qr/.*[[:space:]]LINK[[:space:]]*(0x$x{1,8})/o;
93         } else {
94                 print("wrong or unknown architecture\n");
95                 exit
96         }
97 }
98
99 sub bysize($) {
100         my ($asize, $bsize);
101         ($asize = $a) =~ s/.*:  *(.*)$/$1/;
102         ($bsize = $b) =~ s/.*:  *(.*)$/$1/;
103         $bsize <=> $asize
104 }
105
106 #
107 # main()
108 #
109 my $funcre = qr/^$x* <(.*)>:$/;
110 my $func;
111 my $file, $lastslash;
112
113 while (my $line = <STDIN>) {
114         if ($line =~ m/$funcre/) {
115                 $func = $1;
116         }
117         elsif ($line =~ m/(.*):\s*file format/) {
118                 $file = $1;
119                 $file =~ s/\.ko//;
120                 $lastslash = rindex($file, "/");
121                 if ($lastslash != -1) {
122                         $file = substr($file, $lastslash + 1);
123                 }
124         }
125         elsif ($line =~ m/$re/) {
126                 my $size = $1;
127                 $size = hex($size) if ($size =~ /^0x/);
128
129                 if ($size > 0xf0000000) {
130                         $size = - $size;
131                         $size += 0x80000000;
132                         $size += 0x80000000;
133                 }
134                 next if ($size > 0x10000000);
135
136                 next if $line !~ m/^($xs*)/;
137                 my $addr = $1;
138                 $addr =~ s/ /0/g;
139                 $addr = "0x$addr";
140
141                 my $intro = "$addr $func [$file]:";
142                 my $padlen = 56 - length($intro);
143                 while ($padlen > 0) {
144                         $intro .= '     ';
145                         $padlen -= 8;
146                 }
147                 next if ($size < 100);
148                 push @stack, "$intro$size\n";
149         }
150         elsif (defined $dre && $line =~ m/$dre/) {
151                 my $size = "Dynamic ($1)";
152
153                 next if $line !~ m/^($xs*)/;
154                 my $addr = $1;
155                 $addr =~ s/ /0/g;
156                 $addr = "0x$addr";
157
158                 my $intro = "$addr $func [$file]:";
159                 my $padlen = 56 - length($intro);
160                 while ($padlen > 0) {
161                         $intro .= '     ';
162                         $padlen -= 8;
163                 }
164                 push @stack, "$intro$size\n";
165         }
166 }
167
168 print sort bysize @stack;